arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers up to R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page_types.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/percpu.h>
  56
  57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  58 #include <linux/elf-em.h>
  59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  60 #define __AUDIT_ARCH_64BIT 0x80000000
  61 #define __AUDIT_ARCH_LE    0x40000000
  62
  63         .code64
  64         .section .entry.text, "ax"
  65
  66 #ifdef CONFIG_FUNCTION_TRACER
  67 #ifdef CONFIG_DYNAMIC_FTRACE
  68 ENTRY(mcount)
  69         retq
  70 END(mcount)
  71
  72 ENTRY(ftrace_caller)
  73         cmpl $0, function_trace_stop
  74         jne  ftrace_stub
  75
  76         MCOUNT_SAVE_FRAME
  77
  78         movq 0x38(%rsp), %rdi
  79         movq 8(%rbp), %rsi
  80         subq $MCOUNT_INSN_SIZE, %rdi
  81
  82 GLOBAL(ftrace_call)
  83         call ftrace_stub
  84
  85         MCOUNT_RESTORE_FRAME
  86
  87 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  88 GLOBAL(ftrace_graph_call)
  89         jmp ftrace_stub
  90 #endif
  91
  92 GLOBAL(ftrace_stub)
  93         retq
  94 END(ftrace_caller)
  95
  96 #else /* ! CONFIG_DYNAMIC_FTRACE */
  97 ENTRY(mcount)
  98         cmpl $0, function_trace_stop
  99         jne  ftrace_stub
 100
 101         cmpq $ftrace_stub, ftrace_trace_function
 102         jnz trace
 103
 104 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 105         cmpq $ftrace_stub, ftrace_graph_return
 106         jnz ftrace_graph_caller
 107
 108         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 109         jnz ftrace_graph_caller
 110 #endif
 111
 112 GLOBAL(ftrace_stub)
 113         retq
 114
 115 trace:
 116         MCOUNT_SAVE_FRAME
 117
 118         movq 0x38(%rsp), %rdi
 119         movq 8(%rbp), %rsi
 120         subq $MCOUNT_INSN_SIZE, %rdi
 121
 122         call   *ftrace_trace_function
 123
 124         MCOUNT_RESTORE_FRAME
 125
 126         jmp ftrace_stub
 127 END(mcount)
 128 #endif /* CONFIG_DYNAMIC_FTRACE */
 129 #endif /* CONFIG_FUNCTION_TRACER */
 130
 131 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 132 ENTRY(ftrace_graph_caller)
 133         cmpl $0, function_trace_stop
 134         jne ftrace_stub
 135
 136         MCOUNT_SAVE_FRAME
 137
 138         leaq 8(%rbp), %rdi
 139         movq 0x38(%rsp), %rsi
 140         movq (%rbp), %rdx
 141         subq $MCOUNT_INSN_SIZE, %rsi
 142
 143         call    prepare_ftrace_return
 144
 145         MCOUNT_RESTORE_FRAME
 146
 147         retq
 148 END(ftrace_graph_caller)
 149
 150 GLOBAL(return_to_handler)
 151         subq  $24, %rsp
 152
 153         /* Save the return values */
 154         movq %rax, (%rsp)
 155         movq %rdx, 8(%rsp)
 156         movq %rbp, %rdi
 157
 158         call ftrace_return_to_handler
 159
 160         movq %rax, %rdi
 161         movq 8(%rsp), %rdx
 162         movq (%rsp), %rax
 163         addq $24, %rsp
 164         jmp *%rdi
 165 #endif
 166
 167
 168 #ifndef CONFIG_PREEMPT
 169 #define retint_kernel retint_restore_args
 170 #endif
 171
 172 #ifdef CONFIG_PARAVIRT
 173 ENTRY(native_usergs_sysret64)
 174         swapgs
 175         sysretq
 176 ENDPROC(native_usergs_sysret64)
 177 #endif /* CONFIG_PARAVIRT */
 178
 179
 180 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 181 #ifdef CONFIG_TRACE_IRQFLAGS
 182         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 183         jnc  1f
 184         TRACE_IRQS_ON
 185 1:
 186 #endif
 187 .endm
 188
 189 /*
 190  * C code is not supposed to know about undefined top of stack. Every time
 191  * a C function with an pt_regs argument is called from the SYSCALL based
 192  * fast path FIXUP_TOP_OF_STACK is needed.
 193  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 194  * manipulation.
 195  */
 196
 197         /* %rsp:at FRAMEEND */
 198         .macro FIXUP_TOP_OF_STACK tmp offset=0
 199         movq PER_CPU_VAR(old_rsp),\tmp
 200         movq \tmp,RSP+\offset(%rsp)
 201         movq $__USER_DS,SS+\offset(%rsp)
 202         movq $__USER_CS,CS+\offset(%rsp)
 203         movq $-1,RCX+\offset(%rsp)
 204         movq R11+\offset(%rsp),\tmp  /* get eflags */
 205         movq \tmp,EFLAGS+\offset(%rsp)
 206         .endm
 207
 208         .macro RESTORE_TOP_OF_STACK tmp offset=0
 209         movq RSP+\offset(%rsp),\tmp
 210         movq \tmp,PER_CPU_VAR(old_rsp)
 211         movq EFLAGS+\offset(%rsp),\tmp
 212         movq \tmp,R11+\offset(%rsp)
 213         .endm
 214
 215         .macro FAKE_STACK_FRAME child_rip
 216         /* push in order ss, rsp, eflags, cs, rip */
 217         xorl %eax, %eax
 218         pushq_cfi $__KERNEL_DS /* ss */
 219         /*CFI_REL_OFFSET        ss,0*/
 220         pushq_cfi %rax /* rsp */
 221         CFI_REL_OFFSET  rsp,0
 222         pushq_cfi $X86_EFLAGS_IF /* eflags - interrupts on */
 223         /*CFI_REL_OFFSET        rflags,0*/
 224         pushq_cfi $__KERNEL_CS /* cs */
 225         /*CFI_REL_OFFSET        cs,0*/
 226         pushq_cfi \child_rip /* rip */
 227         CFI_REL_OFFSET  rip,0
 228         pushq_cfi %rax /* orig rax */
 229         .endm
 230
 231         .macro UNFAKE_STACK_FRAME
 232         addq $8*6, %rsp
 233         CFI_ADJUST_CFA_OFFSET   -(6*8)
 234         .endm
 235
 236 /*
 237  * initial frame state for interrupts (and exceptions without error code)
 238  */
 239         .macro EMPTY_FRAME start=1 offset=0
 240         .if \start
 241         CFI_STARTPROC simple
 242         CFI_SIGNAL_FRAME
 243         CFI_DEF_CFA rsp,8+\offset
 244         .else
 245         CFI_DEF_CFA_OFFSET 8+\offset
 246         .endif
 247         .endm
 248
 249 /*
 250  * initial frame state for interrupts (and exceptions without error code)
 251  */
 252         .macro INTR_FRAME start=1 offset=0
 253         EMPTY_FRAME \start, SS+8+\offset-RIP
 254         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 255         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 256         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 257         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 258         CFI_REL_OFFSET rip, RIP+\offset-RIP
 259         .endm
 260
 261 /*
 262  * initial frame state for exceptions with error code (and interrupts
 263  * with vector already pushed)
 264  */
 265         .macro XCPT_FRAME start=1 offset=0
 266         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 267         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 268         .endm
 269
 270 /*
 271  * frame that enables calling into C.
 272  */
 273         .macro PARTIAL_FRAME start=1 offset=0
 274         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 275         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 276         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 277         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 278         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 280         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 281         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 282         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 283         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 284         .endm
 285
 286 /*
 287  * frame that enables passing a complete pt_regs to a C function.
 288  */
 289         .macro DEFAULT_FRAME start=1 offset=0
 290         PARTIAL_FRAME \start, R11+\offset-R15
 291         CFI_REL_OFFSET rbx, RBX+\offset
 292         CFI_REL_OFFSET rbp, RBP+\offset
 293         CFI_REL_OFFSET r12, R12+\offset
 294         CFI_REL_OFFSET r13, R13+\offset
 295         CFI_REL_OFFSET r14, R14+\offset
 296         CFI_REL_OFFSET r15, R15+\offset
 297         .endm
 298
 299 /* save partial stack frame */
 300         .macro SAVE_ARGS_IRQ
 301         cld
 302         /* start from rbp in pt_regs and jump over */
 303         movq_cfi rdi, RDI-RBP
 304         movq_cfi rsi, RSI-RBP
 305         movq_cfi rdx, RDX-RBP
 306         movq_cfi rcx, RCX-RBP
 307         movq_cfi rax, RAX-RBP
 308         movq_cfi  r8,  R8-RBP
 309         movq_cfi  r9,  R9-RBP
 310         movq_cfi r10, R10-RBP
 311         movq_cfi r11, R11-RBP
 312
 313         /* Save rbp so that we can unwind from get_irq_regs() */
 314         movq_cfi rbp, 0
 315
 316         /* Save previous stack value */
 317         movq %rsp, %rsi
 318
 319         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 320         testl $3, CS(%rdi)
 321         je 1f
 322         SWAPGS
 323         /*
 324          * irq_count is used to check if a CPU is already on an interrupt stack
 325          * or not. While this is essentially redundant with preempt_count it is
 326          * a little cheaper to use a separate counter in the PDA (short of
 327          * moving irq_enter into assembly, which would be too much work)
 328          */
 329 1:      incl PER_CPU_VAR(irq_count)
 330         jne 2f
 331         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 332         EMPTY_FRAME 0
 333
 334 2:      /* Store previous stack value */
 335         pushq %rsi
 336         /* We entered an interrupt context - irqs are off: */
 337         TRACE_IRQS_OFF
 338         .endm
 339
 340 ENTRY(save_rest)
 341         PARTIAL_FRAME 1 REST_SKIP+8
 342         movq 5*8+16(%rsp), %r11 /* save return address */
 343         movq_cfi rbx, RBX+16
 344         movq_cfi rbp, RBP+16
 345         movq_cfi r12, R12+16
 346         movq_cfi r13, R13+16
 347         movq_cfi r14, R14+16
 348         movq_cfi r15, R15+16
 349         movq %r11, 8(%rsp)      /* return address */
 350         FIXUP_TOP_OF_STACK %r11, 16
 351         ret
 352         CFI_ENDPROC
 353 END(save_rest)
 354
 355 /* save complete stack frame */
 356         .pushsection .kprobes.text, "ax"
 357 ENTRY(save_paranoid)
 358         XCPT_FRAME 1 RDI+8
 359         cld
 360         movq_cfi rdi, RDI+8
 361         movq_cfi rsi, RSI+8
 362         movq_cfi rdx, RDX+8
 363         movq_cfi rcx, RCX+8
 364         movq_cfi rax, RAX+8
 365         movq_cfi r8, R8+8
 366         movq_cfi r9, R9+8
 367         movq_cfi r10, R10+8
 368         movq_cfi r11, R11+8
 369         movq_cfi rbx, RBX+8
 370         movq_cfi rbp, RBP+8
 371         movq_cfi r12, R12+8
 372         movq_cfi r13, R13+8
 373         movq_cfi r14, R14+8
 374         movq_cfi r15, R15+8
 375         movl $1,%ebx
 376         movl $MSR_GS_BASE,%ecx
 377         rdmsr
 378         testl %edx,%edx
 379         js 1f   /* negative -> in kernel */
 380         SWAPGS
 381         xorl %ebx,%ebx
 382 1:      ret
 383         CFI_ENDPROC
 384 END(save_paranoid)
 385         .popsection
 386
 387 /*
 388  * A newly forked process directly context switches into this address.
 389  *
 390  * rdi: prev task we switched from
 391  */
 392 ENTRY(ret_from_fork)
 393         DEFAULT_FRAME
 394
 395         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 396
 397         pushq_cfi kernel_eflags(%rip)
 398         popfq_cfi                               # reset kernel eflags
 399
 400         call schedule_tail                      # rdi: 'prev' task parameter
 401
 402         GET_THREAD_INFO(%rcx)
 403
 404         RESTORE_REST
 405
 406         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 407         je   int_ret_from_sys_call
 408
 409         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 410         jnz  int_ret_from_sys_call
 411
 412         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 413         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 414
 415         CFI_ENDPROC
 416 END(ret_from_fork)
 417
 418 /*
 419  * System call entry. Up to 6 arguments in registers are supported.
 420  *
 421  * SYSCALL does not save anything on the stack and does not change the
 422  * stack pointer.
 423  */
 424
 425 /*
 426  * Register setup:
 427  * rax  system call number
 428  * rdi  arg0
 429  * rcx  return address for syscall/sysret, C arg3
 430  * rsi  arg1
 431  * rdx  arg2
 432  * r10  arg3    (--> moved to rcx for C)
 433  * r8   arg4
 434  * r9   arg5
 435  * r11  eflags for syscall/sysret, temporary for C
 436  * r12-r15,rbp,rbx saved by C code, not touched.
 437  *
 438  * Interrupts are off on entry.
 439  * Only called from user space.
 440  *
 441  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 442  *      and report it properly in ps. Unfortunately we haven't.
 443  *
 444  * When user can change the frames always force IRET. That is because
 445  * it deals with uncanonical addresses better. SYSRET has trouble
 446  * with them due to bugs in both AMD and Intel CPUs.
 447  */
 448
 449 ENTRY(system_call)
 450         CFI_STARTPROC   simple
 451         CFI_SIGNAL_FRAME
 452         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 453         CFI_REGISTER    rip,rcx
 454         /*CFI_REGISTER  rflags,r11*/
 455         SWAPGS_UNSAFE_STACK
 456         /*
 457          * A hypervisor implementation might want to use a label
 458          * after the swapgs, so that it can do the swapgs
 459          * for the guest and jump here on syscall.
 460          */
 461 ENTRY(system_call_after_swapgs)
 462
 463         movq    %rsp,PER_CPU_VAR(old_rsp)
 464         movq    PER_CPU_VAR(kernel_stack),%rsp
 465         /*
 466          * No need to follow this irqs off/on section - it's straight
 467          * and short:
 468          */
 469         ENABLE_INTERRUPTS(CLBR_NONE)
 470         SAVE_ARGS 8,1
 471         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 472         movq  %rcx,RIP-ARGOFFSET(%rsp)
 473         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 474         GET_THREAD_INFO(%rcx)
 475         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 476         jnz tracesys
 477 system_call_fastpath:
 478         cmpq $__NR_syscall_max,%rax
 479         ja badsys
 480         movq %r10,%rcx
 481         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 482         movq %rax,RAX-ARGOFFSET(%rsp)
 483 /*
 484  * Syscall return path ending with SYSRET (fast path)
 485  * Has incomplete stack frame and undefined top of stack.
 486  */
 487 ret_from_sys_call:
 488         movl $_TIF_ALLWORK_MASK,%edi
 489         /* edi: flagmask */
 490 sysret_check:
 491         LOCKDEP_SYS_EXIT
 492         GET_THREAD_INFO(%rcx)
 493         DISABLE_INTERRUPTS(CLBR_NONE)
 494         TRACE_IRQS_OFF
 495         movl TI_flags(%rcx),%edx
 496         andl %edi,%edx
 497         jnz  sysret_careful
 498         CFI_REMEMBER_STATE
 499         /*
 500          * sysretq will re-enable interrupts:
 501          */
 502         TRACE_IRQS_ON
 503         movq RIP-ARGOFFSET(%rsp),%rcx
 504         CFI_REGISTER    rip,rcx
 505         RESTORE_ARGS 0,-ARG_SKIP,1
 506         /*CFI_REGISTER  rflags,r11*/
 507         movq    PER_CPU_VAR(old_rsp), %rsp
 508         USERGS_SYSRET64
 509
 510         CFI_RESTORE_STATE
 511         /* Handle reschedules */
 512         /* edx: work, edi: workmask */
 513 sysret_careful:
 514         bt $TIF_NEED_RESCHED,%edx
 515         jnc sysret_signal
 516         TRACE_IRQS_ON
 517         ENABLE_INTERRUPTS(CLBR_NONE)
 518         pushq_cfi %rdi
 519         call schedule
 520         popq_cfi %rdi
 521         jmp sysret_check
 522
 523         /* Handle a signal */
 524 sysret_signal:
 525         TRACE_IRQS_ON
 526         ENABLE_INTERRUPTS(CLBR_NONE)
 527 #ifdef CONFIG_AUDITSYSCALL
 528         bt $TIF_SYSCALL_AUDIT,%edx
 529         jc sysret_audit
 530 #endif
 531         /*
 532          * We have a signal, or exit tracing or single-step.
 533          * These all wind up with the iret return path anyway,
 534          * so just join that path right now.
 535          */
 536         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 537         jmp int_check_syscall_exit_work
 538
 539 badsys:
 540         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 541         jmp ret_from_sys_call
 542
 543 #ifdef CONFIG_AUDITSYSCALL
 544         /*
 545          * Fast path for syscall audit without full syscall trace.
 546          * We just call audit_syscall_entry() directly, and then
 547          * jump back to the normal fast path.
 548          */
 549 auditsys:
 550         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 551         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 552         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 553         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 554         movq %rax,%rsi                  /* 2nd arg: syscall number */
 555         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 556         call audit_syscall_entry
 557         LOAD_ARGS 0             /* reload call-clobbered registers */
 558         jmp system_call_fastpath
 559
 560         /*
 561          * Return fast path for syscall audit.  Call audit_syscall_exit()
 562          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 563          * masked off.
 564          */
 565 sysret_audit:
 566         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 567         cmpq $0,%rsi            /* is it < 0? */
 568         setl %al                /* 1 if so, 0 if not */
 569         movzbl %al,%edi         /* zero-extend that into %edi */
 570         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 571         call audit_syscall_exit
 572         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 573         jmp sysret_check
 574 #endif  /* CONFIG_AUDITSYSCALL */
 575
 576         /* Do syscall tracing */
 577 tracesys:
 578 #ifdef CONFIG_AUDITSYSCALL
 579         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 580         jz auditsys
 581 #endif
 582         SAVE_REST
 583         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 584         FIXUP_TOP_OF_STACK %rdi
 585         movq %rsp,%rdi
 586         call syscall_trace_enter
 587         /*
 588          * Reload arg registers from stack in case ptrace changed them.
 589          * We don't reload %rax because syscall_trace_enter() returned
 590          * the value it wants us to use in the table lookup.
 591          */
 592         LOAD_ARGS ARGOFFSET, 1
 593         RESTORE_REST
 594         cmpq $__NR_syscall_max,%rax
 595         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 596         movq %r10,%rcx  /* fixup for C */
 597         call *sys_call_table(,%rax,8)
 598         movq %rax,RAX-ARGOFFSET(%rsp)
 599         /* Use IRET because user could have changed frame */
 600
 601 /*
 602  * Syscall return path ending with IRET.
 603  * Has correct top of stack, but partial stack frame.
 604  */
 605 GLOBAL(int_ret_from_sys_call)
 606         DISABLE_INTERRUPTS(CLBR_NONE)
 607         TRACE_IRQS_OFF
 608         testl $3,CS-ARGOFFSET(%rsp)
 609         je retint_restore_args
 610         movl $_TIF_ALLWORK_MASK,%edi
 611         /* edi: mask to check */
 612 GLOBAL(int_with_check)
 613         LOCKDEP_SYS_EXIT_IRQ
 614         GET_THREAD_INFO(%rcx)
 615         movl TI_flags(%rcx),%edx
 616         andl %edi,%edx
 617         jnz   int_careful
 618         andl    $~TS_COMPAT,TI_status(%rcx)
 619         jmp   retint_swapgs
 620
 621         /* Either reschedule or signal or syscall exit tracking needed. */
 622         /* First do a reschedule test. */
 623         /* edx: work, edi: workmask */
 624 int_careful:
 625         bt $TIF_NEED_RESCHED,%edx
 626         jnc  int_very_careful
 627         TRACE_IRQS_ON
 628         ENABLE_INTERRUPTS(CLBR_NONE)
 629         pushq_cfi %rdi
 630         call schedule
 631         popq_cfi %rdi
 632         DISABLE_INTERRUPTS(CLBR_NONE)
 633         TRACE_IRQS_OFF
 634         jmp int_with_check
 635
 636         /* handle signals and tracing -- both require a full stack frame */
 637 int_very_careful:
 638         TRACE_IRQS_ON
 639         ENABLE_INTERRUPTS(CLBR_NONE)
 640 int_check_syscall_exit_work:
 641         SAVE_REST
 642         /* Check for syscall exit trace */
 643         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 644         jz int_signal
 645         pushq_cfi %rdi
 646         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 647         call syscall_trace_leave
 648         popq_cfi %rdi
 649         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 650         jmp int_restore_rest
 651
 652 int_signal:
 653         testl $_TIF_DO_NOTIFY_MASK,%edx
 654         jz 1f
 655         movq %rsp,%rdi          # &ptregs -> arg1
 656         xorl %esi,%esi          # oldset -> arg2
 657         call do_notify_resume
 658 1:      movl $_TIF_WORK_MASK,%edi
 659 int_restore_rest:
 660         RESTORE_REST
 661         DISABLE_INTERRUPTS(CLBR_NONE)
 662         TRACE_IRQS_OFF
 663         jmp int_with_check
 664         CFI_ENDPROC
 665 END(system_call)
 666
 667 /*
 668  * Certain special system calls that need to save a complete full stack frame.
 669  */
 670         .macro PTREGSCALL label,func,arg
 671 ENTRY(\label)
 672         PARTIAL_FRAME 1 8               /* offset 8: return address */
 673         subq $REST_SKIP, %rsp
 674         CFI_ADJUST_CFA_OFFSET REST_SKIP
 675         call save_rest
 676         DEFAULT_FRAME 0 8               /* offset 8: return address */
 677         leaq 8(%rsp), \arg      /* pt_regs pointer */
 678         call \func
 679         jmp ptregscall_common
 680         CFI_ENDPROC
 681 END(\label)
 682         .endm
 683
 684         PTREGSCALL stub_clone, sys_clone, %r8
 685         PTREGSCALL stub_fork, sys_fork, %rdi
 686         PTREGSCALL stub_vfork, sys_vfork, %rdi
 687         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 688         PTREGSCALL stub_iopl, sys_iopl, %rsi
 689
 690 ENTRY(ptregscall_common)
 691         DEFAULT_FRAME 1 8       /* offset 8: return address */
 692         RESTORE_TOP_OF_STACK %r11, 8
 693         movq_cfi_restore R15+8, r15
 694         movq_cfi_restore R14+8, r14
 695         movq_cfi_restore R13+8, r13
 696         movq_cfi_restore R12+8, r12
 697         movq_cfi_restore RBP+8, rbp
 698         movq_cfi_restore RBX+8, rbx
 699         ret $REST_SKIP          /* pop extended registers */
 700         CFI_ENDPROC
 701 END(ptregscall_common)
 702
 703 ENTRY(stub_execve)
 704         CFI_STARTPROC
 705         addq $8, %rsp
 706         PARTIAL_FRAME 0
 707         SAVE_REST
 708         FIXUP_TOP_OF_STACK %r11
 709         movq %rsp, %rcx
 710         call sys_execve
 711         RESTORE_TOP_OF_STACK %r11
 712         movq %rax,RAX(%rsp)
 713         RESTORE_REST
 714         jmp int_ret_from_sys_call
 715         CFI_ENDPROC
 716 END(stub_execve)
 717
 718 /*
 719  * sigreturn is special because it needs to restore all registers on return.
 720  * This cannot be done with SYSRET, so use the IRET return path instead.
 721  */
 722 ENTRY(stub_rt_sigreturn)
 723         CFI_STARTPROC
 724         addq $8, %rsp
 725         PARTIAL_FRAME 0
 726         SAVE_REST
 727         movq %rsp,%rdi
 728         FIXUP_TOP_OF_STACK %r11
 729         call sys_rt_sigreturn
 730         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 731         RESTORE_REST
 732         jmp int_ret_from_sys_call
 733         CFI_ENDPROC
 734 END(stub_rt_sigreturn)
 735
 736 /*
 737  * Build the entry stubs and pointer table with some assembler magic.
 738  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 739  * single cache line on all modern x86 implementations.
 740  */
 741         .section .init.rodata,"a"
 742 ENTRY(interrupt)
 743         .section .entry.text
 744         .p2align 5
 745         .p2align CONFIG_X86_L1_CACHE_SHIFT
 746 ENTRY(irq_entries_start)
 747         INTR_FRAME
 748 vector=FIRST_EXTERNAL_VECTOR
 749 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 750         .balign 32
 751   .rept 7
 752     .if vector < NR_VECTORS
 753       .if vector <> FIRST_EXTERNAL_VECTOR
 754         CFI_ADJUST_CFA_OFFSET -8
 755       .endif
 756 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 757       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 758         jmp 2f
 759       .endif
 760       .previous
 761         .quad 1b
 762       .section .entry.text
 763 vector=vector+1
 764     .endif
 765   .endr
 766 2:      jmp common_interrupt
 767 .endr
 768         CFI_ENDPROC
 769 END(irq_entries_start)
 770
 771 .previous
 772 END(interrupt)
 773 .previous
 774
 775 /*
 776  * Interrupt entry/exit.
 777  *
 778  * Interrupt entry points save only callee clobbered registers in fast path.
 779  *
 780  * Entry runs with interrupts off.
 781  */
 782
 783 /* 0(%rsp): ~(interrupt number) */
 784         .macro interrupt func
 785         /* reserve pt_regs for scratch regs and rbp */
 786         subq $ORIG_RAX-RBP, %rsp
 787         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 788         SAVE_ARGS_IRQ
 789         PARTIAL_FRAME 0
 790         call \func
 791         .endm
 792
 793 /*
 794  * Interrupt entry/exit should be protected against kprobes
 795  */
 796         .pushsection .kprobes.text, "ax"
 797         /*
 798          * The interrupt stubs push (~vector+0x80) onto the stack and
 799          * then jump to common_interrupt.
 800          */
 801         .p2align CONFIG_X86_L1_CACHE_SHIFT
 802 common_interrupt:
 803         XCPT_FRAME
 804         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 805         interrupt do_IRQ
 806         /* 0(%rsp): old_rsp-ARGOFFSET */
 807 ret_from_intr:
 808         DISABLE_INTERRUPTS(CLBR_NONE)
 809         TRACE_IRQS_OFF
 810         decl PER_CPU_VAR(irq_count)
 811
 812         /* Restore saved previous stack */
 813         popq %rsi
 814         leaq 16(%rsi), %rsp
 815
 816         CFI_DEF_CFA_REGISTER    rsp
 817         CFI_ADJUST_CFA_OFFSET   -16
 818
 819 exit_intr:
 820         GET_THREAD_INFO(%rcx)
 821         testl $3,CS-ARGOFFSET(%rsp)
 822         je retint_kernel
 823
 824         /* Interrupt came from user space */
 825         /*
 826          * Has a correct top of stack, but a partial stack frame
 827          * %rcx: thread info. Interrupts off.
 828          */
 829 retint_with_reschedule:
 830         movl $_TIF_WORK_MASK,%edi
 831 retint_check:
 832         LOCKDEP_SYS_EXIT_IRQ
 833         movl TI_flags(%rcx),%edx
 834         andl %edi,%edx
 835         CFI_REMEMBER_STATE
 836         jnz  retint_careful
 837
 838 retint_swapgs:          /* return to user-space */
 839         /*
 840          * The iretq could re-enable interrupts:
 841          */
 842         DISABLE_INTERRUPTS(CLBR_ANY)
 843         TRACE_IRQS_IRETQ
 844         SWAPGS
 845         jmp restore_args
 846
 847 retint_restore_args:    /* return to kernel space */
 848         DISABLE_INTERRUPTS(CLBR_ANY)
 849         /*
 850          * The iretq could re-enable interrupts:
 851          */
 852         TRACE_IRQS_IRETQ
 853 restore_args:
 854         RESTORE_ARGS 0,8,0
 855
 856 irq_return:
 857         INTERRUPT_RETURN
 858
 859         .section __ex_table, "a"
 860         .quad irq_return, bad_iret
 861         .previous
 862
 863 #ifdef CONFIG_PARAVIRT
 864 ENTRY(native_iret)
 865         iretq
 866
 867         .section __ex_table,"a"
 868         .quad native_iret, bad_iret
 869         .previous
 870 #endif
 871
 872         .section .fixup,"ax"
 873 bad_iret:
 874         /*
 875          * The iret traps when the %cs or %ss being restored is bogus.
 876          * We've lost the original trap vector and error code.
 877          * #GPF is the most likely one to get for an invalid selector.
 878          * So pretend we completed the iret and took the #GPF in user mode.
 879          *
 880          * We are now running with the kernel GS after exception recovery.
 881          * But error_entry expects us to have user GS to match the user %cs,
 882          * so swap back.
 883          */
 884         pushq $0
 885
 886         SWAPGS
 887         jmp general_protection
 888
 889         .previous
 890
 891         /* edi: workmask, edx: work */
 892 retint_careful:
 893         CFI_RESTORE_STATE
 894         bt    $TIF_NEED_RESCHED,%edx
 895         jnc   retint_signal
 896         TRACE_IRQS_ON
 897         ENABLE_INTERRUPTS(CLBR_NONE)
 898         pushq_cfi %rdi
 899         call  schedule
 900         popq_cfi %rdi
 901         GET_THREAD_INFO(%rcx)
 902         DISABLE_INTERRUPTS(CLBR_NONE)
 903         TRACE_IRQS_OFF
 904         jmp retint_check
 905
 906 retint_signal:
 907         testl $_TIF_DO_NOTIFY_MASK,%edx
 908         jz    retint_swapgs
 909         TRACE_IRQS_ON
 910         ENABLE_INTERRUPTS(CLBR_NONE)
 911         SAVE_REST
 912         movq $-1,ORIG_RAX(%rsp)
 913         xorl %esi,%esi          # oldset
 914         movq %rsp,%rdi          # &pt_regs
 915         call do_notify_resume
 916         RESTORE_REST
 917         DISABLE_INTERRUPTS(CLBR_NONE)
 918         TRACE_IRQS_OFF
 919         GET_THREAD_INFO(%rcx)
 920         jmp retint_with_reschedule
 921
 922 #ifdef CONFIG_PREEMPT
 923         /* Returning to kernel space. Check if we need preemption */
 924         /* rcx:  threadinfo. interrupts off. */
 925 ENTRY(retint_kernel)
 926         cmpl $0,TI_preempt_count(%rcx)
 927         jnz  retint_restore_args
 928         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 929         jnc  retint_restore_args
 930         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 931         jnc  retint_restore_args
 932         call preempt_schedule_irq
 933         jmp exit_intr
 934 #endif
 935
 936         CFI_ENDPROC
 937 END(common_interrupt)
 938 /*
 939  * End of kprobes section
 940  */
 941        .popsection
 942
 943 /*
 944  * APIC interrupts.
 945  */
 946 .macro apicinterrupt num sym do_sym
 947 ENTRY(\sym)
 948         INTR_FRAME
 949         pushq_cfi $~(\num)
 950         interrupt \do_sym
 951         jmp ret_from_intr
 952         CFI_ENDPROC
 953 END(\sym)
 954 .endm
 955
 956 #ifdef CONFIG_SMP
 957 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 958         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 959 apicinterrupt REBOOT_VECTOR \
 960         reboot_interrupt smp_reboot_interrupt
 961 #endif
 962
 963 #ifdef CONFIG_X86_UV
 964 apicinterrupt UV_BAU_MESSAGE \
 965         uv_bau_message_intr1 uv_bau_message_interrupt
 966 #endif
 967 apicinterrupt LOCAL_TIMER_VECTOR \
 968         apic_timer_interrupt smp_apic_timer_interrupt
 969 apicinterrupt X86_PLATFORM_IPI_VECTOR \
 970         x86_platform_ipi smp_x86_platform_ipi
 971
 972 #ifdef CONFIG_SMP
 973 .irp idx,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
 974         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
 975 .if NUM_INVALIDATE_TLB_VECTORS > \idx
 976 apicinterrupt (INVALIDATE_TLB_VECTOR_START)+\idx \
 977         invalidate_interrupt\idx smp_invalidate_interrupt
 978 .endif
 979 .endr
 980 #endif
 981
 982 apicinterrupt THRESHOLD_APIC_VECTOR \
 983         threshold_interrupt smp_threshold_interrupt
 984 apicinterrupt THERMAL_APIC_VECTOR \
 985         thermal_interrupt smp_thermal_interrupt
 986
 987 #ifdef CONFIG_X86_MCE
 988 apicinterrupt MCE_SELF_VECTOR \
 989         mce_self_interrupt smp_mce_self_interrupt
 990 #endif
 991
 992 #ifdef CONFIG_SMP
 993 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
 994         call_function_single_interrupt smp_call_function_single_interrupt
 995 apicinterrupt CALL_FUNCTION_VECTOR \
 996         call_function_interrupt smp_call_function_interrupt
 997 apicinterrupt RESCHEDULE_VECTOR \
 998         reschedule_interrupt smp_reschedule_interrupt
 999 #endif
