arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/pgtable_types.h>
  59 #include <asm/alternative-asm.h>
  60 #include <asm/cpufeature.h>
  61 #include <asm/kaiser.h>
  62 #include <asm/nospec-branch.h>
  63
  64 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  65 #include <linux/elf-em.h>
  66 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  67 #define __AUDIT_ARCH_64BIT 0x80000000
  68 #define __AUDIT_ARCH_LE    0x40000000
  69
  70         .code64
  71         .section .entry.text, "ax"
  72
  73 #ifdef CONFIG_FUNCTION_TRACER
  74 #ifdef CONFIG_DYNAMIC_FTRACE
  75 ENTRY(mcount)
  76         retq
  77 END(mcount)
  78
  79 ENTRY(ftrace_caller)
  80         cmpl $0, function_trace_stop
  81         jne  ftrace_stub
  82
  83         MCOUNT_SAVE_FRAME
  84
  85         movq 0x38(%rsp), %rdi
  86         movq 8(%rbp), %rsi
  87         subq $MCOUNT_INSN_SIZE, %rdi
  88
  89 GLOBAL(ftrace_call)
  90         call ftrace_stub
  91
  92         MCOUNT_RESTORE_FRAME
  93
  94 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  95 GLOBAL(ftrace_graph_call)
  96         jmp ftrace_stub
  97 #endif
  98
  99 GLOBAL(ftrace_stub)
 100         retq
 101 END(ftrace_caller)
 102
 103 #else /* ! CONFIG_DYNAMIC_FTRACE */
 104 ENTRY(mcount)
 105         cmpl $0, function_trace_stop
 106         jne  ftrace_stub
 107
 108         cmpq $ftrace_stub, ftrace_trace_function
 109         jnz trace
 110
 111 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 112         cmpq $ftrace_stub, ftrace_graph_return
 113         jnz ftrace_graph_caller
 114
 115         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 116         jnz ftrace_graph_caller
 117 #endif
 118
 119 GLOBAL(ftrace_stub)
 120         retq
 121
 122 trace:
 123         MCOUNT_SAVE_FRAME
 124
 125         movq 0x38(%rsp), %rdi
 126         movq 8(%rbp), %rsi
 127         subq $MCOUNT_INSN_SIZE, %rdi
 128
 129         movq ftrace_trace_function, %r8
 130         CALL_NOSPEC %r8
 131         MCOUNT_RESTORE_FRAME
 132
 133         jmp ftrace_stub
 134 END(mcount)
 135 #endif /* CONFIG_DYNAMIC_FTRACE */
 136 #endif /* CONFIG_FUNCTION_TRACER */
 137
 138 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 139 ENTRY(ftrace_graph_caller)
 140         cmpl $0, function_trace_stop
 141         jne ftrace_stub
 142
 143         MCOUNT_SAVE_FRAME
 144
 145         leaq 8(%rbp), %rdi
 146         movq 0x38(%rsp), %rsi
 147         movq (%rbp), %rdx
 148         subq $MCOUNT_INSN_SIZE, %rsi
 149
 150         call    prepare_ftrace_return
 151
 152         MCOUNT_RESTORE_FRAME
 153
 154         retq
 155 END(ftrace_graph_caller)
 156
 157 GLOBAL(return_to_handler)
 158         subq  $24, %rsp
 159
 160         /* Save the return values */
 161         movq %rax, (%rsp)
 162         movq %rdx, 8(%rsp)
 163         movq %rbp, %rdi
 164
 165         call ftrace_return_to_handler
 166
 167         movq %rax, %rdi
 168         movq 8(%rsp), %rdx
 169         movq (%rsp), %rax
 170         addq $24, %rsp
 171         JMP_NOSPEC %rdi
 172 #endif
 173
 174
 175 #ifndef CONFIG_PREEMPT
 176 #define retint_kernel retint_restore_args
 177 #endif
 178
 179 #ifdef CONFIG_PARAVIRT
 180 ENTRY(native_usergs_sysret64)
 181         swapgs
 182         sysretq
 183 ENDPROC(native_usergs_sysret64)
 184 #endif /* CONFIG_PARAVIRT */
 185
 186
 187 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 188 #ifdef CONFIG_TRACE_IRQFLAGS
 189         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 190         jnc  1f
 191         TRACE_IRQS_ON
 192 1:
 193 #endif
 194 .endm
 195
 196 /*
 197  * C code is not supposed to know about undefined top of stack. Every time
 198  * a C function with an pt_regs argument is called from the SYSCALL based
 199  * fast path FIXUP_TOP_OF_STACK is needed.
 200  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 201  * manipulation.
 202  */
 203
 204         /* %rsp:at FRAMEEND */
 205         .macro FIXUP_TOP_OF_STACK tmp offset=0
 206         movq PER_CPU_VAR(old_rsp),\tmp
 207         movq \tmp,RSP+\offset(%rsp)
 208         movq $__USER_DS,SS+\offset(%rsp)
 209         movq $__USER_CS,CS+\offset(%rsp)
 210         movq $-1,RCX+\offset(%rsp)
 211         movq R11+\offset(%rsp),\tmp  /* get eflags */
 212         movq \tmp,EFLAGS+\offset(%rsp)
 213         .endm
 214
 215         .macro RESTORE_TOP_OF_STACK tmp offset=0
 216         movq RSP+\offset(%rsp),\tmp
 217         movq \tmp,PER_CPU_VAR(old_rsp)
 218         movq EFLAGS+\offset(%rsp),\tmp
 219         movq \tmp,R11+\offset(%rsp)
 220         .endm
 221
 222         .macro FAKE_STACK_FRAME child_rip
 223         /* push in order ss, rsp, eflags, cs, rip */
 224         xorl %eax, %eax
 225         pushq_cfi $__KERNEL_DS /* ss */
 226         /*CFI_REL_OFFSET        ss,0*/
 227         pushq_cfi %rax /* rsp */
 228         CFI_REL_OFFSET  rsp,0
 229         pushq_cfi $X86_EFLAGS_IF /* eflags - interrupts on */
 230         /*CFI_REL_OFFSET        rflags,0*/
 231         pushq_cfi $__KERNEL_CS /* cs */
 232         /*CFI_REL_OFFSET        cs,0*/
 233         pushq_cfi \child_rip /* rip */
 234         CFI_REL_OFFSET  rip,0
 235         pushq_cfi %rax /* orig rax */
 236         .endm
 237
 238         .macro UNFAKE_STACK_FRAME
 239         addq $8*6, %rsp
 240         CFI_ADJUST_CFA_OFFSET   -(6*8)
 241         .endm
 242
 243 /*
 244  * initial frame state for interrupts (and exceptions without error code)
 245  */
 246         .macro EMPTY_FRAME start=1 offset=0
 247         .if \start
 248         CFI_STARTPROC simple
 249         CFI_SIGNAL_FRAME
 250         CFI_DEF_CFA rsp,8+\offset
 251         .else
 252         CFI_DEF_CFA_OFFSET 8+\offset
 253         .endif
 254         .endm
 255
 256 /*
 257  * initial frame state for interrupts (and exceptions without error code)
 258  */
 259         .macro INTR_FRAME start=1 offset=0
 260         EMPTY_FRAME \start, SS+8+\offset-RIP
 261         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 262         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 263         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 264         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 265         CFI_REL_OFFSET rip, RIP+\offset-RIP
 266         .endm
 267
 268 /*
 269  * initial frame state for exceptions with error code (and interrupts
 270  * with vector already pushed)
 271  */
 272         .macro XCPT_FRAME start=1 offset=0
 273         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 274         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 275         .endm
 276
 277 /*
 278  * frame that enables calling into C.
 279  */
 280         .macro PARTIAL_FRAME start=1 offset=0
 281         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 283         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 284         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 285         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 286         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 287         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 288         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 289         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 290         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 291         .endm
 292
 293 /*
 294  * frame that enables passing a complete pt_regs to a C function.
 295  */
 296         .macro DEFAULT_FRAME start=1 offset=0
 297         PARTIAL_FRAME \start, R11+\offset-R15
 298         CFI_REL_OFFSET rbx, RBX+\offset
 299         CFI_REL_OFFSET rbp, RBP+\offset
 300         CFI_REL_OFFSET r12, R12+\offset
 301         CFI_REL_OFFSET r13, R13+\offset
 302         CFI_REL_OFFSET r14, R14+\offset
 303         CFI_REL_OFFSET r15, R15+\offset
 304         .endm
 305
 306 /* save partial stack frame */
 307         .macro SAVE_ARGS_IRQ
 308         cld
 309         /* start from rbp in pt_regs and jump over */
 310         movq_cfi rdi, RDI-RBP
 311         movq_cfi rsi, RSI-RBP
 312         movq_cfi rdx, RDX-RBP
 313         movq_cfi rcx, RCX-RBP
 314         movq_cfi rax, RAX-RBP
 315         movq_cfi  r8,  R8-RBP
 316         movq_cfi  r9,  R9-RBP
 317         movq_cfi r10, R10-RBP
 318         movq_cfi r11, R11-RBP
 319
 320         /* Save rbp so that we can unwind from get_irq_regs() */
 321         movq_cfi rbp, 0
 322
 323         /* Save previous stack value */
 324         movq %rsp, %rsi
 325
 326         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 327         testl $3, CS(%rdi)
 328         je 1f
 329         SWAPGS
 330         SWITCH_KERNEL_CR3
 331         /*
 332          * irq_count is used to check if a CPU is already on an interrupt stack
 333          * or not. While this is essentially redundant with preempt_count it is
 334          * a little cheaper to use a separate counter in the PDA (short of
 335          * moving irq_enter into assembly, which would be too much work)
 336          */
 337 1:      incl PER_CPU_VAR(irq_count)
 338         jne 2f
 339         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 340         CFI_DEF_CFA_REGISTER    rsi
 341
 342 2:      /* Store previous stack value */
 343         pushq %rsi
 344         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 345                         0x77 /* DW_OP_breg7 */, 0, \
 346                         0x06 /* DW_OP_deref */, \
 347                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 348                         0x22 /* DW_OP_plus */
 349         /* We entered an interrupt context - irqs are off: */
 350         TRACE_IRQS_OFF
 351         .endm
 352
 353 ENTRY(save_rest)
 354         PARTIAL_FRAME 1 REST_SKIP+8
 355         movq 5*8+16(%rsp), %r11 /* save return address */
 356         movq_cfi rbx, RBX+16
 357         movq_cfi rbp, RBP+16
 358         movq_cfi r12, R12+16
 359         movq_cfi r13, R13+16
 360         movq_cfi r14, R14+16
 361         movq_cfi r15, R15+16
 362         movq %r11, 8(%rsp)      /* return address */
 363         FIXUP_TOP_OF_STACK %r11, 16
 364         ret
 365         CFI_ENDPROC
 366 END(save_rest)
 367
 368 /* save complete stack frame */
 369         .pushsection .kprobes.text, "ax"
 370 /*
 371  * Return: ebx=0: needs swapgs but not SWITCH_USER_CR3 in paranoid_exit
 372  *         ebx=1: needs neither swapgs nor SWITCH_USER_CR3 in paranoid_exit
 373  *         ebx=2: needs both swapgs and SWITCH_USER_CR3 in paranoid_exit
 374  *         ebx=3: needs SWITCH_USER_CR3 but not swapgs in paranoid_exit
 375  */
 376 ENTRY(save_paranoid)
 377         XCPT_FRAME 1 RDI+8
 378         cld
 379         movq_cfi rdi, RDI+8
 380         movq_cfi rsi, RSI+8
 381         movq_cfi rdx, RDX+8
 382         movq_cfi rcx, RCX+8
 383         movq_cfi rax, RAX+8
 384         movq_cfi r8, R8+8
 385         movq_cfi r9, R9+8
 386         movq_cfi r10, R10+8
 387         movq_cfi r11, R11+8
 388         movq_cfi rbx, RBX+8
 389         movq_cfi rbp, RBP+8
 390         movq_cfi r12, R12+8
 391         movq_cfi r13, R13+8
 392         movq_cfi r14, R14+8
 393         movq_cfi r15, R15+8
 394         movl $1,%ebx
 395         movl $MSR_GS_BASE,%ecx
 396         rdmsr
 397         testl %edx,%edx
 398         js 1f   /* negative -> in kernel */
 399         SWAPGS
 400         xorl %ebx,%ebx
 401 1:
 402 #ifdef CONFIG_PAGE_TABLE_ISOLATION
 403         /*
 404          * We might have come in between a swapgs and a SWITCH_KERNEL_CR3
 405          * on entry, or between a SWITCH_USER_CR3 and a swapgs on exit.
 406          * Do a conditional SWITCH_KERNEL_CR3: this could safely be done
 407          * unconditionally, but we need to find out whether the reverse
 408          * should be done on return (conveyed to paranoid_exit in %ebx).
 409          */
 410         ALTERNATIVE "jmp 2f", "movq %cr3, %rax", X86_FEATURE_KAISER
 411         testl   $KAISER_SHADOW_PGD_OFFSET, %eax
 412         jz      2f
 413         orl     $2, %ebx
 414         andq    $(~(X86_CR3_PCID_ASID_MASK | KAISER_SHADOW_PGD_OFFSET)), %rax
 415         /* If PCID enabled, set X86_CR3_PCID_NOFLUSH_BIT */
 416         ALTERNATIVE "", "bts $63, %rax", X86_FEATURE_PCID
 417         movq    %rax, %cr3
 418 2:
 419 #endif
 420         ret
 421         CFI_ENDPROC
 422 END(save_paranoid)
 423         .popsection
 424
 425 /*
 426  * A newly forked process directly context switches into this address.
 427  *
 428  * rdi: prev task we switched from
 429  */
 430 ENTRY(ret_from_fork)
 431         DEFAULT_FRAME
 432
 433         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 434
 435         pushq_cfi kernel_eflags(%rip)
 436         popfq_cfi                               # reset kernel eflags
 437
 438         call schedule_tail                      # rdi: 'prev' task parameter
 439
 440         GET_THREAD_INFO(%rcx)
 441
 442         RESTORE_REST
 443
 444         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 445         je   int_ret_from_sys_call
 446
 447         /*
 448          * By the time we get here, we have no idea whether our pt_regs,
 449          * ti flags, and ti status came from the 64-bit SYSCALL fast path,
 450          * the slow path, or one of the ia32entry paths.
 451          * Use int_ret_from_sys_call to return, since it can safely handle
 452          * all of the above.
 453          */
 454         jmp  int_ret_from_sys_call
 455
 456         CFI_ENDPROC
 457 END(ret_from_fork)
 458
 459 /*
 460  * System call entry. Up to 6 arguments in registers are supported.
 461  *
 462  * SYSCALL does not save anything on the stack and does not change the
 463  * stack pointer.
 464  */
 465
 466 /*
 467  * Register setup:
 468  * rax  system call number
 469  * rdi  arg0
 470  * rcx  return address for syscall/sysret, C arg3
 471  * rsi  arg1
 472  * rdx  arg2
 473  * r10  arg3    (--> moved to rcx for C)
 474  * r8   arg4
 475  * r9   arg5
 476  * r11  eflags for syscall/sysret, temporary for C
 477  * r12-r15,rbp,rbx saved by C code, not touched.
 478  *
 479  * Interrupts are off on entry.
 480  * Only called from user space.
 481  *
 482  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 483  *      and report it properly in ps. Unfortunately we haven't.
 484  *
 485  * When user can change the frames always force IRET. That is because
 486  * it deals with uncanonical addresses better. SYSRET has trouble
 487  * with them due to bugs in both AMD and Intel CPUs.
 488  */
 489
 490 ENTRY(system_call)
 491         CFI_STARTPROC   simple
 492         CFI_SIGNAL_FRAME
 493         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 494         CFI_REGISTER    rip,rcx
 495         /*CFI_REGISTER  rflags,r11*/
 496         SWAPGS_UNSAFE_STACK
 497         SWITCH_KERNEL_CR3_NO_STACK
 498         /*
 499          * A hypervisor implementation might want to use a label
 500          * after the swapgs, so that it can do the swapgs
 501          * for the guest and jump here on syscall.
 502          */
 503 ENTRY(system_call_after_swapgs)
 504
 505         movq    %rsp,PER_CPU_VAR(old_rsp)
 506         movq    PER_CPU_VAR(kernel_stack),%rsp
 507         /*
 508          * No need to follow this irqs off/on section - it's straight
 509          * and short:
 510          */
 511         ENABLE_INTERRUPTS(CLBR_NONE)
 512         SAVE_ARGS 8,0
 513         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 514         movq  %rcx,RIP-ARGOFFSET(%rsp)
 515         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 516         GET_THREAD_INFO(%rcx)
 517         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 518         jnz tracesys
 519 system_call_fastpath:
 520         cmpq $__NR_syscall_max,%rax
 521         ja badsys
 522         movq %r10,%rcx
 523 #ifdef CONFIG_RETPOLINE
 524         movq    sys_call_table(, %rax, 8), %rax
 525         call    __x86_indirect_thunk_rax
 526 #else
 527         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 528 #endif
 529         movq %rax,RAX-ARGOFFSET(%rsp)
 530 /*
 531  * Syscall return path ending with SYSRET (fast path)
 532  * Has incomplete stack frame and undefined top of stack.
 533  */
 534 ret_from_sys_call:
 535         movl $_TIF_ALLWORK_MASK,%edi
 536         /* edi: flagmask */
 537 sysret_check:
 538         LOCKDEP_SYS_EXIT
 539         GET_THREAD_INFO(%rcx)
 540         DISABLE_INTERRUPTS(CLBR_NONE)
 541         TRACE_IRQS_OFF
 542         movl TI_flags(%rcx),%edx
 543         andl %edi,%edx
 544         jnz  sysret_careful
 545         CFI_REMEMBER_STATE
 546         /*
 547          * sysretq will re-enable interrupts:
 548          */
 549         TRACE_IRQS_ON
 550         movq RIP-ARGOFFSET(%rsp),%rcx
 551         CFI_REGISTER    rip,rcx
 552         RESTORE_ARGS 1,-ARG_SKIP,0
 553         /*CFI_REGISTER  rflags,r11*/
 554         /*
 555          * This opens a window where we have a user CR3, but are
 556          * running in the kernel.  This makes using the CS
 557          * register useless for telling whether or not we need to
 558          * switch CR3 in NMIs.  Normal interrupts are OK because
 559          * they are off here.
 560          */
 561         SWITCH_USER_CR3
 562         movq    PER_CPU_VAR(old_rsp), %rsp
 563         USERGS_SYSRET64
 564
 565         CFI_RESTORE_STATE
 566         /* Handle reschedules */
 567         /* edx: work, edi: workmask */
 568 sysret_careful:
 569         bt $TIF_NEED_RESCHED,%edx
 570         jnc sysret_signal
 571         TRACE_IRQS_ON
 572         ENABLE_INTERRUPTS(CLBR_NONE)
 573         pushq_cfi %rdi
 574         call schedule
 575         popq_cfi %rdi
 576         jmp sysret_check
 577
 578         /* Handle a signal */
 579 sysret_signal:
 580         TRACE_IRQS_ON
 581         ENABLE_INTERRUPTS(CLBR_NONE)
 582 #ifdef CONFIG_AUDITSYSCALL
 583         bt $TIF_SYSCALL_AUDIT,%edx
 584         jc sysret_audit
 585 #endif
 586         /*
 587          * We have a signal, or exit tracing or single-step.
 588          * These all wind up with the iret return path anyway,
 589          * so just join that path right now.
 590          */
 591         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 592         jmp int_check_syscall_exit_work
 593
 594 badsys:
 595         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 596         jmp ret_from_sys_call
 597
 598 #ifdef CONFIG_AUDITSYSCALL
 599         /*
 600          * Fast path for syscall audit without full syscall trace.
 601          * We just call audit_syscall_entry() directly, and then
 602          * jump back to the normal fast path.
 603          */
 604 auditsys:
 605         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 606         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 607         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 608         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 609         movq %rax,%rsi                  /* 2nd arg: syscall number */
 610         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 611         call audit_syscall_entry
 612         LOAD_ARGS 0             /* reload call-clobbered registers */
 613         jmp system_call_fastpath
 614
 615         /*
 616          * Return fast path for syscall audit.  Call audit_syscall_exit()
 617          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 618          * masked off.
 619          */
 620 sysret_audit:
 621         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 622         cmpq $0,%rsi            /* is it < 0? */
 623         setl %al                /* 1 if so, 0 if not */
 624         movzbl %al,%edi         /* zero-extend that into %edi */
 625         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 626         call audit_syscall_exit
 627         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 628         jmp sysret_check
 629 #endif  /* CONFIG_AUDITSYSCALL */
 630
 631         /* Do syscall tracing */
 632 tracesys:
 633 #ifdef CONFIG_AUDITSYSCALL
 634         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 635         jz auditsys
 636 #endif
 637         SAVE_REST
 638         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 639         FIXUP_TOP_OF_STACK %rdi
 640         movq %rsp,%rdi
 641         call syscall_trace_enter
 642         /*
 643          * Reload arg registers from stack in case ptrace changed them.
 644          * We don't reload %rax because syscall_trace_enter() returned
 645          * the value it wants us to use in the table lookup.
 646          */
 647         LOAD_ARGS ARGOFFSET, 1
 648         RESTORE_REST
 649         cmpq $__NR_syscall_max,%rax
 650         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 651         movq %r10,%rcx  /* fixup for C */
 652 #ifdef CONFIG_RETPOLINE
 653         movq    sys_call_table(, %rax, 8), %rax
 654         call    __x86_indirect_thunk_rax
 655 #else
 656         call *sys_call_table(,%rax,8)
 657 #endif
 658         movq %rax,RAX-ARGOFFSET(%rsp)
 659         /* Use IRET because user could have changed frame */
 660
 661 /*
 662  * Syscall return path ending with IRET.
 663  * Has correct top of stack, but partial stack frame.
 664  */
 665 GLOBAL(int_ret_from_sys_call)
 666         DISABLE_INTERRUPTS(CLBR_NONE)
 667         TRACE_IRQS_OFF
 668         testl $3,CS-ARGOFFSET(%rsp)
 669         je retint_restore_args
 670         movl $_TIF_ALLWORK_MASK,%edi
 671         /* edi: mask to check */
 672 GLOBAL(int_with_check)
 673         LOCKDEP_SYS_EXIT_IRQ
 674         GET_THREAD_INFO(%rcx)
 675         movl TI_flags(%rcx),%edx
 676         andl %edi,%edx
 677         jnz   int_careful
 678         andl    $~TS_COMPAT,TI_status(%rcx)
 679         jmp   retint_swapgs
 680
 681         /* Either reschedule or signal or syscall exit tracking needed. */
 682         /* First do a reschedule test. */
 683         /* edx: work, edi: workmask */
 684 int_careful:
 685         bt $TIF_NEED_RESCHED,%edx
 686         jnc  int_very_careful
 687         TRACE_IRQS_ON
 688         ENABLE_INTERRUPTS(CLBR_NONE)
 689         pushq_cfi %rdi
 690         call schedule
 691         popq_cfi %rdi
 692         DISABLE_INTERRUPTS(CLBR_NONE)
 693         TRACE_IRQS_OFF
 694         jmp int_with_check
 695
 696         /* handle signals and tracing -- both require a full stack frame */
 697 int_very_careful:
 698         TRACE_IRQS_ON
 699         ENABLE_INTERRUPTS(CLBR_NONE)
 700 int_check_syscall_exit_work:
 701         SAVE_REST
 702         /* Check for syscall exit trace */
 703         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 704         jz int_signal
 705         pushq_cfi %rdi
 706         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 707         call syscall_trace_leave
 708         popq_cfi %rdi
 709         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 710         jmp int_restore_rest
 711
 712 int_signal:
 713         testl $_TIF_DO_NOTIFY_MASK,%edx
 714         jz 1f
 715         movq %rsp,%rdi          # &ptregs -> arg1
 716         xorl %esi,%esi          # oldset -> arg2
 717         call do_notify_resume
 718 1:      movl $_TIF_WORK_MASK,%edi
 719 int_restore_rest:
 720         RESTORE_REST
 721         DISABLE_INTERRUPTS(CLBR_NONE)
 722         TRACE_IRQS_OFF
 723         jmp int_with_check
 724         CFI_ENDPROC
 725 END(system_call)
 726
 727 /*
 728  * Certain special system calls that need to save a complete full stack frame.
 729  */
 730         .macro PTREGSCALL label,func,arg
 731 ENTRY(\label)
 732         PARTIAL_FRAME 1 8               /* offset 8: return address */
 733         subq $REST_SKIP, %rsp
 734         CFI_ADJUST_CFA_OFFSET REST_SKIP
 735         call save_rest
 736         DEFAULT_FRAME 0 8               /* offset 8: return address */
 737         leaq 8(%rsp), \arg      /* pt_regs pointer */
 738         call \func
 739         jmp ptregscall_common
 740         CFI_ENDPROC
 741 END(\label)
 742         .endm
 743
 744         PTREGSCALL stub_clone, sys_clone, %r8
 745         PTREGSCALL stub_fork, sys_fork, %rdi
 746         PTREGSCALL stub_vfork, sys_vfork, %rdi
 747         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 748         PTREGSCALL stub_iopl, sys_iopl, %rsi
 749
 750 ENTRY(ptregscall_common)
 751         DEFAULT_FRAME 1 8       /* offset 8: return address */
 752         RESTORE_TOP_OF_STACK %r11, 8
 753         movq_cfi_restore R15+8, r15
 754         movq_cfi_restore R14+8, r14
 755         movq_cfi_restore R13+8, r13
 756         movq_cfi_restore R12+8, r12
 757         movq_cfi_restore RBP+8, rbp
 758         movq_cfi_restore RBX+8, rbx
 759         ret $REST_SKIP          /* pop extended registers */
 760         CFI_ENDPROC
 761 END(ptregscall_common)
 762
 763 ENTRY(stub_execve)
 764         CFI_STARTPROC
 765         addq $8, %rsp
 766         PARTIAL_FRAME 0
 767         SAVE_REST
 768         FIXUP_TOP_OF_STACK %r11
 769         movq %rsp, %rcx
 770         call sys_execve
 771         RESTORE_TOP_OF_STACK %r11
 772         movq %rax,RAX(%rsp)
 773         RESTORE_REST
 774         jmp int_ret_from_sys_call
 775         CFI_ENDPROC
 776 END(stub_execve)
 777
 778 /*
 779  * sigreturn is special because it needs to restore all registers on return.
 780  * This cannot be done with SYSRET, so use the IRET return path instead.
 781  */
 782 ENTRY(stub_rt_sigreturn)
 783         CFI_STARTPROC
 784         addq $8, %rsp
 785         PARTIAL_FRAME 0
 786         SAVE_REST
 787         movq %rsp,%rdi
 788         FIXUP_TOP_OF_STACK %r11
 789         call sys_rt_sigreturn
 790         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 791         RESTORE_REST
 792         jmp int_ret_from_sys_call
 793         CFI_ENDPROC
 794 END(stub_rt_sigreturn)
 795
 796 /*
 797  * Build the entry stubs and pointer table with some assembler magic.
 798  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 799  * single cache line on all modern x86 implementations.
 800  */
 801         .section .init.rodata,"a"
 802 ENTRY(interrupt)
 803         .section .entry.text
 804         .p2align 5
 805         .p2align CONFIG_X86_L1_CACHE_SHIFT
 806 ENTRY(irq_entries_start)
 807         INTR_FRAME
 808 vector=FIRST_EXTERNAL_VECTOR
 809 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 810         .balign 32
 811   .rept 7
 812     .if vector < NR_VECTORS
 813       .if vector <> FIRST_EXTERNAL_VECTOR
 814         CFI_ADJUST_CFA_OFFSET -8
 815       .endif
 816 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 817       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 818         jmp 2f
 819       .endif
 820       .previous
 821         .quad 1b
 822       .section .entry.text
 823 vector=vector+1
 824     .endif
 825   .endr
 826 2:      jmp common_interrupt
 827 .endr
 828         CFI_ENDPROC
 829 END(irq_entries_start)
 830
 831 .previous
 832 END(interrupt)
 833 .previous
 834
 835 /*
 836  * Interrupt entry/exit.
 837  *
 838  * Interrupt entry points save only callee clobbered registers in fast path.
 839  *
 840  * Entry runs with interrupts off.
 841  */
 842
 843 /* 0(%rsp): ~(interrupt number) */
 844         .macro interrupt func
 845         /* reserve pt_regs for scratch regs and rbp */
 846         subq $ORIG_RAX-RBP, %rsp
 847         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 848         SAVE_ARGS_IRQ
 849         call \func
 850         .endm
 851
 852 /*
 853  * Interrupt entry/exit should be protected against kprobes
 854  */
 855         .pushsection .kprobes.text, "ax"
 856         /*
 857          * The interrupt stubs push (~vector+0x80) onto the stack and
 858          * then jump to common_interrupt.
 859          */
 860         .p2align CONFIG_X86_L1_CACHE_SHIFT
 861 common_interrupt:
 862         XCPT_FRAME
 863         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 864         interrupt do_IRQ
 865         /* 0(%rsp): old_rsp-ARGOFFSET */
 866 ret_from_intr:
 867         DISABLE_INTERRUPTS(CLBR_NONE)
 868         TRACE_IRQS_OFF
 869         decl PER_CPU_VAR(irq_count)
 870
 871         /* Restore saved previous stack */
 872         popq %rsi
 873         CFI_DEF_CFA_REGISTER    rsi
 874         leaq ARGOFFSET-RBP(%rsi), %rsp
 875         CFI_DEF_CFA_REGISTER    rsp
 876         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 877
 878 exit_intr:
 879         GET_THREAD_INFO(%rcx)
 880         testl $3,CS-ARGOFFSET(%rsp)
 881         je retint_kernel
 882
 883         /* Interrupt came from user space */
 884         /*
 885          * Has a correct top of stack, but a partial stack frame
 886          * %rcx: thread info. Interrupts off.
 887          */
 888 retint_with_reschedule:
 889         movl $_TIF_WORK_MASK,%edi
 890 retint_check:
 891         LOCKDEP_SYS_EXIT_IRQ
 892         movl TI_flags(%rcx),%edx
 893         andl %edi,%edx
 894         CFI_REMEMBER_STATE
 895         jnz  retint_careful
 896
 897 retint_swapgs:          /* return to user-space */
 898         /*
 899          * The iretq could re-enable interrupts:
 900          */
 901         DISABLE_INTERRUPTS(CLBR_ANY)
 902         TRACE_IRQS_IRETQ
 903         /*
 904          * This opens a window where we have a user CR3, but are
 905          * running in the kernel.  This makes using the CS
 906          * register useless for telling whether or not we need to
 907          * switch CR3 in NMIs.  Normal interrupts are OK because
 908          * they are off here.
 909          */
 910         SWITCH_USER_CR3
 911         SWAPGS
 912         jmp restore_args
 913
 914 retint_restore_args:    /* return to kernel space */
 915         DISABLE_INTERRUPTS(CLBR_ANY)
 916         /*
 917          * The iretq could re-enable interrupts:
 918          */
 919         TRACE_IRQS_IRETQ
 920 restore_args:
 921         RESTORE_ARGS 1,8,1
 922
 923 irq_return:
 924         INTERRUPT_RETURN
 925
 926 ENTRY(native_iret)
 927         /*
 928          * Are we returning to a stack segment from the LDT?  Note: in
 929          * 64-bit mode SS:RSP on the exception stack is always valid.
 930          */
 931 #ifdef CONFIG_X86_ESPFIX64
 932         testb $4,(SS-RIP)(%rsp)
 933         jnz native_irq_return_ldt
 934 #endif
 935
 936 .global native_irq_return_iret
 937 native_irq_return_iret:
 938         /*
 939          * This may fault.  Non-paranoid faults on return to userspace are
 940          * handled by fixup_bad_iret.  These include #SS, #GP, and #NP.
 941          * Double-faults due to espfix64 are handled in do_double_fault.
 942          * Other faults here are fatal.
 943          */
 944         iretq
 945
 946 #ifdef CONFIG_X86_ESPFIX64
 947 native_irq_return_ldt:
 948         pushq_cfi %rax
 949         pushq_cfi %rdi
 950         SWAPGS
 951         SWITCH_KERNEL_CR3
 952         movq PER_CPU_VAR(espfix_waddr),%rdi
 953         movq %rax,(0*8)(%rdi)   /* RAX */
 954         movq (2*8)(%rsp),%rax   /* RIP */
 955         movq %rax,(1*8)(%rdi)
 956         movq (3*8)(%rsp),%rax   /* CS */
 957         movq %rax,(2*8)(%rdi)
 958         movq (4*8)(%rsp),%rax   /* RFLAGS */
 959         movq %rax,(3*8)(%rdi)
 960         movq (6*8)(%rsp),%rax   /* SS */
 961         movq %rax,(5*8)(%rdi)
 962         movq (5*8)(%rsp),%rax   /* RSP */
 963         movq %rax,(4*8)(%rdi)
 964         andl $0xffff0000,%eax
 965         popq_cfi %rdi
 966         orq PER_CPU_VAR(espfix_stack),%rax
 967         SWITCH_USER_CR3
 968         SWAPGS
 969         movq %rax,%rsp
 970         popq_cfi %rax
 971         jmp native_irq_return_iret
 972 #endif
 973
 974         /* edi: workmask, edx: work */
 975 retint_careful:
 976         CFI_RESTORE_STATE
 977         bt    $TIF_NEED_RESCHED,%edx
 978         jnc   retint_signal
 979         TRACE_IRQS_ON
 980         ENABLE_INTERRUPTS(CLBR_NONE)
 981         pushq_cfi %rdi
 982         call  schedule
 983         popq_cfi %rdi
 984         GET_THREAD_INFO(%rcx)
 985         DISABLE_INTERRUPTS(CLBR_NONE)
 986         TRACE_IRQS_OFF
 987         jmp retint_check
 988
 989 retint_signal:
 990         testl $_TIF_DO_NOTIFY_MASK,%edx
 991         jz    retint_swapgs
 992         TRACE_IRQS_ON
 993         ENABLE_INTERRUPTS(CLBR_NONE)
 994         SAVE_REST
 995         movq $-1,ORIG_RAX(%rsp)
 996         xorl %esi,%esi          # oldset
 997         movq %rsp,%rdi          # &pt_regs
 998         call do_notify_resume
 999         RESTORE_REST
