arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/pgtable_types.h>
  59
  60 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  61 #include <linux/elf-em.h>
  62 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  63 #define __AUDIT_ARCH_64BIT 0x80000000
  64 #define __AUDIT_ARCH_LE    0x40000000
  65
  66         .code64
  67         .section .entry.text, "ax"
  68
  69 #ifdef CONFIG_FUNCTION_TRACER
  70 #ifdef CONFIG_DYNAMIC_FTRACE
  71 ENTRY(mcount)
  72         retq
  73 END(mcount)
  74
  75 ENTRY(ftrace_caller)
  76         cmpl $0, function_trace_stop
  77         jne  ftrace_stub
  78
  79         MCOUNT_SAVE_FRAME
  80
  81         movq 0x38(%rsp), %rdi
  82         movq 8(%rbp), %rsi
  83         subq $MCOUNT_INSN_SIZE, %rdi
  84
  85 GLOBAL(ftrace_call)
  86         call ftrace_stub
  87
  88         MCOUNT_RESTORE_FRAME
  89
  90 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  91 GLOBAL(ftrace_graph_call)
  92         jmp ftrace_stub
  93 #endif
  94
  95 GLOBAL(ftrace_stub)
  96         retq
  97 END(ftrace_caller)
  98
  99 #else /* ! CONFIG_DYNAMIC_FTRACE */
 100 ENTRY(mcount)
 101         cmpl $0, function_trace_stop
 102         jne  ftrace_stub
 103
 104         cmpq $ftrace_stub, ftrace_trace_function
 105         jnz trace
 106
 107 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 108         cmpq $ftrace_stub, ftrace_graph_return
 109         jnz ftrace_graph_caller
 110
 111         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 112         jnz ftrace_graph_caller
 113 #endif
 114
 115 GLOBAL(ftrace_stub)
 116         retq
 117
 118 trace:
 119         MCOUNT_SAVE_FRAME
 120
 121         movq 0x38(%rsp), %rdi
 122         movq 8(%rbp), %rsi
 123         subq $MCOUNT_INSN_SIZE, %rdi
 124
 125         call   *ftrace_trace_function
 126
 127         MCOUNT_RESTORE_FRAME
 128
 129         jmp ftrace_stub
 130 END(mcount)
 131 #endif /* CONFIG_DYNAMIC_FTRACE */
 132 #endif /* CONFIG_FUNCTION_TRACER */
 133
 134 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 135 ENTRY(ftrace_graph_caller)
 136         cmpl $0, function_trace_stop
 137         jne ftrace_stub
 138
 139         MCOUNT_SAVE_FRAME
 140
 141         leaq 8(%rbp), %rdi
 142         movq 0x38(%rsp), %rsi
 143         movq (%rbp), %rdx
 144         subq $MCOUNT_INSN_SIZE, %rsi
 145
 146         call    prepare_ftrace_return
 147
 148         MCOUNT_RESTORE_FRAME
 149
 150         retq
 151 END(ftrace_graph_caller)
 152
 153 GLOBAL(return_to_handler)
 154         subq  $24, %rsp
 155
 156         /* Save the return values */
 157         movq %rax, (%rsp)
 158         movq %rdx, 8(%rsp)
 159         movq %rbp, %rdi
 160
 161         call ftrace_return_to_handler
 162
 163         movq %rax, %rdi
 164         movq 8(%rsp), %rdx
 165         movq (%rsp), %rax
 166         addq $24, %rsp
 167         jmp *%rdi
 168 #endif
 169
 170
 171 #ifndef CONFIG_PREEMPT
 172 #define retint_kernel retint_restore_args
 173 #endif
 174
 175 #ifdef CONFIG_PARAVIRT
 176 ENTRY(native_usergs_sysret64)
 177         swapgs
 178         sysretq
 179 ENDPROC(native_usergs_sysret64)
 180 #endif /* CONFIG_PARAVIRT */
 181
 182
 183 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 184 #ifdef CONFIG_TRACE_IRQFLAGS
 185         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 186         jnc  1f
 187         TRACE_IRQS_ON
 188 1:
 189 #endif
 190 .endm
 191
 192 /*
 193  * C code is not supposed to know about undefined top of stack. Every time
 194  * a C function with an pt_regs argument is called from the SYSCALL based
 195  * fast path FIXUP_TOP_OF_STACK is needed.
 196  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 197  * manipulation.
 198  */
 199
 200         /* %rsp:at FRAMEEND */
 201         .macro FIXUP_TOP_OF_STACK tmp offset=0
 202         movq PER_CPU_VAR(old_rsp),\tmp
 203         movq \tmp,RSP+\offset(%rsp)
 204         movq $__USER_DS,SS+\offset(%rsp)
 205         movq $__USER_CS,CS+\offset(%rsp)
 206         movq $-1,RCX+\offset(%rsp)
 207         movq R11+\offset(%rsp),\tmp  /* get eflags */
 208         movq \tmp,EFLAGS+\offset(%rsp)
 209         .endm
 210
 211         .macro RESTORE_TOP_OF_STACK tmp offset=0
 212         movq RSP+\offset(%rsp),\tmp
 213         movq \tmp,PER_CPU_VAR(old_rsp)
 214         movq EFLAGS+\offset(%rsp),\tmp
 215         movq \tmp,R11+\offset(%rsp)
 216         .endm
 217
 218         .macro FAKE_STACK_FRAME child_rip
 219         /* push in order ss, rsp, eflags, cs, rip */
 220         xorl %eax, %eax
 221         pushq_cfi $__KERNEL_DS /* ss */
 222         /*CFI_REL_OFFSET        ss,0*/
 223         pushq_cfi %rax /* rsp */
 224         CFI_REL_OFFSET  rsp,0
 225         pushq_cfi $X86_EFLAGS_IF /* eflags - interrupts on */
 226         /*CFI_REL_OFFSET        rflags,0*/
 227         pushq_cfi $__KERNEL_CS /* cs */
 228         /*CFI_REL_OFFSET        cs,0*/
 229         pushq_cfi \child_rip /* rip */
 230         CFI_REL_OFFSET  rip,0
 231         pushq_cfi %rax /* orig rax */
 232         .endm
 233
 234         .macro UNFAKE_STACK_FRAME
 235         addq $8*6, %rsp
 236         CFI_ADJUST_CFA_OFFSET   -(6*8)
 237         .endm
 238
 239 /*
 240  * initial frame state for interrupts (and exceptions without error code)
 241  */
 242         .macro EMPTY_FRAME start=1 offset=0
 243         .if \start
 244         CFI_STARTPROC simple
 245         CFI_SIGNAL_FRAME
 246         CFI_DEF_CFA rsp,8+\offset
 247         .else
 248         CFI_DEF_CFA_OFFSET 8+\offset
 249         .endif
 250         .endm
 251
 252 /*
 253  * initial frame state for interrupts (and exceptions without error code)
 254  */
 255         .macro INTR_FRAME start=1 offset=0
 256         EMPTY_FRAME \start, SS+8+\offset-RIP
 257         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 258         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 259         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 260         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 261         CFI_REL_OFFSET rip, RIP+\offset-RIP
 262         .endm
 263
 264 /*
 265  * initial frame state for exceptions with error code (and interrupts
 266  * with vector already pushed)
 267  */
 268         .macro XCPT_FRAME start=1 offset=0
 269         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 270         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 271         .endm
 272
 273 /*
 274  * frame that enables calling into C.
 275  */
 276         .macro PARTIAL_FRAME start=1 offset=0
 277         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 278         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 283         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 286         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 287         .endm
 288
 289 /*
 290  * frame that enables passing a complete pt_regs to a C function.
 291  */
 292         .macro DEFAULT_FRAME start=1 offset=0
 293         PARTIAL_FRAME \start, R11+\offset-R15
 294         CFI_REL_OFFSET rbx, RBX+\offset
 295         CFI_REL_OFFSET rbp, RBP+\offset
 296         CFI_REL_OFFSET r12, R12+\offset
 297         CFI_REL_OFFSET r13, R13+\offset
 298         CFI_REL_OFFSET r14, R14+\offset
 299         CFI_REL_OFFSET r15, R15+\offset
 300         .endm
 301
 302 /* save partial stack frame */
 303         .macro SAVE_ARGS_IRQ
 304         cld
 305         /* start from rbp in pt_regs and jump over */
 306         movq_cfi rdi, RDI-RBP
 307         movq_cfi rsi, RSI-RBP
 308         movq_cfi rdx, RDX-RBP
 309         movq_cfi rcx, RCX-RBP
 310         movq_cfi rax, RAX-RBP
 311         movq_cfi  r8,  R8-RBP
 312         movq_cfi  r9,  R9-RBP
 313         movq_cfi r10, R10-RBP
 314         movq_cfi r11, R11-RBP
 315
 316         /* Save rbp so that we can unwind from get_irq_regs() */
 317         movq_cfi rbp, 0
 318
 319         /* Save previous stack value */
 320         movq %rsp, %rsi
 321
 322         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 323         testl $3, CS(%rdi)
 324         je 1f
 325         SWAPGS
 326         /*
 327          * irq_count is used to check if a CPU is already on an interrupt stack
 328          * or not. While this is essentially redundant with preempt_count it is
 329          * a little cheaper to use a separate counter in the PDA (short of
 330          * moving irq_enter into assembly, which would be too much work)
 331          */
 332 1:      incl PER_CPU_VAR(irq_count)
 333         jne 2f
 334         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 335         CFI_DEF_CFA_REGISTER    rsi
 336
 337 2:      /* Store previous stack value */
 338         pushq %rsi
 339         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 340                         0x77 /* DW_OP_breg7 */, 0, \
 341                         0x06 /* DW_OP_deref */, \
 342                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 343                         0x22 /* DW_OP_plus */
 344         /* We entered an interrupt context - irqs are off: */
 345         TRACE_IRQS_OFF
 346         .endm
 347
 348 ENTRY(save_rest)
 349         PARTIAL_FRAME 1 REST_SKIP+8
 350         movq 5*8+16(%rsp), %r11 /* save return address */
 351         movq_cfi rbx, RBX+16
 352         movq_cfi rbp, RBP+16
 353         movq_cfi r12, R12+16
 354         movq_cfi r13, R13+16
 355         movq_cfi r14, R14+16
 356         movq_cfi r15, R15+16
 357         movq %r11, 8(%rsp)      /* return address */
 358         FIXUP_TOP_OF_STACK %r11, 16
 359         ret
 360         CFI_ENDPROC
 361 END(save_rest)
 362
 363 /* save complete stack frame */
 364         .pushsection .kprobes.text, "ax"
 365 ENTRY(save_paranoid)
 366         XCPT_FRAME 1 RDI+8
 367         cld
 368         movq_cfi rdi, RDI+8
 369         movq_cfi rsi, RSI+8
 370         movq_cfi rdx, RDX+8
 371         movq_cfi rcx, RCX+8
 372         movq_cfi rax, RAX+8
 373         movq_cfi r8, R8+8
 374         movq_cfi r9, R9+8
 375         movq_cfi r10, R10+8
 376         movq_cfi r11, R11+8
 377         movq_cfi rbx, RBX+8
 378         movq_cfi rbp, RBP+8
 379         movq_cfi r12, R12+8
 380         movq_cfi r13, R13+8
 381         movq_cfi r14, R14+8
 382         movq_cfi r15, R15+8
 383         movl $1,%ebx
 384         movl $MSR_GS_BASE,%ecx
 385         rdmsr
 386         testl %edx,%edx
 387         js 1f   /* negative -> in kernel */
 388         SWAPGS
 389         xorl %ebx,%ebx
 390 1:      ret
 391         CFI_ENDPROC
 392 END(save_paranoid)
 393         .popsection
 394
 395 /*
 396  * A newly forked process directly context switches into this address.
 397  *
 398  * rdi: prev task we switched from
 399  */
 400 ENTRY(ret_from_fork)
 401         DEFAULT_FRAME
 402
 403         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 404
 405         pushq_cfi kernel_eflags(%rip)
 406         popfq_cfi                               # reset kernel eflags
 407
 408         call schedule_tail                      # rdi: 'prev' task parameter
 409
 410         GET_THREAD_INFO(%rcx)
 411
 412         RESTORE_REST
 413
 414         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 415         je   int_ret_from_sys_call
 416
 417         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 418         jnz  int_ret_from_sys_call
 419
 420         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 421         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 422
 423         CFI_ENDPROC
 424 END(ret_from_fork)
 425
 426 /*
 427  * System call entry. Up to 6 arguments in registers are supported.
 428  *
 429  * SYSCALL does not save anything on the stack and does not change the
 430  * stack pointer.
 431  */
 432
 433 /*
 434  * Register setup:
 435  * rax  system call number
 436  * rdi  arg0
 437  * rcx  return address for syscall/sysret, C arg3
 438  * rsi  arg1
 439  * rdx  arg2
 440  * r10  arg3    (--> moved to rcx for C)
 441  * r8   arg4
 442  * r9   arg5
 443  * r11  eflags for syscall/sysret, temporary for C
 444  * r12-r15,rbp,rbx saved by C code, not touched.
 445  *
 446  * Interrupts are off on entry.
 447  * Only called from user space.
 448  *
 449  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 450  *      and report it properly in ps. Unfortunately we haven't.
 451  *
 452  * When user can change the frames always force IRET. That is because
 453  * it deals with uncanonical addresses better. SYSRET has trouble
 454  * with them due to bugs in both AMD and Intel CPUs.
 455  */
 456
 457 ENTRY(system_call)
 458         CFI_STARTPROC   simple
 459         CFI_SIGNAL_FRAME
 460         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 461         CFI_REGISTER    rip,rcx
 462         /*CFI_REGISTER  rflags,r11*/
 463         SWAPGS_UNSAFE_STACK
 464         /*
 465          * A hypervisor implementation might want to use a label
 466          * after the swapgs, so that it can do the swapgs
 467          * for the guest and jump here on syscall.
 468          */
 469 ENTRY(system_call_after_swapgs)
 470
 471         movq    %rsp,PER_CPU_VAR(old_rsp)
 472         movq    PER_CPU_VAR(kernel_stack),%rsp
 473         /*
 474          * No need to follow this irqs off/on section - it's straight
 475          * and short:
 476          */
 477         ENABLE_INTERRUPTS(CLBR_NONE)
 478         SAVE_ARGS 8,0
 479         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 480         movq  %rcx,RIP-ARGOFFSET(%rsp)
 481         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 482         GET_THREAD_INFO(%rcx)
 483         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 484         jnz tracesys
 485 system_call_fastpath:
 486         cmpq $__NR_syscall_max,%rax
 487         ja badsys
 488         movq %r10,%rcx
 489         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 490         movq %rax,RAX-ARGOFFSET(%rsp)
 491 /*
 492  * Syscall return path ending with SYSRET (fast path)
 493  * Has incomplete stack frame and undefined top of stack.
 494  */
 495 ret_from_sys_call:
 496         movl $_TIF_ALLWORK_MASK,%edi
 497         /* edi: flagmask */
 498 sysret_check:
 499         LOCKDEP_SYS_EXIT
 500         GET_THREAD_INFO(%rcx)
 501         DISABLE_INTERRUPTS(CLBR_NONE)
 502         TRACE_IRQS_OFF
 503         movl TI_flags(%rcx),%edx
 504         andl %edi,%edx
 505         jnz  sysret_careful
 506         CFI_REMEMBER_STATE
 507         /*
 508          * sysretq will re-enable interrupts:
 509          */
 510         TRACE_IRQS_ON
 511         movq RIP-ARGOFFSET(%rsp),%rcx
 512         CFI_REGISTER    rip,rcx
 513         RESTORE_ARGS 1,-ARG_SKIP,0
 514         /*CFI_REGISTER  rflags,r11*/
 515         movq    PER_CPU_VAR(old_rsp), %rsp
 516         USERGS_SYSRET64
 517
 518         CFI_RESTORE_STATE
 519         /* Handle reschedules */
 520         /* edx: work, edi: workmask */
 521 sysret_careful:
 522         bt $TIF_NEED_RESCHED,%edx
 523         jnc sysret_signal
 524         TRACE_IRQS_ON
 525         ENABLE_INTERRUPTS(CLBR_NONE)
 526         pushq_cfi %rdi
 527         call schedule
 528         popq_cfi %rdi
 529         jmp sysret_check
 530
 531         /* Handle a signal */
 532 sysret_signal:
 533         TRACE_IRQS_ON
 534         ENABLE_INTERRUPTS(CLBR_NONE)
 535 #ifdef CONFIG_AUDITSYSCALL
 536         bt $TIF_SYSCALL_AUDIT,%edx
 537         jc sysret_audit
 538 #endif
 539         /*
 540          * We have a signal, or exit tracing or single-step.
 541          * These all wind up with the iret return path anyway,
 542          * so just join that path right now.
 543          */
 544         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 545         jmp int_check_syscall_exit_work
 546
 547 badsys:
 548         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 549         jmp ret_from_sys_call
 550
 551 #ifdef CONFIG_AUDITSYSCALL
 552         /*
 553          * Fast path for syscall audit without full syscall trace.
 554          * We just call audit_syscall_entry() directly, and then
 555          * jump back to the normal fast path.
 556          */
 557 auditsys:
 558         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 559         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 560         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 561         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 562         movq %rax,%rsi                  /* 2nd arg: syscall number */
 563         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 564         call audit_syscall_entry
 565         LOAD_ARGS 0             /* reload call-clobbered registers */
 566         jmp system_call_fastpath
 567
 568         /*
 569          * Return fast path for syscall audit.  Call audit_syscall_exit()
 570          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 571          * masked off.
 572          */
 573 sysret_audit:
 574         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 575         cmpq $0,%rsi            /* is it < 0? */
 576         setl %al                /* 1 if so, 0 if not */
 577         movzbl %al,%edi         /* zero-extend that into %edi */
 578         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 579         call audit_syscall_exit
 580         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 581         jmp sysret_check
 582 #endif  /* CONFIG_AUDITSYSCALL */
 583
 584         /* Do syscall tracing */
 585 tracesys:
 586 #ifdef CONFIG_AUDITSYSCALL
 587         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 588         jz auditsys
 589 #endif
 590         SAVE_REST
 591         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 592         FIXUP_TOP_OF_STACK %rdi
 593         movq %rsp,%rdi
 594         call syscall_trace_enter
 595         /*
 596          * Reload arg registers from stack in case ptrace changed them.
 597          * We don't reload %rax because syscall_trace_enter() returned
 598          * the value it wants us to use in the table lookup.
 599          */
 600         LOAD_ARGS ARGOFFSET, 1
 601         RESTORE_REST
 602         cmpq $__NR_syscall_max,%rax
 603         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 604         movq %r10,%rcx  /* fixup for C */
 605         call *sys_call_table(,%rax,8)
 606         movq %rax,RAX-ARGOFFSET(%rsp)
 607         /* Use IRET because user could have changed frame */
 608
 609 /*
 610  * Syscall return path ending with IRET.
 611  * Has correct top of stack, but partial stack frame.
 612  */
 613 GLOBAL(int_ret_from_sys_call)
 614         DISABLE_INTERRUPTS(CLBR_NONE)
 615         TRACE_IRQS_OFF
 616         testl $3,CS-ARGOFFSET(%rsp)
 617         je retint_restore_args
 618         movl $_TIF_ALLWORK_MASK,%edi
 619         /* edi: mask to check */
 620 GLOBAL(int_with_check)
 621         LOCKDEP_SYS_EXIT_IRQ
 622         GET_THREAD_INFO(%rcx)
 623         movl TI_flags(%rcx),%edx
 624         andl %edi,%edx
 625         jnz   int_careful
 626         andl    $~TS_COMPAT,TI_status(%rcx)
 627         jmp   retint_swapgs
 628
 629         /* Either reschedule or signal or syscall exit tracking needed. */
 630         /* First do a reschedule test. */
 631         /* edx: work, edi: workmask */
 632 int_careful:
 633         bt $TIF_NEED_RESCHED,%edx
 634         jnc  int_very_careful
 635         TRACE_IRQS_ON
 636         ENABLE_INTERRUPTS(CLBR_NONE)
 637         pushq_cfi %rdi
 638         call schedule
 639         popq_cfi %rdi
 640         DISABLE_INTERRUPTS(CLBR_NONE)
 641         TRACE_IRQS_OFF
 642         jmp int_with_check
 643
 644         /* handle signals and tracing -- both require a full stack frame */
 645 int_very_careful:
 646         TRACE_IRQS_ON
 647         ENABLE_INTERRUPTS(CLBR_NONE)
 648 int_check_syscall_exit_work:
 649         SAVE_REST
 650         /* Check for syscall exit trace */
 651         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 652         jz int_signal
 653         pushq_cfi %rdi
 654         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 655         call syscall_trace_leave
 656         popq_cfi %rdi
 657         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 658         jmp int_restore_rest
 659
 660 int_signal:
 661         testl $_TIF_DO_NOTIFY_MASK,%edx
 662         jz 1f
 663         movq %rsp,%rdi          # &ptregs -> arg1
 664         xorl %esi,%esi          # oldset -> arg2
 665         call do_notify_resume
 666 1:      movl $_TIF_WORK_MASK,%edi
 667 int_restore_rest:
 668         RESTORE_REST
 669         DISABLE_INTERRUPTS(CLBR_NONE)
 670         TRACE_IRQS_OFF
 671         jmp int_with_check
 672         CFI_ENDPROC
 673 END(system_call)
 674
 675 /*
 676  * Certain special system calls that need to save a complete full stack frame.
 677  */
 678         .macro PTREGSCALL label,func,arg
 679 ENTRY(\label)
 680         PARTIAL_FRAME 1 8               /* offset 8: return address */
 681         subq $REST_SKIP, %rsp
 682         CFI_ADJUST_CFA_OFFSET REST_SKIP
 683         call save_rest
 684         DEFAULT_FRAME 0 8               /* offset 8: return address */
 685         leaq 8(%rsp), \arg      /* pt_regs pointer */
 686         call \func
 687         jmp ptregscall_common
 688         CFI_ENDPROC
 689 END(\label)
 690         .endm
 691
 692         PTREGSCALL stub_clone, sys_clone, %r8
 693         PTREGSCALL stub_fork, sys_fork, %rdi
 694         PTREGSCALL stub_vfork, sys_vfork, %rdi
 695         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 696         PTREGSCALL stub_iopl, sys_iopl, %rsi
 697
 698 ENTRY(ptregscall_common)
 699         DEFAULT_FRAME 1 8       /* offset 8: return address */
 700         RESTORE_TOP_OF_STACK %r11, 8
 701         movq_cfi_restore R15+8, r15
 702         movq_cfi_restore R14+8, r14
 703         movq_cfi_restore R13+8, r13
 704         movq_cfi_restore R12+8, r12
 705         movq_cfi_restore RBP+8, rbp
 706         movq_cfi_restore RBX+8, rbx
 707         ret $REST_SKIP          /* pop extended registers */
 708         CFI_ENDPROC
 709 END(ptregscall_common)
 710
 711 ENTRY(stub_execve)
 712         CFI_STARTPROC
 713         addq $8, %rsp
 714         PARTIAL_FRAME 0
 715         SAVE_REST
 716         FIXUP_TOP_OF_STACK %r11
 717         movq %rsp, %rcx
 718         call sys_execve
 719         RESTORE_TOP_OF_STACK %r11
 720         movq %rax,RAX(%rsp)
 721         RESTORE_REST
 722         jmp int_ret_from_sys_call
 723         CFI_ENDPROC
 724 END(stub_execve)
 725
 726 /*
 727  * sigreturn is special because it needs to restore all registers on return.
 728  * This cannot be done with SYSRET, so use the IRET return path instead.
 729  */
 730 ENTRY(stub_rt_sigreturn)
 731         CFI_STARTPROC
 732         addq $8, %rsp
 733         PARTIAL_FRAME 0
 734         SAVE_REST
 735         movq %rsp,%rdi
 736         FIXUP_TOP_OF_STACK %r11
 737         call sys_rt_sigreturn
 738         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 739         RESTORE_REST
 740         jmp int_ret_from_sys_call
 741         CFI_ENDPROC
 742 END(stub_rt_sigreturn)
 743
 744 /*
 745  * Build the entry stubs and pointer table with some assembler magic.
 746  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 747  * single cache line on all modern x86 implementations.
 748  */
 749         .section .init.rodata,"a"
 750 ENTRY(interrupt)
 751         .section .entry.text
 752         .p2align 5
 753         .p2align CONFIG_X86_L1_CACHE_SHIFT
 754 ENTRY(irq_entries_start)
 755         INTR_FRAME
 756 vector=FIRST_EXTERNAL_VECTOR
 757 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 758         .balign 32
 759   .rept 7
 760     .if vector < NR_VECTORS
 761       .if vector <> FIRST_EXTERNAL_VECTOR
 762         CFI_ADJUST_CFA_OFFSET -8
 763       .endif
 764 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 765       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 766         jmp 2f
 767       .endif
 768       .previous
 769         .quad 1b
 770       .section .entry.text
 771 vector=vector+1
 772     .endif
 773   .endr
 774 2:      jmp common_interrupt
 775 .endr
 776         CFI_ENDPROC
 777 END(irq_entries_start)
 778
 779 .previous
 780 END(interrupt)
 781 .previous
 782
 783 /*
 784  * Interrupt entry/exit.
 785  *
 786  * Interrupt entry points save only callee clobbered registers in fast path.
 787  *
 788  * Entry runs with interrupts off.
 789  */
 790
 791 /* 0(%rsp): ~(interrupt number) */
 792         .macro interrupt func
 793         /* reserve pt_regs for scratch regs and rbp */
 794         subq $ORIG_RAX-RBP, %rsp
 795         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 796         SAVE_ARGS_IRQ
 797         call \func
 798         .endm
 799
 800 /*
 801  * Interrupt entry/exit should be protected against kprobes
 802  */
 803         .pushsection .kprobes.text, "ax"
 804         /*
 805          * The interrupt stubs push (~vector+0x80) onto the stack and
 806          * then jump to common_interrupt.
 807          */
 808         .p2align CONFIG_X86_L1_CACHE_SHIFT
 809 common_interrupt:
 810         XCPT_FRAME
 811         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 812         interrupt do_IRQ
 813         /* 0(%rsp): old_rsp-ARGOFFSET */
 814 ret_from_intr:
 815         DISABLE_INTERRUPTS(CLBR_NONE)
 816         TRACE_IRQS_OFF
 817         decl PER_CPU_VAR(irq_count)
 818
 819         /* Restore saved previous stack */
 820         popq %rsi
 821         CFI_DEF_CFA_REGISTER    rsi
 822         leaq ARGOFFSET-RBP(%rsi), %rsp
 823         CFI_DEF_CFA_REGISTER    rsp
 824         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 825
 826 exit_intr:
 827         GET_THREAD_INFO(%rcx)
 828         testl $3,CS-ARGOFFSET(%rsp)
 829         je retint_kernel
 830
 831         /* Interrupt came from user space */
 832         /*
 833          * Has a correct top of stack, but a partial stack frame
 834          * %rcx: thread info. Interrupts off.
 835          */
 836 retint_with_reschedule:
 837         movl $_TIF_WORK_MASK,%edi
 838 retint_check:
 839         LOCKDEP_SYS_EXIT_IRQ
 840         movl TI_flags(%rcx),%edx
 841         andl %edi,%edx
 842         CFI_REMEMBER_STATE
 843         jnz  retint_careful
 844
 845 retint_swapgs:          /* return to user-space */
 846         /*
 847          * The iretq could re-enable interrupts:
 848          */
 849         DISABLE_INTERRUPTS(CLBR_ANY)
 850         TRACE_IRQS_IRETQ
 851         SWAPGS
 852         jmp restore_args
 853
 854 retint_restore_args:    /* return to kernel space */
 855         DISABLE_INTERRUPTS(CLBR_ANY)
 856         /*
 857          * The iretq could re-enable interrupts:
 858          */
 859         TRACE_IRQS_IRETQ
 860 restore_args:
 861         RESTORE_ARGS 1,8,1
 862
 863 irq_return:
 864         INTERRUPT_RETURN
 865
 866 ENTRY(native_iret)
 867         /*
 868          * Are we returning to a stack segment from the LDT?  Note: in
 869          * 64-bit mode SS:RSP on the exception stack is always valid.
 870          */
 871 #ifdef CONFIG_X86_ESPFIX64
 872         testb $4,(SS-RIP)(%rsp)
 873         jnz native_irq_return_ldt
 874 #endif
 875
 876 native_irq_return_iret:
 877         iretq
 878
 879         .section __ex_table,"a"
 880         .quad native_irq_return_iret, bad_iret
 881         .previous
 882
 883 #ifdef CONFIG_X86_ESPFIX64
 884 native_irq_return_ldt:
 885         pushq_cfi %rax
 886         pushq_cfi %rdi
 887         SWAPGS
 888         movq PER_CPU_VAR(espfix_waddr),%rdi
 889         movq %rax,(0*8)(%rdi)   /* RAX */
 890         movq (2*8)(%rsp),%rax   /* RIP */
 891         movq %rax,(1*8)(%rdi)
 892         movq (3*8)(%rsp),%rax   /* CS */
 893         movq %rax,(2*8)(%rdi)
 894         movq (4*8)(%rsp),%rax   /* RFLAGS */
 895         movq %rax,(3*8)(%rdi)
 896         movq (6*8)(%rsp),%rax   /* SS */
 897         movq %rax,(5*8)(%rdi)
 898         movq (5*8)(%rsp),%rax   /* RSP */
 899         movq %rax,(4*8)(%rdi)
 900         andl $0xffff0000,%eax
 901         popq_cfi %rdi
 902         orq PER_CPU_VAR(espfix_stack),%rax
 903         SWAPGS
 904         movq %rax,%rsp
 905         popq_cfi %rax
 906         jmp native_irq_return_iret
 907 #endif
 908
 909         .section .fixup,"ax"
 910 bad_iret:
 911         /*
 912          * The iret traps when the %cs or %ss being restored is bogus.
 913          * We've lost the original trap vector and error code.
 914          * #GPF is the most likely one to get for an invalid selector.
 915          * So pretend we completed the iret and took the #GPF in user mode.
 916          *
 917          * We are now running with the kernel GS after exception recovery.
 918          * But error_entry expects us to have user GS to match the user %cs,
 919          * so swap back.
 920          */
 921         pushq $0
 922
 923         SWAPGS
 924         jmp general_protection
 925
 926         .previous
 927
 928         /* edi: workmask, edx: work */
 929 retint_careful:
 930         CFI_RESTORE_STATE
 931         bt    $TIF_NEED_RESCHED,%edx
 932         jnc   retint_signal
 933         TRACE_IRQS_ON
 934         ENABLE_INTERRUPTS(CLBR_NONE)
 935         pushq_cfi %rdi
 936         call  schedule
 937         popq_cfi %rdi
 938         GET_THREAD_INFO(%rcx)
 939         DISABLE_INTERRUPTS(CLBR_NONE)
 940         TRACE_IRQS_OFF
 941         jmp retint_check
 942
 943 retint_signal:
 944         testl $_TIF_DO_NOTIFY_MASK,%edx
 945         jz    retint_swapgs
 946         TRACE_IRQS_ON
 947         ENABLE_INTERRUPTS(CLBR_NONE)
 948         SAVE_REST
 949         movq $-1,ORIG_RAX(%rsp)
 950         xorl %esi,%esi          # oldset
 951         movq %rsp,%rdi          # &pt_regs
 952         call do_notify_resume
 953         RESTORE_REST
 954         DISABLE_INTERRUPTS(CLBR_NONE)
 955         TRACE_IRQS_OFF
 956         GET_THREAD_INFO(%rcx)
 957         jmp retint_with_reschedule
 958
 959 #ifdef CONFIG_PREEMPT
 960         /* Returning to kernel space. Check if we need preemption */
 961         /* rcx:  threadinfo. interrupts off. */
 962 ENTRY(retint_kernel)
 963         cmpl $0,TI_preempt_count(%rcx)
 964         jnz  retint_restore_args
 965         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 966         jnc  retint_restore_args
 967         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 968         jnc  retint_restore_args
 969         call preempt_schedule_irq
 970         jmp exit_intr
 971 #endif
 972         CFI_ENDPROC
 973 END(common_interrupt)
 974
 975         /*
 976          * If IRET takes a fault on the espfix stack, then we
 977          * end up promoting it to a doublefault.  In that case,
 978          * modify the stack to make it look like we just entered
 979          * the #GP handler from user space, similar to bad_iret.
 980          */
 981 #ifdef CONFIG_X86_ESPFIX64
 982         ALIGN
 983 __do_double_fault:
 984         XCPT_FRAME 1 RDI+8
 985         movq RSP(%rdi),%rax             /* Trap on the espfix stack? */
 986         sarq $PGDIR_SHIFT,%rax
 987         cmpl $ESPFIX_PGD_ENTRY,%eax
 988         jne do_double_fault             /* No, just deliver the fault */
 989         cmpl $__KERNEL_CS,CS(%rdi)
 990         jne do_double_fault
 991         movq RIP(%rdi),%rax
 992         cmpq $native_irq_return_iret,%rax
 993         jne do_double_fault             /* This shouldn't happen... */
 994         movq PER_CPU_VAR(kernel_stack),%rax
 995         subq $(6*8-KERNEL_STACK_OFFSET),%rax    /* Reset to original stack */
 996         movq %rax,RSP(%rdi)
 997         movq $0,(%rax)                  /* Missing (lost) #GP error code */
 998         movq $general_protection,RIP(%rdi)
 999         retq