1000
1001 apicinterrupt ERROR_APIC_VECTOR \
1002         error_interrupt smp_error_interrupt
1003 apicinterrupt SPURIOUS_APIC_VECTOR \
1004         spurious_interrupt smp_spurious_interrupt
1005
1006 #ifdef CONFIG_IRQ_WORK
1007 apicinterrupt IRQ_WORK_VECTOR \
1008         irq_work_interrupt smp_irq_work_interrupt
1009 #endif
1010
1011 /*
1012  * Exception entry points.
1013  */
1014 .macro zeroentry sym do_sym
1015 ENTRY(\sym)
1016         INTR_FRAME
1017         PARAVIRT_ADJUST_EXCEPTION_FRAME
1018         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1019         subq $ORIG_RAX-R15, %rsp
1020         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1021         call error_entry
1022         DEFAULT_FRAME 0
1023         movq %rsp,%rdi          /* pt_regs pointer */
1024         xorl %esi,%esi          /* no error code */
1025         call \do_sym
1026         jmp error_exit          /* %ebx: no swapgs flag */
1027         CFI_ENDPROC
1028 END(\sym)
1029 .endm
1030
1031 .macro paranoidzeroentry sym do_sym
1032 ENTRY(\sym)
1033         INTR_FRAME
1034         PARAVIRT_ADJUST_EXCEPTION_FRAME
1035         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1036         subq $ORIG_RAX-R15, %rsp
1037         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1038         call save_paranoid
1039         TRACE_IRQS_OFF
1040         movq %rsp,%rdi          /* pt_regs pointer */
1041         xorl %esi,%esi          /* no error code */
1042         call \do_sym
1043         jmp paranoid_exit       /* %ebx: no swapgs flag */
1044         CFI_ENDPROC
1045 END(\sym)
1046 .endm
1047
1048 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1049 .macro paranoidzeroentry_ist sym do_sym ist
1050 ENTRY(\sym)
1051         INTR_FRAME
1052         PARAVIRT_ADJUST_EXCEPTION_FRAME
1053         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1054         subq $ORIG_RAX-R15, %rsp
1055         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1056         call save_paranoid
1057         TRACE_IRQS_OFF
1058         movq %rsp,%rdi          /* pt_regs pointer */
1059         xorl %esi,%esi          /* no error code */
1060         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1061         call \do_sym
1062         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1063         jmp paranoid_exit       /* %ebx: no swapgs flag */
1064         CFI_ENDPROC
1065 END(\sym)
1066 .endm
1067
1068 .macro errorentry sym do_sym
1069 ENTRY(\sym)
1070         XCPT_FRAME
1071         PARAVIRT_ADJUST_EXCEPTION_FRAME
1072         subq $ORIG_RAX-R15, %rsp
1073         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1074         call error_entry
1075         DEFAULT_FRAME 0
1076         movq %rsp,%rdi                  /* pt_regs pointer */
1077         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1078         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1079         call \do_sym
1080         jmp error_exit                  /* %ebx: no swapgs flag */
1081         CFI_ENDPROC
1082 END(\sym)
1083 .endm
1084
1085         /* error code is on the stack already */
1086 .macro paranoiderrorentry sym do_sym
1087 ENTRY(\sym)
1088         XCPT_FRAME
1089         PARAVIRT_ADJUST_EXCEPTION_FRAME
1090         subq $ORIG_RAX-R15, %rsp
1091         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1092         call save_paranoid
1093         DEFAULT_FRAME 0
1094         TRACE_IRQS_OFF
1095         movq %rsp,%rdi                  /* pt_regs pointer */
1096         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1097         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1098         call \do_sym
1099         jmp paranoid_exit               /* %ebx: no swapgs flag */
1100         CFI_ENDPROC
1101 END(\sym)
1102 .endm
1103
1104 zeroentry divide_error do_divide_error
1105 zeroentry overflow do_overflow
1106 zeroentry bounds do_bounds
1107 zeroentry invalid_op do_invalid_op
1108 zeroentry device_not_available do_device_not_available
1109 paranoiderrorentry double_fault do_double_fault
1110 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1111 errorentry invalid_TSS do_invalid_TSS
1112 errorentry segment_not_present do_segment_not_present
1113 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1114 zeroentry coprocessor_error do_coprocessor_error
1115 errorentry alignment_check do_alignment_check
1116 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1117
1118         /* Reload gs selector with exception handling */
1119         /* edi:  new selector */
1120 ENTRY(native_load_gs_index)
1121         CFI_STARTPROC
1122         pushfq_cfi
1123         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1124         SWAPGS
1125 gs_change:
1126         movl %edi,%gs
1127 2:      mfence          /* workaround */
1128         SWAPGS
1129         popfq_cfi
1130         ret
1131         CFI_ENDPROC
1132 END(native_load_gs_index)
1133
1134         .section __ex_table,"a"
1135         .align 8
1136         .quad gs_change,bad_gs
1137         .previous
1138         .section .fixup,"ax"
1139         /* running with kernelgs */
1140 bad_gs:
1141         SWAPGS                  /* switch back to user gs */
1142         xorl %eax,%eax
1143         movl %eax,%gs
1144         jmp  2b
1145         .previous
1146
1147 ENTRY(kernel_thread_helper)
1148         pushq $0                # fake return address
1149         CFI_STARTPROC
1150         /*
1151          * Here we are in the child and the registers are set as they were
1152          * at kernel_thread() invocation in the parent.
1153          */
1154         call *%rsi
1155         # exit
1156         mov %eax, %edi
1157         call do_exit
1158         ud2                     # padding for call trace
1159         CFI_ENDPROC
1160 END(kernel_thread_helper)
1161
1162 /*
1163  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1164  *
1165  * C extern interface:
1166  *       extern long execve(const char *name, char **argv, char **envp)
1167  *
1168  * asm input arguments:
1169  *      rdi: name, rsi: argv, rdx: envp
1170  *
1171  * We want to fallback into:
1172  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1173  *
1174  * do_sys_execve asm fallback arguments:
1175  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1176  */
1177 ENTRY(kernel_execve)
1178         CFI_STARTPROC
1179         FAKE_STACK_FRAME $0
1180         SAVE_ALL
1181         movq %rsp,%rcx
1182         call sys_execve
1183         movq %rax, RAX(%rsp)
1184         RESTORE_REST
1185         testq %rax,%rax
1186         je int_ret_from_sys_call
1187         RESTORE_ARGS
1188         UNFAKE_STACK_FRAME
1189         ret
1190         CFI_ENDPROC
1191 END(kernel_execve)
1192
1193 /* Call softirq on interrupt stack. Interrupts are off. */
1194 ENTRY(call_softirq)
1195         CFI_STARTPROC
1196         pushq_cfi %rbp
1197         CFI_REL_OFFSET rbp,0
1198         mov  %rsp,%rbp
1199         CFI_DEF_CFA_REGISTER rbp
1200         incl PER_CPU_VAR(irq_count)
1201         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1202         push  %rbp                      # backlink for old unwinder
1203         call __do_softirq
1204         leaveq
1205         CFI_RESTORE             rbp
1206         CFI_DEF_CFA_REGISTER    rsp
1207         CFI_ADJUST_CFA_OFFSET   -8
1208         decl PER_CPU_VAR(irq_count)
1209         ret
1210         CFI_ENDPROC
1211 END(call_softirq)
1212
1213 #ifdef CONFIG_XEN
1214 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1215
1216 /*
1217  * A note on the "critical region" in our callback handler.
1218  * We want to avoid stacking callback handlers due to events occurring
1219  * during handling of the last event. To do this, we keep events disabled
1220  * until we've done all processing. HOWEVER, we must enable events before
1221  * popping the stack frame (can't be done atomically) and so it would still
1222  * be possible to get enough handler activations to overflow the stack.
1223  * Although unlikely, bugs of that kind are hard to track down, so we'd
1224  * like to avoid the possibility.
1225  * So, on entry to the handler we detect whether we interrupted an
1226  * existing activation in its critical region -- if so, we pop the current
1227  * activation and restart the handler using the previous one.
1228  */
1229 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1230         CFI_STARTPROC
1231 /*
1232  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1233  * see the correct pointer to the pt_regs
1234  */
1235         movq %rdi, %rsp            # we don't return, adjust the stack frame
1236         CFI_ENDPROC
1237         DEFAULT_FRAME
1238 11:     incl PER_CPU_VAR(irq_count)
1239         movq %rsp,%rbp
1240         CFI_DEF_CFA_REGISTER rbp
1241         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1242         pushq %rbp                      # backlink for old unwinder
1243         call xen_evtchn_do_upcall
1244         popq %rsp
1245         CFI_DEF_CFA_REGISTER rsp
1246         decl PER_CPU_VAR(irq_count)
1247         jmp  error_exit
1248         CFI_ENDPROC
1249 END(xen_do_hypervisor_callback)
1250
1251 /*
1252  * Hypervisor uses this for application faults while it executes.
1253  * We get here for two reasons:
1254  *  1. Fault while reloading DS, ES, FS or GS
1255  *  2. Fault while executing IRET
1256  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1257  * registers that could be reloaded and zeroed the others.
1258  * Category 2 we fix up by killing the current process. We cannot use the
1259  * normal Linux return path in this case because if we use the IRET hypercall
1260  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1261  * We distinguish between categories by comparing each saved segment register
1262  * with its current contents: any discrepancy means we in category 1.
1263  */
1264 ENTRY(xen_failsafe_callback)
1265         INTR_FRAME 1 (6*8)
1266         /*CFI_REL_OFFSET gs,GS*/
1267         /*CFI_REL_OFFSET fs,FS*/
1268         /*CFI_REL_OFFSET es,ES*/
1269         /*CFI_REL_OFFSET ds,DS*/
1270         CFI_REL_OFFSET r11,8
1271         CFI_REL_OFFSET rcx,0
1272         movw %ds,%cx
1273         cmpw %cx,0x10(%rsp)
1274         CFI_REMEMBER_STATE
1275         jne 1f
1276         movw %es,%cx
1277         cmpw %cx,0x18(%rsp)
1278         jne 1f
1279         movw %fs,%cx
1280         cmpw %cx,0x20(%rsp)
1281         jne 1f
1282         movw %gs,%cx
1283         cmpw %cx,0x28(%rsp)
1284         jne 1f
1285         /* All segments match their saved values => Category 2 (Bad IRET). */
1286         movq (%rsp),%rcx
1287         CFI_RESTORE rcx
1288         movq 8(%rsp),%r11
1289         CFI_RESTORE r11
1290         addq $0x30,%rsp
1291         CFI_ADJUST_CFA_OFFSET -0x30
1292         pushq_cfi $0    /* RIP */
1293         pushq_cfi %r11
1294         pushq_cfi %rcx
1295         jmp general_protection
1296         CFI_RESTORE_STATE
1297 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1298         movq (%rsp),%rcx
1299         CFI_RESTORE rcx
1300         movq 8(%rsp),%r11
1301         CFI_RESTORE r11
1302         addq $0x30,%rsp
1303         CFI_ADJUST_CFA_OFFSET -0x30
1304         pushq_cfi $0
1305         SAVE_ALL
1306         jmp error_exit
1307         CFI_ENDPROC
1308 END(xen_failsafe_callback)
1309
1310 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1311         xen_hvm_callback_vector xen_evtchn_do_upcall
1312
1313 #endif /* CONFIG_XEN */
1314
1315 /*
1316  * Some functions should be protected against kprobes
1317  */
1318         .pushsection .kprobes.text, "ax"
1319
1320 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1321 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1322 paranoiderrorentry stack_segment do_stack_segment
1323 #ifdef CONFIG_XEN
1324 zeroentry xen_debug do_debug
1325 zeroentry xen_int3 do_int3
1326 errorentry xen_stack_segment do_stack_segment
1327 #endif
1328 errorentry general_protection do_general_protection
1329 errorentry page_fault do_page_fault
1330 #ifdef CONFIG_KVM_GUEST
1331 errorentry async_page_fault do_async_page_fault
1332 #endif
1333 #ifdef CONFIG_X86_MCE
1334 paranoidzeroentry machine_check *machine_check_vector(%rip)
1335 #endif
1336
1337         /*
1338          * "Paranoid" exit path from exception stack.
1339          * Paranoid because this is used by NMIs and cannot take
1340          * any kernel state for granted.
1341          * We don't do kernel preemption checks here, because only
1342          * NMI should be common and it does not enable IRQs and
1343          * cannot get reschedule ticks.
1344          *
1345          * "trace" is 0 for the NMI handler only, because irq-tracing
1346          * is fundamentally NMI-unsafe. (we cannot change the soft and
1347          * hard flags at once, atomically)
1348          */
1349
1350         /* ebx: no swapgs flag */
1351 ENTRY(paranoid_exit)
1352         DEFAULT_FRAME
1353         DISABLE_INTERRUPTS(CLBR_NONE)
1354         TRACE_IRQS_OFF
1355         testl %ebx,%ebx                         /* swapgs needed? */
1356         jnz paranoid_restore
1357         testl $3,CS(%rsp)
1358         jnz   paranoid_userspace
1359 paranoid_swapgs:
1360         TRACE_IRQS_IRETQ 0
1361         SWAPGS_UNSAFE_STACK
1362         RESTORE_ALL 8
1363         jmp irq_return
1364 paranoid_restore:
1365         TRACE_IRQS_IRETQ 0
1366         RESTORE_ALL 8
1367         jmp irq_return
1368 paranoid_userspace:
1369         GET_THREAD_INFO(%rcx)
1370         movl TI_flags(%rcx),%ebx
1371         andl $_TIF_WORK_MASK,%ebx
1372         jz paranoid_swapgs
1373         movq %rsp,%rdi                  /* &pt_regs */
1374         call sync_regs
1375         movq %rax,%rsp                  /* switch stack for scheduling */
1376         testl $_TIF_NEED_RESCHED,%ebx
1377         jnz paranoid_schedule
1378         movl %ebx,%edx                  /* arg3: thread flags */
1379         TRACE_IRQS_ON
1380         ENABLE_INTERRUPTS(CLBR_NONE)
1381         xorl %esi,%esi                  /* arg2: oldset */
1382         movq %rsp,%rdi                  /* arg1: &pt_regs */
1383         call do_notify_resume
1384         DISABLE_INTERRUPTS(CLBR_NONE)
1385         TRACE_IRQS_OFF
1386         jmp paranoid_userspace
1387 paranoid_schedule:
1388         TRACE_IRQS_ON
1389         ENABLE_INTERRUPTS(CLBR_ANY)
1390         call schedule
1391         DISABLE_INTERRUPTS(CLBR_ANY)
1392         TRACE_IRQS_OFF
1393         jmp paranoid_userspace
1394         CFI_ENDPROC
1395 END(paranoid_exit)
1396
1397 /*
1398  * Exception entry point. This expects an error code/orig_rax on the stack.
1399  * returns in "no swapgs flag" in %ebx.
1400  */
1401 ENTRY(error_entry)
1402         XCPT_FRAME
1403         CFI_ADJUST_CFA_OFFSET 15*8
1404         /* oldrax contains error code */
1405         cld
1406         movq_cfi rdi, RDI+8
1407         movq_cfi rsi, RSI+8
1408         movq_cfi rdx, RDX+8
1409         movq_cfi rcx, RCX+8
1410         movq_cfi rax, RAX+8
1411         movq_cfi  r8,  R8+8
1412         movq_cfi  r9,  R9+8
1413         movq_cfi r10, R10+8
1414         movq_cfi r11, R11+8
1415         movq_cfi rbx, RBX+8
1416         movq_cfi rbp, RBP+8
1417         movq_cfi r12, R12+8
1418         movq_cfi r13, R13+8
1419         movq_cfi r14, R14+8
1420         movq_cfi r15, R15+8
1421         xorl %ebx,%ebx
1422         testl $3,CS+8(%rsp)
1423         je error_kernelspace
1424 error_swapgs:
1425         SWAPGS
1426 error_sti:
1427         TRACE_IRQS_OFF
1428         ret
1429
1430 /*
1431  * There are two places in the kernel that can potentially fault with
1432  * usergs. Handle them here. The exception handlers after iret run with
1433  * kernel gs again, so don't set the user space flag. B stepping K8s
1434  * sometimes report an truncated RIP for IRET exceptions returning to
1435  * compat mode. Check for these here too.
1436  */
1437 error_kernelspace:
1438         incl %ebx
1439         leaq irq_return(%rip),%rcx
1440         cmpq %rcx,RIP+8(%rsp)
1441         je error_swapgs
1442         movl %ecx,%eax  /* zero extend */
1443         cmpq %rax,RIP+8(%rsp)
1444         je bstep_iret
1445         cmpq $gs_change,RIP+8(%rsp)
1446         je error_swapgs
1447         jmp error_sti
1448
1449 bstep_iret:
1450         /* Fix truncated RIP */
1451         movq %rcx,RIP+8(%rsp)
1452         jmp error_swapgs
1453         CFI_ENDPROC
1454 END(error_entry)
1455
1456
1457 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1458 ENTRY(error_exit)
1459         DEFAULT_FRAME
1460         movl %ebx,%eax
1461         RESTORE_REST
1462         DISABLE_INTERRUPTS(CLBR_NONE)
1463         TRACE_IRQS_OFF
1464         GET_THREAD_INFO(%rcx)
1465         testl %eax,%eax
1466         jne retint_kernel
1467         LOCKDEP_SYS_EXIT_IRQ
1468         movl TI_flags(%rcx),%edx
1469         movl $_TIF_WORK_MASK,%edi
1470         andl %edi,%edx
1471         jnz retint_careful
1472         jmp retint_swapgs
1473         CFI_ENDPROC
1474 END(error_exit)
1475
1476
1477         /* runs on exception stack */
1478 ENTRY(nmi)
1479         INTR_FRAME
1480         PARAVIRT_ADJUST_EXCEPTION_FRAME
1481         pushq_cfi $-1
1482         subq $ORIG_RAX-R15, %rsp
1483         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1484         call save_paranoid
1485         DEFAULT_FRAME 0
1486         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1487         movq %rsp,%rdi
1488         movq $-1,%rsi
1489         call do_nmi
1490 #ifdef CONFIG_TRACE_IRQFLAGS
1491         /* paranoidexit; without TRACE_IRQS_OFF */
1492         /* ebx: no swapgs flag */
1493         DISABLE_INTERRUPTS(CLBR_NONE)
1494         testl %ebx,%ebx                         /* swapgs needed? */
1495         jnz nmi_restore
1496         testl $3,CS(%rsp)
1497         jnz nmi_userspace
1498 nmi_swapgs:
1499         SWAPGS_UNSAFE_STACK
1500 nmi_restore:
1501         RESTORE_ALL 8
1502         jmp irq_return
1503 nmi_userspace:
1504         GET_THREAD_INFO(%rcx)
1505         movl TI_flags(%rcx),%ebx
1506         andl $_TIF_WORK_MASK,%ebx
1507         jz nmi_swapgs
1508         movq %rsp,%rdi                  /* &pt_regs */
1509         call sync_regs
1510         movq %rax,%rsp                  /* switch stack for scheduling */
1511         testl $_TIF_NEED_RESCHED,%ebx
1512         jnz nmi_schedule
1513         movl %ebx,%edx                  /* arg3: thread flags */
1514         ENABLE_INTERRUPTS(CLBR_NONE)
1515         xorl %esi,%esi                  /* arg2: oldset */
1516         movq %rsp,%rdi                  /* arg1: &pt_regs */
1517         call do_notify_resume
1518         DISABLE_INTERRUPTS(CLBR_NONE)
1519         jmp nmi_userspace
1520 nmi_schedule:
1521         ENABLE_INTERRUPTS(CLBR_ANY)
1522         call schedule
1523         DISABLE_INTERRUPTS(CLBR_ANY)
1524         jmp nmi_userspace
1525         CFI_ENDPROC
1526 #else
1527         jmp paranoid_exit
1528         CFI_ENDPROC
1529 #endif
1530 END(nmi)
1531
1532 ENTRY(ignore_sysret)
1533         CFI_STARTPROC
1534         mov $-ENOSYS,%eax
1535         sysret
1536         CFI_ENDPROC
1537 END(ignore_sysret)
1538
1539 /*
1540  * End of kprobes section
1541  */
1542         .popsection