arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page_types.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/percpu.h>
  56
  57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  58 #include <linux/elf-em.h>
  59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  60 #define __AUDIT_ARCH_64BIT 0x80000000
  61 #define __AUDIT_ARCH_LE    0x40000000
  62
  63         .code64
  64 #ifdef CONFIG_FUNCTION_TRACER
  65 #ifdef CONFIG_DYNAMIC_FTRACE
  66 ENTRY(mcount)
  67         retq
  68 END(mcount)
  69
  70 ENTRY(ftrace_caller)
  71         cmpl $0, function_trace_stop
  72         jne  ftrace_stub
  73
  74         MCOUNT_SAVE_FRAME
  75
  76         movq 0x38(%rsp), %rdi
  77         movq 8(%rbp), %rsi
  78         subq $MCOUNT_INSN_SIZE, %rdi
  79
  80 GLOBAL(ftrace_call)
  81         call ftrace_stub
  82
  83         MCOUNT_RESTORE_FRAME
  84
  85 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  86 GLOBAL(ftrace_graph_call)
  87         jmp ftrace_stub
  88 #endif
  89
  90 GLOBAL(ftrace_stub)
  91         retq
  92 END(ftrace_caller)
  93
  94 #else /* ! CONFIG_DYNAMIC_FTRACE */
  95 ENTRY(mcount)
  96         cmpl $0, function_trace_stop
  97         jne  ftrace_stub
  98
  99         cmpq $ftrace_stub, ftrace_trace_function
 100         jnz trace
 101
 102 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 103         cmpq $ftrace_stub, ftrace_graph_return
 104         jnz ftrace_graph_caller
 105
 106         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 107         jnz ftrace_graph_caller
 108 #endif
 109
 110 GLOBAL(ftrace_stub)
 111         retq
 112
 113 trace:
 114         MCOUNT_SAVE_FRAME
 115
 116         movq 0x38(%rsp), %rdi
 117         movq 8(%rbp), %rsi
 118         subq $MCOUNT_INSN_SIZE, %rdi
 119
 120         call   *ftrace_trace_function
 121
 122         MCOUNT_RESTORE_FRAME
 123
 124         jmp ftrace_stub
 125 END(mcount)
 126 #endif /* CONFIG_DYNAMIC_FTRACE */
 127 #endif /* CONFIG_FUNCTION_TRACER */
 128
 129 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 130 ENTRY(ftrace_graph_caller)
 131         cmpl $0, function_trace_stop
 132         jne ftrace_stub
 133
 134         MCOUNT_SAVE_FRAME
 135
 136         leaq 8(%rbp), %rdi
 137         movq 0x38(%rsp), %rsi
 138         movq (%rbp), %rdx
 139         subq $MCOUNT_INSN_SIZE, %rsi
 140
 141         call    prepare_ftrace_return
 142
 143         MCOUNT_RESTORE_FRAME
 144
 145         retq
 146 END(ftrace_graph_caller)
 147
 148 GLOBAL(return_to_handler)
 149         subq  $24, %rsp
 150
 151         /* Save the return values */
 152         movq %rax, (%rsp)
 153         movq %rdx, 8(%rsp)
 154         movq %rbp, %rdi
 155
 156         call ftrace_return_to_handler
 157
 158         movq %rax, %rdi
 159         movq 8(%rsp), %rdx
 160         movq (%rsp), %rax
 161         addq $24, %rsp
 162         jmp *%rdi
 163 #endif
 164
 165
 166 #ifndef CONFIG_PREEMPT
 167 #define retint_kernel retint_restore_args
 168 #endif
 169
 170 #ifdef CONFIG_PARAVIRT
 171 ENTRY(native_usergs_sysret64)
 172         swapgs
 173         sysretq
 174 ENDPROC(native_usergs_sysret64)
 175 #endif /* CONFIG_PARAVIRT */
 176
 177
 178 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 179 #ifdef CONFIG_TRACE_IRQFLAGS
 180         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 181         jnc  1f
 182         TRACE_IRQS_ON
 183 1:
 184 #endif
 185 .endm
 186
 187 /*
 188  * C code is not supposed to know about undefined top of stack. Every time
 189  * a C function with an pt_regs argument is called from the SYSCALL based
 190  * fast path FIXUP_TOP_OF_STACK is needed.
 191  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 192  * manipulation.
 193  */
 194
 195         /* %rsp:at FRAMEEND */
 196         .macro FIXUP_TOP_OF_STACK tmp offset=0
 197         movq PER_CPU_VAR(old_rsp),\tmp
 198         movq \tmp,RSP+\offset(%rsp)
 199         movq $__USER_DS,SS+\offset(%rsp)
 200         movq $__USER_CS,CS+\offset(%rsp)
 201         movq $-1,RCX+\offset(%rsp)
 202         movq R11+\offset(%rsp),\tmp  /* get eflags */
 203         movq \tmp,EFLAGS+\offset(%rsp)
 204         .endm
 205
 206         .macro RESTORE_TOP_OF_STACK tmp offset=0
 207         movq RSP+\offset(%rsp),\tmp
 208         movq \tmp,PER_CPU_VAR(old_rsp)
 209         movq EFLAGS+\offset(%rsp),\tmp
 210         movq \tmp,R11+\offset(%rsp)
 211         .endm
 212
 213         .macro FAKE_STACK_FRAME child_rip
 214         /* push in order ss, rsp, eflags, cs, rip */
 215         xorl %eax, %eax
 216         pushq_cfi $__KERNEL_DS /* ss */
 217         /*CFI_REL_OFFSET        ss,0*/
 218         pushq_cfi %rax /* rsp */
 219         CFI_REL_OFFSET  rsp,0
 220         pushq_cfi $X86_EFLAGS_IF /* eflags - interrupts on */
 221         /*CFI_REL_OFFSET        rflags,0*/
 222         pushq_cfi $__KERNEL_CS /* cs */
 223         /*CFI_REL_OFFSET        cs,0*/
 224         pushq_cfi \child_rip /* rip */
 225         CFI_REL_OFFSET  rip,0
 226         pushq_cfi %rax /* orig rax */
 227         .endm
 228
 229         .macro UNFAKE_STACK_FRAME
 230         addq $8*6, %rsp
 231         CFI_ADJUST_CFA_OFFSET   -(6*8)
 232         .endm
 233
 234 /*
 235  * initial frame state for interrupts (and exceptions without error code)
 236  */
 237         .macro EMPTY_FRAME start=1 offset=0
 238         .if \start
 239         CFI_STARTPROC simple
 240         CFI_SIGNAL_FRAME
 241         CFI_DEF_CFA rsp,8+\offset
 242         .else
 243         CFI_DEF_CFA_OFFSET 8+\offset
 244         .endif
 245         .endm
 246
 247 /*
 248  * initial frame state for interrupts (and exceptions without error code)
 249  */
 250         .macro INTR_FRAME start=1 offset=0
 251         EMPTY_FRAME \start, SS+8+\offset-RIP
 252         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 253         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 254         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 255         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 256         CFI_REL_OFFSET rip, RIP+\offset-RIP
 257         .endm
 258
 259 /*
 260  * initial frame state for exceptions with error code (and interrupts
 261  * with vector already pushed)
 262  */
 263         .macro XCPT_FRAME start=1 offset=0
 264         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 265         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 266         .endm
 267
 268 /*
 269  * frame that enables calling into C.
 270  */
 271         .macro PARTIAL_FRAME start=1 offset=0
 272         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 273         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 274         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 275         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 276         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 277         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 278         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 279         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 280         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 281         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 282         .endm
 283
 284 /*
 285  * frame that enables passing a complete pt_regs to a C function.
 286  */
 287         .macro DEFAULT_FRAME start=1 offset=0
 288         PARTIAL_FRAME \start, R11+\offset-R15
 289         CFI_REL_OFFSET rbx, RBX+\offset
 290         CFI_REL_OFFSET rbp, RBP+\offset
 291         CFI_REL_OFFSET r12, R12+\offset
 292         CFI_REL_OFFSET r13, R13+\offset
 293         CFI_REL_OFFSET r14, R14+\offset
 294         CFI_REL_OFFSET r15, R15+\offset
 295         .endm
 296
 297 /* save partial stack frame */
 298         .pushsection .kprobes.text, "ax"
 299 ENTRY(save_args)
 300         XCPT_FRAME
 301         cld
 302         movq_cfi rdi, RDI+16-ARGOFFSET
 303         movq_cfi rsi, RSI+16-ARGOFFSET
 304         movq_cfi rdx, RDX+16-ARGOFFSET
 305         movq_cfi rcx, RCX+16-ARGOFFSET
 306         movq_cfi rax, RAX+16-ARGOFFSET
 307         movq_cfi  r8,  R8+16-ARGOFFSET
 308         movq_cfi  r9,  R9+16-ARGOFFSET
 309         movq_cfi r10, R10+16-ARGOFFSET
 310         movq_cfi r11, R11+16-ARGOFFSET
 311
 312         leaq -ARGOFFSET+16(%rsp),%rdi   /* arg1 for handler */
 313         movq_cfi rbp, 8         /* push %rbp */
 314         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 315         testl $3, CS(%rdi)
 316         je 1f
 317         SWAPGS
 318         /*
 319          * irq_count is used to check if a CPU is already on an interrupt stack
 320          * or not. While this is essentially redundant with preempt_count it is
 321          * a little cheaper to use a separate counter in the PDA (short of
 322          * moving irq_enter into assembly, which would be too much work)
 323          */
 324 1:      incl PER_CPU_VAR(irq_count)
 325         jne 2f
 326         popq_cfi %rax                   /* move return address... */
 327         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 328         EMPTY_FRAME 0
 329         pushq_cfi %rbp                  /* backlink for unwinder */
 330         pushq_cfi %rax                  /* ... to the new stack */
 331         /*
 332          * We entered an interrupt context - irqs are off:
 333          */
 334 2:      TRACE_IRQS_OFF
 335         ret
 336         CFI_ENDPROC
 337 END(save_args)
 338         .popsection
 339
 340 ENTRY(save_rest)
 341         PARTIAL_FRAME 1 REST_SKIP+8
 342         movq 5*8+16(%rsp), %r11 /* save return address */
 343         movq_cfi rbx, RBX+16
 344         movq_cfi rbp, RBP+16
 345         movq_cfi r12, R12+16
 346         movq_cfi r13, R13+16
 347         movq_cfi r14, R14+16
 348         movq_cfi r15, R15+16
 349         movq %r11, 8(%rsp)      /* return address */
 350         FIXUP_TOP_OF_STACK %r11, 16
 351         ret
 352         CFI_ENDPROC
 353 END(save_rest)
 354
 355 /* save complete stack frame */
 356         .pushsection .kprobes.text, "ax"
 357 ENTRY(save_paranoid)
 358         XCPT_FRAME 1 RDI+8
 359         cld
 360         movq_cfi rdi, RDI+8
 361         movq_cfi rsi, RSI+8
 362         movq_cfi rdx, RDX+8
 363         movq_cfi rcx, RCX+8
 364         movq_cfi rax, RAX+8
 365         movq_cfi r8, R8+8
 366         movq_cfi r9, R9+8
 367         movq_cfi r10, R10+8
 368         movq_cfi r11, R11+8
 369         movq_cfi rbx, RBX+8
 370         movq_cfi rbp, RBP+8
 371         movq_cfi r12, R12+8
 372         movq_cfi r13, R13+8
 373         movq_cfi r14, R14+8
 374         movq_cfi r15, R15+8
 375         movl $1,%ebx
 376         movl $MSR_GS_BASE,%ecx
 377         rdmsr
 378         testl %edx,%edx
 379         js 1f   /* negative -> in kernel */
 380         SWAPGS
 381         xorl %ebx,%ebx
 382 1:      ret
 383         CFI_ENDPROC
 384 END(save_paranoid)
 385         .popsection
 386
 387 /*
 388  * A newly forked process directly context switches into this address.
 389  *
 390  * rdi: prev task we switched from
 391  */
 392 ENTRY(ret_from_fork)
 393         DEFAULT_FRAME
 394
 395         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 396
 397         pushq_cfi kernel_eflags(%rip)
 398         popfq_cfi                               # reset kernel eflags
 399
 400         call schedule_tail                      # rdi: 'prev' task parameter
 401
 402         GET_THREAD_INFO(%rcx)
 403
 404         RESTORE_REST
 405
 406         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 407         je   int_ret_from_sys_call
 408
 409         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 410         jnz  int_ret_from_sys_call
 411
 412         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 413         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 414
 415         CFI_ENDPROC
 416 END(ret_from_fork)
 417
 418 /*
 419  * System call entry. Upto 6 arguments in registers are supported.
 420  *
 421  * SYSCALL does not save anything on the stack and does not change the
 422  * stack pointer.
 423  */
 424
 425 /*
 426  * Register setup:
 427  * rax  system call number
 428  * rdi  arg0
 429  * rcx  return address for syscall/sysret, C arg3
 430  * rsi  arg1
 431  * rdx  arg2
 432  * r10  arg3    (--> moved to rcx for C)
 433  * r8   arg4
 434  * r9   arg5
 435  * r11  eflags for syscall/sysret, temporary for C
 436  * r12-r15,rbp,rbx saved by C code, not touched.
 437  *
 438  * Interrupts are off on entry.
 439  * Only called from user space.
 440  *
 441  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 442  *      and report it properly in ps. Unfortunately we haven't.
 443  *
 444  * When user can change the frames always force IRET. That is because
 445  * it deals with uncanonical addresses better. SYSRET has trouble
 446  * with them due to bugs in both AMD and Intel CPUs.
 447  */
 448
 449 ENTRY(system_call)
 450         CFI_STARTPROC   simple
 451         CFI_SIGNAL_FRAME
 452         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 453         CFI_REGISTER    rip,rcx
 454         /*CFI_REGISTER  rflags,r11*/
 455         SWAPGS_UNSAFE_STACK
 456         /*
 457          * A hypervisor implementation might want to use a label
 458          * after the swapgs, so that it can do the swapgs
 459          * for the guest and jump here on syscall.
 460          */
 461 ENTRY(system_call_after_swapgs)
 462
 463         movq    %rsp,PER_CPU_VAR(old_rsp)
 464         movq    PER_CPU_VAR(kernel_stack),%rsp
 465         /*
 466          * No need to follow this irqs off/on section - it's straight
 467          * and short:
 468          */
 469         ENABLE_INTERRUPTS(CLBR_NONE)
 470         SAVE_ARGS 8,1
 471         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 472         movq  %rcx,RIP-ARGOFFSET(%rsp)
 473         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 474         GET_THREAD_INFO(%rcx)
 475         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 476         jnz tracesys
 477 system_call_fastpath:
 478         cmpq $__NR_syscall_max,%rax
 479         ja badsys
 480         movq %r10,%rcx
 481         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 482         movq %rax,RAX-ARGOFFSET(%rsp)
 483 /*
 484  * Syscall return path ending with SYSRET (fast path)
 485  * Has incomplete stack frame and undefined top of stack.
 486  */
 487 ret_from_sys_call:
 488         movl $_TIF_ALLWORK_MASK,%edi
 489         /* edi: flagmask */
 490 sysret_check:
 491         LOCKDEP_SYS_EXIT
 492         GET_THREAD_INFO(%rcx)
 493         DISABLE_INTERRUPTS(CLBR_NONE)
 494         TRACE_IRQS_OFF
 495         movl TI_flags(%rcx),%edx
 496         andl %edi,%edx
 497         jnz  sysret_careful
 498         CFI_REMEMBER_STATE
 499         /*
 500          * sysretq will re-enable interrupts:
 501          */
 502         TRACE_IRQS_ON
 503         movq RIP-ARGOFFSET(%rsp),%rcx
 504         CFI_REGISTER    rip,rcx
 505         RESTORE_ARGS 0,-ARG_SKIP,1
 506         /*CFI_REGISTER  rflags,r11*/
 507         movq    PER_CPU_VAR(old_rsp), %rsp
 508         USERGS_SYSRET64
 509
 510         CFI_RESTORE_STATE
 511         /* Handle reschedules */
 512         /* edx: work, edi: workmask */
 513 sysret_careful:
 514         bt $TIF_NEED_RESCHED,%edx
 515         jnc sysret_signal
 516         TRACE_IRQS_ON
 517         ENABLE_INTERRUPTS(CLBR_NONE)
 518         pushq_cfi %rdi
 519         call schedule
 520         popq_cfi %rdi
 521         jmp sysret_check
 522
 523         /* Handle a signal */
 524 sysret_signal:
 525         TRACE_IRQS_ON
 526         ENABLE_INTERRUPTS(CLBR_NONE)
 527 #ifdef CONFIG_AUDITSYSCALL
 528         bt $TIF_SYSCALL_AUDIT,%edx
 529         jc sysret_audit
 530 #endif
 531         /*
 532          * We have a signal, or exit tracing or single-step.
 533          * These all wind up with the iret return path anyway,
 534          * so just join that path right now.
 535          */
 536         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 537         jmp int_check_syscall_exit_work
 538
 539 badsys:
 540         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 541         jmp ret_from_sys_call
 542
 543 #ifdef CONFIG_AUDITSYSCALL
 544         /*
 545          * Fast path for syscall audit without full syscall trace.
 546          * We just call audit_syscall_entry() directly, and then
 547          * jump back to the normal fast path.
 548          */
 549 auditsys:
 550         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 551         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 552         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 553         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 554         movq %rax,%rsi                  /* 2nd arg: syscall number */
 555         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 556         call audit_syscall_entry
 557         LOAD_ARGS 0             /* reload call-clobbered registers */
 558         jmp system_call_fastpath
 559
 560         /*
 561          * Return fast path for syscall audit.  Call audit_syscall_exit()
 562          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 563          * masked off.
 564          */
 565 sysret_audit:
 566         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 567         cmpq $0,%rsi            /* is it < 0? */
 568         setl %al                /* 1 if so, 0 if not */
 569         movzbl %al,%edi         /* zero-extend that into %edi */
 570         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 571         call audit_syscall_exit
 572         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 573         jmp sysret_check
 574 #endif  /* CONFIG_AUDITSYSCALL */
 575
 576         /* Do syscall tracing */
 577 tracesys:
 578 #ifdef CONFIG_AUDITSYSCALL
 579         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 580         jz auditsys
 581 #endif
 582         SAVE_REST
 583         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 584         FIXUP_TOP_OF_STACK %rdi
 585         movq %rsp,%rdi
 586         call syscall_trace_enter
 587         /*
 588          * Reload arg registers from stack in case ptrace changed them.
 589          * We don't reload %rax because syscall_trace_enter() returned
 590          * the value it wants us to use in the table lookup.
 591          */
 592         LOAD_ARGS ARGOFFSET, 1
 593         RESTORE_REST
 594         cmpq $__NR_syscall_max,%rax
 595         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 596         movq %r10,%rcx  /* fixup for C */
 597         call *sys_call_table(,%rax,8)
 598         movq %rax,RAX-ARGOFFSET(%rsp)
 599         /* Use IRET because user could have changed frame */
 600
 601 /*
 602  * Syscall return path ending with IRET.
 603  * Has correct top of stack, but partial stack frame.
 604  */
 605 GLOBAL(int_ret_from_sys_call)
 606         DISABLE_INTERRUPTS(CLBR_NONE)
 607         TRACE_IRQS_OFF
 608         testl $3,CS-ARGOFFSET(%rsp)
 609         je retint_restore_args
 610         movl $_TIF_ALLWORK_MASK,%edi
 611         /* edi: mask to check */
 612 GLOBAL(int_with_check)
 613         LOCKDEP_SYS_EXIT_IRQ
 614         GET_THREAD_INFO(%rcx)
 615         movl TI_flags(%rcx),%edx
 616         andl %edi,%edx
 617         jnz   int_careful
 618         andl    $~TS_COMPAT,TI_status(%rcx)
 619         jmp   retint_swapgs
 620
 621         /* Either reschedule or signal or syscall exit tracking needed. */
 622         /* First do a reschedule test. */
 623         /* edx: work, edi: workmask */
 624 int_careful:
 625         bt $TIF_NEED_RESCHED,%edx
 626         jnc  int_very_careful
 627         TRACE_IRQS_ON
 628         ENABLE_INTERRUPTS(CLBR_NONE)
 629         pushq_cfi %rdi
 630         call schedule
 631         popq_cfi %rdi
 632         DISABLE_INTERRUPTS(CLBR_NONE)
 633         TRACE_IRQS_OFF
 634         jmp int_with_check
 635
 636         /* handle signals and tracing -- both require a full stack frame */
 637 int_very_careful:
 638         TRACE_IRQS_ON
 639         ENABLE_INTERRUPTS(CLBR_NONE)
 640 int_check_syscall_exit_work:
 641         SAVE_REST
 642         /* Check for syscall exit trace */
 643         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 644         jz int_signal
 645         pushq_cfi %rdi
 646         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 647         call syscall_trace_leave
 648         popq_cfi %rdi
 649         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 650         jmp int_restore_rest
 651
 652 int_signal:
 653         testl $_TIF_DO_NOTIFY_MASK,%edx
 654         jz 1f
 655         movq %rsp,%rdi          # &ptregs -> arg1
 656         xorl %esi,%esi          # oldset -> arg2
 657         call do_notify_resume
 658 1:      movl $_TIF_WORK_MASK,%edi
 659 int_restore_rest:
 660         RESTORE_REST
 661         DISABLE_INTERRUPTS(CLBR_NONE)
 662         TRACE_IRQS_OFF
 663         jmp int_with_check
 664         CFI_ENDPROC
 665 END(system_call)
 666
 667 /*
 668  * Certain special system calls that need to save a complete full stack frame.
 669  */
 670         .macro PTREGSCALL label,func,arg
 671 ENTRY(\label)
 672         PARTIAL_FRAME 1 8               /* offset 8: return address */
 673         subq $REST_SKIP, %rsp
 674         CFI_ADJUST_CFA_OFFSET REST_SKIP
 675         call save_rest
 676         DEFAULT_FRAME 0 8               /* offset 8: return address */
 677         leaq 8(%rsp), \arg      /* pt_regs pointer */
 678         call \func
 679         jmp ptregscall_common
 680         CFI_ENDPROC
 681 END(\label)
 682         .endm
 683
 684         PTREGSCALL stub_clone, sys_clone, %r8
 685         PTREGSCALL stub_fork, sys_fork, %rdi
 686         PTREGSCALL stub_vfork, sys_vfork, %rdi
 687         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 688         PTREGSCALL stub_iopl, sys_iopl, %rsi
 689
 690 ENTRY(ptregscall_common)
 691         DEFAULT_FRAME 1 8       /* offset 8: return address */
 692         RESTORE_TOP_OF_STACK %r11, 8
 693         movq_cfi_restore R15+8, r15
 694         movq_cfi_restore R14+8, r14
 695         movq_cfi_restore R13+8, r13
 696         movq_cfi_restore R12+8, r12
 697         movq_cfi_restore RBP+8, rbp
 698         movq_cfi_restore RBX+8, rbx
 699         ret $REST_SKIP          /* pop extended registers */
 700         CFI_ENDPROC
 701 END(ptregscall_common)
 702
 703 ENTRY(stub_execve)
 704         CFI_STARTPROC
 705         addq $8, %rsp
 706         PARTIAL_FRAME 0
 707         SAVE_REST
 708         FIXUP_TOP_OF_STACK %r11
 709         movq %rsp, %rcx
 710         call sys_execve
 711         RESTORE_TOP_OF_STACK %r11
 712         movq %rax,RAX(%rsp)
 713         RESTORE_REST
 714         jmp int_ret_from_sys_call
 715         CFI_ENDPROC
 716 END(stub_execve)
 717
 718 /*
 719  * sigreturn is special because it needs to restore all registers on return.
 720  * This cannot be done with SYSRET, so use the IRET return path instead.
 721  */
 722 ENTRY(stub_rt_sigreturn)
 723         CFI_STARTPROC
 724         addq $8, %rsp
 725         PARTIAL_FRAME 0
 726         SAVE_REST
 727         movq %rsp,%rdi
 728         FIXUP_TOP_OF_STACK %r11
 729         call sys_rt_sigreturn
 730         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 731         RESTORE_REST
 732         jmp int_ret_from_sys_call
 733         CFI_ENDPROC
 734 END(stub_rt_sigreturn)
 735
 736 /*
 737  * Build the entry stubs and pointer table with some assembler magic.
 738  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 739  * single cache line on all modern x86 implementations.
 740  */
 741         .section .init.rodata,"a"
 742 ENTRY(interrupt)
 743         .text
 744         .p2align 5
 745         .p2align CONFIG_X86_L1_CACHE_SHIFT
 746 ENTRY(irq_entries_start)
 747         INTR_FRAME
 748 vector=FIRST_EXTERNAL_VECTOR
 749 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 750         .balign 32
 751   .rept 7
 752     .if vector < NR_VECTORS
 753       .if vector <> FIRST_EXTERNAL_VECTOR
 754         CFI_ADJUST_CFA_OFFSET -8
 755       .endif
 756 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 757       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 758         jmp 2f
 759       .endif
 760       .previous
 761         .quad 1b
 762       .text
 763 vector=vector+1
 764     .endif
 765   .endr
 766 2:      jmp common_interrupt
 767 .endr
 768         CFI_ENDPROC
 769 END(irq_entries_start)
 770
 771 .previous
 772 END(interrupt)
 773 .previous
 774
 775 /*
 776  * Interrupt entry/exit.
 777  *
 778  * Interrupt entry points save only callee clobbered registers in fast path.
 779  *
 780  * Entry runs with interrupts off.
 781  */
 782
 783 /* 0(%rsp): ~(interrupt number) */
 784         .macro interrupt func
 785         subq $ORIG_RAX-ARGOFFSET+8, %rsp
 786         CFI_ADJUST_CFA_OFFSET ORIG_RAX-ARGOFFSET+8
 787         call save_args
 788         PARTIAL_FRAME 0
 789         call \func
 790         .endm
 791
 792 /*
 793  * Interrupt entry/exit should be protected against kprobes
 794  */
 795         .pushsection .kprobes.text, "ax"
 796         /*
 797          * The interrupt stubs push (~vector+0x80) onto the stack and
 798          * then jump to common_interrupt.
 799          */
 800         .p2align CONFIG_X86_L1_CACHE_SHIFT
 801 common_interrupt:
 802         XCPT_FRAME
 803         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 804         interrupt do_IRQ
 805         /* 0(%rsp): old_rsp-ARGOFFSET */
 806 ret_from_intr:
 807         DISABLE_INTERRUPTS(CLBR_NONE)
 808         TRACE_IRQS_OFF
 809         decl PER_CPU_VAR(irq_count)
 810         leaveq
 811         CFI_RESTORE             rbp
 812         CFI_DEF_CFA_REGISTER    rsp
 813         CFI_ADJUST_CFA_OFFSET   -8
 814 exit_intr:
 815         GET_THREAD_INFO(%rcx)
 816         testl $3,CS-ARGOFFSET(%rsp)
 817         je retint_kernel
 818
 819         /* Interrupt came from user space */
 820         /*
 821          * Has a correct top of stack, but a partial stack frame
 822          * %rcx: thread info. Interrupts off.
 823          */
 824 retint_with_reschedule:
 825         movl $_TIF_WORK_MASK,%edi
 826 retint_check:
 827         LOCKDEP_SYS_EXIT_IRQ
 828         movl TI_flags(%rcx),%edx
 829         andl %edi,%edx
 830         CFI_REMEMBER_STATE
 831         jnz  retint_careful
 832
 833 retint_swapgs:          /* return to user-space */
 834         /*
 835          * The iretq could re-enable interrupts:
 836          */
 837         DISABLE_INTERRUPTS(CLBR_ANY)
 838         TRACE_IRQS_IRETQ
 839         SWAPGS
 840         jmp restore_args
 841
 842 retint_restore_args:    /* return to kernel space */
 843         DISABLE_INTERRUPTS(CLBR_ANY)
 844         /*
 845          * The iretq could re-enable interrupts:
 846          */
 847         TRACE_IRQS_IRETQ
 848 restore_args:
 849         RESTORE_ARGS 0,8,0
 850
 851 irq_return:
 852         INTERRUPT_RETURN
 853
 854         .section __ex_table, "a"
 855         .quad irq_return, bad_iret
 856         .previous
 857
 858 #ifdef CONFIG_PARAVIRT
 859 ENTRY(native_iret)
 860         iretq
 861
 862         .section __ex_table,"a"
 863         .quad native_iret, bad_iret
 864         .previous
 865 #endif
 866
 867         .section .fixup,"ax"
 868 bad_iret:
 869         /*
 870          * The iret traps when the %cs or %ss being restored is bogus.
 871          * We've lost the original trap vector and error code.
 872          * #GPF is the most likely one to get for an invalid selector.
 873          * So pretend we completed the iret and took the #GPF in user mode.
 874          *
 875          * We are now running with the kernel GS after exception recovery.
 876          * But error_entry expects us to have user GS to match the user %cs,
 877          * so swap back.
 878          */
 879         pushq $0
 880
 881         SWAPGS
 882         jmp general_protection
 883
 884         .previous
 885
 886         /* edi: workmask, edx: work */
 887 retint_careful:
 888         CFI_RESTORE_STATE
 889         bt    $TIF_NEED_RESCHED,%edx
 890         jnc   retint_signal
 891         TRACE_IRQS_ON
 892         ENABLE_INTERRUPTS(CLBR_NONE)
 893         pushq_cfi %rdi
 894         call  schedule
 895         popq_cfi %rdi
 896         GET_THREAD_INFO(%rcx)
 897         DISABLE_INTERRUPTS(CLBR_NONE)
 898         TRACE_IRQS_OFF
 899         jmp retint_check
 900
 901 retint_signal:
 902         testl $_TIF_DO_NOTIFY_MASK,%edx
 903         jz    retint_swapgs
 904         TRACE_IRQS_ON
 905         ENABLE_INTERRUPTS(CLBR_NONE)
 906         SAVE_REST
 907         movq $-1,ORIG_RAX(%rsp)
 908         xorl %esi,%esi          # oldset
 909         movq %rsp,%rdi          # &pt_regs
 910         call do_notify_resume
 911         RESTORE_REST
 912         DISABLE_INTERRUPTS(CLBR_NONE)
 913         TRACE_IRQS_OFF
 914         GET_THREAD_INFO(%rcx)
 915         jmp retint_with_reschedule
 916
 917 #ifdef CONFIG_PREEMPT
 918         /* Returning to kernel space. Check if we need preemption */
 919         /* rcx:  threadinfo. interrupts off. */
 920 ENTRY(retint_kernel)
 921         cmpl $0,TI_preempt_count(%rcx)
 922         jnz  retint_restore_args
 923         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 924         jnc  retint_restore_args
 925         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 926         jnc  retint_restore_args
 927         call preempt_schedule_irq
 928         jmp exit_intr
 929 #endif
 930
 931         CFI_ENDPROC
 932 END(common_interrupt)
 933 /*
 934  * End of kprobes section
 935  */
 936        .popsection
 937
 938 /*
 939  * APIC interrupts.
 940  */
 941 .macro apicinterrupt num sym do_sym
 942 ENTRY(\sym)
 943         INTR_FRAME
 944         pushq_cfi $~(\num)
 945         interrupt \do_sym
 946         jmp ret_from_intr
 947         CFI_ENDPROC
 948 END(\sym)
 949 .endm
 950
 951 #ifdef CONFIG_SMP
 952 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 953         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 954 apicinterrupt REBOOT_VECTOR \
 955         reboot_interrupt smp_reboot_interrupt
 956 #endif
 957
 958 #ifdef CONFIG_X86_UV
 959 apicinterrupt UV_BAU_MESSAGE \
 960         uv_bau_message_intr1 uv_bau_message_interrupt
 961 #endif
 962 apicinterrupt LOCAL_TIMER_VECTOR \
 963         apic_timer_interrupt smp_apic_timer_interrupt
 964 apicinterrupt X86_PLATFORM_IPI_VECTOR \
 965         x86_platform_ipi smp_x86_platform_ipi
 966
 967 #ifdef CONFIG_SMP
 968 .irpc idx, "01234567"
 969 apicinterrupt (INVALIDATE_TLB_VECTOR_START)+\idx \
 970         invalidate_interrupt\idx smp_invalidate_interrupt
 971 .endr
 972 #endif
 973
 974 apicinterrupt THRESHOLD_APIC_VECTOR \
 975         threshold_interrupt smp_threshold_interrupt
 976 apicinterrupt THERMAL_APIC_VECTOR \
 977         thermal_interrupt smp_thermal_interrupt
 978
 979 #ifdef CONFIG_X86_MCE
 980 apicinterrupt MCE_SELF_VECTOR \
 981         mce_self_interrupt smp_mce_self_interrupt
 982 #endif
 983
 984 #ifdef CONFIG_SMP
 985 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
 986         call_function_single_interrupt smp_call_function_single_interrupt
 987 apicinterrupt CALL_FUNCTION_VECTOR \
 988         call_function_interrupt smp_call_function_interrupt
 989 apicinterrupt RESCHEDULE_VECTOR \
 990         reschedule_interrupt smp_reschedule_interrupt
 991 #endif
 992
 993 apicinterrupt ERROR_APIC_VECTOR \
 994         error_interrupt smp_error_interrupt
 995 apicinterrupt SPURIOUS_APIC_VECTOR \
 996         spurious_interrupt smp_spurious_interrupt
 997
 998 #ifdef CONFIG_IRQ_WORK
 999 apicinterrupt IRQ_WORK_VECTOR \
