arch/x86/kernel/head_64.S

   1 /*
   2  *  linux/arch/x86_64/kernel/head.S -- start in 32bit and switch to 64bit
   3  *
   4  *  Copyright (C) 2000 Andrea Arcangeli <andrea@suse.de> SuSE
   5  *  Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
   6  *  Copyright (C) 2000 Karsten Keil <kkeil@suse.de>
   7  *  Copyright (C) 2001,2002 Andi Kleen <ak@suse.de>
   8  *  Copyright (C) 2005 Eric Biederman <ebiederm@xmission.com>
   9  */
  10
  11
  12 #include <linux/linkage.h>
  13 #include <linux/threads.h>
  14 #include <linux/init.h>
  15 #include <asm/segment.h>
  16 #include <asm/pgtable.h>
  17 #include <asm/page.h>
  18 #include <asm/msr.h>
  19 #include <asm/cache.h>
  20 #include <asm/processor-flags.h>
  21 #include <asm/percpu.h>
  22
  23 #ifdef CONFIG_PARAVIRT
  24 #include <asm/asm-offsets.h>
  25 #include <asm/paravirt.h>
  26 #else
  27 #define GET_CR2_INTO_RCX movq %cr2, %rcx
  28 #endif
  29
  30 /* we are not able to switch in one step to the final KERNEL ADDRESS SPACE
  31  * because we need identity-mapped pages.
  32  *
  33  */
  34
  35 #define pud_index(x)    (((x) >> PUD_SHIFT) & (PTRS_PER_PUD-1))
  36
  37 L4_PAGE_OFFSET = pgd_index(__PAGE_OFFSET)
  38 L3_PAGE_OFFSET = pud_index(__PAGE_OFFSET)
  39 L4_START_KERNEL = pgd_index(__START_KERNEL_map)
  40 L3_START_KERNEL = pud_index(__START_KERNEL_map)
  41
  42         .text
  43         __HEAD
  44         .code64
  45         .globl startup_64
  46 startup_64:
  47
  48         /*
  49          * At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 1,
  50          * and someone has loaded an identity mapped page table
  51          * for us.  These identity mapped page tables map all of the
  52          * kernel pages and possibly all of memory.
  53          *
  54          * %esi holds a physical pointer to real_mode_data.
  55          *
  56          * We come here either directly from a 64bit bootloader, or from
  57          * arch/x86_64/boot/compressed/head.S.
  58          *
  59          * We only come here initially at boot nothing else comes here.
  60          *
  61          * Since we may be loaded at an address different from what we were
  62          * compiled to run at we first fixup the physical addresses in our page
  63          * tables and then reload them.
  64          */
  65
  66         /* Sanitize CPU configuration */
  67         call verify_cpu
  68
  69         /* Compute the delta between the address I am compiled to run at and the
  70          * address I am actually running at.
  71          */
  72         leaq    _text(%rip), %rbp
  73         subq    $_text - __START_KERNEL_map, %rbp
  74
  75         /* Is the address not 2M aligned? */
  76         movq    %rbp, %rax
  77         andl    $~PMD_PAGE_MASK, %eax
  78         testl   %eax, %eax
  79         jnz     bad_address
  80
  81         /* Is the address too large? */
  82         leaq    _text(%rip), %rdx
  83         movq    $PGDIR_SIZE, %rax
  84         cmpq    %rax, %rdx
  85         jae     bad_address
  86
  87         /* Fixup the physical addresses in the page table
  88          */
  89         addq    %rbp, init_level4_pgt + 0(%rip)
  90         addq    %rbp, init_level4_pgt + (L4_PAGE_OFFSET*8)(%rip)
  91         addq    %rbp, init_level4_pgt + (L4_START_KERNEL*8)(%rip)
  92
  93         addq    %rbp, level3_ident_pgt + 0(%rip)
  94
  95         addq    %rbp, level3_kernel_pgt + (510*8)(%rip)
  96         addq    %rbp, level3_kernel_pgt + (511*8)(%rip)
  97
  98         addq    %rbp, level2_fixmap_pgt + (506*8)(%rip)
  99
 100         /* Add an Identity mapping if I am above 1G */
 101         leaq    _text(%rip), %rdi
 102         andq    $PMD_PAGE_MASK, %rdi
 103
 104         movq    %rdi, %rax
 105         shrq    $PUD_SHIFT, %rax
 106         andq    $(PTRS_PER_PUD - 1), %rax
 107         jz      ident_complete
 108
 109         leaq    (level2_spare_pgt - __START_KERNEL_map + _KERNPG_TABLE)(%rbp), %rdx
 110         leaq    level3_ident_pgt(%rip), %rbx
 111         movq    %rdx, 0(%rbx, %rax, 8)
 112
 113         movq    %rdi, %rax
 114         shrq    $PMD_SHIFT, %rax
 115         andq    $(PTRS_PER_PMD - 1), %rax
 116         leaq    __PAGE_KERNEL_IDENT_LARGE_EXEC(%rdi), %rdx
 117         leaq    level2_spare_pgt(%rip), %rbx
 118         movq    %rdx, 0(%rbx, %rax, 8)
 119 ident_complete:
 120
 121         /*
 122          * Fixup the kernel text+data virtual addresses. Note that
 123          * we might write invalid pmds, when the kernel is relocated
 124          * cleanup_highmap() fixes this up along with the mappings
 125          * beyond _end.
 126          */
 127
 128         leaq    level2_kernel_pgt(%rip), %rdi
 129         leaq    4096(%rdi), %r8
 130         /* See if it is a valid page table entry */
 131 1:      testq   $1, 0(%rdi)
 132         jz      2f
 133         addq    %rbp, 0(%rdi)
 134         /* Go to the next page */
 135 2:      addq    $8, %rdi
 136         cmp     %r8, %rdi
 137         jne     1b
 138
 139         /* Fixup phys_base */
 140         addq    %rbp, phys_base(%rip)
 141
 142         /* Fixup trampoline */
 143         addq    %rbp, trampoline_level4_pgt + 0(%rip)
 144         addq    %rbp, trampoline_level4_pgt + (511*8)(%rip)
 145
 146         /* Due to ENTRY(), sometimes the empty space gets filled with
 147          * zeros. Better take a jmp than relying on empty space being
 148          * filled with 0x90 (nop)
 149          */
 150         jmp secondary_startup_64
 151 ENTRY(secondary_startup_64)
 152         /*
 153          * At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 1,
 154          * and someone has loaded a mapped page table.
 155          *
 156          * %esi holds a physical pointer to real_mode_data.
 157          *
 158          * We come here either from startup_64 (using physical addresses)
 159          * or from trampoline.S (using virtual addresses).
 160          *
 161          * Using virtual addresses from trampoline.S removes the need
 162          * to have any identity mapped pages in the kernel page table
 163          * after the boot processor executes this code.
 164          */
 165
 166         /* Sanitize CPU configuration */
 167         call verify_cpu
 168
 169         /* Enable PAE mode and PGE */
 170         movl    $(X86_CR4_PAE | X86_CR4_PGE), %eax
 171         movq    %rax, %cr4
 172
 173         /* Setup early boot stage 4 level pagetables. */
 174         movq    $(init_level4_pgt - __START_KERNEL_map), %rax
 175         addq    phys_base(%rip), %rax
 176         movq    %rax, %cr3
 177
 178         /* Ensure I am executing from virtual addresses */
 179         movq    $1f, %rax
 180         jmp     *%rax
 181 1:
 182
 183         /* Check if nx is implemented */
 184         movl    $0x80000001, %eax
 185         cpuid
 186         movl    %edx,%edi
 187
 188         /* Setup EFER (Extended Feature Enable Register) */
 189         movl    $MSR_EFER, %ecx
 190         rdmsr
 191         btsl    $_EFER_SCE, %eax        /* Enable System Call */
 192         btl     $20,%edi                /* No Execute supported? */
 193         jnc     1f
 194         btsl    $_EFER_NX, %eax
 195 1:      wrmsr                           /* Make changes effective */
 196
 197         /* Setup cr0 */
 198 #define CR0_STATE       (X86_CR0_PE | X86_CR0_MP | X86_CR0_ET | \
 199                          X86_CR0_NE | X86_CR0_WP | X86_CR0_AM | \
 200                          X86_CR0_PG)
 201         movl    $CR0_STATE, %eax
 202         /* Make changes effective */
 203         movq    %rax, %cr0
 204
 205         /* Setup a boot time stack */
 206         movq stack_start(%rip),%rsp
 207
 208         /* zero EFLAGS after setting rsp */
 209         pushq $0
 210         popfq
 211
 212         /*
 213          * We must switch to a new descriptor in kernel space for the GDT
 214          * because soon the kernel won't have access anymore to the userspace
 215          * addresses where we're currently running on. We have to do that here
 216          * because in 32bit we couldn't load a 64bit linear address.
 217          */
 218         lgdt    early_gdt_descr(%rip)
 219
 220         /* set up data segments */
 221         xorl %eax,%eax
 222         movl %eax,%ds
 223         movl %eax,%ss
 224         movl %eax,%es
 225
 226         /*
 227          * We don't really need to load %fs or %gs, but load them anyway
 228          * to kill any stale realmode selectors.  This allows execution
 229          * under VT hardware.
 230          */
 231         movl %eax,%fs
 232         movl %eax,%gs
 233
 234         /* Set up %gs.
 235          *
 236          * The base of %gs always points to the bottom of the irqstack
 237          * union.  If the stack protector canary is enabled, it is
 238          * located at %gs:40.  Note that, on SMP, the boot cpu uses
 239          * init data section till per cpu areas are set up.
 240          */
 241         movl    $MSR_GS_BASE,%ecx
 242         movl    initial_gs(%rip),%eax
 243         movl    initial_gs+4(%rip),%edx
 244         wrmsr
 245
 246         /* esi is pointer to real mode structure with interesting info.
 247            pass it to C */
 248         movl    %esi, %edi
 249
 250         /* Finally jump to run C code and to be on real kernel address
 251          * Since we are running on identity-mapped space we have to jump
 252          * to the full 64bit address, this is only possible as indirect
 253          * jump.  In addition we need to ensure %cs is set so we make this
 254          * a far return.
 255          */
 256         movq    initial_code(%rip),%rax
 257         pushq   $0              # fake return address to stop unwinder
 258         pushq   $__KERNEL_CS    # set correct cs
 259         pushq   %rax            # target address in negative space
 260         lretq
 261
 262 #include "verify_cpu.S"
 263
 264         /* SMP bootup changes these two */
 265         __REFDATA
 266         .align  8
 267         ENTRY(initial_code)
 268         .quad   x86_64_start_kernel
 269         ENTRY(initial_gs)
 270         .quad   INIT_PER_CPU_VAR(irq_stack_union)
 271
 272         ENTRY(stack_start)
 273         .quad  init_thread_union+THREAD_SIZE-8
 274         .word  0
 275         __FINITDATA
 276
 277 bad_address:
 278         jmp bad_address
 279
 280         .section ".init.text","ax"
 281 #ifdef CONFIG_EARLY_PRINTK
 282         .globl early_idt_handlers
 283 early_idt_handlers:
 284         i = 0
 285         .rept NUM_EXCEPTION_VECTORS
 286         movl $i, %esi
 287         jmp early_idt_handler
 288         i = i + 1
 289         .endr
 290 #endif
 291
 292 ENTRY(early_idt_handler)
 293 #ifdef CONFIG_EARLY_PRINTK
 294         cmpl $2,early_recursion_flag(%rip)
 295         jz  1f
 296         incl early_recursion_flag(%rip)
 297         GET_CR2_INTO_RCX
 298         movq %rcx,%r9
 299         xorl %r8d,%r8d          # zero for error code
 300         movl %esi,%ecx          # get vector number
 301         # Test %ecx against mask of vectors that push error code.
 302         cmpl $31,%ecx
 303         ja 0f
 304         movl $1,%eax
 305         salq %cl,%rax
 306         testl $0x27d00,%eax
 307         je 0f
 308         popq %r8                # get error code
 309 0:      movq 0(%rsp),%rcx       # get ip
 310         movq 8(%rsp),%rdx       # get cs
 311         xorl %eax,%eax
 312         leaq early_idt_msg(%rip),%rdi
 313         call early_printk
 314         cmpl $2,early_recursion_flag(%rip)
 315         jz  1f
 316         call dump_stack
 317 #ifdef CONFIG_KALLSYMS
 318         leaq early_idt_ripmsg(%rip),%rdi
 319         movq 0(%rsp),%rsi       # get rip again
 320         call __print_symbol
 321 #endif
 322 #endif /* EARLY_PRINTK */
 323 1:      hlt
 324         jmp 1b
 325
 326 #ifdef CONFIG_EARLY_PRINTK
 327 early_recursion_flag:
 328         .long 0
 329
 330 early_idt_msg:
 331         .asciz "PANIC: early exception %02lx rip %lx:%lx error %lx cr2 %lx\n"
 332 early_idt_ripmsg:
 333         .asciz "RIP %s\n"
 334 #endif /* CONFIG_EARLY_PRINTK */
 335         .previous
 336
 337 #define NEXT_PAGE(name) \
 338         .balign PAGE_SIZE; \
 339 ENTRY(name)
 340
 341 /* Automate the creation of 1 to 1 mapping pmd entries */
 342 #define PMDS(START, PERM, COUNT)                        \
 343         i = 0 ;                                         \
 344         .rept (COUNT) ;                                 \
 345         .quad   (START) + (i << PMD_SHIFT) + (PERM) ;   \
 346         i = i + 1 ;                                     \
 347         .endr
 348
 349         .data
 350         /*
 351          * This default setting generates an ident mapping at address 0x100000
 352          * and a mapping for the kernel that precisely maps virtual address
 353          * 0xffffffff80000000 to physical address 0x000000. (always using
 354          * 2Mbyte large pages provided by PAE mode)
 355          */
 356 NEXT_PAGE(init_level4_pgt)
 357         .quad   level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
 358         .org    init_level4_pgt + L4_PAGE_OFFSET*8, 0
 359         .quad   level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
 360         .org    init_level4_pgt + L4_START_KERNEL*8, 0
 361         /* (2^48-(2*1024*1024*1024))/(2^39) = 511 */
 362         .quad   level3_kernel_pgt - __START_KERNEL_map + _PAGE_TABLE
 363
 364 NEXT_PAGE(level3_ident_pgt)
 365         .quad   level2_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
 366         .fill   511,8,0
 367
 368 NEXT_PAGE(level3_kernel_pgt)
 369         .fill   L3_START_KERNEL,8,0
 370         /* (2^48-(2*1024*1024*1024)-((2^39)*511))/(2^30) = 510 */
 371         .quad   level2_kernel_pgt - __START_KERNEL_map + _KERNPG_TABLE
 372         .quad   level2_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE
 373
 374 NEXT_PAGE(level2_fixmap_pgt)
 375         .fill   506,8,0
 376         .quad   level1_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE
 377         /* 8MB reserved for vsyscalls + a 2MB hole = 4 + 1 entries */
 378         .fill   5,8,0
 379
 380 NEXT_PAGE(level1_fixmap_pgt)
 381         .fill   512,8,0
 382
 383 NEXT_PAGE(level2_ident_pgt)
 384         /* Since I easily can, map the first 1G.
 385          * Don't set NX because code runs from these pages.
 386          */
 387         PMDS(0, __PAGE_KERNEL_IDENT_LARGE_EXEC, PTRS_PER_PMD)
 388
 389 NEXT_PAGE(level2_kernel_pgt)
 390         /*
 391          * 512 MB kernel mapping. We spend a full page on this pagetable
 392          * anyway.
 393          *
 394          * The kernel code+data+bss must not be bigger than that.
 395          *
 396          * (NOTE: at +512MB starts the module area, see MODULES_VADDR.
 397          *  If you want to increase this then increase MODULES_VADDR
 398          *  too.)
 399          */
 400         PMDS(0, __PAGE_KERNEL_LARGE_EXEC,
 401                 KERNEL_IMAGE_SIZE/PMD_SIZE)
 402
 403 NEXT_PAGE(level2_spare_pgt)
 404         .fill   512, 8, 0
 405
 406 #undef PMDS
 407 #undef NEXT_PAGE
 408
 409         .data
 410         .align 16
 411         .globl early_gdt_descr
 412 early_gdt_descr:
 413         .word   GDT_ENTRIES*8-1
 414 early_gdt_descr_base:
 415         .quad   INIT_PER_CPU_VAR(gdt_page)
 416
 417 ENTRY(phys_base)
 418         /* This must match the first entry in level2_kernel_pgt */
 419         .quad   0x0000000000000000
 420
 421 #include "../../x86/xen/xen-head.S"
 422
 423         .section .bss, "aw", @nobits
 424         .align L1_CACHE_BYTES
 425 ENTRY(idt_table)
 426         .skip IDT_ENTRIES * 16
 427
 428         __PAGE_ALIGNED_BSS
 429         .align PAGE_SIZE
 430 ENTRY(empty_zero_page)
 431         .skip PAGE_SIZE