arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/pgtable_types.h>
  59
  60 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  61 #include <linux/elf-em.h>
  62 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  63 #define __AUDIT_ARCH_64BIT 0x80000000
  64 #define __AUDIT_ARCH_LE    0x40000000
  65
  66         .code64
  67         .section .entry.text, "ax"
  68
  69 #ifdef CONFIG_FUNCTION_TRACER
  70 #ifdef CONFIG_DYNAMIC_FTRACE
  71 ENTRY(mcount)
  72         retq
  73 END(mcount)
  74
  75 ENTRY(ftrace_caller)
  76         cmpl $0, function_trace_stop
  77         jne  ftrace_stub
  78
  79         MCOUNT_SAVE_FRAME
  80
  81         movq 0x38(%rsp), %rdi
  82         movq 8(%rbp), %rsi
  83         subq $MCOUNT_INSN_SIZE, %rdi
  84
  85 GLOBAL(ftrace_call)
  86         call ftrace_stub
  87
  88         MCOUNT_RESTORE_FRAME
  89
  90 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  91 GLOBAL(ftrace_graph_call)
  92         jmp ftrace_stub
  93 #endif
  94
  95 GLOBAL(ftrace_stub)
  96         retq
  97 END(ftrace_caller)
  98
  99 #else /* ! CONFIG_DYNAMIC_FTRACE */
 100 ENTRY(mcount)
 101         cmpl $0, function_trace_stop
 102         jne  ftrace_stub
 103
 104         cmpq $ftrace_stub, ftrace_trace_function
 105         jnz trace
 106
 107 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 108         cmpq $ftrace_stub, ftrace_graph_return
 109         jnz ftrace_graph_caller
 110
 111         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 112         jnz ftrace_graph_caller
 113 #endif
 114
 115 GLOBAL(ftrace_stub)
 116         retq
 117
 118 trace:
 119         MCOUNT_SAVE_FRAME
 120
 121         movq 0x38(%rsp), %rdi
 122         movq 8(%rbp), %rsi
 123         subq $MCOUNT_INSN_SIZE, %rdi
 124
 125         call   *ftrace_trace_function
 126
 127         MCOUNT_RESTORE_FRAME
 128
 129         jmp ftrace_stub
 130 END(mcount)
 131 #endif /* CONFIG_DYNAMIC_FTRACE */
 132 #endif /* CONFIG_FUNCTION_TRACER */
 133
 134 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 135 ENTRY(ftrace_graph_caller)
 136         cmpl $0, function_trace_stop
 137         jne ftrace_stub
 138
 139         MCOUNT_SAVE_FRAME
 140
 141         leaq 8(%rbp), %rdi
 142         movq 0x38(%rsp), %rsi
 143         movq (%rbp), %rdx
 144         subq $MCOUNT_INSN_SIZE, %rsi
 145
 146         call    prepare_ftrace_return
 147
 148         MCOUNT_RESTORE_FRAME
 149
 150         retq
 151 END(ftrace_graph_caller)
 152
 153 GLOBAL(return_to_handler)
 154         subq  $24, %rsp
 155
 156         /* Save the return values */
 157         movq %rax, (%rsp)
 158         movq %rdx, 8(%rsp)
 159         movq %rbp, %rdi
 160
 161         call ftrace_return_to_handler
 162
 163         movq %rax, %rdi
 164         movq 8(%rsp), %rdx
 165         movq (%rsp), %rax
 166         addq $24, %rsp
 167         jmp *%rdi
 168 #endif
 169
 170
 171 #ifndef CONFIG_PREEMPT
 172 #define retint_kernel retint_restore_args
 173 #endif
 174
 175 #ifdef CONFIG_PARAVIRT
 176 ENTRY(native_usergs_sysret64)
 177         swapgs
 178         sysretq
 179 ENDPROC(native_usergs_sysret64)
 180 #endif /* CONFIG_PARAVIRT */
 181
 182
 183 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 184 #ifdef CONFIG_TRACE_IRQFLAGS
 185         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 186         jnc  1f
 187         TRACE_IRQS_ON
 188 1:
 189 #endif
 190 .endm
 191
 192 /*
 193  * C code is not supposed to know about undefined top of stack. Every time
 194  * a C function with an pt_regs argument is called from the SYSCALL based
 195  * fast path FIXUP_TOP_OF_STACK is needed.
 196  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 197  * manipulation.
 198  */
 199
 200         /* %rsp:at FRAMEEND */
 201         .macro FIXUP_TOP_OF_STACK tmp offset=0
 202         movq PER_CPU_VAR(old_rsp),\tmp
 203         movq \tmp,RSP+\offset(%rsp)
 204         movq $__USER_DS,SS+\offset(%rsp)
 205         movq $__USER_CS,CS+\offset(%rsp)
 206         movq $-1,RCX+\offset(%rsp)
 207         movq R11+\offset(%rsp),\tmp  /* get eflags */
 208         movq \tmp,EFLAGS+\offset(%rsp)
 209         .endm
 210
 211         .macro RESTORE_TOP_OF_STACK tmp offset=0
 212         movq RSP+\offset(%rsp),\tmp
 213         movq \tmp,PER_CPU_VAR(old_rsp)
 214         movq EFLAGS+\offset(%rsp),\tmp
 215         movq \tmp,R11+\offset(%rsp)
 216         .endm
 217
 218         .macro FAKE_STACK_FRAME child_rip
 219         /* push in order ss, rsp, eflags, cs, rip */
 220         xorl %eax, %eax
 221         pushq_cfi $__KERNEL_DS /* ss */
 222         /*CFI_REL_OFFSET        ss,0*/
 223         pushq_cfi %rax /* rsp */
 224         CFI_REL_OFFSET  rsp,0
 225         pushq_cfi $X86_EFLAGS_IF /* eflags - interrupts on */
 226         /*CFI_REL_OFFSET        rflags,0*/
 227         pushq_cfi $__KERNEL_CS /* cs */
 228         /*CFI_REL_OFFSET        cs,0*/
 229         pushq_cfi \child_rip /* rip */
 230         CFI_REL_OFFSET  rip,0
 231         pushq_cfi %rax /* orig rax */
 232         .endm
 233
 234         .macro UNFAKE_STACK_FRAME
 235         addq $8*6, %rsp
 236         CFI_ADJUST_CFA_OFFSET   -(6*8)
 237         .endm
 238
 239 /*
 240  * initial frame state for interrupts (and exceptions without error code)
 241  */
 242         .macro EMPTY_FRAME start=1 offset=0
 243         .if \start
 244         CFI_STARTPROC simple
 245         CFI_SIGNAL_FRAME
 246         CFI_DEF_CFA rsp,8+\offset
 247         .else
 248         CFI_DEF_CFA_OFFSET 8+\offset
 249         .endif
 250         .endm
 251
 252 /*
 253  * initial frame state for interrupts (and exceptions without error code)
 254  */
 255         .macro INTR_FRAME start=1 offset=0
 256         EMPTY_FRAME \start, SS+8+\offset-RIP
 257         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 258         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 259         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 260         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 261         CFI_REL_OFFSET rip, RIP+\offset-RIP
 262         .endm
 263
 264 /*
 265  * initial frame state for exceptions with error code (and interrupts
 266  * with vector already pushed)
 267  */
 268         .macro XCPT_FRAME start=1 offset=0
 269         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 270         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 271         .endm
 272
 273 /*
 274  * frame that enables calling into C.
 275  */
 276         .macro PARTIAL_FRAME start=1 offset=0
 277         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 278         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 283         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 286         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 287         .endm
 288
 289 /*
 290  * frame that enables passing a complete pt_regs to a C function.
 291  */
 292         .macro DEFAULT_FRAME start=1 offset=0
 293         PARTIAL_FRAME \start, R11+\offset-R15
 294         CFI_REL_OFFSET rbx, RBX+\offset
 295         CFI_REL_OFFSET rbp, RBP+\offset
 296         CFI_REL_OFFSET r12, R12+\offset
 297         CFI_REL_OFFSET r13, R13+\offset
 298         CFI_REL_OFFSET r14, R14+\offset
 299         CFI_REL_OFFSET r15, R15+\offset
 300         .endm
 301
 302 /* save partial stack frame */
 303         .macro SAVE_ARGS_IRQ
 304         cld
 305         /* start from rbp in pt_regs and jump over */
 306         movq_cfi rdi, RDI-RBP
 307         movq_cfi rsi, RSI-RBP
 308         movq_cfi rdx, RDX-RBP
 309         movq_cfi rcx, RCX-RBP
 310         movq_cfi rax, RAX-RBP
 311         movq_cfi  r8,  R8-RBP
 312         movq_cfi  r9,  R9-RBP
 313         movq_cfi r10, R10-RBP
 314         movq_cfi r11, R11-RBP
 315
 316         /* Save rbp so that we can unwind from get_irq_regs() */
 317         movq_cfi rbp, 0
 318
 319         /* Save previous stack value */
 320         movq %rsp, %rsi
 321
 322         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 323         testl $3, CS(%rdi)
 324         je 1f
 325         SWAPGS
 326         /*
 327          * irq_count is used to check if a CPU is already on an interrupt stack
 328          * or not. While this is essentially redundant with preempt_count it is
 329          * a little cheaper to use a separate counter in the PDA (short of
 330          * moving irq_enter into assembly, which would be too much work)
 331          */
 332 1:      incl PER_CPU_VAR(irq_count)
 333         jne 2f
 334         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 335         CFI_DEF_CFA_REGISTER    rsi
 336
 337 2:      /* Store previous stack value */
 338         pushq %rsi
 339         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 340                         0x77 /* DW_OP_breg7 */, 0, \
 341                         0x06 /* DW_OP_deref */, \
 342                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 343                         0x22 /* DW_OP_plus */
 344         /* We entered an interrupt context - irqs are off: */
 345         TRACE_IRQS_OFF
 346         .endm
 347
 348 ENTRY(save_rest)
 349         PARTIAL_FRAME 1 REST_SKIP+8
 350         movq 5*8+16(%rsp), %r11 /* save return address */
 351         movq_cfi rbx, RBX+16
 352         movq_cfi rbp, RBP+16
 353         movq_cfi r12, R12+16
 354         movq_cfi r13, R13+16
 355         movq_cfi r14, R14+16
 356         movq_cfi r15, R15+16
 357         movq %r11, 8(%rsp)      /* return address */
 358         FIXUP_TOP_OF_STACK %r11, 16
 359         ret
 360         CFI_ENDPROC
 361 END(save_rest)
 362
 363 /* save complete stack frame */
 364         .pushsection .kprobes.text, "ax"
 365 ENTRY(save_paranoid)
 366         XCPT_FRAME 1 RDI+8
 367         cld
 368         movq_cfi rdi, RDI+8
 369         movq_cfi rsi, RSI+8
 370         movq_cfi rdx, RDX+8
 371         movq_cfi rcx, RCX+8
 372         movq_cfi rax, RAX+8
 373         movq_cfi r8, R8+8
 374         movq_cfi r9, R9+8
 375         movq_cfi r10, R10+8
 376         movq_cfi r11, R11+8
 377         movq_cfi rbx, RBX+8
 378         movq_cfi rbp, RBP+8
 379         movq_cfi r12, R12+8
 380         movq_cfi r13, R13+8
 381         movq_cfi r14, R14+8
 382         movq_cfi r15, R15+8
 383         movl $1,%ebx
 384         movl $MSR_GS_BASE,%ecx
 385         rdmsr
 386         testl %edx,%edx
 387         js 1f   /* negative -> in kernel */
 388         SWAPGS
 389         xorl %ebx,%ebx
 390 1:      ret
 391         CFI_ENDPROC
 392 END(save_paranoid)
 393         .popsection
 394
 395 /*
 396  * A newly forked process directly context switches into this address.
 397  *
 398  * rdi: prev task we switched from
 399  */
 400 ENTRY(ret_from_fork)
 401         DEFAULT_FRAME
 402
 403         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 404
 405         pushq_cfi kernel_eflags(%rip)
 406         popfq_cfi                               # reset kernel eflags
 407
 408         call schedule_tail                      # rdi: 'prev' task parameter
 409
 410         GET_THREAD_INFO(%rcx)
 411
 412         RESTORE_REST
 413
 414         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 415         je   int_ret_from_sys_call
 416
 417         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 418         jnz  int_ret_from_sys_call
 419
 420         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 421         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 422
 423         CFI_ENDPROC
 424 END(ret_from_fork)
 425
 426 /*
 427  * System call entry. Up to 6 arguments in registers are supported.
 428  *
 429  * SYSCALL does not save anything on the stack and does not change the
 430  * stack pointer.
 431  */
 432
 433 /*
 434  * Register setup:
 435  * rax  system call number
 436  * rdi  arg0
 437  * rcx  return address for syscall/sysret, C arg3
 438  * rsi  arg1
 439  * rdx  arg2
 440  * r10  arg3    (--> moved to rcx for C)
 441  * r8   arg4
 442  * r9   arg5
 443  * r11  eflags for syscall/sysret, temporary for C
 444  * r12-r15,rbp,rbx saved by C code, not touched.
 445  *
 446  * Interrupts are off on entry.
 447  * Only called from user space.
 448  *
 449  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 450  *      and report it properly in ps. Unfortunately we haven't.
 451  *
 452  * When user can change the frames always force IRET. That is because
 453  * it deals with uncanonical addresses better. SYSRET has trouble
 454  * with them due to bugs in both AMD and Intel CPUs.
 455  */
 456
 457 ENTRY(system_call)
 458         CFI_STARTPROC   simple
 459         CFI_SIGNAL_FRAME
 460         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 461         CFI_REGISTER    rip,rcx
 462         /*CFI_REGISTER  rflags,r11*/
 463         SWAPGS_UNSAFE_STACK
 464         /*
 465          * A hypervisor implementation might want to use a label
 466          * after the swapgs, so that it can do the swapgs
 467          * for the guest and jump here on syscall.
 468          */
 469 ENTRY(system_call_after_swapgs)
 470
 471         movq    %rsp,PER_CPU_VAR(old_rsp)
 472         movq    PER_CPU_VAR(kernel_stack),%rsp
 473         /*
 474          * No need to follow this irqs off/on section - it's straight
 475          * and short:
 476          */
 477         ENABLE_INTERRUPTS(CLBR_NONE)
 478         SAVE_ARGS 8,0
 479         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 480         movq  %rcx,RIP-ARGOFFSET(%rsp)
 481         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 482         GET_THREAD_INFO(%rcx)
 483         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 484         jnz tracesys
 485 system_call_fastpath:
 486         cmpq $__NR_syscall_max,%rax
 487         ja badsys
 488         movq %r10,%rcx
 489         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 490         movq %rax,RAX-ARGOFFSET(%rsp)
 491 /*
 492  * Syscall return path ending with SYSRET (fast path)
 493  * Has incomplete stack frame and undefined top of stack.
 494  */
 495 ret_from_sys_call:
 496         movl $_TIF_ALLWORK_MASK,%edi
 497         /* edi: flagmask */
 498 sysret_check:
 499         LOCKDEP_SYS_EXIT
 500         GET_THREAD_INFO(%rcx)
 501         DISABLE_INTERRUPTS(CLBR_NONE)
 502         TRACE_IRQS_OFF
 503         movl TI_flags(%rcx),%edx
 504         andl %edi,%edx
 505         jnz  sysret_careful
 506         CFI_REMEMBER_STATE
 507         /*
 508          * sysretq will re-enable interrupts:
 509          */
 510         TRACE_IRQS_ON
 511         movq RIP-ARGOFFSET(%rsp),%rcx
 512         CFI_REGISTER    rip,rcx
 513         RESTORE_ARGS 1,-ARG_SKIP,0
 514         /*CFI_REGISTER  rflags,r11*/
 515         movq    PER_CPU_VAR(old_rsp), %rsp
 516         USERGS_SYSRET64
 517
 518         CFI_RESTORE_STATE
 519         /* Handle reschedules */
 520         /* edx: work, edi: workmask */
 521 sysret_careful:
 522         bt $TIF_NEED_RESCHED,%edx
 523         jnc sysret_signal
 524         TRACE_IRQS_ON
 525         ENABLE_INTERRUPTS(CLBR_NONE)
 526         pushq_cfi %rdi
 527         call schedule
 528         popq_cfi %rdi
 529         jmp sysret_check
 530
 531         /* Handle a signal */
 532 sysret_signal:
 533         TRACE_IRQS_ON
 534         ENABLE_INTERRUPTS(CLBR_NONE)
 535 #ifdef CONFIG_AUDITSYSCALL
 536         bt $TIF_SYSCALL_AUDIT,%edx
 537         jc sysret_audit
 538 #endif
 539         /*
 540          * We have a signal, or exit tracing or single-step.
 541          * These all wind up with the iret return path anyway,
 542          * so just join that path right now.
 543          */
 544         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 545         jmp int_check_syscall_exit_work
 546
 547 badsys:
 548         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 549         jmp ret_from_sys_call
 550
 551 #ifdef CONFIG_AUDITSYSCALL
 552         /*
 553          * Fast path for syscall audit without full syscall trace.
 554          * We just call audit_syscall_entry() directly, and then
 555          * jump back to the normal fast path.
 556          */
 557 auditsys:
 558         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 559         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 560         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 561         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 562         movq %rax,%rsi                  /* 2nd arg: syscall number */
 563         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 564         call audit_syscall_entry
 565         LOAD_ARGS 0             /* reload call-clobbered registers */
 566         jmp system_call_fastpath
 567
 568         /*
 569          * Return fast path for syscall audit.  Call audit_syscall_exit()
 570          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 571          * masked off.
 572          */
 573 sysret_audit:
 574         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 575         cmpq $0,%rsi            /* is it < 0? */
 576         setl %al                /* 1 if so, 0 if not */
 577         movzbl %al,%edi         /* zero-extend that into %edi */
 578         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 579         call audit_syscall_exit
 580         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 581         jmp sysret_check
 582 #endif  /* CONFIG_AUDITSYSCALL */
 583
 584         /* Do syscall tracing */
 585 tracesys:
 586 #ifdef CONFIG_AUDITSYSCALL
 587         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 588         jz auditsys
 589 #endif
 590         SAVE_REST
 591         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 592         FIXUP_TOP_OF_STACK %rdi
 593         movq %rsp,%rdi
 594         call syscall_trace_enter
 595         /*
 596          * Reload arg registers from stack in case ptrace changed them.
 597          * We don't reload %rax because syscall_trace_enter() returned
 598          * the value it wants us to use in the table lookup.
 599          */
 600         LOAD_ARGS ARGOFFSET, 1
 601         RESTORE_REST
 602         cmpq $__NR_syscall_max,%rax
 603         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 604         movq %r10,%rcx  /* fixup for C */
 605         call *sys_call_table(,%rax,8)
 606         movq %rax,RAX-ARGOFFSET(%rsp)
 607         /* Use IRET because user could have changed frame */
 608
 609 /*
 610  * Syscall return path ending with IRET.
 611  * Has correct top of stack, but partial stack frame.
 612  */
 613 GLOBAL(int_ret_from_sys_call)
 614         DISABLE_INTERRUPTS(CLBR_NONE)
 615         TRACE_IRQS_OFF
 616         testl $3,CS-ARGOFFSET(%rsp)
 617         je retint_restore_args
 618         movl $_TIF_ALLWORK_MASK,%edi
 619         /* edi: mask to check */
 620 GLOBAL(int_with_check)
 621         LOCKDEP_SYS_EXIT_IRQ
 622         GET_THREAD_INFO(%rcx)
 623         movl TI_flags(%rcx),%edx
 624         andl %edi,%edx
 625         jnz   int_careful
 626         andl    $~TS_COMPAT,TI_status(%rcx)
 627         jmp   retint_swapgs
 628
 629         /* Either reschedule or signal or syscall exit tracking needed. */
 630         /* First do a reschedule test. */
 631         /* edx: work, edi: workmask */
 632 int_careful:
 633         bt $TIF_NEED_RESCHED,%edx
 634         jnc  int_very_careful
 635         TRACE_IRQS_ON
 636         ENABLE_INTERRUPTS(CLBR_NONE)
 637         pushq_cfi %rdi
 638         call schedule
 639         popq_cfi %rdi
 640         DISABLE_INTERRUPTS(CLBR_NONE)
 641         TRACE_IRQS_OFF
 642         jmp int_with_check
 643
 644         /* handle signals and tracing -- both require a full stack frame */
 645 int_very_careful:
 646         TRACE_IRQS_ON
 647         ENABLE_INTERRUPTS(CLBR_NONE)
 648 int_check_syscall_exit_work:
 649         SAVE_REST
 650         /* Check for syscall exit trace */
 651         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 652         jz int_signal
 653         pushq_cfi %rdi
 654         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 655         call syscall_trace_leave
 656         popq_cfi %rdi
 657         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 658         jmp int_restore_rest
 659
 660 int_signal:
 661         testl $_TIF_DO_NOTIFY_MASK,%edx
 662         jz 1f
 663         movq %rsp,%rdi          # &ptregs -> arg1
 664         xorl %esi,%esi          # oldset -> arg2
 665         call do_notify_resume
 666 1:      movl $_TIF_WORK_MASK,%edi
 667 int_restore_rest:
 668         RESTORE_REST
 669         DISABLE_INTERRUPTS(CLBR_NONE)
 670         TRACE_IRQS_OFF
 671         jmp int_with_check
 672         CFI_ENDPROC
 673 END(system_call)
 674
 675 /*
 676  * Certain special system calls that need to save a complete full stack frame.
 677  */
 678         .macro PTREGSCALL label,func,arg
 679 ENTRY(\label)
 680         PARTIAL_FRAME 1 8               /* offset 8: return address */
 681         subq $REST_SKIP, %rsp
 682         CFI_ADJUST_CFA_OFFSET REST_SKIP
 683         call save_rest
 684         DEFAULT_FRAME 0 8               /* offset 8: return address */
 685         leaq 8(%rsp), \arg      /* pt_regs pointer */
 686         call \func
 687         jmp ptregscall_common
 688         CFI_ENDPROC
 689 END(\label)
 690         .endm
 691
 692         PTREGSCALL stub_clone, sys_clone, %r8
 693         PTREGSCALL stub_fork, sys_fork, %rdi
 694         PTREGSCALL stub_vfork, sys_vfork, %rdi
 695         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 696         PTREGSCALL stub_iopl, sys_iopl, %rsi
 697
 698 ENTRY(ptregscall_common)
 699         DEFAULT_FRAME 1 8       /* offset 8: return address */
 700         RESTORE_TOP_OF_STACK %r11, 8
 701         movq_cfi_restore R15+8, r15
 702         movq_cfi_restore R14+8, r14
 703         movq_cfi_restore R13+8, r13
 704         movq_cfi_restore R12+8, r12
 705         movq_cfi_restore RBP+8, rbp
 706         movq_cfi_restore RBX+8, rbx
 707         ret $REST_SKIP          /* pop extended registers */
 708         CFI_ENDPROC
 709 END(ptregscall_common)
 710
 711 ENTRY(stub_execve)
 712         CFI_STARTPROC
 713         addq $8, %rsp
 714         PARTIAL_FRAME 0
 715         SAVE_REST
 716         FIXUP_TOP_OF_STACK %r11
 717         movq %rsp, %rcx
 718         call sys_execve
 719         RESTORE_TOP_OF_STACK %r11
 720         movq %rax,RAX(%rsp)
 721         RESTORE_REST
 722         jmp int_ret_from_sys_call
 723         CFI_ENDPROC
 724 END(stub_execve)
 725
 726 /*
 727  * sigreturn is special because it needs to restore all registers on return.
 728  * This cannot be done with SYSRET, so use the IRET return path instead.
 729  */
 730 ENTRY(stub_rt_sigreturn)
 731         CFI_STARTPROC
 732         addq $8, %rsp
 733         PARTIAL_FRAME 0
 734         SAVE_REST
 735         movq %rsp,%rdi
 736         FIXUP_TOP_OF_STACK %r11
 737         call sys_rt_sigreturn
 738         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 739         RESTORE_REST
 740         jmp int_ret_from_sys_call
 741         CFI_ENDPROC
 742 END(stub_rt_sigreturn)
 743
 744 /*
 745  * Build the entry stubs and pointer table with some assembler magic.
 746  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 747  * single cache line on all modern x86 implementations.
 748  */
 749         .section .init.rodata,"a"
 750 ENTRY(interrupt)
 751         .section .entry.text
 752         .p2align 5
 753         .p2align CONFIG_X86_L1_CACHE_SHIFT
 754 ENTRY(irq_entries_start)
 755         INTR_FRAME
 756 vector=FIRST_EXTERNAL_VECTOR
 757 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 758         .balign 32
 759   .rept 7
 760     .if vector < NR_VECTORS
 761       .if vector <> FIRST_EXTERNAL_VECTOR
 762         CFI_ADJUST_CFA_OFFSET -8
 763       .endif
 764 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 765       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 766         jmp 2f
 767       .endif
 768       .previous
 769         .quad 1b
 770       .section .entry.text
 771 vector=vector+1
 772     .endif
 773   .endr
 774 2:      jmp common_interrupt
 775 .endr
 776         CFI_ENDPROC
 777 END(irq_entries_start)
 778
 779 .previous
 780 END(interrupt)
 781 .previous
 782
 783 /*
 784  * Interrupt entry/exit.
 785  *
 786  * Interrupt entry points save only callee clobbered registers in fast path.
 787  *
 788  * Entry runs with interrupts off.
 789  */
 790
 791 /* 0(%rsp): ~(interrupt number) */
 792         .macro interrupt func
 793         /* reserve pt_regs for scratch regs and rbp */
 794         subq $ORIG_RAX-RBP, %rsp
 795         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 796         SAVE_ARGS_IRQ
 797         call \func
 798         .endm
 799
 800 /*
 801  * Interrupt entry/exit should be protected against kprobes
 802  */
 803         .pushsection .kprobes.text, "ax"
 804         /*
 805          * The interrupt stubs push (~vector+0x80) onto the stack and
 806          * then jump to common_interrupt.
 807          */
 808         .p2align CONFIG_X86_L1_CACHE_SHIFT
 809 common_interrupt:
 810         XCPT_FRAME
 811         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 812         interrupt do_IRQ
 813         /* 0(%rsp): old_rsp-ARGOFFSET */
 814 ret_from_intr:
 815         DISABLE_INTERRUPTS(CLBR_NONE)
 816         TRACE_IRQS_OFF
 817         decl PER_CPU_VAR(irq_count)
 818
 819         /* Restore saved previous stack */
 820         popq %rsi
 821         CFI_DEF_CFA_REGISTER    rsi
 822         leaq ARGOFFSET-RBP(%rsi), %rsp
 823         CFI_DEF_CFA_REGISTER    rsp
 824         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 825
 826 exit_intr:
 827         GET_THREAD_INFO(%rcx)
 828         testl $3,CS-ARGOFFSET(%rsp)
 829         je retint_kernel
 830
 831         /* Interrupt came from user space */
 832         /*
 833          * Has a correct top of stack, but a partial stack frame
 834          * %rcx: thread info. Interrupts off.
 835          */
 836 retint_with_reschedule:
 837         movl $_TIF_WORK_MASK,%edi
 838 retint_check:
 839         LOCKDEP_SYS_EXIT_IRQ
 840         movl TI_flags(%rcx),%edx
 841         andl %edi,%edx
 842         CFI_REMEMBER_STATE
 843         jnz  retint_careful
 844
 845 retint_swapgs:          /* return to user-space */
 846         /*
 847          * The iretq could re-enable interrupts:
 848          */
 849         DISABLE_INTERRUPTS(CLBR_ANY)
 850         TRACE_IRQS_IRETQ
 851         SWAPGS
 852         jmp restore_args
 853
 854 retint_restore_args:    /* return to kernel space */
 855         DISABLE_INTERRUPTS(CLBR_ANY)
 856         /*
 857          * The iretq could re-enable interrupts:
 858          */
 859         TRACE_IRQS_IRETQ
 860 restore_args:
 861         RESTORE_ARGS 1,8,1
 862
 863 irq_return:
 864         /*
 865          * Are we returning to a stack segment from the LDT?  Note: in
 866          * 64-bit mode SS:RSP on the exception stack is always valid.
 867          */
 868         testb $4,(SS-RIP)(%rsp)
 869         jnz irq_return_ldt
 870
 871 irq_return_iret:
 872         INTERRUPT_RETURN
 873
 874         .section __ex_table, "a"
 875         .quad irq_return_iret, bad_iret
 876         .previous
 877
 878 #ifdef CONFIG_PARAVIRT
 879 ENTRY(native_iret)
 880         iretq
 881
 882         .section __ex_table,"a"
 883         .quad native_iret, bad_iret
 884         .previous
 885 #endif
 886
 887 irq_return_ldt:
 888         pushq_cfi %rax
 889         pushq_cfi %rdi
 890         SWAPGS
 891         movq PER_CPU_VAR(espfix_waddr),%rdi
 892         movq %rax,(0*8)(%rdi)   /* RAX */
 893         movq (2*8)(%rsp),%rax   /* RIP */
 894         movq %rax,(1*8)(%rdi)
 895         movq (3*8)(%rsp),%rax   /* CS */
 896         movq %rax,(2*8)(%rdi)
 897         movq (4*8)(%rsp),%rax   /* RFLAGS */
 898         movq %rax,(3*8)(%rdi)
 899         movq (6*8)(%rsp),%rax   /* SS */
 900         movq %rax,(5*8)(%rdi)
 901         movq (5*8)(%rsp),%rax   /* RSP */
 902         movq %rax,(4*8)(%rdi)
 903         andl $0xffff0000,%eax
 904         popq_cfi %rdi
 905         orq PER_CPU_VAR(espfix_stack),%rax
 906         SWAPGS
 907         movq %rax,%rsp
 908         popq_cfi %rax
 909         jmp irq_return_iret
 910
 911         .section .fixup,"ax"
 912 bad_iret:
 913         /*
 914          * The iret traps when the %cs or %ss being restored is bogus.
 915          * We've lost the original trap vector and error code.
 916          * #GPF is the most likely one to get for an invalid selector.
 917          * So pretend we completed the iret and took the #GPF in user mode.
 918          *
 919          * We are now running with the kernel GS after exception recovery.
 920          * But error_entry expects us to have user GS to match the user %cs,
 921          * so swap back.
 922          */
 923         pushq $0
 924
 925         SWAPGS
 926         jmp general_protection
 927
 928         .previous
 929
 930         /* edi: workmask, edx: work */
 931 retint_careful:
 932         CFI_RESTORE_STATE
 933         bt    $TIF_NEED_RESCHED,%edx
 934         jnc   retint_signal
 935         TRACE_IRQS_ON
 936         ENABLE_INTERRUPTS(CLBR_NONE)
 937         pushq_cfi %rdi
 938         call  schedule
 939         popq_cfi %rdi
 940         GET_THREAD_INFO(%rcx)
 941         DISABLE_INTERRUPTS(CLBR_NONE)
 942         TRACE_IRQS_OFF
 943         jmp retint_check
 944
 945 retint_signal:
 946         testl $_TIF_DO_NOTIFY_MASK,%edx
 947         jz    retint_swapgs
 948         TRACE_IRQS_ON
 949         ENABLE_INTERRUPTS(CLBR_NONE)
 950         SAVE_REST
 951         movq $-1,ORIG_RAX(%rsp)
 952         xorl %esi,%esi          # oldset
 953         movq %rsp,%rdi          # &pt_regs
 954         call do_notify_resume
 955         RESTORE_REST
 956         DISABLE_INTERRUPTS(CLBR_NONE)
 957         TRACE_IRQS_OFF
 958         GET_THREAD_INFO(%rcx)
 959         jmp retint_with_reschedule
 960
 961 #ifdef CONFIG_PREEMPT
 962         /* Returning to kernel space. Check if we need preemption */
 963         /* rcx:  threadinfo. interrupts off. */
 964 ENTRY(retint_kernel)
 965         cmpl $0,TI_preempt_count(%rcx)
 966         jnz  retint_restore_args
 967         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 968         jnc  retint_restore_args
 969         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 970         jnc  retint_restore_args
 971         call preempt_schedule_irq
 972         jmp exit_intr
 973 #endif
 974         CFI_ENDPROC
 975 END(common_interrupt)
 976
 977         /*
 978          * If IRET takes a fault on the espfix stack, then we
 979          * end up promoting it to a doublefault.  In that case,
 980          * modify the stack to make it look like we just entered
 981          * the #GP handler from user space, similar to bad_iret.
 982          */
 983         ALIGN
 984 __do_double_fault:
 985         XCPT_FRAME 1 RDI+8
 986         movq RSP(%rdi),%rax             /* Trap on the espfix stack? */
 987         sarq $PGDIR_SHIFT,%rax
 988         cmpl $ESPFIX_PGD_ENTRY,%eax
 989         jne do_double_fault             /* No, just deliver the fault */
 990         cmpl $__KERNEL_CS,CS(%rdi)
 991         jne do_double_fault
 992         movq RIP(%rdi),%rax
 993         cmpq $irq_return_iret,%rax
 994 #ifdef CONFIG_PARAVIRT
 995         je 1f
 996         cmpq $native_iret,%rax
 997 #endif
 998         jne do_double_fault             /* This shouldn't happen... */
 999 1:
1000         movq PER_CPU_VAR(kernel_stack),%rax
1001         subq $(6*8-KERNEL_STACK_OFFSET),%rax    /* Reset to original stack */
1002         movq %rax,RSP(%rdi)
1003         movq $0,(%rax)                  /* Missing (lost) #GP error code */
1004         movq $general_protection,RIP(%rdi)
1005         retq
1006         CFI_ENDPROC
1007 END(__do_double_fault)
1008
1009 /*
1010  * End of kprobes section
1011  */
1012        .popsection
1013
1014 /*
1015  * APIC interrupts.
1016  */
1017 .macro apicinterrupt num sym do_sym
1018 ENTRY(\sym)
1019         INTR_FRAME
1020         pushq_cfi $~(\num)
1021         interrupt \do_sym
1022         jmp ret_from_intr
1023         CFI_ENDPROC
1024 END(\sym)
1025 .endm
1026
1027 #ifdef CONFIG_SMP
1028 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
1029         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1030 apicinterrupt REBOOT_VECTOR \
1031         reboot_interrupt smp_reboot_interrupt
1032 #endif
1033
1034 #ifdef CONFIG_X86_UV
1035 apicinterrupt UV_BAU_MESSAGE \
1036         uv_bau_message_intr1 uv_bau_message_interrupt
1037 #endif
1038 apicinterrupt LOCAL_TIMER_VECTOR \
1039         apic_timer_interrupt smp_apic_timer_interrupt
1040 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1041         x86_platform_ipi smp_x86_platform_ipi
1042
1043 #ifdef CONFIG_SMP
1044 .irp idx,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
1045         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
1046 .if NUM_INVALIDATE_TLB_VECTORS > \idx
1047 apicinterrupt (INVALIDATE_TLB_VECTOR_START)+\idx \
1048         invalidate_interrupt\idx smp_invalidate_interrupt
1049 .endif
1050 .endr
1051 #endif
1052
1053 apicinterrupt THRESHOLD_APIC_VECTOR \
1054         threshold_interrupt smp_threshold_interrupt
1055 apicinterrupt THERMAL_APIC_VECTOR \
1056         thermal_interrupt smp_thermal_interrupt
1057
1058 #ifdef CONFIG_SMP
1059 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1060         call_function_single_interrupt smp_call_function_single_interrupt
1061 apicinterrupt CALL_FUNCTION_VECTOR \
1062         call_function_interrupt smp_call_function_interrupt
1063 apicinterrupt RESCHEDULE_VECTOR \
1064         reschedule_interrupt smp_reschedule_interrupt
1065 #endif
1066
1067 apicinterrupt ERROR_APIC_VECTOR \
1068         error_interrupt smp_error_interrupt
1069 apicinterrupt SPURIOUS_APIC_VECTOR \
1070         spurious_interrupt smp_spurious_interrupt
1071
1072 #ifdef CONFIG_IRQ_WORK
1073 apicinterrupt IRQ_WORK_VECTOR \
1074         irq_work_interrupt smp_irq_work_interrupt
1075 #endif
1076
1077 /*
1078  * Exception entry points.
1079  */
1080 .macro zeroentry sym do_sym
1081 ENTRY(\sym)
1082         INTR_FRAME
1083         PARAVIRT_ADJUST_EXCEPTION_FRAME
1084         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1085         subq $ORIG_RAX-R15, %rsp
1086         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1087         call error_entry
1088         DEFAULT_FRAME 0
1089         movq %rsp,%rdi          /* pt_regs pointer */
1090         xorl %esi,%esi          /* no error code */
1091         call \do_sym
1092         jmp error_exit          /* %ebx: no swapgs flag */
1093         CFI_ENDPROC
1094 END(\sym)
1095 .endm
1096
1097 .macro paranoidzeroentry sym do_sym
1098 ENTRY(\sym)
1099         INTR_FRAME
1100         PARAVIRT_ADJUST_EXCEPTION_FRAME
1101         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1102         subq $ORIG_RAX-R15, %rsp
1103         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1104         call save_paranoid
1105         TRACE_IRQS_OFF
1106         movq %rsp,%rdi          /* pt_regs pointer */
1107         xorl %esi,%esi          /* no error code */
1108         call \do_sym
1109         jmp paranoid_exit       /* %ebx: no swapgs flag */
1110         CFI_ENDPROC
1111 END(\sym)
1112 .endm
1113
1114 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1115 .macro paranoidzeroentry_ist sym do_sym ist
1116 ENTRY(\sym)
1117         INTR_FRAME
1118         PARAVIRT_ADJUST_EXCEPTION_FRAME
1119         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1120         subq $ORIG_RAX-R15, %rsp
1121         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1122         call save_paranoid
1123         TRACE_IRQS_OFF
1124         movq %rsp,%rdi          /* pt_regs pointer */
1125         xorl %esi,%esi          /* no error code */
1126         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1127         call \do_sym
1128         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1129         jmp paranoid_exit       /* %ebx: no swapgs flag */
1130         CFI_ENDPROC
1131 END(\sym)
1132 .endm
1133
1134 .macro errorentry sym do_sym
1135 ENTRY(\sym)
1136         XCPT_FRAME
1137         PARAVIRT_ADJUST_EXCEPTION_FRAME
1138         subq $ORIG_RAX-R15, %rsp
1139         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1140         call error_entry
1141         DEFAULT_FRAME 0
1142         movq %rsp,%rdi                  /* pt_regs pointer */
1143         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1144         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1145         call \do_sym
1146         jmp error_exit                  /* %ebx: no swapgs flag */
1147         CFI_ENDPROC
1148 END(\sym)
1149 .endm
1150
1151         /* error code is on the stack already */
1152 .macro paranoiderrorentry sym do_sym
1153 ENTRY(\sym)
1154         XCPT_FRAME
1155         PARAVIRT_ADJUST_EXCEPTION_FRAME
1156         subq $ORIG_RAX-R15, %rsp
1157         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1158         call save_paranoid
1159         DEFAULT_FRAME 0
1160         TRACE_IRQS_OFF
1161         movq %rsp,%rdi                  /* pt_regs pointer */
1162         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1163         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1164         call \do_sym
1165         jmp paranoid_exit               /* %ebx: no swapgs flag */
1166         CFI_ENDPROC
1167 END(\sym)
1168 .endm
1169
1170 zeroentry divide_error do_divide_error
1171 zeroentry overflow do_overflow
1172 zeroentry bounds do_bounds
1173 zeroentry invalid_op do_invalid_op
1174 zeroentry device_not_available do_device_not_available
1175 paranoiderrorentry double_fault __do_double_fault
1176 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1177 errorentry invalid_TSS do_invalid_TSS
1178 errorentry segment_not_present do_segment_not_present
1179 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1180 zeroentry coprocessor_error do_coprocessor_error
1181 errorentry alignment_check do_alignment_check
1182 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1183
1184
1185         /* Reload gs selector with exception handling */
1186         /* edi:  new selector */
1187 ENTRY(native_load_gs_index)
1188         CFI_STARTPROC
1189         pushfq_cfi
1190         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1191         SWAPGS
1192 gs_change:
1193         movl %edi,%gs
1194 2:      mfence          /* workaround */
1195         SWAPGS
1196         popfq_cfi
1197         ret
1198         CFI_ENDPROC
1199 END(native_load_gs_index)
1200
1201         .section __ex_table,"a"
1202         .align 8
1203         .quad gs_change,bad_gs
1204         .previous
1205         .section .fixup,"ax"
1206         /* running with kernelgs */
1207 bad_gs:
1208         SWAPGS                  /* switch back to user gs */
1209         xorl %eax,%eax
1210         movl %eax,%gs
1211         jmp  2b
1212         .previous
1213
1214 ENTRY(kernel_thread_helper)
1215         pushq $0                # fake return address
1216         CFI_STARTPROC
1217         /*
1218          * Here we are in the child and the registers are set as they were
1219          * at kernel_thread() invocation in the parent.
1220          */
1221         call *%rsi
1222         # exit
1223         mov %eax, %edi
1224         call do_exit
1225         ud2                     # padding for call trace
1226         CFI_ENDPROC
1227 END(kernel_thread_helper)
1228
1229 /*
1230  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1231  *
1232  * C extern interface:
1233  *       extern long execve(const char *name, char **argv, char **envp)
1234  *
1235  * asm input arguments:
1236  *      rdi: name, rsi: argv, rdx: envp
1237  *
1238  * We want to fallback into:
1239  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1240  *
1241  * do_sys_execve asm fallback arguments:
1242  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1243  */
1244 ENTRY(kernel_execve)
1245         CFI_STARTPROC
1246         FAKE_STACK_FRAME $0
1247         SAVE_ALL
1248         movq %rsp,%rcx
1249         call sys_execve
1250         movq %rax, RAX(%rsp)
1251         RESTORE_REST
1252         testq %rax,%rax
1253         je int_ret_from_sys_call
1254         RESTORE_ARGS
1255         UNFAKE_STACK_FRAME
1256         ret
1257         CFI_ENDPROC
1258 END(kernel_execve)
1259
1260 /* Call softirq on interrupt stack. Interrupts are off. */
1261 ENTRY(call_softirq)
1262         CFI_STARTPROC
1263         pushq_cfi %rbp
1264         CFI_REL_OFFSET rbp,0
1265         mov  %rsp,%rbp
1266         CFI_DEF_CFA_REGISTER rbp
1267         incl PER_CPU_VAR(irq_count)
1268         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1269         push  %rbp                      # backlink for old unwinder
1270         call __do_softirq
1271         leaveq
1272         CFI_RESTORE             rbp
1273         CFI_DEF_CFA_REGISTER    rsp
1274         CFI_ADJUST_CFA_OFFSET   -8
1275         decl PER_CPU_VAR(irq_count)
1276         ret
1277         CFI_ENDPROC
1278 END(call_softirq)
1279
1280 #ifdef CONFIG_XEN
1281 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1282
1283 /*
1284  * A note on the "critical region" in our callback handler.
1285  * We want to avoid stacking callback handlers due to events occurring
1286  * during handling of the last event. To do this, we keep events disabled
1287  * until we've done all processing. HOWEVER, we must enable events before
1288  * popping the stack frame (can't be done atomically) and so it would still
1289  * be possible to get enough handler activations to overflow the stack.
1290  * Although unlikely, bugs of that kind are hard to track down, so we'd
1291  * like to avoid the possibility.
1292  * So, on entry to the handler we detect whether we interrupted an
1293  * existing activation in its critical region -- if so, we pop the current
1294  * activation and restart the handler using the previous one.
1295  */
1296 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1297         CFI_STARTPROC
1298 /*
1299  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1300  * see the correct pointer to the pt_regs
1301  */
1302         movq %rdi, %rsp            # we don't return, adjust the stack frame
1303         CFI_ENDPROC
1304         DEFAULT_FRAME
1305 11:     incl PER_CPU_VAR(irq_count)
1306         movq %rsp,%rbp
1307         CFI_DEF_CFA_REGISTER rbp
1308         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1309         pushq %rbp                      # backlink for old unwinder
1310         call xen_evtchn_do_upcall
1311         popq %rsp
1312         CFI_DEF_CFA_REGISTER rsp
1313         decl PER_CPU_VAR(irq_count)
1314         jmp  error_exit
1315         CFI_ENDPROC
1316 END(xen_do_hypervisor_callback)
1317
1318 /*
1319  * Hypervisor uses this for application faults while it executes.
1320  * We get here for two reasons:
1321  *  1. Fault while reloading DS, ES, FS or GS
1322  *  2. Fault while executing IRET
1323  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1324  * registers that could be reloaded and zeroed the others.
1325  * Category 2 we fix up by killing the current process. We cannot use the
1326  * normal Linux return path in this case because if we use the IRET hypercall
1327  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1328  * We distinguish between categories by comparing each saved segment register
1329  * with its current contents: any discrepancy means we in category 1.
1330  */
1331 ENTRY(xen_failsafe_callback)
1332         INTR_FRAME 1 (6*8)
1333         /*CFI_REL_OFFSET gs,GS*/
1334         /*CFI_REL_OFFSET fs,FS*/
1335         /*CFI_REL_OFFSET es,ES*/
1336         /*CFI_REL_OFFSET ds,DS*/
1337         CFI_REL_OFFSET r11,8
1338         CFI_REL_OFFSET rcx,0
1339         movw %ds,%cx
1340         cmpw %cx,0x10(%rsp)
1341         CFI_REMEMBER_STATE
1342         jne 1f
1343         movw %es,%cx
1344         cmpw %cx,0x18(%rsp)
1345         jne 1f
1346         movw %fs,%cx
1347         cmpw %cx,0x20(%rsp)
1348         jne 1f
1349         movw %gs,%cx
1350         cmpw %cx,0x28(%rsp)
1351         jne 1f
1352         /* All segments match their saved values => Category 2 (Bad IRET). */
1353         movq (%rsp),%rcx
1354         CFI_RESTORE rcx
1355         movq 8(%rsp),%r11
1356         CFI_RESTORE r11
1357         addq $0x30,%rsp
1358         CFI_ADJUST_CFA_OFFSET -0x30
1359         pushq_cfi $0    /* RIP */
1360         pushq_cfi %r11
1361         pushq_cfi %rcx
1362         jmp general_protection
1363         CFI_RESTORE_STATE
1364 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1365         movq (%rsp),%rcx
1366         CFI_RESTORE rcx
1367         movq 8(%rsp),%r11
1368         CFI_RESTORE r11
1369         addq $0x30,%rsp
1370         CFI_ADJUST_CFA_OFFSET -0x30
1371         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1372         SAVE_ALL
1373         jmp error_exit
1374         CFI_ENDPROC
1375 END(xen_failsafe_callback)
1376
1377 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1378         xen_hvm_callback_vector xen_evtchn_do_upcall
1379
1380 #endif /* CONFIG_XEN */
1381
1382 /*
1383  * Some functions should be protected against kprobes
1384  */
1385         .pushsection .kprobes.text, "ax"
1386
1387 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1388 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1389 paranoiderrorentry stack_segment do_stack_segment
1390 #ifdef CONFIG_XEN
1391 zeroentry xen_debug do_debug
1392 zeroentry xen_int3 do_int3
1393 errorentry xen_stack_segment do_stack_segment
1394 #endif
1395 errorentry general_protection do_general_protection
1396 errorentry page_fault do_page_fault
1397 #ifdef CONFIG_KVM_GUEST
1398 errorentry async_page_fault do_async_page_fault
1399 #endif
1400 #ifdef CONFIG_X86_MCE
1401 paranoidzeroentry machine_check *machine_check_vector(%rip)
1402 #endif
1403
1404         /*
1405          * "Paranoid" exit path from exception stack.
1406          * Paranoid because this is used by NMIs and cannot take
1407          * any kernel state for granted.
1408          * We don't do kernel preemption checks here, because only
1409          * NMI should be common and it does not enable IRQs and
1410          * cannot get reschedule ticks.
1411          *
1412          * "trace" is 0 for the NMI handler only, because irq-tracing
1413          * is fundamentally NMI-unsafe. (we cannot change the soft and
1414          * hard flags at once, atomically)
1415          */
1416
1417         /* ebx: no swapgs flag */
1418 ENTRY(paranoid_exit)
1419         DEFAULT_FRAME
1420         DISABLE_INTERRUPTS(CLBR_NONE)
1421         TRACE_IRQS_OFF
1422         testl %ebx,%ebx                         /* swapgs needed? */
1423         jnz paranoid_restore
1424         testl $3,CS(%rsp)
1425         jnz   paranoid_userspace
1426 paranoid_swapgs:
1427         TRACE_IRQS_IRETQ 0
1428         SWAPGS_UNSAFE_STACK
1429         RESTORE_ALL 8
1430         jmp irq_return
1431 paranoid_restore:
1432         TRACE_IRQS_IRETQ 0
1433         RESTORE_ALL 8
1434         jmp irq_return
1435 paranoid_userspace:
1436         GET_THREAD_INFO(%rcx)
1437         movl TI_flags(%rcx),%ebx
1438         andl $_TIF_WORK_MASK,%ebx
1439         jz paranoid_swapgs
1440         movq %rsp,%rdi                  /* &pt_regs */
1441         call sync_regs
1442         movq %rax,%rsp                  /* switch stack for scheduling */
1443         testl $_TIF_NEED_RESCHED,%ebx
1444         jnz paranoid_schedule
1445         movl %ebx,%edx                  /* arg3: thread flags */
1446         TRACE_IRQS_ON
1447         ENABLE_INTERRUPTS(CLBR_NONE)
1448         xorl %esi,%esi                  /* arg2: oldset */
1449         movq %rsp,%rdi                  /* arg1: &pt_regs */
1450         call do_notify_resume
1451         DISABLE_INTERRUPTS(CLBR_NONE)
1452         TRACE_IRQS_OFF
1453         jmp paranoid_userspace
1454 paranoid_schedule:
1455         TRACE_IRQS_ON
1456         ENABLE_INTERRUPTS(CLBR_ANY)
1457         call schedule
1458         DISABLE_INTERRUPTS(CLBR_ANY)
1459         TRACE_IRQS_OFF
1460         jmp paranoid_userspace
1461         CFI_ENDPROC
1462 END(paranoid_exit)
1463
1464 /*
1465  * Exception entry point. This expects an error code/orig_rax on the stack.
1466  * returns in "no swapgs flag" in %ebx.
1467  */
1468 ENTRY(error_entry)
1469         XCPT_FRAME
1470         CFI_ADJUST_CFA_OFFSET 15*8
1471         /* oldrax contains error code */
1472         cld
1473         movq_cfi rdi, RDI+8
1474         movq_cfi rsi, RSI+8
1475         movq_cfi rdx, RDX+8
1476         movq_cfi rcx, RCX+8
1477         movq_cfi rax, RAX+8
1478         movq_cfi  r8,  R8+8
1479         movq_cfi  r9,  R9+8
1480         movq_cfi r10, R10+8
1481         movq_cfi r11, R11+8
1482         movq_cfi rbx, RBX+8
1483         movq_cfi rbp, RBP+8
1484         movq_cfi r12, R12+8
1485         movq_cfi r13, R13+8
1486         movq_cfi r14, R14+8
1487         movq_cfi r15, R15+8
1488         xorl %ebx,%ebx
1489         testl $3,CS+8(%rsp)
1490         je error_kernelspace
1491 error_swapgs:
1492         SWAPGS
1493 error_sti:
1494         TRACE_IRQS_OFF
1495         ret
1496
1497 /*
1498  * There are two places in the kernel that can potentially fault with
1499  * usergs. Handle them here. The exception handlers after iret run with
1500  * kernel gs again, so don't set the user space flag. B stepping K8s
1501  * sometimes report an truncated RIP for IRET exceptions returning to
1502  * compat mode. Check for these here too.
1503  */
1504 error_kernelspace:
1505         incl %ebx
1506         leaq irq_return_iret(%rip),%rcx
1507         cmpq %rcx,RIP+8(%rsp)
1508         je error_swapgs
1509         movl %ecx,%eax  /* zero extend */
1510         cmpq %rax,RIP+8(%rsp)
1511         je bstep_iret
1512         cmpq $gs_change,RIP+8(%rsp)
1513         je error_swapgs
1514         jmp error_sti
1515
1516 bstep_iret:
1517         /* Fix truncated RIP */
1518         movq %rcx,RIP+8(%rsp)
1519         jmp error_swapgs
1520         CFI_ENDPROC
1521 END(error_entry)
1522
1523
1524 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1525 ENTRY(error_exit)
1526         DEFAULT_FRAME
1527         movl %ebx,%eax
1528         RESTORE_REST
1529         DISABLE_INTERRUPTS(CLBR_NONE)
1530         TRACE_IRQS_OFF
1531         GET_THREAD_INFO(%rcx)
1532         testl %eax,%eax
1533         jne retint_kernel
1534         LOCKDEP_SYS_EXIT_IRQ
1535         movl TI_flags(%rcx),%edx
1536         movl $_TIF_WORK_MASK,%edi
1537         andl %edi,%edx
1538         jnz retint_careful
1539         jmp retint_swapgs
1540         CFI_ENDPROC
1541 END(error_exit)
1542
1543
1544         /* runs on exception stack */
1545 ENTRY(nmi)
1546         INTR_FRAME
1547         PARAVIRT_ADJUST_EXCEPTION_FRAME
1548         pushq_cfi $-1
1549         subq $ORIG_RAX-R15, %rsp
1550         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1551         call save_paranoid
1552         DEFAULT_FRAME 0
1553         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1554         movq %rsp,%rdi
1555         movq $-1,%rsi
1556         call do_nmi
1557 #ifdef CONFIG_TRACE_IRQFLAGS
1558         /* paranoidexit; without TRACE_IRQS_OFF */
1559         /* ebx: no swapgs flag */
1560         DISABLE_INTERRUPTS(CLBR_NONE)
1561         testl %ebx,%ebx                         /* swapgs needed? */
1562         jnz nmi_restore
1563         testl $3,CS(%rsp)
1564         jnz nmi_userspace
1565 nmi_swapgs:
1566         SWAPGS_UNSAFE_STACK
1567 nmi_restore:
1568         RESTORE_ALL 8
1569         jmp irq_return
1570 nmi_userspace:
1571         GET_THREAD_INFO(%rcx)
1572         movl TI_flags(%rcx),%ebx
1573         andl $_TIF_WORK_MASK,%ebx
1574         jz nmi_swapgs
1575         movq %rsp,%rdi                  /* &pt_regs */
1576         call sync_regs
1577         movq %rax,%rsp                  /* switch stack for scheduling */
1578         testl $_TIF_NEED_RESCHED,%ebx
1579         jnz nmi_schedule
1580         movl %ebx,%edx                  /* arg3: thread flags */
1581         ENABLE_INTERRUPTS(CLBR_NONE)
1582         xorl %esi,%esi                  /* arg2: oldset */
1583         movq %rsp,%rdi                  /* arg1: &pt_regs */
1584         call do_notify_resume
1585         DISABLE_INTERRUPTS(CLBR_NONE)
1586         jmp nmi_userspace
1587 nmi_schedule:
1588         ENABLE_INTERRUPTS(CLBR_ANY)
1589         call schedule
1590         DISABLE_INTERRUPTS(CLBR_ANY)
1591         jmp nmi_userspace
1592         CFI_ENDPROC
1593 #else
1594         jmp paranoid_exit
1595         CFI_ENDPROC
1596 #endif
1597 END(nmi)
1598
1599 ENTRY(ignore_sysret)
1600         CFI_STARTPROC
1601         mov $-ENOSYS,%eax
1602         sysret
1603         CFI_ENDPROC
1604 END(ignore_sysret)
1605
1606 /*
1607  * End of kprobes section
1608  */
1609         .popsection