1000         irq_work_interrupt smp_irq_work_interrupt
1001 #endif
1002
1003 /*
1004  * Exception entry points.
1005  */
1006 .macro zeroentry sym do_sym
1007 ENTRY(\sym)
1008         INTR_FRAME
1009         PARAVIRT_ADJUST_EXCEPTION_FRAME
1010         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1011         subq $ORIG_RAX-R15, %rsp
1012         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1013         call error_entry
1014         DEFAULT_FRAME 0
1015         movq %rsp,%rdi          /* pt_regs pointer */
1016         xorl %esi,%esi          /* no error code */
1017         call \do_sym
1018         jmp error_exit          /* %ebx: no swapgs flag */
1019         CFI_ENDPROC
1020 END(\sym)
1021 .endm
1022
1023 .macro paranoidzeroentry sym do_sym
1024 ENTRY(\sym)
1025         INTR_FRAME
1026         PARAVIRT_ADJUST_EXCEPTION_FRAME
1027         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1028         subq $ORIG_RAX-R15, %rsp
1029         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1030         call save_paranoid
1031         TRACE_IRQS_OFF
1032         movq %rsp,%rdi          /* pt_regs pointer */
1033         xorl %esi,%esi          /* no error code */
1034         call \do_sym
1035         jmp paranoid_exit       /* %ebx: no swapgs flag */
1036         CFI_ENDPROC
1037 END(\sym)
1038 .endm
1039
1040 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1041 .macro paranoidzeroentry_ist sym do_sym ist
1042 ENTRY(\sym)
1043         INTR_FRAME
1044         PARAVIRT_ADJUST_EXCEPTION_FRAME
1045         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1046         subq $ORIG_RAX-R15, %rsp
1047         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1048         call save_paranoid
1049         TRACE_IRQS_OFF
1050         movq %rsp,%rdi          /* pt_regs pointer */
1051         xorl %esi,%esi          /* no error code */
1052         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1053         call \do_sym
1054         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1055         jmp paranoid_exit       /* %ebx: no swapgs flag */
1056         CFI_ENDPROC
1057 END(\sym)
1058 .endm
1059
1060 .macro errorentry sym do_sym
1061 ENTRY(\sym)
1062         XCPT_FRAME
1063         PARAVIRT_ADJUST_EXCEPTION_FRAME
1064         subq $ORIG_RAX-R15, %rsp
1065         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1066         call error_entry
1067         DEFAULT_FRAME 0
1068         movq %rsp,%rdi                  /* pt_regs pointer */
1069         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1070         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1071         call \do_sym
1072         jmp error_exit                  /* %ebx: no swapgs flag */
1073         CFI_ENDPROC
1074 END(\sym)
1075 .endm
1076
1077         /* error code is on the stack already */
1078 .macro paranoiderrorentry sym do_sym
1079 ENTRY(\sym)
1080         XCPT_FRAME
1081         PARAVIRT_ADJUST_EXCEPTION_FRAME
1082         subq $ORIG_RAX-R15, %rsp
1083         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1084         call save_paranoid
1085         DEFAULT_FRAME 0
1086         TRACE_IRQS_OFF
1087         movq %rsp,%rdi                  /* pt_regs pointer */
1088         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1089         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1090         call \do_sym
1091         jmp paranoid_exit               /* %ebx: no swapgs flag */
1092         CFI_ENDPROC
1093 END(\sym)
1094 .endm
1095
1096 zeroentry divide_error do_divide_error
1097 zeroentry overflow do_overflow
1098 zeroentry bounds do_bounds
1099 zeroentry invalid_op do_invalid_op
1100 zeroentry device_not_available do_device_not_available
1101 paranoiderrorentry double_fault do_double_fault
1102 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1103 errorentry invalid_TSS do_invalid_TSS
1104 errorentry segment_not_present do_segment_not_present
1105 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1106 zeroentry coprocessor_error do_coprocessor_error
1107 errorentry alignment_check do_alignment_check
1108 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1109
1110         /* Reload gs selector with exception handling */
1111         /* edi:  new selector */
1112 ENTRY(native_load_gs_index)
1113         CFI_STARTPROC
1114         pushfq_cfi
1115         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1116         SWAPGS
1117 gs_change:
1118         movl %edi,%gs
1119 2:      mfence          /* workaround */
1120         SWAPGS
1121         popfq_cfi
1122         ret
1123         CFI_ENDPROC
1124 END(native_load_gs_index)
1125
1126         .section __ex_table,"a"
1127         .align 8
1128         .quad gs_change,bad_gs
1129         .previous
1130         .section .fixup,"ax"
1131         /* running with kernelgs */
1132 bad_gs:
1133         SWAPGS                  /* switch back to user gs */
1134         xorl %eax,%eax
1135         movl %eax,%gs
1136         jmp  2b
1137         .previous
1138
1139 ENTRY(kernel_thread_helper)
1140         pushq $0                # fake return address
1141         CFI_STARTPROC
1142         /*
1143          * Here we are in the child and the registers are set as they were
1144          * at kernel_thread() invocation in the parent.
1145          */
1146         call *%rsi
1147         # exit
1148         mov %eax, %edi
1149         call do_exit
1150         ud2                     # padding for call trace
1151         CFI_ENDPROC
1152 END(kernel_thread_helper)
1153
1154 /*
1155  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1156  *
1157  * C extern interface:
1158  *       extern long execve(const char *name, char **argv, char **envp)
1159  *
1160  * asm input arguments:
1161  *      rdi: name, rsi: argv, rdx: envp
1162  *
1163  * We want to fallback into:
1164  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1165  *
1166  * do_sys_execve asm fallback arguments:
1167  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1168  */
1169 ENTRY(kernel_execve)
1170         CFI_STARTPROC
1171         FAKE_STACK_FRAME $0
1172         SAVE_ALL
1173         movq %rsp,%rcx
1174         call sys_execve
1175         movq %rax, RAX(%rsp)
1176         RESTORE_REST
1177         testq %rax,%rax
1178         je int_ret_from_sys_call
1179         RESTORE_ARGS
1180         UNFAKE_STACK_FRAME
1181         ret
1182         CFI_ENDPROC
1183 END(kernel_execve)
1184
1185 /* Call softirq on interrupt stack. Interrupts are off. */
1186 ENTRY(call_softirq)
1187         CFI_STARTPROC
1188         pushq_cfi %rbp
1189         CFI_REL_OFFSET rbp,0
1190         mov  %rsp,%rbp
1191         CFI_DEF_CFA_REGISTER rbp
1192         incl PER_CPU_VAR(irq_count)
1193         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1194         push  %rbp                      # backlink for old unwinder
1195         call __do_softirq
1196         leaveq
1197         CFI_RESTORE             rbp
1198         CFI_DEF_CFA_REGISTER    rsp
1199         CFI_ADJUST_CFA_OFFSET   -8
1200         decl PER_CPU_VAR(irq_count)
1201         ret
1202         CFI_ENDPROC
1203 END(call_softirq)
1204
1205 #ifdef CONFIG_XEN
1206 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1207
1208 /*
1209  * A note on the "critical region" in our callback handler.
1210  * We want to avoid stacking callback handlers due to events occurring
1211  * during handling of the last event. To do this, we keep events disabled
1212  * until we've done all processing. HOWEVER, we must enable events before
1213  * popping the stack frame (can't be done atomically) and so it would still
1214  * be possible to get enough handler activations to overflow the stack.
1215  * Although unlikely, bugs of that kind are hard to track down, so we'd
1216  * like to avoid the possibility.
1217  * So, on entry to the handler we detect whether we interrupted an
1218  * existing activation in its critical region -- if so, we pop the current
1219  * activation and restart the handler using the previous one.
1220  */
1221 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1222         CFI_STARTPROC
1223 /*
1224  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1225  * see the correct pointer to the pt_regs
1226  */
1227         movq %rdi, %rsp            # we don't return, adjust the stack frame
1228         CFI_ENDPROC
1229         DEFAULT_FRAME
1230 11:     incl PER_CPU_VAR(irq_count)
1231         movq %rsp,%rbp
1232         CFI_DEF_CFA_REGISTER rbp
1233         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1234         pushq %rbp                      # backlink for old unwinder
1235         call xen_evtchn_do_upcall
1236         popq %rsp
1237         CFI_DEF_CFA_REGISTER rsp
1238         decl PER_CPU_VAR(irq_count)
1239         jmp  error_exit
1240         CFI_ENDPROC
1241 END(do_hypervisor_callback)
1242
1243 /*
1244  * Hypervisor uses this for application faults while it executes.
1245  * We get here for two reasons:
1246  *  1. Fault while reloading DS, ES, FS or GS
1247  *  2. Fault while executing IRET
1248  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1249  * registers that could be reloaded and zeroed the others.
1250  * Category 2 we fix up by killing the current process. We cannot use the
1251  * normal Linux return path in this case because if we use the IRET hypercall
1252  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1253  * We distinguish between categories by comparing each saved segment register
1254  * with its current contents: any discrepancy means we in category 1.
1255  */
1256 ENTRY(xen_failsafe_callback)
1257         INTR_FRAME 1 (6*8)
1258         /*CFI_REL_OFFSET gs,GS*/
1259         /*CFI_REL_OFFSET fs,FS*/
1260         /*CFI_REL_OFFSET es,ES*/
1261         /*CFI_REL_OFFSET ds,DS*/
1262         CFI_REL_OFFSET r11,8
1263         CFI_REL_OFFSET rcx,0
1264         movw %ds,%cx
1265         cmpw %cx,0x10(%rsp)
1266         CFI_REMEMBER_STATE
1267         jne 1f
1268         movw %es,%cx
1269         cmpw %cx,0x18(%rsp)
1270         jne 1f
1271         movw %fs,%cx
1272         cmpw %cx,0x20(%rsp)
1273         jne 1f
1274         movw %gs,%cx
1275         cmpw %cx,0x28(%rsp)
1276         jne 1f
1277         /* All segments match their saved values => Category 2 (Bad IRET). */
1278         movq (%rsp),%rcx
1279         CFI_RESTORE rcx
1280         movq 8(%rsp),%r11
1281         CFI_RESTORE r11
1282         addq $0x30,%rsp
1283         CFI_ADJUST_CFA_OFFSET -0x30
1284         pushq_cfi $0    /* RIP */
1285         pushq_cfi %r11
1286         pushq_cfi %rcx
1287         jmp general_protection
1288         CFI_RESTORE_STATE
1289 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1290         movq (%rsp),%rcx
1291         CFI_RESTORE rcx
1292         movq 8(%rsp),%r11
1293         CFI_RESTORE r11
1294         addq $0x30,%rsp
1295         CFI_ADJUST_CFA_OFFSET -0x30
1296         pushq_cfi $0
1297         SAVE_ALL
1298         jmp error_exit
1299         CFI_ENDPROC
1300 END(xen_failsafe_callback)
1301
1302 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1303         xen_hvm_callback_vector xen_evtchn_do_upcall
1304
1305 #endif /* CONFIG_XEN */
1306
1307 /*
1308  * Some functions should be protected against kprobes
1309  */
1310         .pushsection .kprobes.text, "ax"
1311
1312 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1313 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1314 paranoiderrorentry stack_segment do_stack_segment
1315 #ifdef CONFIG_XEN
1316 zeroentry xen_debug do_debug
1317 zeroentry xen_int3 do_int3
1318 errorentry xen_stack_segment do_stack_segment
1319 #endif
1320 errorentry general_protection do_general_protection
1321 errorentry page_fault do_page_fault
1322 #ifdef CONFIG_X86_MCE
1323 paranoidzeroentry machine_check *machine_check_vector(%rip)
1324 #endif
1325
1326         /*
1327          * "Paranoid" exit path from exception stack.
1328          * Paranoid because this is used by NMIs and cannot take
1329          * any kernel state for granted.
1330          * We don't do kernel preemption checks here, because only
1331          * NMI should be common and it does not enable IRQs and
1332          * cannot get reschedule ticks.
1333          *
1334          * "trace" is 0 for the NMI handler only, because irq-tracing
1335          * is fundamentally NMI-unsafe. (we cannot change the soft and
1336          * hard flags at once, atomically)
1337          */
1338
1339         /* ebx: no swapgs flag */
1340 ENTRY(paranoid_exit)
1341         DEFAULT_FRAME
1342         DISABLE_INTERRUPTS(CLBR_NONE)
1343         TRACE_IRQS_OFF
1344         testl %ebx,%ebx                         /* swapgs needed? */
1345         jnz paranoid_restore
1346         testl $3,CS(%rsp)
1347         jnz   paranoid_userspace
1348 paranoid_swapgs:
1349         TRACE_IRQS_IRETQ 0
1350         SWAPGS_UNSAFE_STACK
1351         RESTORE_ALL 8
1352         jmp irq_return
1353 paranoid_restore:
1354         TRACE_IRQS_IRETQ 0
1355         RESTORE_ALL 8
1356         jmp irq_return
1357 paranoid_userspace:
1358         GET_THREAD_INFO(%rcx)
1359         movl TI_flags(%rcx),%ebx
1360         andl $_TIF_WORK_MASK,%ebx
1361         jz paranoid_swapgs
1362         movq %rsp,%rdi                  /* &pt_regs */
1363         call sync_regs
1364         movq %rax,%rsp                  /* switch stack for scheduling */
1365         testl $_TIF_NEED_RESCHED,%ebx
1366         jnz paranoid_schedule
1367         movl %ebx,%edx                  /* arg3: thread flags */
1368         TRACE_IRQS_ON
1369         ENABLE_INTERRUPTS(CLBR_NONE)
1370         xorl %esi,%esi                  /* arg2: oldset */
1371         movq %rsp,%rdi                  /* arg1: &pt_regs */
1372         call do_notify_resume
1373         DISABLE_INTERRUPTS(CLBR_NONE)
1374         TRACE_IRQS_OFF
1375         jmp paranoid_userspace
1376 paranoid_schedule:
1377         TRACE_IRQS_ON
1378         ENABLE_INTERRUPTS(CLBR_ANY)
1379         call schedule
1380         DISABLE_INTERRUPTS(CLBR_ANY)
1381         TRACE_IRQS_OFF
1382         jmp paranoid_userspace
1383         CFI_ENDPROC
1384 END(paranoid_exit)
1385
1386 /*
1387  * Exception entry point. This expects an error code/orig_rax on the stack.
1388  * returns in "no swapgs flag" in %ebx.
1389  */
1390 ENTRY(error_entry)
1391         XCPT_FRAME
1392         CFI_ADJUST_CFA_OFFSET 15*8
1393         /* oldrax contains error code */
1394         cld
1395         movq_cfi rdi, RDI+8
1396         movq_cfi rsi, RSI+8
1397         movq_cfi rdx, RDX+8
1398         movq_cfi rcx, RCX+8
1399         movq_cfi rax, RAX+8
1400         movq_cfi  r8,  R8+8
1401         movq_cfi  r9,  R9+8
1402         movq_cfi r10, R10+8
1403         movq_cfi r11, R11+8
1404         movq_cfi rbx, RBX+8
1405         movq_cfi rbp, RBP+8
1406         movq_cfi r12, R12+8
1407         movq_cfi r13, R13+8
1408         movq_cfi r14, R14+8
1409         movq_cfi r15, R15+8
1410         xorl %ebx,%ebx
1411         testl $3,CS+8(%rsp)
1412         je error_kernelspace
1413 error_swapgs:
1414         SWAPGS
1415 error_sti:
1416         TRACE_IRQS_OFF
1417         ret
1418
1419 /*
1420  * There are two places in the kernel that can potentially fault with
1421  * usergs. Handle them here. The exception handlers after iret run with
1422  * kernel gs again, so don't set the user space flag. B stepping K8s
1423  * sometimes report an truncated RIP for IRET exceptions returning to
1424  * compat mode. Check for these here too.
1425  */
1426 error_kernelspace:
1427         incl %ebx
1428         leaq irq_return(%rip),%rcx
1429         cmpq %rcx,RIP+8(%rsp)
1430         je error_swapgs
1431         movl %ecx,%eax  /* zero extend */
1432         cmpq %rax,RIP+8(%rsp)
1433         je bstep_iret
1434         cmpq $gs_change,RIP+8(%rsp)
1435         je error_swapgs
1436         jmp error_sti
1437
1438 bstep_iret:
1439         /* Fix truncated RIP */
1440         movq %rcx,RIP+8(%rsp)
1441         jmp error_swapgs
1442         CFI_ENDPROC
1443 END(error_entry)
1444
1445
1446 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1447 ENTRY(error_exit)
1448         DEFAULT_FRAME
1449         movl %ebx,%eax
1450         RESTORE_REST
1451         DISABLE_INTERRUPTS(CLBR_NONE)
1452         TRACE_IRQS_OFF
1453         GET_THREAD_INFO(%rcx)
1454         testl %eax,%eax
1455         jne retint_kernel
1456         LOCKDEP_SYS_EXIT_IRQ
1457         movl TI_flags(%rcx),%edx
1458         movl $_TIF_WORK_MASK,%edi
1459         andl %edi,%edx
1460         jnz retint_careful
1461         jmp retint_swapgs
1462         CFI_ENDPROC
1463 END(error_exit)
1464
1465
1466         /* runs on exception stack */
1467 ENTRY(nmi)
1468         INTR_FRAME
1469         PARAVIRT_ADJUST_EXCEPTION_FRAME
1470         pushq_cfi $-1
1471         subq $ORIG_RAX-R15, %rsp
1472         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1473         call save_paranoid
1474         DEFAULT_FRAME 0
1475         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1476         movq %rsp,%rdi
1477         movq $-1,%rsi
1478         call do_nmi
1479 #ifdef CONFIG_TRACE_IRQFLAGS
1480         /* paranoidexit; without TRACE_IRQS_OFF */
1481         /* ebx: no swapgs flag */
1482         DISABLE_INTERRUPTS(CLBR_NONE)
1483         testl %ebx,%ebx                         /* swapgs needed? */
1484         jnz nmi_restore
1485         testl $3,CS(%rsp)
1486         jnz nmi_userspace
1487 nmi_swapgs:
1488         SWAPGS_UNSAFE_STACK
1489 nmi_restore:
1490         RESTORE_ALL 8
1491         jmp irq_return
1492 nmi_userspace:
1493         GET_THREAD_INFO(%rcx)
1494         movl TI_flags(%rcx),%ebx
1495         andl $_TIF_WORK_MASK,%ebx
1496         jz nmi_swapgs
1497         movq %rsp,%rdi                  /* &pt_regs */
1498         call sync_regs
1499         movq %rax,%rsp                  /* switch stack for scheduling */
1500         testl $_TIF_NEED_RESCHED,%ebx
1501         jnz nmi_schedule
1502         movl %ebx,%edx                  /* arg3: thread flags */
1503         ENABLE_INTERRUPTS(CLBR_NONE)
1504         xorl %esi,%esi                  /* arg2: oldset */
1505         movq %rsp,%rdi                  /* arg1: &pt_regs */
1506         call do_notify_resume
1507         DISABLE_INTERRUPTS(CLBR_NONE)
1508         jmp nmi_userspace
1509 nmi_schedule:
1510         ENABLE_INTERRUPTS(CLBR_ANY)
1511         call schedule
1512         DISABLE_INTERRUPTS(CLBR_ANY)
1513         jmp nmi_userspace
1514         CFI_ENDPROC
1515 #else
1516         jmp paranoid_exit
1517         CFI_ENDPROC
1518 #endif
1519 END(nmi)
1520
1521 ENTRY(ignore_sysret)
1522         CFI_STARTPROC
1523         mov $-ENOSYS,%eax
1524         sysret
1525         CFI_ENDPROC
1526 END(ignore_sysret)
1527
1528 /*
1529  * End of kprobes section
1530  */
1531         .popsection