arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page_types.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/percpu.h>
  56
  57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  58 #include <linux/elf-em.h>
  59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  60 #define __AUDIT_ARCH_64BIT 0x80000000
  61 #define __AUDIT_ARCH_LE    0x40000000
  62
  63         .code64
  64 #ifdef CONFIG_FUNCTION_TRACER
  65 #ifdef CONFIG_DYNAMIC_FTRACE
  66 ENTRY(mcount)
  67         retq
  68 END(mcount)
  69
  70 ENTRY(ftrace_caller)
  71         cmpl $0, function_trace_stop
  72         jne  ftrace_stub
  73
  74         MCOUNT_SAVE_FRAME
  75
  76         movq 0x38(%rsp), %rdi
  77         movq 8(%rbp), %rsi
  78         subq $MCOUNT_INSN_SIZE, %rdi
  79
  80 GLOBAL(ftrace_call)
  81         call ftrace_stub
  82
  83         MCOUNT_RESTORE_FRAME
  84
  85 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  86 GLOBAL(ftrace_graph_call)
  87         jmp ftrace_stub
  88 #endif
  89
  90 GLOBAL(ftrace_stub)
  91         retq
  92 END(ftrace_caller)
  93
  94 #else /* ! CONFIG_DYNAMIC_FTRACE */
  95 ENTRY(mcount)
  96         cmpl $0, function_trace_stop
  97         jne  ftrace_stub
  98
  99         cmpq $ftrace_stub, ftrace_trace_function
 100         jnz trace
 101
 102 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 103         cmpq $ftrace_stub, ftrace_graph_return
 104         jnz ftrace_graph_caller
 105
 106         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 107         jnz ftrace_graph_caller
 108 #endif
 109
 110 GLOBAL(ftrace_stub)
 111         retq
 112
 113 trace:
 114         MCOUNT_SAVE_FRAME
 115
 116         movq 0x38(%rsp), %rdi
 117         movq 8(%rbp), %rsi
 118         subq $MCOUNT_INSN_SIZE, %rdi
 119
 120         call   *ftrace_trace_function
 121
 122         MCOUNT_RESTORE_FRAME
 123
 124         jmp ftrace_stub
 125 END(mcount)
 126 #endif /* CONFIG_DYNAMIC_FTRACE */
 127 #endif /* CONFIG_FUNCTION_TRACER */
 128
 129 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 130 ENTRY(ftrace_graph_caller)
 131         cmpl $0, function_trace_stop
 132         jne ftrace_stub
 133
 134         MCOUNT_SAVE_FRAME
 135
 136         leaq 8(%rbp), %rdi
 137         movq 0x38(%rsp), %rsi
 138         movq (%rbp), %rdx
 139         subq $MCOUNT_INSN_SIZE, %rsi
 140
 141         call    prepare_ftrace_return
 142
 143         MCOUNT_RESTORE_FRAME
 144
 145         retq
 146 END(ftrace_graph_caller)
 147
 148 GLOBAL(return_to_handler)
 149         subq  $80, %rsp
 150
 151         /* Save the return values */
 152         movq %rax, (%rsp)
 153         movq %rdx, 8(%rsp)
 154         movq %rbp, %rdi
 155
 156         call ftrace_return_to_handler
 157
 158         movq %rax, 72(%rsp)
 159         movq 8(%rsp), %rdx
 160         movq (%rsp), %rax
 161         addq $72, %rsp
 162         retq
 163 #endif
 164
 165
 166 #ifndef CONFIG_PREEMPT
 167 #define retint_kernel retint_restore_args
 168 #endif
 169
 170 #ifdef CONFIG_PARAVIRT
 171 ENTRY(native_usergs_sysret64)
 172         swapgs
 173         sysretq
 174 ENDPROC(native_usergs_sysret64)
 175 #endif /* CONFIG_PARAVIRT */
 176
 177
 178 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 179 #ifdef CONFIG_TRACE_IRQFLAGS
 180         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 181         jnc  1f
 182         TRACE_IRQS_ON
 183 1:
 184 #endif
 185 .endm
 186
 187 /*
 188  * C code is not supposed to know about undefined top of stack. Every time
 189  * a C function with an pt_regs argument is called from the SYSCALL based
 190  * fast path FIXUP_TOP_OF_STACK is needed.
 191  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 192  * manipulation.
 193  */
 194
 195         /* %rsp:at FRAMEEND */
 196         .macro FIXUP_TOP_OF_STACK tmp offset=0
 197         movq PER_CPU_VAR(old_rsp),\tmp
 198         movq \tmp,RSP+\offset(%rsp)
 199         movq $__USER_DS,SS+\offset(%rsp)
 200         movq $__USER_CS,CS+\offset(%rsp)
 201         movq $-1,RCX+\offset(%rsp)
 202         movq R11+\offset(%rsp),\tmp  /* get eflags */
 203         movq \tmp,EFLAGS+\offset(%rsp)
 204         .endm
 205
 206         .macro RESTORE_TOP_OF_STACK tmp offset=0
 207         movq RSP+\offset(%rsp),\tmp
 208         movq \tmp,PER_CPU_VAR(old_rsp)
 209         movq EFLAGS+\offset(%rsp),\tmp
 210         movq \tmp,R11+\offset(%rsp)
 211         .endm
 212
 213         .macro FAKE_STACK_FRAME child_rip
 214         /* push in order ss, rsp, eflags, cs, rip */
 215         xorl %eax, %eax
 216         pushq $__KERNEL_DS /* ss */
 217         CFI_ADJUST_CFA_OFFSET   8
 218         /*CFI_REL_OFFSET        ss,0*/
 219         pushq %rax /* rsp */
 220         CFI_ADJUST_CFA_OFFSET   8
 221         CFI_REL_OFFSET  rsp,0
 222         pushq $X86_EFLAGS_IF /* eflags - interrupts on */
 223         CFI_ADJUST_CFA_OFFSET   8
 224         /*CFI_REL_OFFSET        rflags,0*/
 225         pushq $__KERNEL_CS /* cs */
 226         CFI_ADJUST_CFA_OFFSET   8
 227         /*CFI_REL_OFFSET        cs,0*/
 228         pushq \child_rip /* rip */
 229         CFI_ADJUST_CFA_OFFSET   8
 230         CFI_REL_OFFSET  rip,0
 231         pushq   %rax /* orig rax */
 232         CFI_ADJUST_CFA_OFFSET   8
 233         .endm
 234
 235         .macro UNFAKE_STACK_FRAME
 236         addq $8*6, %rsp
 237         CFI_ADJUST_CFA_OFFSET   -(6*8)
 238         .endm
 239
 240 /*
 241  * initial frame state for interrupts (and exceptions without error code)
 242  */
 243         .macro EMPTY_FRAME start=1 offset=0
 244         .if \start
 245         CFI_STARTPROC simple
 246         CFI_SIGNAL_FRAME
 247         CFI_DEF_CFA rsp,8+\offset
 248         .else
 249         CFI_DEF_CFA_OFFSET 8+\offset
 250         .endif
 251         .endm
 252
 253 /*
 254  * initial frame state for interrupts (and exceptions without error code)
 255  */
 256         .macro INTR_FRAME start=1 offset=0
 257         EMPTY_FRAME \start, SS+8+\offset-RIP
 258         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 259         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 260         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 261         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 262         CFI_REL_OFFSET rip, RIP+\offset-RIP
 263         .endm
 264
 265 /*
 266  * initial frame state for exceptions with error code (and interrupts
 267  * with vector already pushed)
 268  */
 269         .macro XCPT_FRAME start=1 offset=0
 270         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 271         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 272         .endm
 273
 274 /*
 275  * frame that enables calling into C.
 276  */
 277         .macro PARTIAL_FRAME start=1 offset=0
 278         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 283         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 286         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 287         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 288         .endm
 289
 290 /*
 291  * frame that enables passing a complete pt_regs to a C function.
 292  */
 293         .macro DEFAULT_FRAME start=1 offset=0
 294         PARTIAL_FRAME \start, R11+\offset-R15
 295         CFI_REL_OFFSET rbx, RBX+\offset
 296         CFI_REL_OFFSET rbp, RBP+\offset
 297         CFI_REL_OFFSET r12, R12+\offset
 298         CFI_REL_OFFSET r13, R13+\offset
 299         CFI_REL_OFFSET r14, R14+\offset
 300         CFI_REL_OFFSET r15, R15+\offset
 301         .endm
 302
 303 /* save partial stack frame */
 304 ENTRY(save_args)
 305         XCPT_FRAME
 306         cld
 307         movq_cfi rdi, RDI+16-ARGOFFSET
 308         movq_cfi rsi, RSI+16-ARGOFFSET
 309         movq_cfi rdx, RDX+16-ARGOFFSET
 310         movq_cfi rcx, RCX+16-ARGOFFSET
 311         movq_cfi rax, RAX+16-ARGOFFSET
 312         movq_cfi  r8,  R8+16-ARGOFFSET
 313         movq_cfi  r9,  R9+16-ARGOFFSET
 314         movq_cfi r10, R10+16-ARGOFFSET
 315         movq_cfi r11, R11+16-ARGOFFSET
 316
 317         leaq -ARGOFFSET+16(%rsp),%rdi   /* arg1 for handler */
 318         movq_cfi rbp, 8         /* push %rbp */
 319         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 320         testl $3, CS(%rdi)
 321         je 1f
 322         SWAPGS
 323         /*
 324          * irq_count is used to check if a CPU is already on an interrupt stack
 325          * or not. While this is essentially redundant with preempt_count it is
 326          * a little cheaper to use a separate counter in the PDA (short of
 327          * moving irq_enter into assembly, which would be too much work)
 328          */
 329 1:      incl PER_CPU_VAR(irq_count)
 330         jne 2f
 331         popq_cfi %rax                   /* move return address... */
 332         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 333         EMPTY_FRAME 0
 334         pushq_cfi %rbp                  /* backlink for unwinder */
 335         pushq_cfi %rax                  /* ... to the new stack */
 336         /*
 337          * We entered an interrupt context - irqs are off:
 338          */
 339 2:      TRACE_IRQS_OFF
 340         ret
 341         CFI_ENDPROC
 342 END(save_args)
 343
 344 ENTRY(save_rest)
 345         PARTIAL_FRAME 1 REST_SKIP+8
 346         movq 5*8+16(%rsp), %r11 /* save return address */
 347         movq_cfi rbx, RBX+16
 348         movq_cfi rbp, RBP+16
 349         movq_cfi r12, R12+16
 350         movq_cfi r13, R13+16
 351         movq_cfi r14, R14+16
 352         movq_cfi r15, R15+16
 353         movq %r11, 8(%rsp)      /* return address */
 354         FIXUP_TOP_OF_STACK %r11, 16
 355         ret
 356         CFI_ENDPROC
 357 END(save_rest)
 358
 359 /* save complete stack frame */
 360         .pushsection .kprobes.text, "ax"
 361 ENTRY(save_paranoid)
 362         XCPT_FRAME 1 RDI+8
 363         cld
 364         movq_cfi rdi, RDI+8
 365         movq_cfi rsi, RSI+8
 366         movq_cfi rdx, RDX+8
 367         movq_cfi rcx, RCX+8
 368         movq_cfi rax, RAX+8
 369         movq_cfi r8, R8+8
 370         movq_cfi r9, R9+8
 371         movq_cfi r10, R10+8
 372         movq_cfi r11, R11+8
 373         movq_cfi rbx, RBX+8
 374         movq_cfi rbp, RBP+8
 375         movq_cfi r12, R12+8
 376         movq_cfi r13, R13+8
 377         movq_cfi r14, R14+8
 378         movq_cfi r15, R15+8
 379         movl $1,%ebx
 380         movl $MSR_GS_BASE,%ecx
 381         rdmsr
 382         testl %edx,%edx
 383         js 1f   /* negative -> in kernel */
 384         SWAPGS
 385         xorl %ebx,%ebx
 386 1:      ret
 387         CFI_ENDPROC
 388 END(save_paranoid)
 389         .popsection
 390
 391 /*
 392  * A newly forked process directly context switches into this address.
 393  *
 394  * rdi: prev task we switched from
 395  */
 396 ENTRY(ret_from_fork)
 397         DEFAULT_FRAME
 398
 399         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 400
 401         push kernel_eflags(%rip)
 402         CFI_ADJUST_CFA_OFFSET 8
 403         popf                                    # reset kernel eflags
 404         CFI_ADJUST_CFA_OFFSET -8
 405
 406         call schedule_tail                      # rdi: 'prev' task parameter
 407
 408         GET_THREAD_INFO(%rcx)
 409
 410         RESTORE_REST
 411
 412         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 413         je   int_ret_from_sys_call
 414
 415         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 416         jnz  int_ret_from_sys_call
 417
 418         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 419         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 420
 421         CFI_ENDPROC
 422 END(ret_from_fork)
 423
 424 /*
 425  * System call entry. Upto 6 arguments in registers are supported.
 426  *
 427  * SYSCALL does not save anything on the stack and does not change the
 428  * stack pointer.
 429  */
 430
 431 /*
 432  * Register setup:
 433  * rax  system call number
 434  * rdi  arg0
 435  * rcx  return address for syscall/sysret, C arg3
 436  * rsi  arg1
 437  * rdx  arg2
 438  * r10  arg3    (--> moved to rcx for C)
 439  * r8   arg4
 440  * r9   arg5
 441  * r11  eflags for syscall/sysret, temporary for C
 442  * r12-r15,rbp,rbx saved by C code, not touched.
 443  *
 444  * Interrupts are off on entry.
 445  * Only called from user space.
 446  *
 447  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 448  *      and report it properly in ps. Unfortunately we haven't.
 449  *
 450  * When user can change the frames always force IRET. That is because
 451  * it deals with uncanonical addresses better. SYSRET has trouble
 452  * with them due to bugs in both AMD and Intel CPUs.
 453  */
 454
 455 ENTRY(system_call)
 456         CFI_STARTPROC   simple
 457         CFI_SIGNAL_FRAME
 458         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 459         CFI_REGISTER    rip,rcx
 460         /*CFI_REGISTER  rflags,r11*/
 461         SWAPGS_UNSAFE_STACK
 462         /*
 463          * A hypervisor implementation might want to use a label
 464          * after the swapgs, so that it can do the swapgs
 465          * for the guest and jump here on syscall.
 466          */
 467 ENTRY(system_call_after_swapgs)
 468
 469         movq    %rsp,PER_CPU_VAR(old_rsp)
 470         movq    PER_CPU_VAR(kernel_stack),%rsp
 471         /*
 472          * No need to follow this irqs off/on section - it's straight
 473          * and short:
 474          */
 475         ENABLE_INTERRUPTS(CLBR_NONE)
 476         SAVE_ARGS 8,1
 477         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 478         movq  %rcx,RIP-ARGOFFSET(%rsp)
 479         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 480         GET_THREAD_INFO(%rcx)
 481         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 482         jnz tracesys
 483 system_call_fastpath:
 484         cmpq $__NR_syscall_max,%rax
 485         ja badsys
 486         movq %r10,%rcx
 487         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 488         movq %rax,RAX-ARGOFFSET(%rsp)
 489 /*
 490  * Syscall return path ending with SYSRET (fast path)
 491  * Has incomplete stack frame and undefined top of stack.
 492  */
 493 ret_from_sys_call:
 494         movl $_TIF_ALLWORK_MASK,%edi
 495         /* edi: flagmask */
 496 sysret_check:
 497         LOCKDEP_SYS_EXIT
 498         GET_THREAD_INFO(%rcx)
 499         DISABLE_INTERRUPTS(CLBR_NONE)
 500         TRACE_IRQS_OFF
 501         movl TI_flags(%rcx),%edx
 502         andl %edi,%edx
 503         jnz  sysret_careful
 504         CFI_REMEMBER_STATE
 505         /*
 506          * sysretq will re-enable interrupts:
 507          */
 508         TRACE_IRQS_ON
 509         movq RIP-ARGOFFSET(%rsp),%rcx
 510         CFI_REGISTER    rip,rcx
 511         RESTORE_ARGS 0,-ARG_SKIP,1
 512         /*CFI_REGISTER  rflags,r11*/
 513         movq    PER_CPU_VAR(old_rsp), %rsp
 514         USERGS_SYSRET64
 515
 516         CFI_RESTORE_STATE
 517         /* Handle reschedules */
 518         /* edx: work, edi: workmask */
 519 sysret_careful:
 520         bt $TIF_NEED_RESCHED,%edx
 521         jnc sysret_signal
 522         TRACE_IRQS_ON
 523         ENABLE_INTERRUPTS(CLBR_NONE)
 524         pushq %rdi
 525         CFI_ADJUST_CFA_OFFSET 8
 526         call schedule
 527         popq  %rdi
 528         CFI_ADJUST_CFA_OFFSET -8
 529         jmp sysret_check
 530
 531         /* Handle a signal */
 532 sysret_signal:
 533         TRACE_IRQS_ON
 534         ENABLE_INTERRUPTS(CLBR_NONE)
 535 #ifdef CONFIG_AUDITSYSCALL
 536         bt $TIF_SYSCALL_AUDIT,%edx
 537         jc sysret_audit
 538 #endif
 539         /* edx: work flags (arg3) */
 540         leaq -ARGOFFSET(%rsp),%rdi # &pt_regs -> arg1
 541         xorl %esi,%esi # oldset -> arg2
 542         SAVE_REST
 543         FIXUP_TOP_OF_STACK %r11
 544         call do_notify_resume
 545         RESTORE_TOP_OF_STACK %r11
 546         RESTORE_REST
 547         movl $_TIF_WORK_MASK,%edi
 548         /* Use IRET because user could have changed frame. This
 549            works because ptregscall_common has called FIXUP_TOP_OF_STACK. */
 550         DISABLE_INTERRUPTS(CLBR_NONE)
 551         TRACE_IRQS_OFF
 552         jmp int_with_check
 553
 554 badsys:
 555         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 556         jmp ret_from_sys_call
 557
 558 #ifdef CONFIG_AUDITSYSCALL
 559         /*
 560          * Fast path for syscall audit without full syscall trace.
 561          * We just call audit_syscall_entry() directly, and then
 562          * jump back to the normal fast path.
 563          */
 564 auditsys:
 565         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 566         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 567         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 568         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 569         movq %rax,%rsi                  /* 2nd arg: syscall number */
 570         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 571         call audit_syscall_entry
 572         LOAD_ARGS 0             /* reload call-clobbered registers */
 573         jmp system_call_fastpath
 574
 575         /*
 576          * Return fast path for syscall audit.  Call audit_syscall_exit()
 577          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 578          * masked off.
 579          */
 580 sysret_audit:
 581         movq %rax,%rsi          /* second arg, syscall return value */
 582         cmpq $0,%rax            /* is it < 0? */
 583         setl %al                /* 1 if so, 0 if not */
 584         movzbl %al,%edi         /* zero-extend that into %edi */
 585         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 586         call audit_syscall_exit
 587         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 588         jmp sysret_check
 589 #endif  /* CONFIG_AUDITSYSCALL */
 590
 591         /* Do syscall tracing */
 592 tracesys:
 593 #ifdef CONFIG_AUDITSYSCALL
 594         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 595         jz auditsys
 596 #endif
 597         SAVE_REST
 598         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 599         FIXUP_TOP_OF_STACK %rdi
 600         movq %rsp,%rdi
 601         call syscall_trace_enter
 602         /*
 603          * Reload arg registers from stack in case ptrace changed them.
 604          * We don't reload %rax because syscall_trace_enter() returned
 605          * the value it wants us to use in the table lookup.
 606          */
 607         LOAD_ARGS ARGOFFSET, 1
 608         RESTORE_REST
 609         cmpq $__NR_syscall_max,%rax
 610         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 611         movq %r10,%rcx  /* fixup for C */
 612         call *sys_call_table(,%rax,8)
 613         movq %rax,RAX-ARGOFFSET(%rsp)
 614         /* Use IRET because user could have changed frame */
 615
 616 /*
 617  * Syscall return path ending with IRET.
 618  * Has correct top of stack, but partial stack frame.
 619  */
 620 GLOBAL(int_ret_from_sys_call)
 621         DISABLE_INTERRUPTS(CLBR_NONE)
 622         TRACE_IRQS_OFF
 623         testl $3,CS-ARGOFFSET(%rsp)
 624         je retint_restore_args
 625         movl $_TIF_ALLWORK_MASK,%edi
 626         /* edi: mask to check */
 627 GLOBAL(int_with_check)
 628         LOCKDEP_SYS_EXIT_IRQ
 629         GET_THREAD_INFO(%rcx)
 630         movl TI_flags(%rcx),%edx
 631         andl %edi,%edx
 632         jnz   int_careful
 633         andl    $~TS_COMPAT,TI_status(%rcx)
 634         jmp   retint_swapgs
 635
 636         /* Either reschedule or signal or syscall exit tracking needed. */
 637         /* First do a reschedule test. */
 638         /* edx: work, edi: workmask */
 639 int_careful:
 640         bt $TIF_NEED_RESCHED,%edx
 641         jnc  int_very_careful
 642         TRACE_IRQS_ON
 643         ENABLE_INTERRUPTS(CLBR_NONE)
 644         pushq %rdi
 645         CFI_ADJUST_CFA_OFFSET 8
 646         call schedule
 647         popq %rdi
 648         CFI_ADJUST_CFA_OFFSET -8
 649         DISABLE_INTERRUPTS(CLBR_NONE)
 650         TRACE_IRQS_OFF
 651         jmp int_with_check
 652
 653         /* handle signals and tracing -- both require a full stack frame */
 654 int_very_careful:
 655         TRACE_IRQS_ON
 656         ENABLE_INTERRUPTS(CLBR_NONE)
 657         SAVE_REST
 658         /* Check for syscall exit trace */
 659         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 660         jz int_signal
 661         pushq %rdi
 662         CFI_ADJUST_CFA_OFFSET 8
 663         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 664         call syscall_trace_leave
 665         popq %rdi
 666         CFI_ADJUST_CFA_OFFSET -8
 667         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 668         jmp int_restore_rest
 669
 670 int_signal:
 671         testl $_TIF_DO_NOTIFY_MASK,%edx
 672         jz 1f
 673         movq %rsp,%rdi          # &ptregs -> arg1
 674         xorl %esi,%esi          # oldset -> arg2
 675         call do_notify_resume
 676 1:      movl $_TIF_WORK_MASK,%edi
 677 int_restore_rest:
 678         RESTORE_REST
 679         DISABLE_INTERRUPTS(CLBR_NONE)
 680         TRACE_IRQS_OFF
 681         jmp int_with_check
 682         CFI_ENDPROC
 683 END(system_call)
 684
 685 /*
 686  * Certain special system calls that need to save a complete full stack frame.
 687  */
 688         .macro PTREGSCALL label,func,arg
 689 ENTRY(\label)
 690         PARTIAL_FRAME 1 8               /* offset 8: return address */
 691         subq $REST_SKIP, %rsp
 692         CFI_ADJUST_CFA_OFFSET REST_SKIP
 693         call save_rest
 694         DEFAULT_FRAME 0 8               /* offset 8: return address */
 695         leaq 8(%rsp), \arg      /* pt_regs pointer */
 696         call \func
 697         jmp ptregscall_common
 698         CFI_ENDPROC
 699 END(\label)
 700         .endm
 701
 702         PTREGSCALL stub_clone, sys_clone, %r8
 703         PTREGSCALL stub_fork, sys_fork, %rdi
 704         PTREGSCALL stub_vfork, sys_vfork, %rdi
 705         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 706         PTREGSCALL stub_iopl, sys_iopl, %rsi
 707
 708 ENTRY(ptregscall_common)
 709         DEFAULT_FRAME 1 8       /* offset 8: return address */
 710         RESTORE_TOP_OF_STACK %r11, 8
 711         movq_cfi_restore R15+8, r15
 712         movq_cfi_restore R14+8, r14
 713         movq_cfi_restore R13+8, r13
 714         movq_cfi_restore R12+8, r12
 715         movq_cfi_restore RBP+8, rbp
 716         movq_cfi_restore RBX+8, rbx
 717         ret $REST_SKIP          /* pop extended registers */
 718         CFI_ENDPROC
 719 END(ptregscall_common)
 720
 721 ENTRY(stub_execve)
 722         CFI_STARTPROC
 723         popq %r11
 724         CFI_ADJUST_CFA_OFFSET -8
 725         CFI_REGISTER rip, r11
 726         SAVE_REST
 727         FIXUP_TOP_OF_STACK %r11
 728         movq %rsp, %rcx
 729         call sys_execve
 730         RESTORE_TOP_OF_STACK %r11
 731         movq %rax,RAX(%rsp)
 732         RESTORE_REST
 733         jmp int_ret_from_sys_call
 734         CFI_ENDPROC
 735 END(stub_execve)
 736
 737 /*
 738  * sigreturn is special because it needs to restore all registers on return.
 739  * This cannot be done with SYSRET, so use the IRET return path instead.
 740  */
 741 ENTRY(stub_rt_sigreturn)
 742         CFI_STARTPROC
 743         addq $8, %rsp
 744         CFI_ADJUST_CFA_OFFSET   -8
 745         SAVE_REST
 746         movq %rsp,%rdi
 747         FIXUP_TOP_OF_STACK %r11
 748         call sys_rt_sigreturn
 749         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 750         RESTORE_REST
 751         jmp int_ret_from_sys_call
 752         CFI_ENDPROC
 753 END(stub_rt_sigreturn)
 754
 755 /*
 756  * Build the entry stubs and pointer table with some assembler magic.
 757  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 758  * single cache line on all modern x86 implementations.
 759  */
 760         .section .init.rodata,"a"
 761 ENTRY(interrupt)
 762         .text
 763         .p2align 5
 764         .p2align CONFIG_X86_L1_CACHE_SHIFT
 765 ENTRY(irq_entries_start)
 766         INTR_FRAME
 767 vector=FIRST_EXTERNAL_VECTOR
 768 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 769         .balign 32
 770   .rept 7
 771     .if vector < NR_VECTORS
 772       .if vector <> FIRST_EXTERNAL_VECTOR
 773         CFI_ADJUST_CFA_OFFSET -8
 774       .endif
 775 1:      pushq $(~vector+0x80)   /* Note: always in signed byte range */
 776         CFI_ADJUST_CFA_OFFSET 8
 777       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 778         jmp 2f
 779       .endif
 780       .previous
 781         .quad 1b
 782       .text
 783 vector=vector+1
 784     .endif
 785   .endr
 786 2:      jmp common_interrupt
 787 .endr
 788         CFI_ENDPROC
 789 END(irq_entries_start)
 790
 791 .previous
 792 END(interrupt)
 793 .previous
 794
 795 /*
 796  * Interrupt entry/exit.
 797  *
 798  * Interrupt entry points save only callee clobbered registers in fast path.
 799  *
 800  * Entry runs with interrupts off.
 801  */
 802
 803 /* 0(%rsp): ~(interrupt number) */
 804         .macro interrupt func
 805         subq $10*8, %rsp
 806         CFI_ADJUST_CFA_OFFSET 10*8
 807         call save_args
 808         PARTIAL_FRAME 0
 809         call \func
 810         .endm
 811
 812 /*
 813  * Interrupt entry/exit should be protected against kprobes
 814  */
 815         .pushsection .kprobes.text, "ax"
 816         /*
 817          * The interrupt stubs push (~vector+0x80) onto the stack and
 818          * then jump to common_interrupt.
 819          */
 820         .p2align CONFIG_X86_L1_CACHE_SHIFT
 821 common_interrupt:
 822         XCPT_FRAME
 823         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 824         interrupt do_IRQ
 825         /* 0(%rsp): old_rsp-ARGOFFSET */
 826 ret_from_intr:
 827         DISABLE_INTERRUPTS(CLBR_NONE)
 828         TRACE_IRQS_OFF
 829         decl PER_CPU_VAR(irq_count)
 830         leaveq
 831         CFI_DEF_CFA_REGISTER    rsp
 832         CFI_ADJUST_CFA_OFFSET   -8
 833 exit_intr:
 834         GET_THREAD_INFO(%rcx)
 835         testl $3,CS-ARGOFFSET(%rsp)
 836         je retint_kernel
 837
 838         /* Interrupt came from user space */
 839         /*
 840          * Has a correct top of stack, but a partial stack frame
 841          * %rcx: thread info. Interrupts off.
 842          */
 843 retint_with_reschedule:
 844         movl $_TIF_WORK_MASK,%edi
 845 retint_check:
 846         LOCKDEP_SYS_EXIT_IRQ
 847         movl TI_flags(%rcx),%edx
 848         andl %edi,%edx
 849         CFI_REMEMBER_STATE
 850         jnz  retint_careful
 851
 852 retint_swapgs:          /* return to user-space */
 853         /*
 854          * The iretq could re-enable interrupts:
 855          */
 856         DISABLE_INTERRUPTS(CLBR_ANY)
 857         TRACE_IRQS_IRETQ
 858         SWAPGS
 859         jmp restore_args
 860
 861 retint_restore_args:    /* return to kernel space */
 862         DISABLE_INTERRUPTS(CLBR_ANY)
 863         /*
 864          * The iretq could re-enable interrupts:
 865          */
 866         TRACE_IRQS_IRETQ
 867 restore_args:
 868         RESTORE_ARGS 0,8,0
 869
 870 irq_return:
 871         INTERRUPT_RETURN
 872
 873         .section __ex_table, "a"
 874         .quad irq_return, bad_iret
 875         .previous
 876
 877 #ifdef CONFIG_PARAVIRT
 878 ENTRY(native_iret)
 879         iretq
 880
 881         .section __ex_table,"a"
 882         .quad native_iret, bad_iret
 883         .previous
 884 #endif
 885
 886         .section .fixup,"ax"
 887 bad_iret:
 888         /*
 889          * The iret traps when the %cs or %ss being restored is bogus.
 890          * We've lost the original trap vector and error code.
 891          * #GPF is the most likely one to get for an invalid selector.
 892          * So pretend we completed the iret and took the #GPF in user mode.
 893          *
 894          * We are now running with the kernel GS after exception recovery.
 895          * But error_entry expects us to have user GS to match the user %cs,
 896          * so swap back.
 897          */
 898         pushq $0
 899
 900         SWAPGS
 901         jmp general_protection
 902
 903         .previous
 904
 905         /* edi: workmask, edx: work */
 906 retint_careful:
 907         CFI_RESTORE_STATE
 908         bt    $TIF_NEED_RESCHED,%edx
 909         jnc   retint_signal
 910         TRACE_IRQS_ON
 911         ENABLE_INTERRUPTS(CLBR_NONE)
 912         pushq %rdi
 913         CFI_ADJUST_CFA_OFFSET   8
 914         call  schedule
 915         popq %rdi
 916         CFI_ADJUST_CFA_OFFSET   -8
 917         GET_THREAD_INFO(%rcx)
 918         DISABLE_INTERRUPTS(CLBR_NONE)
 919         TRACE_IRQS_OFF
 920         jmp retint_check
 921
 922 retint_signal:
 923         testl $_TIF_DO_NOTIFY_MASK,%edx
 924         jz    retint_swapgs
 925         TRACE_IRQS_ON
 926         ENABLE_INTERRUPTS(CLBR_NONE)
 927         SAVE_REST
 928         movq $-1,ORIG_RAX(%rsp)
 929         xorl %esi,%esi          # oldset
 930         movq %rsp,%rdi          # &pt_regs
 931         call do_notify_resume
 932         RESTORE_REST
 933         DISABLE_INTERRUPTS(CLBR_NONE)
 934         TRACE_IRQS_OFF
 935         GET_THREAD_INFO(%rcx)
 936         jmp retint_with_reschedule
 937
 938 #ifdef CONFIG_PREEMPT
 939         /* Returning to kernel space. Check if we need preemption */
 940         /* rcx:  threadinfo. interrupts off. */
 941 ENTRY(retint_kernel)
 942         cmpl $0,TI_preempt_count(%rcx)
 943         jnz  retint_restore_args
 944         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 945         jnc  retint_restore_args
 946         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 947         jnc  retint_restore_args
 948         call preempt_schedule_irq
 949         jmp exit_intr
 950 #endif
 951
 952         CFI_ENDPROC
 953 END(common_interrupt)
 954 /*
 955  * End of kprobes section
 956  */
 957        .popsection
 958
 959 /*
 960  * APIC interrupts.
 961  */
 962 .macro apicinterrupt num sym do_sym
 963 ENTRY(\sym)
 964         INTR_FRAME
 965         pushq $~(\num)
 966         CFI_ADJUST_CFA_OFFSET 8
 967         interrupt \do_sym
 968         jmp ret_from_intr
 969         CFI_ENDPROC
 970 END(\sym)
 971 .endm
 972
 973 #ifdef CONFIG_SMP
 974 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 975         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 976 apicinterrupt REBOOT_VECTOR \
 977         reboot_interrupt smp_reboot_interrupt
 978 #endif
 979
 980 #ifdef CONFIG_X86_UV
 981 apicinterrupt UV_BAU_MESSAGE \
 982         uv_bau_message_intr1 uv_bau_message_interrupt
 983 #endif
 984 apicinterrupt LOCAL_TIMER_VECTOR \
 985         apic_timer_interrupt smp_apic_timer_interrupt
 986 apicinterrupt GENERIC_INTERRUPT_VECTOR \
 987         generic_interrupt smp_generic_interrupt
 988
 989 #ifdef CONFIG_SMP
 990 apicinterrupt INVALIDATE_TLB_VECTOR_START+0 \
 991         invalidate_interrupt0 smp_invalidate_interrupt
 992 apicinterrupt INVALIDATE_TLB_VECTOR_START+1 \
 993         invalidate_interrupt1 smp_invalidate_interrupt
 994 apicinterrupt INVALIDATE_TLB_VECTOR_START+2 \
 995         invalidate_interrupt2 smp_invalidate_interrupt
 996 apicinterrupt INVALIDATE_TLB_VECTOR_START+3 \
 997         invalidate_interrupt3 smp_invalidate_interrupt
 998 apicinterrupt INVALIDATE_TLB_VECTOR_START+4 \
 999         invalidate_interrupt4 smp_invalidate_interrupt