1000         CFI_ENDPROC
1001 END(__do_double_fault)
1002 #else
1003 # define __do_double_fault do_double_fault
1004 #endif
1005
1006 /*
1007  * End of kprobes section
1008  */
1009        .popsection
1010
1011 /*
1012  * APIC interrupts.
1013  */
1014 .macro apicinterrupt num sym do_sym
1015 ENTRY(\sym)
1016         INTR_FRAME
1017         pushq_cfi $~(\num)
1018         interrupt \do_sym
1019         jmp ret_from_intr
1020         CFI_ENDPROC
1021 END(\sym)
1022 .endm
1023
1024 #ifdef CONFIG_SMP
1025 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
1026         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1027 apicinterrupt REBOOT_VECTOR \
1028         reboot_interrupt smp_reboot_interrupt
1029 #endif
1030
1031 #ifdef CONFIG_X86_UV
1032 apicinterrupt UV_BAU_MESSAGE \
1033         uv_bau_message_intr1 uv_bau_message_interrupt
1034 #endif
1035 apicinterrupt LOCAL_TIMER_VECTOR \
1036         apic_timer_interrupt smp_apic_timer_interrupt
1037 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1038         x86_platform_ipi smp_x86_platform_ipi
1039
1040 #ifdef CONFIG_SMP
1041 .irp idx,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
1042         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
1043 .if NUM_INVALIDATE_TLB_VECTORS > \idx
1044 apicinterrupt (INVALIDATE_TLB_VECTOR_START)+\idx \
1045         invalidate_interrupt\idx smp_invalidate_interrupt
1046 .endif
1047 .endr
1048 #endif
1049
1050 apicinterrupt THRESHOLD_APIC_VECTOR \
1051         threshold_interrupt smp_threshold_interrupt
1052 apicinterrupt THERMAL_APIC_VECTOR \
1053         thermal_interrupt smp_thermal_interrupt
1054
1055 #ifdef CONFIG_SMP
1056 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1057         call_function_single_interrupt smp_call_function_single_interrupt
1058 apicinterrupt CALL_FUNCTION_VECTOR \
1059         call_function_interrupt smp_call_function_interrupt
1060 apicinterrupt RESCHEDULE_VECTOR \
1061         reschedule_interrupt smp_reschedule_interrupt
1062 #endif
1063
1064 apicinterrupt ERROR_APIC_VECTOR \
1065         error_interrupt smp_error_interrupt
1066 apicinterrupt SPURIOUS_APIC_VECTOR \
1067         spurious_interrupt smp_spurious_interrupt
1068
1069 #ifdef CONFIG_IRQ_WORK
1070 apicinterrupt IRQ_WORK_VECTOR \
1071         irq_work_interrupt smp_irq_work_interrupt
1072 #endif
1073
1074 /*
1075  * Exception entry points.
1076  */
1077 .macro zeroentry sym do_sym
1078 ENTRY(\sym)
1079         INTR_FRAME
1080         PARAVIRT_ADJUST_EXCEPTION_FRAME
1081         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1082         subq $ORIG_RAX-R15, %rsp
1083         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1084         call error_entry
1085         DEFAULT_FRAME 0
1086         movq %rsp,%rdi          /* pt_regs pointer */
1087         xorl %esi,%esi          /* no error code */
1088         call \do_sym
1089         jmp error_exit          /* %ebx: no swapgs flag */
1090         CFI_ENDPROC
1091 END(\sym)
1092 .endm
1093
1094 .macro paranoidzeroentry sym do_sym
1095 ENTRY(\sym)
1096         INTR_FRAME
1097         PARAVIRT_ADJUST_EXCEPTION_FRAME
1098         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1099         subq $ORIG_RAX-R15, %rsp
1100         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1101         call save_paranoid
1102         TRACE_IRQS_OFF
1103         movq %rsp,%rdi          /* pt_regs pointer */
1104         xorl %esi,%esi          /* no error code */
1105         call \do_sym
1106         jmp paranoid_exit       /* %ebx: no swapgs flag */
1107         CFI_ENDPROC
1108 END(\sym)
1109 .endm
1110
1111 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1112 .macro paranoidzeroentry_ist sym do_sym ist
1113 ENTRY(\sym)
1114         INTR_FRAME
1115         PARAVIRT_ADJUST_EXCEPTION_FRAME
1116         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1117         subq $ORIG_RAX-R15, %rsp
1118         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1119         call save_paranoid
1120         TRACE_IRQS_OFF
1121         movq %rsp,%rdi          /* pt_regs pointer */
1122         xorl %esi,%esi          /* no error code */
1123         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1124         call \do_sym
1125         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1126         jmp paranoid_exit       /* %ebx: no swapgs flag */
1127         CFI_ENDPROC
1128 END(\sym)
1129 .endm
1130
1131 .macro errorentry sym do_sym
1132 ENTRY(\sym)
1133         XCPT_FRAME
1134         PARAVIRT_ADJUST_EXCEPTION_FRAME
1135         subq $ORIG_RAX-R15, %rsp
1136         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1137         call error_entry
1138         DEFAULT_FRAME 0
1139         movq %rsp,%rdi                  /* pt_regs pointer */
1140         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1141         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1142         call \do_sym
1143         jmp error_exit                  /* %ebx: no swapgs flag */
1144         CFI_ENDPROC
1145 END(\sym)
1146 .endm
1147
1148         /* error code is on the stack already */
1149 .macro paranoiderrorentry sym do_sym
1150 ENTRY(\sym)
1151         XCPT_FRAME
1152         PARAVIRT_ADJUST_EXCEPTION_FRAME
1153         subq $ORIG_RAX-R15, %rsp
1154         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1155         call save_paranoid
1156         DEFAULT_FRAME 0
1157         TRACE_IRQS_OFF
1158         movq %rsp,%rdi                  /* pt_regs pointer */
1159         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1160         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1161         call \do_sym
1162         jmp paranoid_exit               /* %ebx: no swapgs flag */
1163         CFI_ENDPROC
1164 END(\sym)
1165 .endm
1166
1167 zeroentry divide_error do_divide_error
1168 zeroentry overflow do_overflow
1169 zeroentry bounds do_bounds
1170 zeroentry invalid_op do_invalid_op
1171 zeroentry device_not_available do_device_not_available
1172 paranoiderrorentry double_fault __do_double_fault
1173 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1174 errorentry invalid_TSS do_invalid_TSS
1175 errorentry segment_not_present do_segment_not_present
1176 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1177 zeroentry coprocessor_error do_coprocessor_error
1178 errorentry alignment_check do_alignment_check
1179 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1180
1181
1182         /* Reload gs selector with exception handling */
1183         /* edi:  new selector */
1184 ENTRY(native_load_gs_index)
1185         CFI_STARTPROC
1186         pushfq_cfi
1187         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1188         SWAPGS
1189 gs_change:
1190         movl %edi,%gs
1191 2:      mfence          /* workaround */
1192         SWAPGS
1193         popfq_cfi
1194         ret
1195         CFI_ENDPROC
1196 END(native_load_gs_index)
1197
1198         .section __ex_table,"a"
1199         .align 8
1200         .quad gs_change,bad_gs
1201         .previous
1202         .section .fixup,"ax"
1203         /* running with kernelgs */
1204 bad_gs:
1205         SWAPGS                  /* switch back to user gs */
1206         xorl %eax,%eax
1207         movl %eax,%gs
1208         jmp  2b
1209         .previous
1210
1211 ENTRY(kernel_thread_helper)
1212         pushq $0                # fake return address
1213         CFI_STARTPROC
1214         /*
1215          * Here we are in the child and the registers are set as they were
1216          * at kernel_thread() invocation in the parent.
1217          */
1218         call *%rsi
1219         # exit
1220         mov %eax, %edi
1221         call do_exit
1222         ud2                     # padding for call trace
1223         CFI_ENDPROC
1224 END(kernel_thread_helper)
1225
1226 /*
1227  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1228  *
1229  * C extern interface:
1230  *       extern long execve(const char *name, char **argv, char **envp)
1231  *
1232  * asm input arguments:
1233  *      rdi: name, rsi: argv, rdx: envp
1234  *
1235  * We want to fallback into:
1236  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1237  *
1238  * do_sys_execve asm fallback arguments:
1239  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1240  */
1241 ENTRY(kernel_execve)
1242         CFI_STARTPROC
1243         FAKE_STACK_FRAME $0
1244         SAVE_ALL
1245         movq %rsp,%rcx
1246         call sys_execve
1247         movq %rax, RAX(%rsp)
1248         RESTORE_REST
1249         testq %rax,%rax
1250         je int_ret_from_sys_call
1251         RESTORE_ARGS
1252         UNFAKE_STACK_FRAME
1253         ret
1254         CFI_ENDPROC
1255 END(kernel_execve)
1256
1257 /* Call softirq on interrupt stack. Interrupts are off. */
1258 ENTRY(call_softirq)
1259         CFI_STARTPROC
1260         pushq_cfi %rbp
1261         CFI_REL_OFFSET rbp,0
1262         mov  %rsp,%rbp
1263         CFI_DEF_CFA_REGISTER rbp
1264         incl PER_CPU_VAR(irq_count)
1265         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1266         push  %rbp                      # backlink for old unwinder
1267         call __do_softirq
1268         leaveq
1269         CFI_RESTORE             rbp
1270         CFI_DEF_CFA_REGISTER    rsp
1271         CFI_ADJUST_CFA_OFFSET   -8
1272         decl PER_CPU_VAR(irq_count)
1273         ret
1274         CFI_ENDPROC
1275 END(call_softirq)
1276
1277 #ifdef CONFIG_XEN
1278 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1279
1280 /*
1281  * A note on the "critical region" in our callback handler.
1282  * We want to avoid stacking callback handlers due to events occurring
1283  * during handling of the last event. To do this, we keep events disabled
1284  * until we've done all processing. HOWEVER, we must enable events before
1285  * popping the stack frame (can't be done atomically) and so it would still
1286  * be possible to get enough handler activations to overflow the stack.
1287  * Although unlikely, bugs of that kind are hard to track down, so we'd
1288  * like to avoid the possibility.
1289  * So, on entry to the handler we detect whether we interrupted an
1290  * existing activation in its critical region -- if so, we pop the current
1291  * activation and restart the handler using the previous one.
1292  */
1293 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1294         CFI_STARTPROC
1295 /*
1296  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1297  * see the correct pointer to the pt_regs
1298  */
1299         movq %rdi, %rsp            # we don't return, adjust the stack frame
1300         CFI_ENDPROC
1301         DEFAULT_FRAME
1302 11:     incl PER_CPU_VAR(irq_count)
1303         movq %rsp,%rbp
1304         CFI_DEF_CFA_REGISTER rbp
1305         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1306         pushq %rbp                      # backlink for old unwinder
1307         call xen_evtchn_do_upcall
1308         popq %rsp
1309         CFI_DEF_CFA_REGISTER rsp
1310         decl PER_CPU_VAR(irq_count)
1311         jmp  error_exit
1312         CFI_ENDPROC
1313 END(xen_do_hypervisor_callback)
1314
1315 /*
1316  * Hypervisor uses this for application faults while it executes.
1317  * We get here for two reasons:
1318  *  1. Fault while reloading DS, ES, FS or GS
1319  *  2. Fault while executing IRET
1320  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1321  * registers that could be reloaded and zeroed the others.
1322  * Category 2 we fix up by killing the current process. We cannot use the
1323  * normal Linux return path in this case because if we use the IRET hypercall
1324  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1325  * We distinguish between categories by comparing each saved segment register
1326  * with its current contents: any discrepancy means we in category 1.
1327  */
1328 ENTRY(xen_failsafe_callback)
1329         INTR_FRAME 1 (6*8)
1330         /*CFI_REL_OFFSET gs,GS*/
1331         /*CFI_REL_OFFSET fs,FS*/
1332         /*CFI_REL_OFFSET es,ES*/
1333         /*CFI_REL_OFFSET ds,DS*/
1334         CFI_REL_OFFSET r11,8
1335         CFI_REL_OFFSET rcx,0
1336         movw %ds,%cx
1337         cmpw %cx,0x10(%rsp)
1338         CFI_REMEMBER_STATE
1339         jne 1f
1340         movw %es,%cx
1341         cmpw %cx,0x18(%rsp)
1342         jne 1f
1343         movw %fs,%cx
1344         cmpw %cx,0x20(%rsp)
1345         jne 1f
1346         movw %gs,%cx
1347         cmpw %cx,0x28(%rsp)
1348         jne 1f
1349         /* All segments match their saved values => Category 2 (Bad IRET). */
1350         movq (%rsp),%rcx
1351         CFI_RESTORE rcx
1352         movq 8(%rsp),%r11
1353         CFI_RESTORE r11
1354         addq $0x30,%rsp
1355         CFI_ADJUST_CFA_OFFSET -0x30
1356         pushq_cfi $0    /* RIP */
1357         pushq_cfi %r11
1358         pushq_cfi %rcx
1359         jmp general_protection
1360         CFI_RESTORE_STATE
1361 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1362         movq (%rsp),%rcx
1363         CFI_RESTORE rcx
1364         movq 8(%rsp),%r11
1365         CFI_RESTORE r11
1366         addq $0x30,%rsp
1367         CFI_ADJUST_CFA_OFFSET -0x30
1368         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1369         SAVE_ALL
1370         jmp error_exit
1371         CFI_ENDPROC
1372 END(xen_failsafe_callback)
1373
1374 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1375         xen_hvm_callback_vector xen_evtchn_do_upcall
1376
1377 #endif /* CONFIG_XEN */
1378
1379 /*
1380  * Some functions should be protected against kprobes
1381  */
1382         .pushsection .kprobes.text, "ax"
1383
1384 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1385 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1386 errorentry stack_segment do_stack_segment
1387 #ifdef CONFIG_XEN
1388 zeroentry xen_debug do_debug
1389 zeroentry xen_int3 do_int3
1390 errorentry xen_stack_segment do_stack_segment
1391 #endif
1392 errorentry general_protection do_general_protection
1393 errorentry page_fault do_page_fault
1394 #ifdef CONFIG_KVM_GUEST
1395 errorentry async_page_fault do_async_page_fault
1396 #endif
1397 #ifdef CONFIG_X86_MCE
1398 paranoidzeroentry machine_check *machine_check_vector(%rip)
1399 #endif
1400
1401         /*
1402          * "Paranoid" exit path from exception stack.
1403          * Paranoid because this is used by NMIs and cannot take
1404          * any kernel state for granted.
1405          * We don't do kernel preemption checks here, because only
1406          * NMI should be common and it does not enable IRQs and
1407          * cannot get reschedule ticks.
1408          *
1409          * "trace" is 0 for the NMI handler only, because irq-tracing
1410          * is fundamentally NMI-unsafe. (we cannot change the soft and
1411          * hard flags at once, atomically)
1412          */
1413
1414         /* ebx: no swapgs flag */
1415 ENTRY(paranoid_exit)
1416         DEFAULT_FRAME
1417         DISABLE_INTERRUPTS(CLBR_NONE)
1418         TRACE_IRQS_OFF
1419         testl %ebx,%ebx                         /* swapgs needed? */
1420         jnz paranoid_restore
1421         testl $3,CS(%rsp)
1422         jnz   paranoid_userspace
1423 paranoid_swapgs:
1424         TRACE_IRQS_IRETQ 0
1425         SWAPGS_UNSAFE_STACK
1426         RESTORE_ALL 8
1427         jmp irq_return
1428 paranoid_restore:
1429         TRACE_IRQS_IRETQ 0
1430         RESTORE_ALL 8
1431         jmp irq_return
1432 paranoid_userspace:
1433         GET_THREAD_INFO(%rcx)
1434         movl TI_flags(%rcx),%ebx
1435         andl $_TIF_WORK_MASK,%ebx
1436         jz paranoid_swapgs
1437         movq %rsp,%rdi                  /* &pt_regs */
1438         call sync_regs
1439         movq %rax,%rsp                  /* switch stack for scheduling */
1440         testl $_TIF_NEED_RESCHED,%ebx
1441         jnz paranoid_schedule
1442         movl %ebx,%edx                  /* arg3: thread flags */
1443         TRACE_IRQS_ON
1444         ENABLE_INTERRUPTS(CLBR_NONE)
1445         xorl %esi,%esi                  /* arg2: oldset */
1446         movq %rsp,%rdi                  /* arg1: &pt_regs */
1447         call do_notify_resume
1448         DISABLE_INTERRUPTS(CLBR_NONE)
1449         TRACE_IRQS_OFF
1450         jmp paranoid_userspace
1451 paranoid_schedule:
1452         TRACE_IRQS_ON
1453         ENABLE_INTERRUPTS(CLBR_ANY)
1454         call schedule
1455         DISABLE_INTERRUPTS(CLBR_ANY)
1456         TRACE_IRQS_OFF
1457         jmp paranoid_userspace
1458         CFI_ENDPROC
1459 END(paranoid_exit)
1460
1461 /*
1462  * Exception entry point. This expects an error code/orig_rax on the stack.
1463  * returns in "no swapgs flag" in %ebx.
1464  */
1465 ENTRY(error_entry)
1466         XCPT_FRAME
1467         CFI_ADJUST_CFA_OFFSET 15*8
1468         /* oldrax contains error code */
1469         cld
1470         movq_cfi rdi, RDI+8
1471         movq_cfi rsi, RSI+8
1472         movq_cfi rdx, RDX+8
1473         movq_cfi rcx, RCX+8
1474         movq_cfi rax, RAX+8
1475         movq_cfi  r8,  R8+8
1476         movq_cfi  r9,  R9+8
1477         movq_cfi r10, R10+8
1478         movq_cfi r11, R11+8
1479         movq_cfi rbx, RBX+8
1480         movq_cfi rbp, RBP+8
1481         movq_cfi r12, R12+8
1482         movq_cfi r13, R13+8
1483         movq_cfi r14, R14+8
1484         movq_cfi r15, R15+8
1485         xorl %ebx,%ebx
1486         testl $3,CS+8(%rsp)
1487         je error_kernelspace
1488 error_swapgs:
1489         SWAPGS
1490 error_sti:
1491         TRACE_IRQS_OFF
1492         ret
1493
1494 /*
1495  * There are two places in the kernel that can potentially fault with
1496  * usergs. Handle them here. The exception handlers after iret run with
1497  * kernel gs again, so don't set the user space flag. B stepping K8s
1498  * sometimes report an truncated RIP for IRET exceptions returning to
1499  * compat mode. Check for these here too.
1500  */
1501 error_kernelspace:
1502         incl %ebx
1503         leaq native_irq_return_iret(%rip),%rcx
1504         cmpq %rcx,RIP+8(%rsp)
1505         je error_swapgs
1506         movl %ecx,%eax  /* zero extend */
1507         cmpq %rax,RIP+8(%rsp)
1508         je bstep_iret
1509         cmpq $gs_change,RIP+8(%rsp)
1510         je error_swapgs
1511         jmp error_sti
1512
1513 bstep_iret:
1514         /* Fix truncated RIP */
1515         movq %rcx,RIP+8(%rsp)
1516         jmp error_swapgs
1517         CFI_ENDPROC
1518 END(error_entry)
1519
1520
1521 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1522 ENTRY(error_exit)
1523         DEFAULT_FRAME
1524         movl %ebx,%eax
1525         RESTORE_REST
1526         DISABLE_INTERRUPTS(CLBR_NONE)
1527         TRACE_IRQS_OFF
1528         GET_THREAD_INFO(%rcx)
1529         testl %eax,%eax
1530         jne retint_kernel
1531         LOCKDEP_SYS_EXIT_IRQ
1532         movl TI_flags(%rcx),%edx
1533         movl $_TIF_WORK_MASK,%edi
1534         andl %edi,%edx
1535         jnz retint_careful
1536         jmp retint_swapgs
1537         CFI_ENDPROC
1538 END(error_exit)
1539
1540
1541         /* runs on exception stack */
1542 ENTRY(nmi)
1543         INTR_FRAME
1544         PARAVIRT_ADJUST_EXCEPTION_FRAME
1545         pushq_cfi $-1
1546         subq $ORIG_RAX-R15, %rsp
1547         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1548         call save_paranoid
1549         DEFAULT_FRAME 0
1550         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1551         movq %rsp,%rdi
1552         movq $-1,%rsi
1553         call do_nmi
1554 #ifdef CONFIG_TRACE_IRQFLAGS
1555         /* paranoidexit; without TRACE_IRQS_OFF */
1556         /* ebx: no swapgs flag */
1557         DISABLE_INTERRUPTS(CLBR_NONE)
1558         testl %ebx,%ebx                         /* swapgs needed? */
1559         jnz nmi_restore
1560         testl $3,CS(%rsp)
1561         jnz nmi_userspace
1562 nmi_swapgs:
1563         SWAPGS_UNSAFE_STACK
1564 nmi_restore:
1565         RESTORE_ALL 8
1566         jmp irq_return
1567 nmi_userspace:
1568         GET_THREAD_INFO(%rcx)
1569         movl TI_flags(%rcx),%ebx
1570         andl $_TIF_WORK_MASK,%ebx
1571         jz nmi_swapgs
1572         movq %rsp,%rdi                  /* &pt_regs */
1573         call sync_regs
1574         movq %rax,%rsp                  /* switch stack for scheduling */
1575         testl $_TIF_NEED_RESCHED,%ebx
1576         jnz nmi_schedule
1577         movl %ebx,%edx                  /* arg3: thread flags */
1578         ENABLE_INTERRUPTS(CLBR_NONE)
1579         xorl %esi,%esi                  /* arg2: oldset */
1580         movq %rsp,%rdi                  /* arg1: &pt_regs */
1581         call do_notify_resume
1582         DISABLE_INTERRUPTS(CLBR_NONE)
1583         jmp nmi_userspace
1584 nmi_schedule:
1585         ENABLE_INTERRUPTS(CLBR_ANY)
1586         call schedule
1587         DISABLE_INTERRUPTS(CLBR_ANY)
1588         jmp nmi_userspace
1589         CFI_ENDPROC
1590 #else
1591         jmp paranoid_exit
1592         CFI_ENDPROC
1593 #endif
1594 END(nmi)
1595
1596 ENTRY(ignore_sysret)
1597         CFI_STARTPROC
1598         mov $-ENOSYS,%eax
1599         sysret
1600         CFI_ENDPROC
1601 END(ignore_sysret)
1602
1603 /*
1604  * End of kprobes section
1605  */
1606         .popsection