arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/pgtable_types.h>
  59 #include <asm/kaiser.h>
  60
  61 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  62 #include <linux/elf-em.h>
  63 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  64 #define __AUDIT_ARCH_64BIT 0x80000000
  65 #define __AUDIT_ARCH_LE    0x40000000
  66
  67         .code64
  68         .section .entry.text, "ax"
  69
  70 #ifdef CONFIG_FUNCTION_TRACER
  71 #ifdef CONFIG_DYNAMIC_FTRACE
  72 ENTRY(mcount)
  73         retq
  74 END(mcount)
  75
  76 ENTRY(ftrace_caller)
  77         cmpl $0, function_trace_stop
  78         jne  ftrace_stub
  79
  80         MCOUNT_SAVE_FRAME
  81
  82         movq 0x38(%rsp), %rdi
  83         movq 8(%rbp), %rsi
  84         subq $MCOUNT_INSN_SIZE, %rdi
  85
  86 GLOBAL(ftrace_call)
  87         call ftrace_stub
  88
  89         MCOUNT_RESTORE_FRAME
  90
  91 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  92 GLOBAL(ftrace_graph_call)
  93         jmp ftrace_stub
  94 #endif
  95
  96 GLOBAL(ftrace_stub)
  97         retq
  98 END(ftrace_caller)
  99
 100 #else /* ! CONFIG_DYNAMIC_FTRACE */
 101 ENTRY(mcount)
 102         cmpl $0, function_trace_stop
 103         jne  ftrace_stub
 104
 105         cmpq $ftrace_stub, ftrace_trace_function
 106         jnz trace
 107
 108 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 109         cmpq $ftrace_stub, ftrace_graph_return
 110         jnz ftrace_graph_caller
 111
 112         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 113         jnz ftrace_graph_caller
 114 #endif
 115
 116 GLOBAL(ftrace_stub)
 117         retq
 118
 119 trace:
 120         MCOUNT_SAVE_FRAME
 121
 122         movq 0x38(%rsp), %rdi
 123         movq 8(%rbp), %rsi
 124         subq $MCOUNT_INSN_SIZE, %rdi
 125
 126         call   *ftrace_trace_function
 127
 128         MCOUNT_RESTORE_FRAME
 129
 130         jmp ftrace_stub
 131 END(mcount)
 132 #endif /* CONFIG_DYNAMIC_FTRACE */
 133 #endif /* CONFIG_FUNCTION_TRACER */
 134
 135 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 136 ENTRY(ftrace_graph_caller)
 137         cmpl $0, function_trace_stop
 138         jne ftrace_stub
 139
 140         MCOUNT_SAVE_FRAME
 141
 142         leaq 8(%rbp), %rdi
 143         movq 0x38(%rsp), %rsi
 144         movq (%rbp), %rdx
 145         subq $MCOUNT_INSN_SIZE, %rsi
 146
 147         call    prepare_ftrace_return
 148
 149         MCOUNT_RESTORE_FRAME
 150
 151         retq
 152 END(ftrace_graph_caller)
 153
 154 GLOBAL(return_to_handler)
 155         subq  $24, %rsp
 156
 157         /* Save the return values */
 158         movq %rax, (%rsp)
 159         movq %rdx, 8(%rsp)
 160         movq %rbp, %rdi
 161
 162         call ftrace_return_to_handler
 163
 164         movq %rax, %rdi
 165         movq 8(%rsp), %rdx
 166         movq (%rsp), %rax
 167         addq $24, %rsp
 168         jmp *%rdi
 169 #endif
 170
 171
 172 #ifndef CONFIG_PREEMPT
 173 #define retint_kernel retint_restore_args
 174 #endif
 175
 176 #ifdef CONFIG_PARAVIRT
 177 ENTRY(native_usergs_sysret64)
 178         swapgs
 179         sysretq
 180 ENDPROC(native_usergs_sysret64)
 181 #endif /* CONFIG_PARAVIRT */
 182
 183
 184 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 185 #ifdef CONFIG_TRACE_IRQFLAGS
 186         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 187         jnc  1f
 188         TRACE_IRQS_ON
 189 1:
 190 #endif
 191 .endm
 192
 193 /*
 194  * C code is not supposed to know about undefined top of stack. Every time
 195  * a C function with an pt_regs argument is called from the SYSCALL based
 196  * fast path FIXUP_TOP_OF_STACK is needed.
 197  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 198  * manipulation.
 199  */
 200
 201         /* %rsp:at FRAMEEND */
 202         .macro FIXUP_TOP_OF_STACK tmp offset=0
 203         movq PER_CPU_VAR(old_rsp),\tmp
 204         movq \tmp,RSP+\offset(%rsp)
 205         movq $__USER_DS,SS+\offset(%rsp)
 206         movq $__USER_CS,CS+\offset(%rsp)
 207         movq $-1,RCX+\offset(%rsp)
 208         movq R11+\offset(%rsp),\tmp  /* get eflags */
 209         movq \tmp,EFLAGS+\offset(%rsp)
 210         .endm
 211
 212         .macro RESTORE_TOP_OF_STACK tmp offset=0
 213         movq RSP+\offset(%rsp),\tmp
 214         movq \tmp,PER_CPU_VAR(old_rsp)
 215         movq EFLAGS+\offset(%rsp),\tmp
 216         movq \tmp,R11+\offset(%rsp)
 217         .endm
 218
 219         .macro FAKE_STACK_FRAME child_rip
 220         /* push in order ss, rsp, eflags, cs, rip */
 221         xorl %eax, %eax
 222         pushq_cfi $__KERNEL_DS /* ss */
 223         /*CFI_REL_OFFSET        ss,0*/
 224         pushq_cfi %rax /* rsp */
 225         CFI_REL_OFFSET  rsp,0
 226         pushq_cfi $X86_EFLAGS_IF /* eflags - interrupts on */
 227         /*CFI_REL_OFFSET        rflags,0*/
 228         pushq_cfi $__KERNEL_CS /* cs */
 229         /*CFI_REL_OFFSET        cs,0*/
 230         pushq_cfi \child_rip /* rip */
 231         CFI_REL_OFFSET  rip,0
 232         pushq_cfi %rax /* orig rax */
 233         .endm
 234
 235         .macro UNFAKE_STACK_FRAME
 236         addq $8*6, %rsp
 237         CFI_ADJUST_CFA_OFFSET   -(6*8)
 238         .endm
 239
 240 /*
 241  * initial frame state for interrupts (and exceptions without error code)
 242  */
 243         .macro EMPTY_FRAME start=1 offset=0
 244         .if \start
 245         CFI_STARTPROC simple
 246         CFI_SIGNAL_FRAME
 247         CFI_DEF_CFA rsp,8+\offset
 248         .else
 249         CFI_DEF_CFA_OFFSET 8+\offset
 250         .endif
 251         .endm
 252
 253 /*
 254  * initial frame state for interrupts (and exceptions without error code)
 255  */
 256         .macro INTR_FRAME start=1 offset=0
 257         EMPTY_FRAME \start, SS+8+\offset-RIP
 258         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 259         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 260         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 261         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 262         CFI_REL_OFFSET rip, RIP+\offset-RIP
 263         .endm
 264
 265 /*
 266  * initial frame state for exceptions with error code (and interrupts
 267  * with vector already pushed)
 268  */
 269         .macro XCPT_FRAME start=1 offset=0
 270         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 271         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 272         .endm
 273
 274 /*
 275  * frame that enables calling into C.
 276  */
 277         .macro PARTIAL_FRAME start=1 offset=0
 278         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 283         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 286         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 287         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 288         .endm
 289
 290 /*
 291  * frame that enables passing a complete pt_regs to a C function.
 292  */
 293         .macro DEFAULT_FRAME start=1 offset=0
 294         PARTIAL_FRAME \start, R11+\offset-R15
 295         CFI_REL_OFFSET rbx, RBX+\offset
 296         CFI_REL_OFFSET rbp, RBP+\offset
 297         CFI_REL_OFFSET r12, R12+\offset
 298         CFI_REL_OFFSET r13, R13+\offset
 299         CFI_REL_OFFSET r14, R14+\offset
 300         CFI_REL_OFFSET r15, R15+\offset
 301         .endm
 302
 303 /* save partial stack frame */
 304         .macro SAVE_ARGS_IRQ
 305         cld
 306         /* start from rbp in pt_regs and jump over */
 307         movq_cfi rdi, RDI-RBP
 308         movq_cfi rsi, RSI-RBP
 309         movq_cfi rdx, RDX-RBP
 310         movq_cfi rcx, RCX-RBP
 311         movq_cfi rax, RAX-RBP
 312         movq_cfi  r8,  R8-RBP
 313         movq_cfi  r9,  R9-RBP
 314         movq_cfi r10, R10-RBP
 315         movq_cfi r11, R11-RBP
 316
 317         /* Save rbp so that we can unwind from get_irq_regs() */
 318         movq_cfi rbp, 0
 319
 320         /* Save previous stack value */
 321         movq %rsp, %rsi
 322
 323         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 324         testl $3, CS(%rdi)
 325         je 1f
 326         SWAPGS
 327         SWITCH_KERNEL_CR3
 328         /*
 329          * irq_count is used to check if a CPU is already on an interrupt stack
 330          * or not. While this is essentially redundant with preempt_count it is
 331          * a little cheaper to use a separate counter in the PDA (short of
 332          * moving irq_enter into assembly, which would be too much work)
 333          */
 334 1:      incl PER_CPU_VAR(irq_count)
 335         jne 2f
 336         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 337         CFI_DEF_CFA_REGISTER    rsi
 338
 339 2:      /* Store previous stack value */
 340         pushq %rsi
 341         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 342                         0x77 /* DW_OP_breg7 */, 0, \
 343                         0x06 /* DW_OP_deref */, \
 344                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 345                         0x22 /* DW_OP_plus */
 346         /* We entered an interrupt context - irqs are off: */
 347         TRACE_IRQS_OFF
 348         .endm
 349
 350 ENTRY(save_rest)
 351         PARTIAL_FRAME 1 REST_SKIP+8
 352         movq 5*8+16(%rsp), %r11 /* save return address */
 353         movq_cfi rbx, RBX+16
 354         movq_cfi rbp, RBP+16
 355         movq_cfi r12, R12+16
 356         movq_cfi r13, R13+16
 357         movq_cfi r14, R14+16
 358         movq_cfi r15, R15+16
 359         movq %r11, 8(%rsp)      /* return address */
 360         FIXUP_TOP_OF_STACK %r11, 16
 361         ret
 362         CFI_ENDPROC
 363 END(save_rest)
 364
 365 /* save complete stack frame */
 366         .pushsection .kprobes.text, "ax"
 367 /*
 368  * Return: ebx=0: needs swapgs but not SWITCH_USER_CR3 in paranoid_exit
 369  *         ebx=1: needs neither swapgs nor SWITCH_USER_CR3 in paranoid_exit
 370  *         ebx=2: needs both swapgs and SWITCH_USER_CR3 in paranoid_exit
 371  *         ebx=3: needs SWITCH_USER_CR3 but not swapgs in paranoid_exit
 372  */
 373 ENTRY(save_paranoid)
 374         XCPT_FRAME 1 RDI+8
 375         cld
 376         movq_cfi rdi, RDI+8
 377         movq_cfi rsi, RSI+8
 378         movq_cfi rdx, RDX+8
 379         movq_cfi rcx, RCX+8
 380         movq_cfi rax, RAX+8
 381         movq_cfi r8, R8+8
 382         movq_cfi r9, R9+8
 383         movq_cfi r10, R10+8
 384         movq_cfi r11, R11+8
 385         movq_cfi rbx, RBX+8
 386         movq_cfi rbp, RBP+8
 387         movq_cfi r12, R12+8
 388         movq_cfi r13, R13+8
 389         movq_cfi r14, R14+8
 390         movq_cfi r15, R15+8
 391         movl $1,%ebx
 392         movl $MSR_GS_BASE,%ecx
 393         rdmsr
 394         testl %edx,%edx
 395         js 1f   /* negative -> in kernel */
 396         SWAPGS
 397         xorl %ebx,%ebx
 398 1:
 399 #ifdef CONFIG_KAISER
 400         /*
 401          * We might have come in between a swapgs and a SWITCH_KERNEL_CR3
 402          * on entry, or between a SWITCH_USER_CR3 and a swapgs on exit.
 403          * Do a conditional SWITCH_KERNEL_CR3: this could safely be done
 404          * unconditionally, but we need to find out whether the reverse
 405          * should be done on return (conveyed to paranoid_exit in %ebx).
 406          */
 407         movq    %cr3, %rax
 408         testl   $KAISER_SHADOW_PGD_OFFSET, %eax
 409         jz      2f
 410         orl     $2, %ebx
 411         andq    $(~(X86_CR3_PCID_ASID_MASK | KAISER_SHADOW_PGD_OFFSET)), %rax
 412         orq     x86_cr3_pcid_noflush, %rax
 413         movq    %rax, %cr3
 414 2:
 415 #endif
 416         ret
 417         CFI_ENDPROC
 418 END(save_paranoid)
 419         .popsection
 420
 421 /*
 422  * A newly forked process directly context switches into this address.
 423  *
 424  * rdi: prev task we switched from
 425  */
 426 ENTRY(ret_from_fork)
 427         DEFAULT_FRAME
 428
 429         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 430
 431         pushq_cfi kernel_eflags(%rip)
 432         popfq_cfi                               # reset kernel eflags
 433
 434         call schedule_tail                      # rdi: 'prev' task parameter
 435
 436         GET_THREAD_INFO(%rcx)
 437
 438         RESTORE_REST
 439
 440         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 441         je   int_ret_from_sys_call
 442
 443         /*
 444          * By the time we get here, we have no idea whether our pt_regs,
 445          * ti flags, and ti status came from the 64-bit SYSCALL fast path,
 446          * the slow path, or one of the ia32entry paths.
 447          * Use int_ret_from_sys_call to return, since it can safely handle
 448          * all of the above.
 449          */
 450         jmp  int_ret_from_sys_call
 451
 452         CFI_ENDPROC
 453 END(ret_from_fork)
 454
 455 /*
 456  * System call entry. Up to 6 arguments in registers are supported.
 457  *
 458  * SYSCALL does not save anything on the stack and does not change the
 459  * stack pointer.
 460  */
 461
 462 /*
 463  * Register setup:
 464  * rax  system call number
 465  * rdi  arg0
 466  * rcx  return address for syscall/sysret, C arg3
 467  * rsi  arg1
 468  * rdx  arg2
 469  * r10  arg3    (--> moved to rcx for C)
 470  * r8   arg4
 471  * r9   arg5
 472  * r11  eflags for syscall/sysret, temporary for C
 473  * r12-r15,rbp,rbx saved by C code, not touched.
 474  *
 475  * Interrupts are off on entry.
 476  * Only called from user space.
 477  *
 478  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 479  *      and report it properly in ps. Unfortunately we haven't.
 480  *
 481  * When user can change the frames always force IRET. That is because
 482  * it deals with uncanonical addresses better. SYSRET has trouble
 483  * with them due to bugs in both AMD and Intel CPUs.
 484  */
 485
 486 ENTRY(system_call)
 487         CFI_STARTPROC   simple
 488         CFI_SIGNAL_FRAME
 489         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 490         CFI_REGISTER    rip,rcx
 491         /*CFI_REGISTER  rflags,r11*/
 492         SWAPGS_UNSAFE_STACK
 493         SWITCH_KERNEL_CR3_NO_STACK
 494         /*
 495          * A hypervisor implementation might want to use a label
 496          * after the swapgs, so that it can do the swapgs
 497          * for the guest and jump here on syscall.
 498          */
 499 ENTRY(system_call_after_swapgs)
 500
 501         movq    %rsp,PER_CPU_VAR(old_rsp)
 502         movq    PER_CPU_VAR(kernel_stack),%rsp
 503         /*
 504          * No need to follow this irqs off/on section - it's straight
 505          * and short:
 506          */
 507         ENABLE_INTERRUPTS(CLBR_NONE)
 508         SAVE_ARGS 8,0
 509         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 510         movq  %rcx,RIP-ARGOFFSET(%rsp)
 511         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 512         GET_THREAD_INFO(%rcx)
 513         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 514         jnz tracesys
 515 system_call_fastpath:
 516         cmpq $__NR_syscall_max,%rax
 517         ja badsys
 518         movq %r10,%rcx
 519         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 520         movq %rax,RAX-ARGOFFSET(%rsp)
 521 /*
 522  * Syscall return path ending with SYSRET (fast path)
 523  * Has incomplete stack frame and undefined top of stack.
 524  */
 525 ret_from_sys_call:
 526         movl $_TIF_ALLWORK_MASK,%edi
 527         /* edi: flagmask */
 528 sysret_check:
 529         LOCKDEP_SYS_EXIT
 530         GET_THREAD_INFO(%rcx)
 531         DISABLE_INTERRUPTS(CLBR_NONE)
 532         TRACE_IRQS_OFF
 533         movl TI_flags(%rcx),%edx
 534         andl %edi,%edx
 535         jnz  sysret_careful
 536         CFI_REMEMBER_STATE
 537         /*
 538          * sysretq will re-enable interrupts:
 539          */
 540         TRACE_IRQS_ON
 541         movq RIP-ARGOFFSET(%rsp),%rcx
 542         CFI_REGISTER    rip,rcx
 543         RESTORE_ARGS 1,-ARG_SKIP,0
 544         /*CFI_REGISTER  rflags,r11*/
 545         /*
 546          * This opens a window where we have a user CR3, but are
 547          * running in the kernel.  This makes using the CS
 548          * register useless for telling whether or not we need to
 549          * switch CR3 in NMIs.  Normal interrupts are OK because
 550          * they are off here.
 551          */
 552         SWITCH_USER_CR3
 553         movq    PER_CPU_VAR(old_rsp), %rsp
 554         USERGS_SYSRET64
 555
 556         CFI_RESTORE_STATE
 557         /* Handle reschedules */
 558         /* edx: work, edi: workmask */
 559 sysret_careful:
 560         bt $TIF_NEED_RESCHED,%edx
 561         jnc sysret_signal
 562         TRACE_IRQS_ON
 563         ENABLE_INTERRUPTS(CLBR_NONE)
 564         pushq_cfi %rdi
 565         call schedule
 566         popq_cfi %rdi
 567         jmp sysret_check
 568
 569         /* Handle a signal */
 570 sysret_signal:
 571         TRACE_IRQS_ON
 572         ENABLE_INTERRUPTS(CLBR_NONE)
 573 #ifdef CONFIG_AUDITSYSCALL
 574         bt $TIF_SYSCALL_AUDIT,%edx
 575         jc sysret_audit
 576 #endif
 577         /*
 578          * We have a signal, or exit tracing or single-step.
 579          * These all wind up with the iret return path anyway,
 580          * so just join that path right now.
 581          */
 582         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 583         jmp int_check_syscall_exit_work
 584
 585 badsys:
 586         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 587         jmp ret_from_sys_call
 588
 589 #ifdef CONFIG_AUDITSYSCALL
 590         /*
 591          * Fast path for syscall audit without full syscall trace.
 592          * We just call audit_syscall_entry() directly, and then
 593          * jump back to the normal fast path.
 594          */
 595 auditsys:
 596         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 597         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 598         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 599         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 600         movq %rax,%rsi                  /* 2nd arg: syscall number */
 601         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 602         call audit_syscall_entry
 603         LOAD_ARGS 0             /* reload call-clobbered registers */
 604         jmp system_call_fastpath
 605
 606         /*
 607          * Return fast path for syscall audit.  Call audit_syscall_exit()
 608          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 609          * masked off.
 610          */
 611 sysret_audit:
 612         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 613         cmpq $0,%rsi            /* is it < 0? */
 614         setl %al                /* 1 if so, 0 if not */
 615         movzbl %al,%edi         /* zero-extend that into %edi */
 616         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 617         call audit_syscall_exit
 618         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 619         jmp sysret_check
 620 #endif  /* CONFIG_AUDITSYSCALL */
 621
 622         /* Do syscall tracing */
 623 tracesys:
 624 #ifdef CONFIG_AUDITSYSCALL
 625         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 626         jz auditsys
 627 #endif
 628         SAVE_REST
 629         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 630         FIXUP_TOP_OF_STACK %rdi
 631         movq %rsp,%rdi
 632         call syscall_trace_enter
 633         /*
 634          * Reload arg registers from stack in case ptrace changed them.
 635          * We don't reload %rax because syscall_trace_enter() returned
 636          * the value it wants us to use in the table lookup.
 637          */
 638         LOAD_ARGS ARGOFFSET, 1
 639         RESTORE_REST
 640         cmpq $__NR_syscall_max,%rax
 641         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 642         movq %r10,%rcx  /* fixup for C */
 643         call *sys_call_table(,%rax,8)
 644         movq %rax,RAX-ARGOFFSET(%rsp)
 645         /* Use IRET because user could have changed frame */
 646
 647 /*
 648  * Syscall return path ending with IRET.
 649  * Has correct top of stack, but partial stack frame.
 650  */
 651 GLOBAL(int_ret_from_sys_call)
 652         DISABLE_INTERRUPTS(CLBR_NONE)
 653         TRACE_IRQS_OFF
 654         testl $3,CS-ARGOFFSET(%rsp)
 655         je retint_restore_args
 656         movl $_TIF_ALLWORK_MASK,%edi
 657         /* edi: mask to check */
 658 GLOBAL(int_with_check)
 659         LOCKDEP_SYS_EXIT_IRQ
 660         GET_THREAD_INFO(%rcx)
 661         movl TI_flags(%rcx),%edx
 662         andl %edi,%edx
 663         jnz   int_careful
 664         andl    $~TS_COMPAT,TI_status(%rcx)
 665         jmp   retint_swapgs
 666
 667         /* Either reschedule or signal or syscall exit tracking needed. */
 668         /* First do a reschedule test. */
 669         /* edx: work, edi: workmask */
 670 int_careful:
 671         bt $TIF_NEED_RESCHED,%edx
 672         jnc  int_very_careful
 673         TRACE_IRQS_ON
 674         ENABLE_INTERRUPTS(CLBR_NONE)
 675         pushq_cfi %rdi
 676         call schedule
 677         popq_cfi %rdi
 678         DISABLE_INTERRUPTS(CLBR_NONE)
 679         TRACE_IRQS_OFF
 680         jmp int_with_check
 681
 682         /* handle signals and tracing -- both require a full stack frame */
 683 int_very_careful:
 684         TRACE_IRQS_ON
 685         ENABLE_INTERRUPTS(CLBR_NONE)
 686 int_check_syscall_exit_work:
 687         SAVE_REST
 688         /* Check for syscall exit trace */
 689         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 690         jz int_signal
 691         pushq_cfi %rdi
 692         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 693         call syscall_trace_leave
 694         popq_cfi %rdi
 695         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 696         jmp int_restore_rest
 697
 698 int_signal:
 699         testl $_TIF_DO_NOTIFY_MASK,%edx
 700         jz 1f
 701         movq %rsp,%rdi          # &ptregs -> arg1
 702         xorl %esi,%esi          # oldset -> arg2
 703         call do_notify_resume
 704 1:      movl $_TIF_WORK_MASK,%edi
 705 int_restore_rest:
 706         RESTORE_REST
 707         DISABLE_INTERRUPTS(CLBR_NONE)
 708         TRACE_IRQS_OFF
 709         jmp int_with_check
 710         CFI_ENDPROC
 711 END(system_call)
 712
 713 /*
 714  * Certain special system calls that need to save a complete full stack frame.
 715  */
 716         .macro PTREGSCALL label,func,arg
 717 ENTRY(\label)
 718         PARTIAL_FRAME 1 8               /* offset 8: return address */
 719         subq $REST_SKIP, %rsp
 720         CFI_ADJUST_CFA_OFFSET REST_SKIP
 721         call save_rest
 722         DEFAULT_FRAME 0 8               /* offset 8: return address */
 723         leaq 8(%rsp), \arg      /* pt_regs pointer */
 724         call \func
 725         jmp ptregscall_common
 726         CFI_ENDPROC
 727 END(\label)
 728         .endm
 729
 730         PTREGSCALL stub_clone, sys_clone, %r8
 731         PTREGSCALL stub_fork, sys_fork, %rdi
 732         PTREGSCALL stub_vfork, sys_vfork, %rdi
 733         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 734         PTREGSCALL stub_iopl, sys_iopl, %rsi
 735
 736 ENTRY(ptregscall_common)
 737         DEFAULT_FRAME 1 8       /* offset 8: return address */
 738         RESTORE_TOP_OF_STACK %r11, 8
 739         movq_cfi_restore R15+8, r15
 740         movq_cfi_restore R14+8, r14
 741         movq_cfi_restore R13+8, r13
 742         movq_cfi_restore R12+8, r12
 743         movq_cfi_restore RBP+8, rbp
 744         movq_cfi_restore RBX+8, rbx
 745         ret $REST_SKIP          /* pop extended registers */
 746         CFI_ENDPROC
 747 END(ptregscall_common)
 748
 749 ENTRY(stub_execve)
 750         CFI_STARTPROC
 751         addq $8, %rsp
 752         PARTIAL_FRAME 0
 753         SAVE_REST
 754         FIXUP_TOP_OF_STACK %r11
 755         movq %rsp, %rcx
 756         call sys_execve
 757         RESTORE_TOP_OF_STACK %r11
 758         movq %rax,RAX(%rsp)
 759         RESTORE_REST
 760         jmp int_ret_from_sys_call
 761         CFI_ENDPROC
 762 END(stub_execve)
 763
 764 /*
 765  * sigreturn is special because it needs to restore all registers on return.
 766  * This cannot be done with SYSRET, so use the IRET return path instead.
 767  */
 768 ENTRY(stub_rt_sigreturn)
 769         CFI_STARTPROC
 770         addq $8, %rsp
 771         PARTIAL_FRAME 0
 772         SAVE_REST
 773         movq %rsp,%rdi
 774         FIXUP_TOP_OF_STACK %r11
 775         call sys_rt_sigreturn
 776         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 777         RESTORE_REST
 778         jmp int_ret_from_sys_call
 779         CFI_ENDPROC
 780 END(stub_rt_sigreturn)
 781
 782 /*
 783  * Build the entry stubs and pointer table with some assembler magic.
 784  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 785  * single cache line on all modern x86 implementations.
 786  */
 787         .section .init.rodata,"a"
 788 ENTRY(interrupt)
 789         .section .entry.text
 790         .p2align 5
 791         .p2align CONFIG_X86_L1_CACHE_SHIFT
 792 ENTRY(irq_entries_start)
 793         INTR_FRAME
 794 vector=FIRST_EXTERNAL_VECTOR
 795 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 796         .balign 32
 797   .rept 7
 798     .if vector < NR_VECTORS
 799       .if vector <> FIRST_EXTERNAL_VECTOR
 800         CFI_ADJUST_CFA_OFFSET -8
 801       .endif
 802 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 803       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 804         jmp 2f
 805       .endif
 806       .previous
 807         .quad 1b
 808       .section .entry.text
 809 vector=vector+1
 810     .endif
 811   .endr
 812 2:      jmp common_interrupt
 813 .endr
 814         CFI_ENDPROC
 815 END(irq_entries_start)
 816
 817 .previous
 818 END(interrupt)
 819 .previous
 820
 821 /*
 822  * Interrupt entry/exit.
 823  *
 824  * Interrupt entry points save only callee clobbered registers in fast path.
 825  *
 826  * Entry runs with interrupts off.
 827  */
 828
 829 /* 0(%rsp): ~(interrupt number) */
 830         .macro interrupt func
 831         /* reserve pt_regs for scratch regs and rbp */
 832         subq $ORIG_RAX-RBP, %rsp
 833         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 834         SAVE_ARGS_IRQ
 835         call \func
 836         .endm
 837
 838 /*
 839  * Interrupt entry/exit should be protected against kprobes
 840  */
 841         .pushsection .kprobes.text, "ax"
 842         /*
 843          * The interrupt stubs push (~vector+0x80) onto the stack and
 844          * then jump to common_interrupt.
 845          */
 846         .p2align CONFIG_X86_L1_CACHE_SHIFT
 847 common_interrupt:
 848         XCPT_FRAME
 849         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 850         interrupt do_IRQ
 851         /* 0(%rsp): old_rsp-ARGOFFSET */
 852 ret_from_intr:
 853         DISABLE_INTERRUPTS(CLBR_NONE)
 854         TRACE_IRQS_OFF
 855         decl PER_CPU_VAR(irq_count)
 856
 857         /* Restore saved previous stack */
 858         popq %rsi
 859         CFI_DEF_CFA_REGISTER    rsi
 860         leaq ARGOFFSET-RBP(%rsi), %rsp
 861         CFI_DEF_CFA_REGISTER    rsp
 862         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 863
 864 exit_intr:
 865         GET_THREAD_INFO(%rcx)
 866         testl $3,CS-ARGOFFSET(%rsp)
 867         je retint_kernel
 868
 869         /* Interrupt came from user space */
 870         /*
 871          * Has a correct top of stack, but a partial stack frame
 872          * %rcx: thread info. Interrupts off.
 873          */
 874 retint_with_reschedule:
 875         movl $_TIF_WORK_MASK,%edi
 876 retint_check:
 877         LOCKDEP_SYS_EXIT_IRQ
 878         movl TI_flags(%rcx),%edx
 879         andl %edi,%edx
 880         CFI_REMEMBER_STATE
 881         jnz  retint_careful
 882
 883 retint_swapgs:          /* return to user-space */
 884         /*
 885          * The iretq could re-enable interrupts:
 886          */
 887         DISABLE_INTERRUPTS(CLBR_ANY)
 888         TRACE_IRQS_IRETQ
 889         /*
 890          * This opens a window where we have a user CR3, but are
 891          * running in the kernel.  This makes using the CS
 892          * register useless for telling whether or not we need to
 893          * switch CR3 in NMIs.  Normal interrupts are OK because
 894          * they are off here.
 895          */
 896         SWITCH_USER_CR3
 897         SWAPGS
 898         jmp restore_args
 899
 900 retint_restore_args:    /* return to kernel space */
 901         DISABLE_INTERRUPTS(CLBR_ANY)
 902         /*
 903          * The iretq could re-enable interrupts:
 904          */
 905         TRACE_IRQS_IRETQ
 906 restore_args:
 907         RESTORE_ARGS 1,8,1
 908
 909 irq_return:
 910         INTERRUPT_RETURN
 911
 912 ENTRY(native_iret)
 913         /*
 914          * Are we returning to a stack segment from the LDT?  Note: in
 915          * 64-bit mode SS:RSP on the exception stack is always valid.
 916          */
 917 #ifdef CONFIG_X86_ESPFIX64
 918         testb $4,(SS-RIP)(%rsp)
 919         jnz native_irq_return_ldt
 920 #endif
 921
 922 .global native_irq_return_iret
 923 native_irq_return_iret:
 924         /*
 925          * This may fault.  Non-paranoid faults on return to userspace are
 926          * handled by fixup_bad_iret.  These include #SS, #GP, and #NP.
 927          * Double-faults due to espfix64 are handled in do_double_fault.
 928          * Other faults here are fatal.
 929          */
 930         iretq
 931
 932 #ifdef CONFIG_X86_ESPFIX64
 933 native_irq_return_ldt:
 934         pushq_cfi %rax
 935         pushq_cfi %rdi
 936         SWAPGS
 937         SWITCH_KERNEL_CR3
 938         movq PER_CPU_VAR(espfix_waddr),%rdi
 939         movq %rax,(0*8)(%rdi)   /* RAX */
 940         movq (2*8)(%rsp),%rax   /* RIP */
 941         movq %rax,(1*8)(%rdi)
 942         movq (3*8)(%rsp),%rax   /* CS */
 943         movq %rax,(2*8)(%rdi)
 944         movq (4*8)(%rsp),%rax   /* RFLAGS */
 945         movq %rax,(3*8)(%rdi)
 946         movq (6*8)(%rsp),%rax   /* SS */
 947         movq %rax,(5*8)(%rdi)
 948         movq (5*8)(%rsp),%rax   /* RSP */
 949         movq %rax,(4*8)(%rdi)
 950         andl $0xffff0000,%eax
 951         popq_cfi %rdi
 952         orq PER_CPU_VAR(espfix_stack),%rax
 953         SWITCH_USER_CR3
 954         SWAPGS
 955         movq %rax,%rsp
 956         popq_cfi %rax
 957         jmp native_irq_return_iret
 958 #endif
 959
 960         /* edi: workmask, edx: work */
 961 retint_careful:
 962         CFI_RESTORE_STATE
 963         bt    $TIF_NEED_RESCHED,%edx
 964         jnc   retint_signal
 965         TRACE_IRQS_ON
 966         ENABLE_INTERRUPTS(CLBR_NONE)
 967         pushq_cfi %rdi
 968         call  schedule
 969         popq_cfi %rdi
 970         GET_THREAD_INFO(%rcx)
 971         DISABLE_INTERRUPTS(CLBR_NONE)
 972         TRACE_IRQS_OFF
 973         jmp retint_check
 974
 975 retint_signal:
 976         testl $_TIF_DO_NOTIFY_MASK,%edx
 977         jz    retint_swapgs
 978         TRACE_IRQS_ON
 979         ENABLE_INTERRUPTS(CLBR_NONE)
 980         SAVE_REST
 981         movq $-1,ORIG_RAX(%rsp)
 982         xorl %esi,%esi          # oldset
 983         movq %rsp,%rdi          # &pt_regs
 984         call do_notify_resume
 985         RESTORE_REST
 986         DISABLE_INTERRUPTS(CLBR_NONE)
 987         TRACE_IRQS_OFF
 988         GET_THREAD_INFO(%rcx)
 989         jmp retint_with_reschedule
 990
 991 #ifdef CONFIG_PREEMPT
 992         /* Returning to kernel space. Check if we need preemption */
 993         /* rcx:  threadinfo. interrupts off. */
 994 ENTRY(retint_kernel)
 995         cmpl $0,TI_preempt_count(%rcx)
 996         jnz  retint_restore_args
 997         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 998         jnc  retint_restore_args
 999         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