1000 apicinterrupt INVALIDATE_TLB_VECTOR_START+5 \
1001         invalidate_interrupt5 smp_invalidate_interrupt
1002 apicinterrupt INVALIDATE_TLB_VECTOR_START+6 \
1003         invalidate_interrupt6 smp_invalidate_interrupt
1004 apicinterrupt INVALIDATE_TLB_VECTOR_START+7 \
1005         invalidate_interrupt7 smp_invalidate_interrupt
1006 #endif
1007
1008 apicinterrupt THRESHOLD_APIC_VECTOR \
1009         threshold_interrupt smp_threshold_interrupt
1010 apicinterrupt THERMAL_APIC_VECTOR \
1011         thermal_interrupt smp_thermal_interrupt
1012
1013 #ifdef CONFIG_X86_MCE
1014 apicinterrupt MCE_SELF_VECTOR \
1015         mce_self_interrupt smp_mce_self_interrupt
1016 #endif
1017
1018 #ifdef CONFIG_SMP
1019 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1020         call_function_single_interrupt smp_call_function_single_interrupt
1021 apicinterrupt CALL_FUNCTION_VECTOR \
1022         call_function_interrupt smp_call_function_interrupt
1023 apicinterrupt RESCHEDULE_VECTOR \
1024         reschedule_interrupt smp_reschedule_interrupt
1025 #endif
1026
1027 apicinterrupt ERROR_APIC_VECTOR \
1028         error_interrupt smp_error_interrupt
1029 apicinterrupt SPURIOUS_APIC_VECTOR \
1030         spurious_interrupt smp_spurious_interrupt
1031
1032 #ifdef CONFIG_PERF_COUNTERS
1033 apicinterrupt LOCAL_PENDING_VECTOR \
1034         perf_pending_interrupt smp_perf_pending_interrupt
1035 #endif
1036
1037 /*
1038  * Exception entry points.
1039  */
1040 .macro zeroentry sym do_sym
1041 ENTRY(\sym)
1042         INTR_FRAME
1043         PARAVIRT_ADJUST_EXCEPTION_FRAME
1044         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1045         subq $15*8,%rsp
1046         CFI_ADJUST_CFA_OFFSET 15*8
1047         call error_entry
1048         DEFAULT_FRAME 0
1049         movq %rsp,%rdi          /* pt_regs pointer */
1050         xorl %esi,%esi          /* no error code */
1051         call \do_sym
1052         jmp error_exit          /* %ebx: no swapgs flag */
1053         CFI_ENDPROC
1054 END(\sym)
1055 .endm
1056
1057 .macro paranoidzeroentry sym do_sym
1058 ENTRY(\sym)
1059         INTR_FRAME
1060         PARAVIRT_ADJUST_EXCEPTION_FRAME
1061         pushq $-1               /* ORIG_RAX: no syscall to restart */
1062         CFI_ADJUST_CFA_OFFSET 8
1063         subq $15*8, %rsp
1064         call save_paranoid
1065         TRACE_IRQS_OFF
1066         movq %rsp,%rdi          /* pt_regs pointer */
1067         xorl %esi,%esi          /* no error code */
1068         call \do_sym
1069         jmp paranoid_exit       /* %ebx: no swapgs flag */
1070         CFI_ENDPROC
1071 END(\sym)
1072 .endm
1073
1074 .macro paranoidzeroentry_ist sym do_sym ist
1075 ENTRY(\sym)
1076         INTR_FRAME
1077         PARAVIRT_ADJUST_EXCEPTION_FRAME
1078         pushq $-1               /* ORIG_RAX: no syscall to restart */
1079         CFI_ADJUST_CFA_OFFSET 8
1080         subq $15*8, %rsp
1081         call save_paranoid
1082         TRACE_IRQS_OFF
1083         movq %rsp,%rdi          /* pt_regs pointer */
1084         xorl %esi,%esi          /* no error code */
1085         PER_CPU(init_tss, %rbp)
1086         subq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1087         call \do_sym
1088         addq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1089         jmp paranoid_exit       /* %ebx: no swapgs flag */
1090         CFI_ENDPROC
1091 END(\sym)
1092 .endm
1093
1094 .macro errorentry sym do_sym
1095 ENTRY(\sym)
1096         XCPT_FRAME
1097         PARAVIRT_ADJUST_EXCEPTION_FRAME
1098         subq $15*8,%rsp
1099         CFI_ADJUST_CFA_OFFSET 15*8
1100         call error_entry
1101         DEFAULT_FRAME 0
1102         movq %rsp,%rdi                  /* pt_regs pointer */
1103         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1104         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1105         call \do_sym
1106         jmp error_exit                  /* %ebx: no swapgs flag */
1107         CFI_ENDPROC
1108 END(\sym)
1109 .endm
1110
1111         /* error code is on the stack already */
1112 .macro paranoiderrorentry sym do_sym
1113 ENTRY(\sym)
1114         XCPT_FRAME
1115         PARAVIRT_ADJUST_EXCEPTION_FRAME
1116         subq $15*8,%rsp
1117         CFI_ADJUST_CFA_OFFSET 15*8
1118         call save_paranoid
1119         DEFAULT_FRAME 0
1120         TRACE_IRQS_OFF
1121         movq %rsp,%rdi                  /* pt_regs pointer */
1122         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1123         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1124         call \do_sym
1125         jmp paranoid_exit               /* %ebx: no swapgs flag */
1126         CFI_ENDPROC
1127 END(\sym)
1128 .endm
1129
1130 zeroentry divide_error do_divide_error
1131 zeroentry overflow do_overflow
1132 zeroentry bounds do_bounds
1133 zeroentry invalid_op do_invalid_op
1134 zeroentry device_not_available do_device_not_available
1135 paranoiderrorentry double_fault do_double_fault
1136 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1137 errorentry invalid_TSS do_invalid_TSS
1138 errorentry segment_not_present do_segment_not_present
1139 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1140 zeroentry coprocessor_error do_coprocessor_error
1141 errorentry alignment_check do_alignment_check
1142 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1143
1144         /* Reload gs selector with exception handling */
1145         /* edi:  new selector */
1146 ENTRY(native_load_gs_index)
1147         CFI_STARTPROC
1148         pushf
1149         CFI_ADJUST_CFA_OFFSET 8
1150         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1151         SWAPGS
1152 gs_change:
1153         movl %edi,%gs
1154 2:      mfence          /* workaround */
1155         SWAPGS
1156         popf
1157         CFI_ADJUST_CFA_OFFSET -8
1158         ret
1159         CFI_ENDPROC
1160 END(native_load_gs_index)
1161
1162         .section __ex_table,"a"
1163         .align 8
1164         .quad gs_change,bad_gs
1165         .previous
1166         .section .fixup,"ax"
1167         /* running with kernelgs */
1168 bad_gs:
1169         SWAPGS                  /* switch back to user gs */
1170         xorl %eax,%eax
1171         movl %eax,%gs
1172         jmp  2b
1173         .previous
1174
1175 /*
1176  * Create a kernel thread.
1177  *
1178  * C extern interface:
1179  *      extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
1180  *
1181  * asm input arguments:
1182  *      rdi: fn, rsi: arg, rdx: flags
1183  */
1184 ENTRY(kernel_thread)
1185         CFI_STARTPROC
1186         FAKE_STACK_FRAME $child_rip
1187         SAVE_ALL
1188
1189         # rdi: flags, rsi: usp, rdx: will be &pt_regs
1190         movq %rdx,%rdi
1191         orq  kernel_thread_flags(%rip),%rdi
1192         movq $-1, %rsi
1193         movq %rsp, %rdx
1194
1195         xorl %r8d,%r8d
1196         xorl %r9d,%r9d
1197
1198         # clone now
1199         call do_fork
1200         movq %rax,RAX(%rsp)
1201         xorl %edi,%edi
1202
1203         /*
1204          * It isn't worth to check for reschedule here,
1205          * so internally to the x86_64 port you can rely on kernel_thread()
1206          * not to reschedule the child before returning, this avoids the need
1207          * of hacks for example to fork off the per-CPU idle tasks.
1208          * [Hopefully no generic code relies on the reschedule -AK]
1209          */
1210         RESTORE_ALL
1211         UNFAKE_STACK_FRAME
1212         ret
1213         CFI_ENDPROC
1214 END(kernel_thread)
1215
1216 ENTRY(child_rip)
1217         pushq $0                # fake return address
1218         CFI_STARTPROC
1219         /*
1220          * Here we are in the child and the registers are set as they were
1221          * at kernel_thread() invocation in the parent.
1222          */
1223         movq %rdi, %rax
1224         movq %rsi, %rdi
1225         call *%rax
1226         # exit
1227         mov %eax, %edi
1228         call do_exit
1229         ud2                     # padding for call trace
1230         CFI_ENDPROC
1231 END(child_rip)
1232
1233 /*
1234  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1235  *
1236  * C extern interface:
1237  *       extern long execve(char *name, char **argv, char **envp)
1238  *
1239  * asm input arguments:
1240  *      rdi: name, rsi: argv, rdx: envp
1241  *
1242  * We want to fallback into:
1243  *      extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1244  *
1245  * do_sys_execve asm fallback arguments:
1246  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1247  */
1248 ENTRY(kernel_execve)
1249         CFI_STARTPROC
1250         FAKE_STACK_FRAME $0
1251         SAVE_ALL
1252         movq %rsp,%rcx
1253         call sys_execve
1254         movq %rax, RAX(%rsp)
1255         RESTORE_REST
1256         testq %rax,%rax
1257         je int_ret_from_sys_call
1258         RESTORE_ARGS
1259         UNFAKE_STACK_FRAME
1260         ret
1261         CFI_ENDPROC
1262 END(kernel_execve)
1263
1264 /* Call softirq on interrupt stack. Interrupts are off. */
1265 ENTRY(call_softirq)
1266         CFI_STARTPROC
1267         push %rbp
1268         CFI_ADJUST_CFA_OFFSET   8
1269         CFI_REL_OFFSET rbp,0
1270         mov  %rsp,%rbp
1271         CFI_DEF_CFA_REGISTER rbp
1272         incl PER_CPU_VAR(irq_count)
1273         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1274         push  %rbp                      # backlink for old unwinder
1275         call __do_softirq
1276         leaveq
1277         CFI_DEF_CFA_REGISTER    rsp
1278         CFI_ADJUST_CFA_OFFSET   -8
1279         decl PER_CPU_VAR(irq_count)
1280         ret
1281         CFI_ENDPROC
1282 END(call_softirq)
1283
1284 #ifdef CONFIG_XEN
1285 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1286
1287 /*
1288  * A note on the "critical region" in our callback handler.
1289  * We want to avoid stacking callback handlers due to events occurring
1290  * during handling of the last event. To do this, we keep events disabled
1291  * until we've done all processing. HOWEVER, we must enable events before
1292  * popping the stack frame (can't be done atomically) and so it would still
1293  * be possible to get enough handler activations to overflow the stack.
1294  * Although unlikely, bugs of that kind are hard to track down, so we'd
1295  * like to avoid the possibility.
1296  * So, on entry to the handler we detect whether we interrupted an
1297  * existing activation in its critical region -- if so, we pop the current
1298  * activation and restart the handler using the previous one.
1299  */
1300 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1301         CFI_STARTPROC
1302 /*
1303  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1304  * see the correct pointer to the pt_regs
1305  */
1306         movq %rdi, %rsp            # we don't return, adjust the stack frame
1307         CFI_ENDPROC
1308         DEFAULT_FRAME
1309 11:     incl PER_CPU_VAR(irq_count)
1310         movq %rsp,%rbp
1311         CFI_DEF_CFA_REGISTER rbp
1312         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1313         pushq %rbp                      # backlink for old unwinder
1314         call xen_evtchn_do_upcall
1315         popq %rsp
1316         CFI_DEF_CFA_REGISTER rsp
1317         decl PER_CPU_VAR(irq_count)
1318         jmp  error_exit
1319         CFI_ENDPROC
1320 END(do_hypervisor_callback)
1321
1322 /*
1323  * Hypervisor uses this for application faults while it executes.
1324  * We get here for two reasons:
1325  *  1. Fault while reloading DS, ES, FS or GS
1326  *  2. Fault while executing IRET
1327  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1328  * registers that could be reloaded and zeroed the others.
1329  * Category 2 we fix up by killing the current process. We cannot use the
1330  * normal Linux return path in this case because if we use the IRET hypercall
1331  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1332  * We distinguish between categories by comparing each saved segment register
1333  * with its current contents: any discrepancy means we in category 1.
1334  */
1335 ENTRY(xen_failsafe_callback)
1336         INTR_FRAME 1 (6*8)
1337         /*CFI_REL_OFFSET gs,GS*/
1338         /*CFI_REL_OFFSET fs,FS*/
1339         /*CFI_REL_OFFSET es,ES*/
1340         /*CFI_REL_OFFSET ds,DS*/
1341         CFI_REL_OFFSET r11,8
1342         CFI_REL_OFFSET rcx,0
1343         movw %ds,%cx
1344         cmpw %cx,0x10(%rsp)
1345         CFI_REMEMBER_STATE
1346         jne 1f
1347         movw %es,%cx
1348         cmpw %cx,0x18(%rsp)
1349         jne 1f
1350         movw %fs,%cx
1351         cmpw %cx,0x20(%rsp)
1352         jne 1f
1353         movw %gs,%cx
1354         cmpw %cx,0x28(%rsp)
1355         jne 1f
1356         /* All segments match their saved values => Category 2 (Bad IRET). */
1357         movq (%rsp),%rcx
1358         CFI_RESTORE rcx
1359         movq 8(%rsp),%r11
1360         CFI_RESTORE r11
1361         addq $0x30,%rsp
1362         CFI_ADJUST_CFA_OFFSET -0x30
1363         pushq_cfi $0    /* RIP */
1364         pushq_cfi %r11
1365         pushq_cfi %rcx
1366         jmp general_protection
1367         CFI_RESTORE_STATE
1368 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1369         movq (%rsp),%rcx
1370         CFI_RESTORE rcx
1371         movq 8(%rsp),%r11
1372         CFI_RESTORE r11
1373         addq $0x30,%rsp
1374         CFI_ADJUST_CFA_OFFSET -0x30
1375         pushq_cfi $0
1376         SAVE_ALL
1377         jmp error_exit
1378         CFI_ENDPROC
1379 END(xen_failsafe_callback)
1380
1381 #endif /* CONFIG_XEN */
1382
1383 /*
1384  * Some functions should be protected against kprobes
1385  */
1386         .pushsection .kprobes.text, "ax"
1387
1388 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1389 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1390 paranoiderrorentry stack_segment do_stack_segment
1391 #ifdef CONFIG_XEN
1392 zeroentry xen_debug do_debug
1393 zeroentry xen_int3 do_int3
1394 errorentry xen_stack_segment do_stack_segment
1395 #endif
1396 errorentry general_protection do_general_protection
1397 errorentry page_fault do_page_fault
1398 #ifdef CONFIG_X86_MCE
1399 paranoidzeroentry machine_check *machine_check_vector(%rip)
1400 #endif
1401
1402         /*
1403          * "Paranoid" exit path from exception stack.
1404          * Paranoid because this is used by NMIs and cannot take
1405          * any kernel state for granted.
1406          * We don't do kernel preemption checks here, because only
1407          * NMI should be common and it does not enable IRQs and
1408          * cannot get reschedule ticks.
1409          *
1410          * "trace" is 0 for the NMI handler only, because irq-tracing
1411          * is fundamentally NMI-unsafe. (we cannot change the soft and
1412          * hard flags at once, atomically)
1413          */
1414
1415         /* ebx: no swapgs flag */
1416 ENTRY(paranoid_exit)
1417         INTR_FRAME
1418         DISABLE_INTERRUPTS(CLBR_NONE)
1419         TRACE_IRQS_OFF
1420         testl %ebx,%ebx                         /* swapgs needed? */
1421         jnz paranoid_restore
1422         testl $3,CS(%rsp)
1423         jnz   paranoid_userspace
1424 paranoid_swapgs:
1425         TRACE_IRQS_IRETQ 0
1426         SWAPGS_UNSAFE_STACK
1427         RESTORE_ALL 8
1428         jmp irq_return
1429 paranoid_restore:
1430         TRACE_IRQS_IRETQ 0
1431         RESTORE_ALL 8
1432         jmp irq_return
1433 paranoid_userspace:
1434         GET_THREAD_INFO(%rcx)
1435         movl TI_flags(%rcx),%ebx
1436         andl $_TIF_WORK_MASK,%ebx
1437         jz paranoid_swapgs
1438         movq %rsp,%rdi                  /* &pt_regs */
1439         call sync_regs
1440         movq %rax,%rsp                  /* switch stack for scheduling */
1441         testl $_TIF_NEED_RESCHED,%ebx
1442         jnz paranoid_schedule
1443         movl %ebx,%edx                  /* arg3: thread flags */
1444         TRACE_IRQS_ON
1445         ENABLE_INTERRUPTS(CLBR_NONE)
1446         xorl %esi,%esi                  /* arg2: oldset */
1447         movq %rsp,%rdi                  /* arg1: &pt_regs */
1448         call do_notify_resume
1449         DISABLE_INTERRUPTS(CLBR_NONE)
1450         TRACE_IRQS_OFF
1451         jmp paranoid_userspace
1452 paranoid_schedule:
1453         TRACE_IRQS_ON
1454         ENABLE_INTERRUPTS(CLBR_ANY)
1455         call schedule
1456         DISABLE_INTERRUPTS(CLBR_ANY)
1457         TRACE_IRQS_OFF
1458         jmp paranoid_userspace
1459         CFI_ENDPROC
1460 END(paranoid_exit)
1461
1462 /*
1463  * Exception entry point. This expects an error code/orig_rax on the stack.
1464  * returns in "no swapgs flag" in %ebx.
1465  */
1466 ENTRY(error_entry)
1467         XCPT_FRAME
1468         CFI_ADJUST_CFA_OFFSET 15*8
1469         /* oldrax contains error code */
1470         cld
1471         movq_cfi rdi, RDI+8
1472         movq_cfi rsi, RSI+8
1473         movq_cfi rdx, RDX+8
1474         movq_cfi rcx, RCX+8
1475         movq_cfi rax, RAX+8
1476         movq_cfi  r8,  R8+8
1477         movq_cfi  r9,  R9+8
1478         movq_cfi r10, R10+8
1479         movq_cfi r11, R11+8
1480         movq_cfi rbx, RBX+8
1481         movq_cfi rbp, RBP+8
1482         movq_cfi r12, R12+8
1483         movq_cfi r13, R13+8
1484         movq_cfi r14, R14+8
1485         movq_cfi r15, R15+8
1486         xorl %ebx,%ebx
1487         testl $3,CS+8(%rsp)
1488         je error_kernelspace
1489 error_swapgs:
1490         SWAPGS
1491 error_sti:
1492         TRACE_IRQS_OFF
1493         ret
1494         CFI_ENDPROC
1495
1496 /*
1497  * There are two places in the kernel that can potentially fault with
1498  * usergs. Handle them here. The exception handlers after iret run with
1499  * kernel gs again, so don't set the user space flag. B stepping K8s
1500  * sometimes report an truncated RIP for IRET exceptions returning to
1501  * compat mode. Check for these here too.
1502  */
1503 error_kernelspace:
1504         incl %ebx
1505         leaq irq_return(%rip),%rcx
1506         cmpq %rcx,RIP+8(%rsp)
1507         je error_swapgs
1508         movl %ecx,%ecx  /* zero extend */
1509         cmpq %rcx,RIP+8(%rsp)
1510         je error_swapgs
1511         cmpq $gs_change,RIP+8(%rsp)
1512         je error_swapgs
1513         jmp error_sti
1514 END(error_entry)
1515
1516
1517 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1518 ENTRY(error_exit)
1519         DEFAULT_FRAME
1520         movl %ebx,%eax
1521         RESTORE_REST
1522         DISABLE_INTERRUPTS(CLBR_NONE)
1523         TRACE_IRQS_OFF
1524         GET_THREAD_INFO(%rcx)
1525         testl %eax,%eax
1526         jne retint_kernel
1527         LOCKDEP_SYS_EXIT_IRQ
1528         movl TI_flags(%rcx),%edx
1529         movl $_TIF_WORK_MASK,%edi
1530         andl %edi,%edx
1531         jnz retint_careful
1532         jmp retint_swapgs
1533         CFI_ENDPROC
1534 END(error_exit)
1535
1536
1537         /* runs on exception stack */
1538 ENTRY(nmi)
1539         INTR_FRAME
1540         PARAVIRT_ADJUST_EXCEPTION_FRAME
1541         pushq_cfi $-1
1542         subq $15*8, %rsp
1543         CFI_ADJUST_CFA_OFFSET 15*8
1544         call save_paranoid
1545         DEFAULT_FRAME 0
1546         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1547         movq %rsp,%rdi
1548         movq $-1,%rsi
1549         call do_nmi
1550 #ifdef CONFIG_TRACE_IRQFLAGS
1551         /* paranoidexit; without TRACE_IRQS_OFF */
1552         /* ebx: no swapgs flag */
1553         DISABLE_INTERRUPTS(CLBR_NONE)
1554         testl %ebx,%ebx                         /* swapgs needed? */
1555         jnz nmi_restore
1556         testl $3,CS(%rsp)
1557         jnz nmi_userspace
1558 nmi_swapgs:
1559         SWAPGS_UNSAFE_STACK
1560 nmi_restore:
1561         RESTORE_ALL 8
1562         jmp irq_return
1563 nmi_userspace:
1564         GET_THREAD_INFO(%rcx)
1565         movl TI_flags(%rcx),%ebx
1566         andl $_TIF_WORK_MASK,%ebx
1567         jz nmi_swapgs
1568         movq %rsp,%rdi                  /* &pt_regs */
1569         call sync_regs
1570         movq %rax,%rsp                  /* switch stack for scheduling */
1571         testl $_TIF_NEED_RESCHED,%ebx
1572         jnz nmi_schedule
1573         movl %ebx,%edx                  /* arg3: thread flags */
1574         ENABLE_INTERRUPTS(CLBR_NONE)
1575         xorl %esi,%esi                  /* arg2: oldset */
1576         movq %rsp,%rdi                  /* arg1: &pt_regs */
1577         call do_notify_resume
1578         DISABLE_INTERRUPTS(CLBR_NONE)
1579         jmp nmi_userspace
1580 nmi_schedule:
1581         ENABLE_INTERRUPTS(CLBR_ANY)
1582         call schedule
1583         DISABLE_INTERRUPTS(CLBR_ANY)
1584         jmp nmi_userspace
1585         CFI_ENDPROC
1586 #else
1587         jmp paranoid_exit
1588         CFI_ENDPROC
1589 #endif
1590 END(nmi)
1591
1592 ENTRY(ignore_sysret)
1593         CFI_STARTPROC
1594         mov $-ENOSYS,%eax
1595         sysret
1596         CFI_ENDPROC
1597 END(ignore_sysret)
1598
1599 /*
1600  * End of kprobes section
1601  */
1602         .popsection