1000         DISABLE_INTERRUPTS(CLBR_NONE)
1001         TRACE_IRQS_OFF
1002         GET_THREAD_INFO(%rcx)
1003         jmp retint_with_reschedule
1004
1005 #ifdef CONFIG_PREEMPT
1006         /* Returning to kernel space. Check if we need preemption */
1007         /* rcx:  threadinfo. interrupts off. */
1008 ENTRY(retint_kernel)
1009         cmpl $0,TI_preempt_count(%rcx)
1010         jnz  retint_restore_args
1011         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
1012         jnc  retint_restore_args
1013         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
1014         jnc  retint_restore_args
1015         call preempt_schedule_irq
1016         jmp exit_intr
1017 #endif
1018         CFI_ENDPROC
1019 END(common_interrupt)
1020
1021 /*
1022  * End of kprobes section
1023  */
1024        .popsection
1025
1026 /*
1027  * APIC interrupts.
1028  */
1029 .macro apicinterrupt num sym do_sym
1030 ENTRY(\sym)
1031         INTR_FRAME
1032         pushq_cfi $~(\num)
1033         interrupt \do_sym
1034         jmp ret_from_intr
1035         CFI_ENDPROC
1036 END(\sym)
1037 .endm
1038
1039 #ifdef CONFIG_SMP
1040 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
1041         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1042 apicinterrupt REBOOT_VECTOR \
1043         reboot_interrupt smp_reboot_interrupt
1044 #endif
1045
1046 #ifdef CONFIG_X86_UV
1047 apicinterrupt UV_BAU_MESSAGE \
1048         uv_bau_message_intr1 uv_bau_message_interrupt
1049 #endif
1050 apicinterrupt LOCAL_TIMER_VECTOR \
1051         apic_timer_interrupt smp_apic_timer_interrupt
1052 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1053         x86_platform_ipi smp_x86_platform_ipi
1054
1055 #ifdef CONFIG_SMP
1056 .irp idx,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
1057         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
1058 .if NUM_INVALIDATE_TLB_VECTORS > \idx
1059 apicinterrupt (INVALIDATE_TLB_VECTOR_START)+\idx \
1060         invalidate_interrupt\idx smp_invalidate_interrupt
1061 .endif
1062 .endr
1063 #endif
1064
1065 apicinterrupt THRESHOLD_APIC_VECTOR \
1066         threshold_interrupt smp_threshold_interrupt
1067 apicinterrupt THERMAL_APIC_VECTOR \
1068         thermal_interrupt smp_thermal_interrupt
1069
1070 #ifdef CONFIG_SMP
1071 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1072         call_function_single_interrupt smp_call_function_single_interrupt
1073 apicinterrupt CALL_FUNCTION_VECTOR \
1074         call_function_interrupt smp_call_function_interrupt
1075 apicinterrupt RESCHEDULE_VECTOR \
1076         reschedule_interrupt smp_reschedule_interrupt
1077 #endif
1078
1079 apicinterrupt ERROR_APIC_VECTOR \
1080         error_interrupt smp_error_interrupt
1081 apicinterrupt SPURIOUS_APIC_VECTOR \
1082         spurious_interrupt smp_spurious_interrupt
1083
1084 #ifdef CONFIG_IRQ_WORK
1085 apicinterrupt IRQ_WORK_VECTOR \
1086         irq_work_interrupt smp_irq_work_interrupt
1087 #endif
1088
1089 /*
1090  * Exception entry points.
1091  */
1092 .macro zeroentry sym do_sym
1093 ENTRY(\sym)
1094         INTR_FRAME
1095         PARAVIRT_ADJUST_EXCEPTION_FRAME
1096         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1097         subq $ORIG_RAX-R15, %rsp
1098         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1099         call error_entry
1100         DEFAULT_FRAME 0
1101         movq %rsp,%rdi          /* pt_regs pointer */
1102         xorl %esi,%esi          /* no error code */
1103         call \do_sym
1104         jmp error_exit          /* %ebx: no swapgs flag */
1105         CFI_ENDPROC
1106 END(\sym)
1107 .endm
1108
1109 .macro paranoidzeroentry sym do_sym
1110 ENTRY(\sym)
1111         INTR_FRAME
1112         PARAVIRT_ADJUST_EXCEPTION_FRAME
1113         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1114         subq $ORIG_RAX-R15, %rsp
1115         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1116         call save_paranoid
1117         TRACE_IRQS_OFF
1118         movq %rsp,%rdi          /* pt_regs pointer */
1119         xorl %esi,%esi          /* no error code */
1120         call \do_sym
1121         jmp paranoid_exit       /* %ebx: no swapgs flag */
1122         CFI_ENDPROC
1123 END(\sym)
1124 .endm
1125
1126 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1127 .macro paranoidzeroentry_ist sym do_sym ist
1128 ENTRY(\sym)
1129         INTR_FRAME
1130         PARAVIRT_ADJUST_EXCEPTION_FRAME
1131         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1132         subq $ORIG_RAX-R15, %rsp
1133         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1134         call save_paranoid
1135         TRACE_IRQS_OFF
1136         movq %rsp,%rdi          /* pt_regs pointer */
1137         xorl %esi,%esi          /* no error code */
1138         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1139         call \do_sym
1140         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1141         jmp paranoid_exit       /* %ebx: no swapgs flag */
1142         CFI_ENDPROC
1143 END(\sym)
1144 .endm
1145
1146 .macro errorentry sym do_sym
1147 ENTRY(\sym)
1148         XCPT_FRAME
1149         PARAVIRT_ADJUST_EXCEPTION_FRAME
1150         subq $ORIG_RAX-R15, %rsp
1151         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1152         call error_entry
1153         DEFAULT_FRAME 0
1154         movq %rsp,%rdi                  /* pt_regs pointer */
1155         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1156         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1157         call \do_sym
1158         jmp error_exit                  /* %ebx: no swapgs flag */
1159         CFI_ENDPROC
1160 END(\sym)
1161 .endm
1162
1163         /* error code is on the stack already */
1164 .macro paranoiderrorentry sym do_sym
1165 ENTRY(\sym)
1166         XCPT_FRAME
1167         PARAVIRT_ADJUST_EXCEPTION_FRAME
1168         subq $ORIG_RAX-R15, %rsp
1169         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1170         call save_paranoid
1171         DEFAULT_FRAME 0
1172         TRACE_IRQS_OFF
1173         movq %rsp,%rdi                  /* pt_regs pointer */
1174         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1175         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1176         call \do_sym
1177         jmp paranoid_exit               /* %ebx: no swapgs flag */
1178         CFI_ENDPROC
1179 END(\sym)
1180 .endm
1181
1182 zeroentry divide_error do_divide_error
1183 zeroentry overflow do_overflow
1184 zeroentry bounds do_bounds
1185 zeroentry invalid_op do_invalid_op
1186 zeroentry device_not_available do_device_not_available
1187 paranoiderrorentry double_fault do_double_fault
1188 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1189 errorentry invalid_TSS do_invalid_TSS
1190 errorentry segment_not_present do_segment_not_present
1191 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1192 zeroentry coprocessor_error do_coprocessor_error
1193 errorentry alignment_check do_alignment_check
1194 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1195
1196
1197         /* Reload gs selector with exception handling */
1198         /* edi:  new selector */
1199 ENTRY(native_load_gs_index)
1200         CFI_STARTPROC
1201         pushfq_cfi
1202         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1203         SWAPGS
1204 gs_change:
1205         movl %edi,%gs
1206 2:      mfence          /* workaround */
1207         SWAPGS
1208         popfq_cfi
1209         ret
1210         CFI_ENDPROC
1211 END(native_load_gs_index)
1212
1213         .section __ex_table,"a"
1214         .align 8
1215         .quad gs_change,bad_gs
1216         .previous
1217         .section .fixup,"ax"
1218         /* running with kernelgs */
1219 bad_gs:
1220         SWAPGS                  /* switch back to user gs */
1221         xorl %eax,%eax
1222         movl %eax,%gs
1223         jmp  2b
1224         .previous
1225
1226 ENTRY(kernel_thread_helper)
1227         pushq $0                # fake return address
1228         CFI_STARTPROC
1229         /*
1230          * Here we are in the child and the registers are set as they were
1231          * at kernel_thread() invocation in the parent.
1232          */
1233         CALL_NOSPEC %rsi
1234         # exit
1235         mov %eax, %edi
1236         call do_exit
1237         ud2                     # padding for call trace
1238         CFI_ENDPROC
1239 END(kernel_thread_helper)
1240
1241 /*
1242  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1243  *
1244  * C extern interface:
1245  *       extern long execve(const char *name, char **argv, char **envp)
1246  *
1247  * asm input arguments:
1248  *      rdi: name, rsi: argv, rdx: envp
1249  *
1250  * We want to fallback into:
1251  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1252  *
1253  * do_sys_execve asm fallback arguments:
1254  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1255  */
1256 ENTRY(kernel_execve)
1257         CFI_STARTPROC
1258         FAKE_STACK_FRAME $0
1259         SAVE_ALL
1260         movq %rsp,%rcx
1261         call sys_execve
1262         movq %rax, RAX(%rsp)
1263         RESTORE_REST
1264         testq %rax,%rax
1265         je int_ret_from_sys_call
1266         RESTORE_ARGS
1267         UNFAKE_STACK_FRAME
1268         ret
1269         CFI_ENDPROC
1270 END(kernel_execve)
1271
1272 /* Call softirq on interrupt stack. Interrupts are off. */
1273 ENTRY(call_softirq)
1274         CFI_STARTPROC
1275         pushq_cfi %rbp
1276         CFI_REL_OFFSET rbp,0
1277         mov  %rsp,%rbp
1278         CFI_DEF_CFA_REGISTER rbp
1279         incl PER_CPU_VAR(irq_count)
1280         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1281         push  %rbp                      # backlink for old unwinder
1282         call __do_softirq
1283         leaveq
1284         CFI_RESTORE             rbp
1285         CFI_DEF_CFA_REGISTER    rsp
1286         CFI_ADJUST_CFA_OFFSET   -8
1287         decl PER_CPU_VAR(irq_count)
1288         ret
1289         CFI_ENDPROC
1290 END(call_softirq)
1291
1292 #ifdef CONFIG_XEN
1293 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1294
1295 /*
1296  * A note on the "critical region" in our callback handler.
1297  * We want to avoid stacking callback handlers due to events occurring
1298  * during handling of the last event. To do this, we keep events disabled
1299  * until we've done all processing. HOWEVER, we must enable events before
1300  * popping the stack frame (can't be done atomically) and so it would still
1301  * be possible to get enough handler activations to overflow the stack.
1302  * Although unlikely, bugs of that kind are hard to track down, so we'd
1303  * like to avoid the possibility.
1304  * So, on entry to the handler we detect whether we interrupted an
1305  * existing activation in its critical region -- if so, we pop the current
1306  * activation and restart the handler using the previous one.
1307  */
1308 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1309         CFI_STARTPROC
1310 /*
1311  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1312  * see the correct pointer to the pt_regs
1313  */
1314         movq %rdi, %rsp            # we don't return, adjust the stack frame
1315         CFI_ENDPROC
1316         DEFAULT_FRAME
1317 11:     incl PER_CPU_VAR(irq_count)
1318         movq %rsp,%rbp
1319         CFI_DEF_CFA_REGISTER rbp
1320         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1321         pushq %rbp                      # backlink for old unwinder
1322         call xen_evtchn_do_upcall
1323         popq %rsp
1324         CFI_DEF_CFA_REGISTER rsp
1325         decl PER_CPU_VAR(irq_count)
1326         jmp  error_exit
1327         CFI_ENDPROC
1328 END(xen_do_hypervisor_callback)
1329
1330 /*
1331  * Hypervisor uses this for application faults while it executes.
1332  * We get here for two reasons:
1333  *  1. Fault while reloading DS, ES, FS or GS
1334  *  2. Fault while executing IRET
1335  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1336  * registers that could be reloaded and zeroed the others.
1337  * Category 2 we fix up by killing the current process. We cannot use the
1338  * normal Linux return path in this case because if we use the IRET hypercall
1339  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1340  * We distinguish between categories by comparing each saved segment register
1341  * with its current contents: any discrepancy means we in category 1.
1342  */
1343 ENTRY(xen_failsafe_callback)
1344         INTR_FRAME 1 (6*8)
1345         /*CFI_REL_OFFSET gs,GS*/
1346         /*CFI_REL_OFFSET fs,FS*/
1347         /*CFI_REL_OFFSET es,ES*/
1348         /*CFI_REL_OFFSET ds,DS*/
1349         CFI_REL_OFFSET r11,8
1350         CFI_REL_OFFSET rcx,0
1351         movw %ds,%cx
1352         cmpw %cx,0x10(%rsp)
1353         CFI_REMEMBER_STATE
1354         jne 1f
1355         movw %es,%cx
1356         cmpw %cx,0x18(%rsp)
1357         jne 1f
1358         movw %fs,%cx
1359         cmpw %cx,0x20(%rsp)
1360         jne 1f
1361         movw %gs,%cx
1362         cmpw %cx,0x28(%rsp)
1363         jne 1f
1364         /* All segments match their saved values => Category 2 (Bad IRET). */
1365         movq (%rsp),%rcx
1366         CFI_RESTORE rcx
1367         movq 8(%rsp),%r11
1368         CFI_RESTORE r11
1369         addq $0x30,%rsp
1370         CFI_ADJUST_CFA_OFFSET -0x30
1371         pushq_cfi $0    /* RIP */
1372         pushq_cfi %r11
1373         pushq_cfi %rcx
1374         jmp general_protection
1375         CFI_RESTORE_STATE
1376 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1377         movq (%rsp),%rcx
1378         CFI_RESTORE rcx
1379         movq 8(%rsp),%r11
1380         CFI_RESTORE r11
1381         addq $0x30,%rsp
1382         CFI_ADJUST_CFA_OFFSET -0x30
1383         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1384         SAVE_ALL
1385         jmp error_exit
1386         CFI_ENDPROC
1387 END(xen_failsafe_callback)
1388
1389 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1390         xen_hvm_callback_vector xen_evtchn_do_upcall
1391
1392 #endif /* CONFIG_XEN */
1393
1394 /*
1395  * Some functions should be protected against kprobes
1396  */
1397         .pushsection .kprobes.text, "ax"
1398
1399 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1400 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1401 errorentry stack_segment do_stack_segment
1402 #ifdef CONFIG_XEN
1403 zeroentry xen_debug do_debug
1404 zeroentry xen_int3 do_int3
1405 errorentry xen_stack_segment do_stack_segment
1406 #endif
1407 errorentry general_protection do_general_protection
1408 errorentry page_fault do_page_fault
1409 #ifdef CONFIG_KVM_GUEST
1410 errorentry async_page_fault do_async_page_fault
1411 #endif
1412 #ifdef CONFIG_X86_MCE
1413 paranoidzeroentry machine_check do_mce
1414 #endif
1415
1416         /*
1417          * "Paranoid" exit path from exception stack.
1418          * Paranoid because this is used by NMIs and cannot take
1419          * any kernel state for granted.
1420          * We don't do kernel preemption checks here, because only
1421          * NMI should be common and it does not enable IRQs and
1422          * cannot get reschedule ticks.
1423          *
1424          * "trace" is 0 for the NMI handler only, because irq-tracing
1425          * is fundamentally NMI-unsafe. (we cannot change the soft and
1426          * hard flags at once, atomically)
1427          */
1428 /*
1429  * On entry: ebx=0: needs swapgs but not SWITCH_USER_CR3
1430  *           ebx=1: needs neither swapgs nor SWITCH_USER_CR3
1431  *           ebx=2: needs both swapgs and SWITCH_USER_CR3
1432  *           ebx=3: needs SWITCH_USER_CR3 but not swapgs
1433  */
1434 ENTRY(paranoid_exit)
1435         DEFAULT_FRAME
1436         DISABLE_INTERRUPTS(CLBR_NONE)
1437         TRACE_IRQS_OFF
1438         movq    %rbx, %r12              /* paranoid_userspace uses %ebx */
1439         testl   $3, CS(%rsp)
1440         jnz     paranoid_userspace
1441 paranoid_kernel:
1442         movq    %r12, %rbx              /* restore after paranoid_userspace */
1443         TRACE_IRQS_IRETQ 0
1444 #ifdef CONFIG_PAGE_TABLE_ISOLATION
1445         /* No ALTERNATIVE for X86_FEATURE_KAISER: save_paranoid sets %ebx */
1446         testl   $2, %ebx                /* SWITCH_USER_CR3 needed? */
1447         jz      paranoid_exit_no_switch
1448         SWITCH_USER_CR3
1449 paranoid_exit_no_switch:
1450 #endif
1451         testl   $1, %ebx                /* swapgs needed? */
1452         jnz     paranoid_exit_no_swapgs
1453         SWAPGS_UNSAFE_STACK
1454 paranoid_exit_no_swapgs:
1455         RESTORE_ALL 8
1456         jmp     irq_return
1457
1458 paranoid_userspace:
1459         GET_THREAD_INFO(%rcx)
1460         movl TI_flags(%rcx),%ebx
1461         andl $_TIF_WORK_MASK,%ebx
1462         jz paranoid_kernel
1463         movq %rsp,%rdi                  /* &pt_regs */
1464         call sync_regs
1465         movq %rax,%rsp                  /* switch stack for scheduling */
1466         testl $_TIF_NEED_RESCHED,%ebx
1467         jnz paranoid_schedule
1468         movl %ebx,%edx                  /* arg3: thread flags */
1469         TRACE_IRQS_ON
1470         ENABLE_INTERRUPTS(CLBR_NONE)
1471         xorl %esi,%esi                  /* arg2: oldset */
1472         movq %rsp,%rdi                  /* arg1: &pt_regs */
1473         call do_notify_resume
1474         DISABLE_INTERRUPTS(CLBR_NONE)
1475         TRACE_IRQS_OFF
1476         jmp paranoid_userspace
1477 paranoid_schedule:
1478         TRACE_IRQS_ON
1479         ENABLE_INTERRUPTS(CLBR_ANY)
1480         call schedule
1481         DISABLE_INTERRUPTS(CLBR_ANY)
1482         TRACE_IRQS_OFF
1483         jmp paranoid_userspace
1484         CFI_ENDPROC
1485 END(paranoid_exit)
1486
1487 /*
1488  * Exception entry point. This expects an error code/orig_rax on the stack.
1489  * returns in "no swapgs flag" in %ebx.
1490  */
1491 ENTRY(error_entry)
1492         XCPT_FRAME
1493         CFI_ADJUST_CFA_OFFSET 15*8
1494         /* oldrax contains error code */
1495         cld
1496         movq_cfi rdi, RDI+8
1497         movq_cfi rsi, RSI+8
1498         movq_cfi rdx, RDX+8
1499         movq_cfi rcx, RCX+8
1500         movq_cfi rax, RAX+8
1501         movq_cfi  r8,  R8+8
1502         movq_cfi  r9,  R9+8
1503         movq_cfi r10, R10+8
1504         movq_cfi r11, R11+8
1505         movq_cfi rbx, RBX+8
1506         movq_cfi rbp, RBP+8
1507         movq_cfi r12, R12+8
1508         movq_cfi r13, R13+8
1509         movq_cfi r14, R14+8
1510         movq_cfi r15, R15+8
1511         /*
1512          * error_entry() always returns with a kernel gsbase and
1513          * CR3.  We must also have a kernel CR3/gsbase before
1514          * calling TRACE_IRQS_*.  Just unconditionally switch to
1515          * the kernel CR3 here.
1516          */
1517         SWITCH_KERNEL_CR3
1518         xorl %ebx,%ebx
1519         testl $3,CS+8(%rsp)
1520         je error_kernelspace
1521 error_swapgs:
1522         SWAPGS
1523 error_sti:
1524         TRACE_IRQS_OFF
1525         ret
1526
1527 /*
1528  * There are two places in the kernel that can potentially fault with
1529  * usergs. Handle them here.  B stepping K8s sometimes report a
1530  * truncated RIP for IRET exceptions returning to compat mode. Check
1531  * for these here too.
1532  */
1533 error_kernelspace:
1534         incl %ebx
1535         leaq native_irq_return_iret(%rip),%rcx
1536         cmpq %rcx,RIP+8(%rsp)
1537         je error_bad_iret
1538         movl %ecx,%eax  /* zero extend */
1539         cmpq %rax,RIP+8(%rsp)
1540         je bstep_iret
1541         cmpq $gs_change,RIP+8(%rsp)
1542         je error_swapgs
1543         jmp error_sti
1544
1545 bstep_iret:
1546         /* Fix truncated RIP */
1547         movq %rcx,RIP+8(%rsp)
1548         /* fall through */
1549
1550 error_bad_iret:
1551         SWAPGS
1552         mov %rsp,%rdi
1553         call fixup_bad_iret
1554         mov %rax,%rsp
1555         decl %ebx       /* Return to usergs */
1556         jmp error_sti
1557         CFI_ENDPROC
1558 END(error_entry)
1559
1560
1561 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1562 ENTRY(error_exit)
1563         DEFAULT_FRAME
1564         movl %ebx,%eax
1565         RESTORE_REST
1566         DISABLE_INTERRUPTS(CLBR_NONE)
1567         TRACE_IRQS_OFF
1568         GET_THREAD_INFO(%rcx)
1569         testl %eax,%eax
1570         jne retint_kernel
1571         LOCKDEP_SYS_EXIT_IRQ
1572         movl TI_flags(%rcx),%edx
1573         movl $_TIF_WORK_MASK,%edi
1574         andl %edi,%edx
1575         jnz retint_careful
1576         jmp retint_swapgs
1577         CFI_ENDPROC
1578 END(error_exit)
1579
1580
1581         /* runs on exception stack */
1582 ENTRY(nmi)
1583         INTR_FRAME
1584         /*
1585          * Fix up the exception frame if we're on Xen.
1586          * PARAVIRT_ADJUST_EXCEPTION_FRAME is guaranteed to push at most
1587          * one value to the stack on native, so it may clobber the rdx
1588          * scratch slot, but it won't clobber any of the important
1589          * slots past it.
1590          *
1591          * Xen is a different story, because the Xen frame itself overlaps
1592          * the "NMI executing" variable.
1593          */
1594         PARAVIRT_ADJUST_EXCEPTION_FRAME
1595
1596         pushq_cfi $-1
1597         subq $ORIG_RAX-R15, %rsp
1598         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1599         call save_paranoid
1600         DEFAULT_FRAME 0
1601         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1602         movq %rsp,%rdi
1603         movq $-1,%rsi
1604         call do_nmi
1605 #ifdef CONFIG_TRACE_IRQFLAGS
1606         /* paranoidexit; without TRACE_IRQS_OFF */
1607         /* ebx: no-swapgs and kaiser-switch-cr3 flag */
1608         DISABLE_INTERRUPTS(CLBR_NONE)
1609         movq    %rbx, %r12              /* nmi_userspace uses %ebx */
1610         testl   $3, CS(%rsp)
1611         jnz     nmi_userspace
1612 nmi_kernel:
1613         movq    %r12, %rbx              /* restore after nmi_userspace */
1614 #ifdef CONFIG_PAGE_TABLE_ISOLATION
1615         /* No ALTERNATIVE for X86_FEATURE_KAISER: save_paranoid sets %ebx */
1616         testl   $2, %ebx                /* SWITCH_USER_CR3 needed? */
1617         jz      nmi_exit_no_switch
1618         SWITCH_USER_CR3
1619 nmi_exit_no_switch:
1620 #endif
1621         testl   $1, %ebx                /* swapgs needed? */
1622         jnz     nmi_exit_no_swapgs
1623         SWAPGS_UNSAFE_STACK
1624 nmi_exit_no_swapgs:
1625         RESTORE_ALL 8
1626         jmp     irq_return
1627
1628 nmi_userspace:
1629         GET_THREAD_INFO(%rcx)
1630         movl TI_flags(%rcx),%ebx
1631         andl $_TIF_WORK_MASK,%ebx
1632         jz nmi_kernel
1633         movq %rsp,%rdi                  /* &pt_regs */
1634         call sync_regs
1635         movq %rax,%rsp                  /* switch stack for scheduling */
1636         testl $_TIF_NEED_RESCHED,%ebx
1637         jnz nmi_schedule
1638         movl %ebx,%edx                  /* arg3: thread flags */
1639         ENABLE_INTERRUPTS(CLBR_NONE)
1640         xorl %esi,%esi                  /* arg2: oldset */
1641         movq %rsp,%rdi                  /* arg1: &pt_regs */
1642         call do_notify_resume
1643         DISABLE_INTERRUPTS(CLBR_NONE)
1644         jmp nmi_userspace
1645 nmi_schedule:
1646         ENABLE_INTERRUPTS(CLBR_ANY)
1647         call schedule
1648         DISABLE_INTERRUPTS(CLBR_ANY)
1649         jmp nmi_userspace
1650         CFI_ENDPROC
1651 #else
1652         jmp paranoid_exit
1653         CFI_ENDPROC
1654 #endif
1655 END(nmi)
1656
1657 ENTRY(ignore_sysret)
1658         CFI_STARTPROC
1659         mov $-ENOSYS,%eax
1660         sysret
1661         CFI_ENDPROC
1662 END(ignore_sysret)
1663
1664 /*
1665  * End of kprobes section
1666  */
1667         .popsection