1000         jnc  retint_restore_args
1001         call preempt_schedule_irq
1002         jmp exit_intr
1003 #endif
1004         CFI_ENDPROC
1005 END(common_interrupt)
1006
1007 /*
1008  * End of kprobes section
1009  */
1010        .popsection
1011
1012 /*
1013  * APIC interrupts.
1014  */
1015 .macro apicinterrupt num sym do_sym
1016 ENTRY(\sym)
1017         INTR_FRAME
1018         pushq_cfi $~(\num)
1019         interrupt \do_sym
1020         jmp ret_from_intr
1021         CFI_ENDPROC
1022 END(\sym)
1023 .endm
1024
1025 #ifdef CONFIG_SMP
1026 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
1027         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1028 apicinterrupt REBOOT_VECTOR \
1029         reboot_interrupt smp_reboot_interrupt
1030 #endif
1031
1032 #ifdef CONFIG_X86_UV
1033 apicinterrupt UV_BAU_MESSAGE \
1034         uv_bau_message_intr1 uv_bau_message_interrupt
1035 #endif
1036 apicinterrupt LOCAL_TIMER_VECTOR \
1037         apic_timer_interrupt smp_apic_timer_interrupt
1038 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1039         x86_platform_ipi smp_x86_platform_ipi
1040
1041 #ifdef CONFIG_SMP
1042 .irp idx,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
1043         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
1044 .if NUM_INVALIDATE_TLB_VECTORS > \idx
1045 apicinterrupt (INVALIDATE_TLB_VECTOR_START)+\idx \
1046         invalidate_interrupt\idx smp_invalidate_interrupt
1047 .endif
1048 .endr
1049 #endif
1050
1051 apicinterrupt THRESHOLD_APIC_VECTOR \
1052         threshold_interrupt smp_threshold_interrupt
1053 apicinterrupt THERMAL_APIC_VECTOR \
1054         thermal_interrupt smp_thermal_interrupt
1055
1056 #ifdef CONFIG_SMP
1057 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1058         call_function_single_interrupt smp_call_function_single_interrupt
1059 apicinterrupt CALL_FUNCTION_VECTOR \
1060         call_function_interrupt smp_call_function_interrupt
1061 apicinterrupt RESCHEDULE_VECTOR \
1062         reschedule_interrupt smp_reschedule_interrupt
1063 #endif
1064
1065 apicinterrupt ERROR_APIC_VECTOR \
1066         error_interrupt smp_error_interrupt
1067 apicinterrupt SPURIOUS_APIC_VECTOR \
1068         spurious_interrupt smp_spurious_interrupt
1069
1070 #ifdef CONFIG_IRQ_WORK
1071 apicinterrupt IRQ_WORK_VECTOR \
1072         irq_work_interrupt smp_irq_work_interrupt
1073 #endif
1074
1075 /*
1076  * Exception entry points.
1077  */
1078 .macro zeroentry sym do_sym
1079 ENTRY(\sym)
1080         INTR_FRAME
1081         PARAVIRT_ADJUST_EXCEPTION_FRAME
1082         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1083         subq $ORIG_RAX-R15, %rsp
1084         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1085         call error_entry
1086         DEFAULT_FRAME 0
1087         movq %rsp,%rdi          /* pt_regs pointer */
1088         xorl %esi,%esi          /* no error code */
1089         call \do_sym
1090         jmp error_exit          /* %ebx: no swapgs flag */
1091         CFI_ENDPROC
1092 END(\sym)
1093 .endm
1094
1095 .macro paranoidzeroentry sym do_sym
1096 ENTRY(\sym)
1097         INTR_FRAME
1098         PARAVIRT_ADJUST_EXCEPTION_FRAME
1099         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1100         subq $ORIG_RAX-R15, %rsp
1101         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1102         call save_paranoid
1103         TRACE_IRQS_OFF
1104         movq %rsp,%rdi          /* pt_regs pointer */
1105         xorl %esi,%esi          /* no error code */
1106         call \do_sym
1107         jmp paranoid_exit       /* %ebx: no swapgs flag */
1108         CFI_ENDPROC
1109 END(\sym)
1110 .endm
1111
1112 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1113 .macro paranoidzeroentry_ist sym do_sym ist
1114 ENTRY(\sym)
1115         INTR_FRAME
1116         PARAVIRT_ADJUST_EXCEPTION_FRAME
1117         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1118         subq $ORIG_RAX-R15, %rsp
1119         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1120         call save_paranoid
1121         TRACE_IRQS_OFF
1122         movq %rsp,%rdi          /* pt_regs pointer */
1123         xorl %esi,%esi          /* no error code */
1124         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1125         call \do_sym
1126         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1127         jmp paranoid_exit       /* %ebx: no swapgs flag */
1128         CFI_ENDPROC
1129 END(\sym)
1130 .endm
1131
1132 .macro errorentry sym do_sym
1133 ENTRY(\sym)
1134         XCPT_FRAME
1135         PARAVIRT_ADJUST_EXCEPTION_FRAME
1136         subq $ORIG_RAX-R15, %rsp
1137         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1138         call error_entry
1139         DEFAULT_FRAME 0
1140         movq %rsp,%rdi                  /* pt_regs pointer */
1141         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1142         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1143         call \do_sym
1144         jmp error_exit                  /* %ebx: no swapgs flag */
1145         CFI_ENDPROC
1146 END(\sym)
1147 .endm
1148
1149         /* error code is on the stack already */
1150 .macro paranoiderrorentry sym do_sym
1151 ENTRY(\sym)
1152         XCPT_FRAME
1153         PARAVIRT_ADJUST_EXCEPTION_FRAME
1154         subq $ORIG_RAX-R15, %rsp
1155         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1156         call save_paranoid
1157         DEFAULT_FRAME 0
1158         TRACE_IRQS_OFF
1159         movq %rsp,%rdi                  /* pt_regs pointer */
1160         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1161         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1162         call \do_sym
1163         jmp paranoid_exit               /* %ebx: no swapgs flag */
1164         CFI_ENDPROC
1165 END(\sym)
1166 .endm
1167
1168 zeroentry divide_error do_divide_error
1169 zeroentry overflow do_overflow
1170 zeroentry bounds do_bounds
1171 zeroentry invalid_op do_invalid_op
1172 zeroentry device_not_available do_device_not_available
1173 paranoiderrorentry double_fault do_double_fault
1174 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1175 errorentry invalid_TSS do_invalid_TSS
1176 errorentry segment_not_present do_segment_not_present
1177 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1178 zeroentry coprocessor_error do_coprocessor_error
1179 errorentry alignment_check do_alignment_check
1180 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1181
1182
1183         /* Reload gs selector with exception handling */
1184         /* edi:  new selector */
1185 ENTRY(native_load_gs_index)
1186         CFI_STARTPROC
1187         pushfq_cfi
1188         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1189         SWAPGS
1190 gs_change:
1191         movl %edi,%gs
1192 2:      mfence          /* workaround */
1193         SWAPGS
1194         popfq_cfi
1195         ret
1196         CFI_ENDPROC
1197 END(native_load_gs_index)
1198
1199         .section __ex_table,"a"
1200         .align 8
1201         .quad gs_change,bad_gs
1202         .previous
1203         .section .fixup,"ax"
1204         /* running with kernelgs */
1205 bad_gs:
1206         SWAPGS                  /* switch back to user gs */
1207         xorl %eax,%eax
1208         movl %eax,%gs
1209         jmp  2b
1210         .previous
1211
1212 ENTRY(kernel_thread_helper)
1213         pushq $0                # fake return address
1214         CFI_STARTPROC
1215         /*
1216          * Here we are in the child and the registers are set as they were
1217          * at kernel_thread() invocation in the parent.
1218          */
1219         call *%rsi
1220         # exit
1221         mov %eax, %edi
1222         call do_exit
1223         ud2                     # padding for call trace
1224         CFI_ENDPROC
1225 END(kernel_thread_helper)
1226
1227 /*
1228  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1229  *
1230  * C extern interface:
1231  *       extern long execve(const char *name, char **argv, char **envp)
1232  *
1233  * asm input arguments:
1234  *      rdi: name, rsi: argv, rdx: envp
1235  *
1236  * We want to fallback into:
1237  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1238  *
1239  * do_sys_execve asm fallback arguments:
1240  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1241  */
1242 ENTRY(kernel_execve)
1243         CFI_STARTPROC
1244         FAKE_STACK_FRAME $0
1245         SAVE_ALL
1246         movq %rsp,%rcx
1247         call sys_execve
1248         movq %rax, RAX(%rsp)
1249         RESTORE_REST
1250         testq %rax,%rax
1251         je int_ret_from_sys_call
1252         RESTORE_ARGS
1253         UNFAKE_STACK_FRAME
1254         ret
1255         CFI_ENDPROC
1256 END(kernel_execve)
1257
1258 /* Call softirq on interrupt stack. Interrupts are off. */
1259 ENTRY(call_softirq)
1260         CFI_STARTPROC
1261         pushq_cfi %rbp
1262         CFI_REL_OFFSET rbp,0
1263         mov  %rsp,%rbp
1264         CFI_DEF_CFA_REGISTER rbp
1265         incl PER_CPU_VAR(irq_count)
1266         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1267         push  %rbp                      # backlink for old unwinder
1268         call __do_softirq
1269         leaveq
1270         CFI_RESTORE             rbp
1271         CFI_DEF_CFA_REGISTER    rsp
1272         CFI_ADJUST_CFA_OFFSET   -8
1273         decl PER_CPU_VAR(irq_count)
1274         ret
1275         CFI_ENDPROC
1276 END(call_softirq)
1277
1278 #ifdef CONFIG_XEN
1279 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1280
1281 /*
1282  * A note on the "critical region" in our callback handler.
1283  * We want to avoid stacking callback handlers due to events occurring
1284  * during handling of the last event. To do this, we keep events disabled
1285  * until we've done all processing. HOWEVER, we must enable events before
1286  * popping the stack frame (can't be done atomically) and so it would still
1287  * be possible to get enough handler activations to overflow the stack.
1288  * Although unlikely, bugs of that kind are hard to track down, so we'd
1289  * like to avoid the possibility.
1290  * So, on entry to the handler we detect whether we interrupted an
1291  * existing activation in its critical region -- if so, we pop the current
1292  * activation and restart the handler using the previous one.
1293  */
1294 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1295         CFI_STARTPROC
1296 /*
1297  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1298  * see the correct pointer to the pt_regs
1299  */
1300         movq %rdi, %rsp            # we don't return, adjust the stack frame
1301         CFI_ENDPROC
1302         DEFAULT_FRAME
1303 11:     incl PER_CPU_VAR(irq_count)
1304         movq %rsp,%rbp
1305         CFI_DEF_CFA_REGISTER rbp
1306         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1307         pushq %rbp                      # backlink for old unwinder
1308         call xen_evtchn_do_upcall
1309         popq %rsp
1310         CFI_DEF_CFA_REGISTER rsp
1311         decl PER_CPU_VAR(irq_count)
1312         jmp  error_exit
1313         CFI_ENDPROC
1314 END(xen_do_hypervisor_callback)
1315
1316 /*
1317  * Hypervisor uses this for application faults while it executes.
1318  * We get here for two reasons:
1319  *  1. Fault while reloading DS, ES, FS or GS
1320  *  2. Fault while executing IRET
1321  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1322  * registers that could be reloaded and zeroed the others.
1323  * Category 2 we fix up by killing the current process. We cannot use the
1324  * normal Linux return path in this case because if we use the IRET hypercall
1325  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1326  * We distinguish between categories by comparing each saved segment register
1327  * with its current contents: any discrepancy means we in category 1.
1328  */
1329 ENTRY(xen_failsafe_callback)
1330         INTR_FRAME 1 (6*8)
1331         /*CFI_REL_OFFSET gs,GS*/
1332         /*CFI_REL_OFFSET fs,FS*/
1333         /*CFI_REL_OFFSET es,ES*/
1334         /*CFI_REL_OFFSET ds,DS*/
1335         CFI_REL_OFFSET r11,8
1336         CFI_REL_OFFSET rcx,0
1337         movw %ds,%cx
1338         cmpw %cx,0x10(%rsp)
1339         CFI_REMEMBER_STATE
1340         jne 1f
1341         movw %es,%cx
1342         cmpw %cx,0x18(%rsp)
1343         jne 1f
1344         movw %fs,%cx
1345         cmpw %cx,0x20(%rsp)
1346         jne 1f
1347         movw %gs,%cx
1348         cmpw %cx,0x28(%rsp)
1349         jne 1f
1350         /* All segments match their saved values => Category 2 (Bad IRET). */
1351         movq (%rsp),%rcx
1352         CFI_RESTORE rcx
1353         movq 8(%rsp),%r11
1354         CFI_RESTORE r11
1355         addq $0x30,%rsp
1356         CFI_ADJUST_CFA_OFFSET -0x30
1357         pushq_cfi $0    /* RIP */
1358         pushq_cfi %r11
1359         pushq_cfi %rcx
1360         jmp general_protection
1361         CFI_RESTORE_STATE
1362 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1363         movq (%rsp),%rcx
1364         CFI_RESTORE rcx
1365         movq 8(%rsp),%r11
1366         CFI_RESTORE r11
1367         addq $0x30,%rsp
1368         CFI_ADJUST_CFA_OFFSET -0x30
1369         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1370         SAVE_ALL
1371         jmp error_exit
1372         CFI_ENDPROC
1373 END(xen_failsafe_callback)
1374
1375 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1376         xen_hvm_callback_vector xen_evtchn_do_upcall
1377
1378 #endif /* CONFIG_XEN */
1379
1380 /*
1381  * Some functions should be protected against kprobes
1382  */
1383         .pushsection .kprobes.text, "ax"
1384
1385 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1386 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1387 errorentry stack_segment do_stack_segment
1388 #ifdef CONFIG_XEN
1389 zeroentry xen_debug do_debug
1390 zeroentry xen_int3 do_int3
1391 errorentry xen_stack_segment do_stack_segment
1392 #endif
1393 errorentry general_protection do_general_protection
1394 errorentry page_fault do_page_fault
1395 #ifdef CONFIG_KVM_GUEST
1396 errorentry async_page_fault do_async_page_fault
1397 #endif
1398 #ifdef CONFIG_X86_MCE
1399 paranoidzeroentry machine_check *machine_check_vector(%rip)
1400 #endif
1401
1402         /*
1403          * "Paranoid" exit path from exception stack.
1404          * Paranoid because this is used by NMIs and cannot take
1405          * any kernel state for granted.
1406          * We don't do kernel preemption checks here, because only
1407          * NMI should be common and it does not enable IRQs and
1408          * cannot get reschedule ticks.
1409          *
1410          * "trace" is 0 for the NMI handler only, because irq-tracing
1411          * is fundamentally NMI-unsafe. (we cannot change the soft and
1412          * hard flags at once, atomically)
1413          */
1414 /*
1415  * On entry: ebx=0: needs swapgs but not SWITCH_USER_CR3
1416  *           ebx=1: needs neither swapgs nor SWITCH_USER_CR3
1417  *           ebx=2: needs both swapgs and SWITCH_USER_CR3
1418  *           ebx=3: needs SWITCH_USER_CR3 but not swapgs
1419  */
1420 ENTRY(paranoid_exit)
1421         DEFAULT_FRAME
1422         DISABLE_INTERRUPTS(CLBR_NONE)
1423         TRACE_IRQS_OFF
1424         movq    %rbx, %r12              /* paranoid_userspace uses %ebx */
1425         testl   $3, CS(%rsp)
1426         jnz     paranoid_userspace
1427 paranoid_kernel:
1428         movq    %r12, %rbx              /* restore after paranoid_userspace */
1429         TRACE_IRQS_IRETQ 0
1430 #ifdef CONFIG_KAISER
1431         testl   $2, %ebx                /* SWITCH_USER_CR3 needed? */
1432         jz      paranoid_exit_no_switch
1433         SWITCH_USER_CR3
1434 paranoid_exit_no_switch:
1435 #endif
1436         testl   $1, %ebx                /* swapgs needed? */
1437         jnz     paranoid_exit_no_swapgs
1438         SWAPGS_UNSAFE_STACK
1439 paranoid_exit_no_swapgs:
1440         RESTORE_ALL 8
1441         jmp     irq_return
1442
1443 paranoid_userspace:
1444         GET_THREAD_INFO(%rcx)
1445         movl TI_flags(%rcx),%ebx
1446         andl $_TIF_WORK_MASK,%ebx
1447         jz paranoid_kernel
1448         movq %rsp,%rdi                  /* &pt_regs */
1449         call sync_regs
1450         movq %rax,%rsp                  /* switch stack for scheduling */
1451         testl $_TIF_NEED_RESCHED,%ebx
1452         jnz paranoid_schedule
1453         movl %ebx,%edx                  /* arg3: thread flags */
1454         TRACE_IRQS_ON
1455         ENABLE_INTERRUPTS(CLBR_NONE)
1456         xorl %esi,%esi                  /* arg2: oldset */
1457         movq %rsp,%rdi                  /* arg1: &pt_regs */
1458         call do_notify_resume
1459         DISABLE_INTERRUPTS(CLBR_NONE)
1460         TRACE_IRQS_OFF
1461         jmp paranoid_userspace
1462 paranoid_schedule:
1463         TRACE_IRQS_ON
1464         ENABLE_INTERRUPTS(CLBR_ANY)
1465         call schedule
1466         DISABLE_INTERRUPTS(CLBR_ANY)
1467         TRACE_IRQS_OFF
1468         jmp paranoid_userspace
1469         CFI_ENDPROC
1470 END(paranoid_exit)
1471
1472 /*
1473  * Exception entry point. This expects an error code/orig_rax on the stack.
1474  * returns in "no swapgs flag" in %ebx.
1475  */
1476 ENTRY(error_entry)
1477         XCPT_FRAME
1478         CFI_ADJUST_CFA_OFFSET 15*8
1479         /* oldrax contains error code */
1480         cld
1481         movq_cfi rdi, RDI+8
1482         movq_cfi rsi, RSI+8
1483         movq_cfi rdx, RDX+8
1484         movq_cfi rcx, RCX+8
1485         movq_cfi rax, RAX+8
1486         movq_cfi  r8,  R8+8
1487         movq_cfi  r9,  R9+8
1488         movq_cfi r10, R10+8
1489         movq_cfi r11, R11+8
1490         movq_cfi rbx, RBX+8
1491         movq_cfi rbp, RBP+8
1492         movq_cfi r12, R12+8
1493         movq_cfi r13, R13+8
1494         movq_cfi r14, R14+8
1495         movq_cfi r15, R15+8
1496         /*
1497          * error_entry() always returns with a kernel gsbase and
1498          * CR3.  We must also have a kernel CR3/gsbase before
1499          * calling TRACE_IRQS_*.  Just unconditionally switch to
1500          * the kernel CR3 here.
1501          */
1502         SWITCH_KERNEL_CR3
1503         xorl %ebx,%ebx
1504         testl $3,CS+8(%rsp)
1505         je error_kernelspace
1506 error_swapgs:
1507         SWAPGS
1508 error_sti:
1509         TRACE_IRQS_OFF
1510         ret
1511
1512 /*
1513  * There are two places in the kernel that can potentially fault with
1514  * usergs. Handle them here.  B stepping K8s sometimes report a
1515  * truncated RIP for IRET exceptions returning to compat mode. Check
1516  * for these here too.
1517  */
1518 error_kernelspace:
1519         incl %ebx
1520         leaq native_irq_return_iret(%rip),%rcx
1521         cmpq %rcx,RIP+8(%rsp)
1522         je error_bad_iret
1523         movl %ecx,%eax  /* zero extend */
1524         cmpq %rax,RIP+8(%rsp)
1525         je bstep_iret
1526         cmpq $gs_change,RIP+8(%rsp)
1527         je error_swapgs
1528         jmp error_sti
1529
1530 bstep_iret:
1531         /* Fix truncated RIP */
1532         movq %rcx,RIP+8(%rsp)
1533         /* fall through */
1534
1535 error_bad_iret:
1536         SWAPGS
1537         mov %rsp,%rdi
1538         call fixup_bad_iret
1539         mov %rax,%rsp
1540         decl %ebx       /* Return to usergs */
1541         jmp error_sti
1542         CFI_ENDPROC
1543 END(error_entry)
1544
1545
1546 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1547 ENTRY(error_exit)
1548         DEFAULT_FRAME
1549         movl %ebx,%eax
1550         RESTORE_REST
1551         DISABLE_INTERRUPTS(CLBR_NONE)
1552         TRACE_IRQS_OFF
1553         GET_THREAD_INFO(%rcx)
1554         testl %eax,%eax
1555         jne retint_kernel
1556         LOCKDEP_SYS_EXIT_IRQ
1557         movl TI_flags(%rcx),%edx
1558         movl $_TIF_WORK_MASK,%edi
1559         andl %edi,%edx
1560         jnz retint_careful
1561         jmp retint_swapgs
1562         CFI_ENDPROC
1563 END(error_exit)
1564
1565
1566         /* runs on exception stack */
1567 ENTRY(nmi)
1568         INTR_FRAME
1569         /*
1570          * Fix up the exception frame if we're on Xen.
1571          * PARAVIRT_ADJUST_EXCEPTION_FRAME is guaranteed to push at most
1572          * one value to the stack on native, so it may clobber the rdx
1573          * scratch slot, but it won't clobber any of the important
1574          * slots past it.
1575          *
1576          * Xen is a different story, because the Xen frame itself overlaps
1577          * the "NMI executing" variable.
1578          */
1579         PARAVIRT_ADJUST_EXCEPTION_FRAME
1580
1581         pushq_cfi $-1
1582         subq $ORIG_RAX-R15, %rsp
1583         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1584         call save_paranoid
1585         DEFAULT_FRAME 0
1586         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1587         movq %rsp,%rdi
1588         movq $-1,%rsi
1589         call do_nmi
1590 #ifdef CONFIG_TRACE_IRQFLAGS
1591         /* paranoidexit; without TRACE_IRQS_OFF */
1592         /* ebx: no-swapgs and kaiser-switch-cr3 flag */
1593         DISABLE_INTERRUPTS(CLBR_NONE)
1594         movq    %rbx, %r12              /* nmi_userspace uses %ebx */
1595         testl   $3, CS(%rsp)
1596         jnz     nmi_userspace
1597 nmi_kernel:
1598         movq    %r12, %rbx              /* restore after nmi_userspace */
1599 #ifdef CONFIG_KAISER
1600         testl   $2, %ebx                /* SWITCH_USER_CR3 needed? */
1601         jz      nmi_exit_no_switch
1602         SWITCH_USER_CR3
1603 nmi_exit_no_switch:
1604 #endif
1605         testl   $1, %ebx                /* swapgs needed? */
1606         jnz     nmi_exit_no_swapgs
1607         SWAPGS_UNSAFE_STACK
1608 nmi_exit_no_swapgs:
1609         RESTORE_ALL 8
1610         jmp     irq_return
1611
1612 nmi_userspace:
1613         GET_THREAD_INFO(%rcx)
1614         movl TI_flags(%rcx),%ebx
1615         andl $_TIF_WORK_MASK,%ebx
1616         jz nmi_kernel
1617         movq %rsp,%rdi                  /* &pt_regs */
1618         call sync_regs
1619         movq %rax,%rsp                  /* switch stack for scheduling */
1620         testl $_TIF_NEED_RESCHED,%ebx
1621         jnz nmi_schedule
1622         movl %ebx,%edx                  /* arg3: thread flags */
1623         ENABLE_INTERRUPTS(CLBR_NONE)
1624         xorl %esi,%esi                  /* arg2: oldset */
1625         movq %rsp,%rdi                  /* arg1: &pt_regs */
1626         call do_notify_resume
1627         DISABLE_INTERRUPTS(CLBR_NONE)
1628         jmp nmi_userspace
1629 nmi_schedule:
1630         ENABLE_INTERRUPTS(CLBR_ANY)
1631         call schedule
1632         DISABLE_INTERRUPTS(CLBR_ANY)
1633         jmp nmi_userspace
1634         CFI_ENDPROC
1635 #else
1636         jmp paranoid_exit
1637         CFI_ENDPROC
1638 #endif
1639 END(nmi)
1640
1641 ENTRY(ignore_sysret)
1642         CFI_STARTPROC
1643         mov $-ENOSYS,%eax
1644         sysret
1645         CFI_ENDPROC
1646 END(ignore_sysret)
1647
1648 /*
1649  * End of kprobes section
1650  */
1651         .popsection