arch/x86/kernel/entry_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  */
   5
   6 /*
   7  * entry.S contains the system-call and fault low-level handling routines.
   8  * This also contains the timer-interrupt handler, as well as all interrupts
   9  * and faults that can result in a task-switch.
  10  *
  11  * NOTE: This code handles signal-recognition, which happens every time
  12  * after a timer-interrupt and after each system call.
  13  *
  14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  15  * on a 486.
  16  *
  17  * Stack layout in 'syscall_exit':
  18  *      ptrace needs to have all regs on the stack.
  19  *      if the order here is changed, it needs to be
  20  *      updated in fork.c:copy_process, signal.c:do_signal,
  21  *      ptrace.c and ptrace.h
  22  *
  23  *       0(%esp) - %ebx
  24  *       4(%esp) - %ecx
  25  *       8(%esp) - %edx
  26  *       C(%esp) - %esi
  27  *      10(%esp) - %edi
  28  *      14(%esp) - %ebp
  29  *      18(%esp) - %eax
  30  *      1C(%esp) - %ds
  31  *      20(%esp) - %es
  32  *      24(%esp) - %fs
  33  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  34  *      2C(%esp) - orig_eax
  35  *      30(%esp) - %eip
  36  *      34(%esp) - %cs
  37  *      38(%esp) - %eflags
  38  *      3C(%esp) - %oldesp
  39  *      40(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <asm/thread_info.h>
  46 #include <asm/irqflags.h>
  47 #include <asm/errno.h>
  48 #include <asm/segment.h>
  49 #include <asm/smp.h>
  50 #include <asm/page_types.h>
  51 #include <asm/percpu.h>
  52 #include <asm/dwarf2.h>
  53 #include <asm/processor-flags.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/irq_vectors.h>
  56 #include <asm/cpufeature.h>
  57 #include <asm/alternative-asm.h>
  58
  59 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  60 #include <linux/elf-em.h>
  61 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  62 #define __AUDIT_ARCH_LE    0x40000000
  63
  64 #ifndef CONFIG_AUDITSYSCALL
  65 #define sysenter_audit  syscall_trace_entry
  66 #define sysexit_audit   syscall_exit_work
  67 #endif
  68
  69         .section .entry.text, "ax"
  70
  71 /*
  72  * We use macros for low-level operations which need to be overridden
  73  * for paravirtualization.  The following will never clobber any registers:
  74  *   INTERRUPT_RETURN (aka. "iret")
  75  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  76  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  77  *
  78  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  79  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  80  * Allowing a register to be clobbered can shrink the paravirt replacement
  81  * enough to patch inline, increasing performance.
  82  */
  83
  84 #define nr_syscalls ((syscall_table_size)/4)
  85
  86 #ifdef CONFIG_PREEMPT
  87 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  88 #else
  89 #define preempt_stop(clobbers)
  90 #define resume_kernel           restore_all
  91 #endif
  92
  93 .macro TRACE_IRQS_IRET
  94 #ifdef CONFIG_TRACE_IRQFLAGS
  95         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
  96         jz 1f
  97         TRACE_IRQS_ON
  98 1:
  99 #endif
 100 .endm
 101
 102 /*
 103  * User gs save/restore
 104  *
 105  * %gs is used for userland TLS and kernel only uses it for stack
 106  * canary which is required to be at %gs:20 by gcc.  Read the comment
 107  * at the top of stackprotector.h for more info.
 108  *
 109  * Local labels 98 and 99 are used.
 110  */
 111 #ifdef CONFIG_X86_32_LAZY_GS
 112
 113  /* unfortunately push/pop can't be no-op */
 114 .macro PUSH_GS
 115         pushl_cfi $0
 116 .endm
 117 .macro POP_GS pop=0
 118         addl $(4 + \pop), %esp
 119         CFI_ADJUST_CFA_OFFSET -(4 + \pop)
 120 .endm
 121 .macro POP_GS_EX
 122 .endm
 123
 124  /* all the rest are no-op */
 125 .macro PTGS_TO_GS
 126 .endm
 127 .macro PTGS_TO_GS_EX
 128 .endm
 129 .macro GS_TO_REG reg
 130 .endm
 131 .macro REG_TO_PTGS reg
 132 .endm
 133 .macro SET_KERNEL_GS reg
 134 .endm
 135
 136 #else   /* CONFIG_X86_32_LAZY_GS */
 137
 138 .macro PUSH_GS
 139         pushl_cfi %gs
 140         /*CFI_REL_OFFSET gs, 0*/
 141 .endm
 142
 143 .macro POP_GS pop=0
 144 98:     popl_cfi %gs
 145         /*CFI_RESTORE gs*/
 146   .if \pop <> 0
 147         add $\pop, %esp
 148         CFI_ADJUST_CFA_OFFSET -\pop
 149   .endif
 150 .endm
 151 .macro POP_GS_EX
 152 .pushsection .fixup, "ax"
 153 99:     movl $0, (%esp)
 154         jmp 98b
 155 .section __ex_table, "a"
 156         .align 4
 157         .long 98b, 99b
 158 .popsection
 159 .endm
 160
 161 .macro PTGS_TO_GS
 162 98:     mov PT_GS(%esp), %gs
 163 .endm
 164 .macro PTGS_TO_GS_EX
 165 .pushsection .fixup, "ax"
 166 99:     movl $0, PT_GS(%esp)
 167         jmp 98b
 168 .section __ex_table, "a"
 169         .align 4
 170         .long 98b, 99b
 171 .popsection
 172 .endm
 173
 174 .macro GS_TO_REG reg
 175         movl %gs, \reg
 176         /*CFI_REGISTER gs, \reg*/
 177 .endm
 178 .macro REG_TO_PTGS reg
 179         movl \reg, PT_GS(%esp)
 180         /*CFI_REL_OFFSET gs, PT_GS*/
 181 .endm
 182 .macro SET_KERNEL_GS reg
 183         movl $(__KERNEL_STACK_CANARY), \reg
 184         movl \reg, %gs
 185 .endm
 186
 187 #endif  /* CONFIG_X86_32_LAZY_GS */
 188
 189 .macro SAVE_ALL
 190         cld
 191         PUSH_GS
 192         pushl_cfi %fs
 193         /*CFI_REL_OFFSET fs, 0;*/
 194         pushl_cfi %es
 195         /*CFI_REL_OFFSET es, 0;*/
 196         pushl_cfi %ds
 197         /*CFI_REL_OFFSET ds, 0;*/
 198         pushl_cfi %eax
 199         CFI_REL_OFFSET eax, 0
 200         pushl_cfi %ebp
 201         CFI_REL_OFFSET ebp, 0
 202         pushl_cfi %edi
 203         CFI_REL_OFFSET edi, 0
 204         pushl_cfi %esi
 205         CFI_REL_OFFSET esi, 0
 206         pushl_cfi %edx
 207         CFI_REL_OFFSET edx, 0
 208         pushl_cfi %ecx
 209         CFI_REL_OFFSET ecx, 0
 210         pushl_cfi %ebx
 211         CFI_REL_OFFSET ebx, 0
 212         movl $(__USER_DS), %edx
 213         movl %edx, %ds
 214         movl %edx, %es
 215         movl $(__KERNEL_PERCPU), %edx
 216         movl %edx, %fs
 217         SET_KERNEL_GS %edx
 218 .endm
 219
 220 .macro RESTORE_INT_REGS
 221         popl_cfi %ebx
 222         CFI_RESTORE ebx
 223         popl_cfi %ecx
 224         CFI_RESTORE ecx
 225         popl_cfi %edx
 226         CFI_RESTORE edx
 227         popl_cfi %esi
 228         CFI_RESTORE esi
 229         popl_cfi %edi
 230         CFI_RESTORE edi
 231         popl_cfi %ebp
 232         CFI_RESTORE ebp
 233         popl_cfi %eax
 234         CFI_RESTORE eax
 235 .endm
 236
 237 .macro RESTORE_REGS pop=0
 238         RESTORE_INT_REGS
 239 1:      popl_cfi %ds
 240         /*CFI_RESTORE ds;*/
 241 2:      popl_cfi %es
 242         /*CFI_RESTORE es;*/
 243 3:      popl_cfi %fs
 244         /*CFI_RESTORE fs;*/
 245         POP_GS \pop
 246 .pushsection .fixup, "ax"
 247 4:      movl $0, (%esp)
 248         jmp 1b
 249 5:      movl $0, (%esp)
 250         jmp 2b
 251 6:      movl $0, (%esp)
 252         jmp 3b
 253 .section __ex_table, "a"
 254         .align 4
 255         .long 1b, 4b
 256         .long 2b, 5b
 257         .long 3b, 6b
 258 .popsection
 259         POP_GS_EX
 260 .endm
 261
 262 .macro RING0_INT_FRAME
 263         CFI_STARTPROC simple
 264         CFI_SIGNAL_FRAME
 265         CFI_DEF_CFA esp, 3*4
 266         /*CFI_OFFSET cs, -2*4;*/
 267         CFI_OFFSET eip, -3*4
 268 .endm
 269
 270 .macro RING0_EC_FRAME
 271         CFI_STARTPROC simple
 272         CFI_SIGNAL_FRAME
 273         CFI_DEF_CFA esp, 4*4
 274         /*CFI_OFFSET cs, -2*4;*/
 275         CFI_OFFSET eip, -3*4
 276 .endm
 277
 278 .macro RING0_PTREGS_FRAME
 279         CFI_STARTPROC simple
 280         CFI_SIGNAL_FRAME
 281         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
 282         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
 283         CFI_OFFSET eip, PT_EIP-PT_OLDESP
 284         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
 285         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
 286         CFI_OFFSET eax, PT_EAX-PT_OLDESP
 287         CFI_OFFSET ebp, PT_EBP-PT_OLDESP
 288         CFI_OFFSET edi, PT_EDI-PT_OLDESP
 289         CFI_OFFSET esi, PT_ESI-PT_OLDESP
 290         CFI_OFFSET edx, PT_EDX-PT_OLDESP
 291         CFI_OFFSET ecx, PT_ECX-PT_OLDESP
 292         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 293 .endm
 294
 295 ENTRY(ret_from_fork)
 296         CFI_STARTPROC
 297         pushl_cfi %eax
 298         call schedule_tail
 299         GET_THREAD_INFO(%ebp)
 300         popl_cfi %eax
 301         pushl_cfi $0x0202               # Reset kernel eflags
 302         popfl_cfi
 303         jmp syscall_exit
 304         CFI_ENDPROC
 305 END(ret_from_fork)
 306
 307 /*
 308  * Interrupt exit functions should be protected against kprobes
 309  */
 310         .pushsection .kprobes.text, "ax"
 311 /*
 312  * Return to user mode is not as complex as all this looks,
 313  * but we want the default path for a system call return to
 314  * go as quickly as possible which is why some of this is
 315  * less clear than it otherwise should be.
 316  */
 317
 318         # userspace resumption stub bypassing syscall exit tracing
 319         ALIGN
 320         RING0_PTREGS_FRAME
 321 ret_from_exception:
 322         preempt_stop(CLBR_ANY)
 323 ret_from_intr:
 324         GET_THREAD_INFO(%ebp)
 325 resume_userspace_sig:
 326 #ifdef CONFIG_VM86
 327         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 328         movb PT_CS(%esp), %al
 329         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 330 #else
 331         /*
 332          * We can be coming here from a syscall done in the kernel space,
 333          * e.g. a failed kernel_execve().
 334          */
 335         movl PT_CS(%esp), %eax
 336         andl $SEGMENT_RPL_MASK, %eax
 337 #endif
 338         cmpl $USER_RPL, %eax
 339         jb resume_kernel                # not returning to v8086 or userspace
 340
 341 ENTRY(resume_userspace)
 342         LOCKDEP_SYS_EXIT
 343         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 344                                         # setting need_resched or sigpending
 345                                         # between sampling and the iret
 346         TRACE_IRQS_OFF
 347         movl TI_flags(%ebp), %ecx
 348         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 349                                         # int/exception return?
 350         jne work_pending
 351         jmp restore_all
 352 END(ret_from_exception)
 353
 354 #ifdef CONFIG_PREEMPT
 355 ENTRY(resume_kernel)
 356         DISABLE_INTERRUPTS(CLBR_ANY)
 357         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 358         jnz restore_all
 359 need_resched:
 360         movl TI_flags(%ebp), %ecx       # need_resched set ?
 361         testb $_TIF_NEED_RESCHED, %cl
 362         jz restore_all
 363         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
 364         jz restore_all
 365         call preempt_schedule_irq
 366         jmp need_resched
 367 END(resume_kernel)
 368 #endif
 369         CFI_ENDPROC
 370 /*
 371  * End of kprobes section
 372  */
 373         .popsection
 374
 375 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 376    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 377
 378         # sysenter call handler stub
 379 ENTRY(ia32_sysenter_target)
 380         CFI_STARTPROC simple
 381         CFI_SIGNAL_FRAME
 382         CFI_DEF_CFA esp, 0
 383         CFI_REGISTER esp, ebp
 384         movl TSS_sysenter_sp0(%esp),%esp
 385 sysenter_past_esp:
 386         /*
 387          * Interrupts are disabled here, but we can't trace it until
 388          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 389          * we immediately enable interrupts at that point anyway.
 390          */
 391         pushl_cfi $__USER_DS
 392         /*CFI_REL_OFFSET ss, 0*/
 393         pushl_cfi %ebp
 394         CFI_REL_OFFSET esp, 0
 395         pushfl_cfi
 396         orl $X86_EFLAGS_IF, (%esp)
 397         pushl_cfi $__USER_CS
 398         /*CFI_REL_OFFSET cs, 0*/
 399         /*
 400          * Push current_thread_info()->sysenter_return to the stack.
 401          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 402          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 403          */
 404         pushl_cfi ((TI_sysenter_return)-THREAD_SIZE+8+4*4)(%esp)
 405         CFI_REL_OFFSET eip, 0
 406
 407         pushl_cfi %eax
 408         SAVE_ALL
 409         ENABLE_INTERRUPTS(CLBR_NONE)
 410
 411 /*
 412  * Load the potential sixth argument from user stack.
 413  * Careful about security.
 414  */
 415         cmpl $__PAGE_OFFSET-3,%ebp
 416         jae syscall_fault
 417 1:      movl (%ebp),%ebp
 418         movl %ebp,PT_EBP(%esp)
 419 .section __ex_table,"a"
 420         .align 4
 421         .long 1b,syscall_fault
 422 .previous
 423
 424         GET_THREAD_INFO(%ebp)
 425
 426         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 427         jnz sysenter_audit
 428 sysenter_do_call:
 429         cmpl $(nr_syscalls), %eax
 430         jae sysenter_badsys
 431         call *sys_call_table(,%eax,4)
 432 sysenter_after_call:
 433         movl %eax,PT_EAX(%esp)
 434         LOCKDEP_SYS_EXIT
 435         DISABLE_INTERRUPTS(CLBR_ANY)
 436         TRACE_IRQS_OFF
 437         movl TI_flags(%ebp), %ecx
 438         testl $_TIF_ALLWORK_MASK, %ecx
 439         jne sysexit_audit
 440 sysenter_exit:
 441 /* if something modifies registers it must also disable sysexit */
 442         movl PT_EIP(%esp), %edx
 443         movl PT_OLDESP(%esp), %ecx
 444         xorl %ebp,%ebp
 445         TRACE_IRQS_ON
 446 1:      mov  PT_FS(%esp), %fs
 447         PTGS_TO_GS
 448         ENABLE_INTERRUPTS_SYSEXIT
 449
 450 #ifdef CONFIG_AUDITSYSCALL
 451 sysenter_audit:
 452         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 453         jnz syscall_trace_entry
 454         addl $4,%esp
 455         CFI_ADJUST_CFA_OFFSET -4
 456         /* %esi already in 8(%esp)         6th arg: 4th syscall arg */
 457         /* %edx already in 4(%esp)         5th arg: 3rd syscall arg */
 458         /* %ecx already in 0(%esp)         4th arg: 2nd syscall arg */
 459         movl %ebx,%ecx                  /* 3rd arg: 1st syscall arg */
 460         movl %eax,%edx                  /* 2nd arg: syscall number */
 461         movl $AUDIT_ARCH_I386,%eax      /* 1st arg: audit arch */
 462         call audit_syscall_entry
 463         pushl_cfi %ebx
 464         movl PT_EAX(%esp),%eax          /* reload syscall number */
 465         jmp sysenter_do_call
 466
 467 sysexit_audit:
 468         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 469         jne syscall_exit_work
 470         TRACE_IRQS_ON
 471         ENABLE_INTERRUPTS(CLBR_ANY)
 472         movl %eax,%edx          /* second arg, syscall return value */
 473         cmpl $0,%eax            /* is it < 0? */
 474         setl %al                /* 1 if so, 0 if not */
 475         movzbl %al,%eax         /* zero-extend that */
 476         inc %eax /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 477         call audit_syscall_exit
 478         DISABLE_INTERRUPTS(CLBR_ANY)
 479         TRACE_IRQS_OFF
 480         movl TI_flags(%ebp), %ecx
 481         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 482         jne syscall_exit_work
 483         movl PT_EAX(%esp),%eax  /* reload syscall return value */
 484         jmp sysenter_exit
 485 #endif
 486
 487         CFI_ENDPROC
 488 .pushsection .fixup,"ax"
 489 2:      movl $0,PT_FS(%esp)
 490         jmp 1b
 491 .section __ex_table,"a"
 492         .align 4
 493         .long 1b,2b
 494 .popsection
 495         PTGS_TO_GS_EX
 496 ENDPROC(ia32_sysenter_target)
 497
 498 /*
 499  * syscall stub including irq exit should be protected against kprobes
 500  */
 501         .pushsection .kprobes.text, "ax"
 502         # system call handler stub
 503 ENTRY(system_call)
 504         RING0_INT_FRAME                 # can't unwind into user space anyway
 505         pushl_cfi %eax                  # save orig_eax
 506         SAVE_ALL
 507         GET_THREAD_INFO(%ebp)
 508                                         # system call tracing in operation / emulation
 509         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 510         jnz syscall_trace_entry
 511         cmpl $(nr_syscalls), %eax
 512         jae syscall_badsys
 513 syscall_call:
 514         call *sys_call_table(,%eax,4)
 515 syscall_after_call:
 516         movl %eax,PT_EAX(%esp)          # store the return value
 517 syscall_exit:
 518         LOCKDEP_SYS_EXIT
 519         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 520                                         # setting need_resched or sigpending
 521                                         # between sampling and the iret
 522         TRACE_IRQS_OFF
 523         movl TI_flags(%ebp), %ecx
 524         testl $_TIF_ALLWORK_MASK, %ecx  # current->work
 525         jne syscall_exit_work
 526
 527 restore_all:
 528         TRACE_IRQS_IRET
 529 restore_all_notrace:
 530         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 531         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 532         # are returning to the kernel.
 533         # See comments in process.c:copy_thread() for details.
 534         movb PT_OLDSS(%esp), %ah
 535         movb PT_CS(%esp), %al
 536         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 537         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 538         CFI_REMEMBER_STATE
 539         je ldt_ss                       # returning to user-space with LDT SS
 540 restore_nocheck:
 541         RESTORE_REGS 4                  # skip orig_eax/error_code
 542 irq_return:
 543         INTERRUPT_RETURN
 544 .section .fixup,"ax"
 545 ENTRY(iret_exc)
 546         pushl $0                        # no error code
 547         pushl $do_iret_error
 548         jmp error_code
 549 .previous
 550 .section __ex_table,"a"
 551         .align 4
 552         .long irq_return,iret_exc
 553 .previous
 554
 555         CFI_RESTORE_STATE
 556 ldt_ss:
 557 #ifdef CONFIG_PARAVIRT
 558         /*
 559          * The kernel can't run on a non-flat stack if paravirt mode
 560          * is active.  Rather than try to fixup the high bits of
 561          * ESP, bypass this code entirely.  This may break DOSemu
 562          * and/or Wine support in a paravirt VM, although the option
 563          * is still available to implement the setting of the high
 564          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 565          */
 566         cmpl $0, pv_info+PARAVIRT_enabled
 567         jne restore_nocheck
 568 #endif
 569
 570 /*
 571  * Setup and switch to ESPFIX stack
 572  *
 573  * We're returning to userspace with a 16 bit stack. The CPU will not
 574  * restore the high word of ESP for us on executing iret... This is an
 575  * "official" bug of all the x86-compatible CPUs, which we can work
 576  * around to make dosemu and wine happy. We do this by preloading the
 577  * high word of ESP with the high word of the userspace ESP while
 578  * compensating for the offset by changing to the ESPFIX segment with
 579  * a base address that matches for the difference.
 580  */
 581 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
 582         mov %esp, %edx                  /* load kernel esp */
 583         mov PT_OLDESP(%esp), %eax       /* load userspace esp */
 584         mov %dx, %ax                    /* eax: new kernel esp */
 585         sub %eax, %edx                  /* offset (low word is 0) */
 586         shr $16, %edx
 587         mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
 588         mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
 589         pushl_cfi $__ESPFIX_SS
 590         pushl_cfi %eax                  /* new kernel esp */
 591         /* Disable interrupts, but do not irqtrace this section: we
 592          * will soon execute iret and the tracer was already set to
 593          * the irqstate after the iret */
 594         DISABLE_INTERRUPTS(CLBR_EAX)
 595         lss (%esp), %esp                /* switch to espfix segment */
 596         CFI_ADJUST_CFA_OFFSET -8
 597         jmp restore_nocheck
 598         CFI_ENDPROC
 599 ENDPROC(system_call)
 600
 601         # perform work that needs to be done immediately before resumption
 602         ALIGN
 603         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 604 work_pending:
 605         testb $_TIF_NEED_RESCHED, %cl
 606         jz work_notifysig
 607 work_resched:
 608         call schedule
 609         LOCKDEP_SYS_EXIT
 610         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 611                                         # setting need_resched or sigpending
 612                                         # between sampling and the iret
 613         TRACE_IRQS_OFF
 614         movl TI_flags(%ebp), %ecx
 615         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 616                                         # than syscall tracing?
 617         jz restore_all
 618         testb $_TIF_NEED_RESCHED, %cl
 619         jnz work_resched
 620
 621 work_notifysig:                         # deal with pending signals and
 622                                         # notify-resume requests
 623 #ifdef CONFIG_VM86
 624         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
 625         movl %esp, %eax
 626         jne work_notifysig_v86          # returning to kernel-space or
 627                                         # vm86-space
 628         xorl %edx, %edx
 629         call do_notify_resume
 630         jmp resume_userspace_sig
 631
 632         ALIGN
 633 work_notifysig_v86:
 634         pushl_cfi %ecx                  # save ti_flags for do_notify_resume
 635         call save_v86_state             # %eax contains pt_regs pointer
 636         popl_cfi %ecx
 637         movl %eax, %esp
 638 #else
 639         movl %esp, %eax
 640 #endif
 641         xorl %edx, %edx
 642         call do_notify_resume
 643         jmp resume_userspace_sig
 644 END(work_pending)
 645
 646         # perform syscall exit tracing
 647         ALIGN
 648 syscall_trace_entry:
 649         movl $-ENOSYS,PT_EAX(%esp)
 650         movl %esp, %eax
 651         call syscall_trace_enter
 652         /* What it returned is what we'll actually use.  */
 653         cmpl $(nr_syscalls), %eax
 654         jnae syscall_call
 655         jmp syscall_exit
 656 END(syscall_trace_entry)
 657
 658         # perform syscall exit tracing
 659         ALIGN
 660 syscall_exit_work:
 661         testl $_TIF_WORK_SYSCALL_EXIT, %ecx
 662         jz work_pending
 663         TRACE_IRQS_ON
 664         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
 665                                         # schedule() instead
 666         movl %esp, %eax
 667         call syscall_trace_leave
 668         jmp resume_userspace
 669 END(syscall_exit_work)
 670         CFI_ENDPROC
 671
 672         RING0_INT_FRAME                 # can't unwind into user space anyway
 673 syscall_fault:
 674         GET_THREAD_INFO(%ebp)
 675         movl $-EFAULT,PT_EAX(%esp)
 676         jmp resume_userspace
 677 END(syscall_fault)
 678
 679 syscall_badsys:
 680         movl $-ENOSYS,%eax
 681         jmp syscall_after_call
 682 END(syscall_badsys)
 683
 684 sysenter_badsys:
 685         movl $-ENOSYS,%eax
 686         jmp sysenter_after_call
 687 END(syscall_badsys)
 688         CFI_ENDPROC
 689 /*
 690  * End of kprobes section
 691  */
 692         .popsection
 693
 694 /*
 695  * System calls that need a pt_regs pointer.
 696  */
 697 #define PTREGSCALL0(name) \
 698         ALIGN; \
 699 ptregs_##name: \
 700         leal 4(%esp),%eax; \
 701         jmp sys_##name;
 702
 703 #define PTREGSCALL1(name) \
 704         ALIGN; \
 705 ptregs_##name: \
 706         leal 4(%esp),%edx; \
 707         movl (PT_EBX+4)(%esp),%eax; \
 708         jmp sys_##name;
 709
 710 #define PTREGSCALL2(name) \
 711         ALIGN; \
 712 ptregs_##name: \
 713         leal 4(%esp),%ecx; \
 714         movl (PT_ECX+4)(%esp),%edx; \
 715         movl (PT_EBX+4)(%esp),%eax; \
 716         jmp sys_##name;
 717
 718 #define PTREGSCALL3(name) \
 719         ALIGN; \
 720 ptregs_##name: \
 721         CFI_STARTPROC; \
 722         leal 4(%esp),%eax; \
 723         pushl_cfi %eax; \
 724         movl PT_EDX(%eax),%ecx; \
 725         movl PT_ECX(%eax),%edx; \
 726         movl PT_EBX(%eax),%eax; \
 727         call sys_##name; \
 728         addl $4,%esp; \
 729         CFI_ADJUST_CFA_OFFSET -4; \
 730         ret; \
 731         CFI_ENDPROC; \
 732 ENDPROC(ptregs_##name)
 733
 734 PTREGSCALL1(iopl)
 735 PTREGSCALL0(fork)
 736 PTREGSCALL0(vfork)
 737 PTREGSCALL3(execve)
 738 PTREGSCALL2(sigaltstack)
 739 PTREGSCALL0(sigreturn)
 740 PTREGSCALL0(rt_sigreturn)
 741 PTREGSCALL2(vm86)
 742 PTREGSCALL1(vm86old)
 743
 744 /* Clone is an oddball.  The 4th arg is in %edi */
 745         ALIGN;
 746 ptregs_clone:
 747         CFI_STARTPROC
 748         leal 4(%esp),%eax
 749         pushl_cfi %eax
 750         pushl_cfi PT_EDI(%eax)
 751         movl PT_EDX(%eax),%ecx
 752         movl PT_ECX(%eax),%edx
 753         movl PT_EBX(%eax),%eax
 754         call sys_clone
 755         addl $8,%esp
 756         CFI_ADJUST_CFA_OFFSET -8
 757         ret
 758         CFI_ENDPROC
 759 ENDPROC(ptregs_clone)
 760
 761 .macro FIXUP_ESPFIX_STACK
 762 /*
 763  * Switch back for ESPFIX stack to the normal zerobased stack
 764  *
 765  * We can't call C functions using the ESPFIX stack. This code reads
 766  * the high word of the segment base from the GDT and swiches to the
 767  * normal stack and adjusts ESP with the matching offset.
 768  */
 769         /* fixup the stack */
 770         mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
 771         mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
 772         shl $16, %eax
 773         addl %esp, %eax                 /* the adjusted stack pointer */
 774         pushl_cfi $__KERNEL_DS
 775         pushl_cfi %eax
 776         lss (%esp), %esp                /* switch to the normal stack segment */
 777         CFI_ADJUST_CFA_OFFSET -8
 778 .endm
 779 .macro UNWIND_ESPFIX_STACK
 780         movl %ss, %eax
 781         /* see if on espfix stack */
 782         cmpw $__ESPFIX_SS, %ax
 783         jne 27f
 784         movl $__KERNEL_DS, %eax
 785         movl %eax, %ds
 786         movl %eax, %es
 787         /* switch to normal stack */
 788         FIXUP_ESPFIX_STACK
 789 27:
 790 .endm
 791
 792 /*
 793  * Build the entry stubs and pointer table with some assembler magic.
 794  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 795  * single cache line on all modern x86 implementations.
 796  */
 797 .section .init.rodata,"a"
 798 ENTRY(interrupt)
 799 .section .entry.text, "ax"
 800         .p2align 5
 801         .p2align CONFIG_X86_L1_CACHE_SHIFT
 802 ENTRY(irq_entries_start)
 803         RING0_INT_FRAME
 804 vector=FIRST_EXTERNAL_VECTOR
 805 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 806         .balign 32
 807   .rept 7
 808     .if vector < NR_VECTORS
 809       .if vector <> FIRST_EXTERNAL_VECTOR
 810         CFI_ADJUST_CFA_OFFSET -4
 811       .endif
 812 1:      pushl_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 813       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 814         jmp 2f
 815       .endif
 816       .previous
 817         .long 1b
 818       .section .entry.text, "ax"
 819 vector=vector+1
 820     .endif
 821   .endr
 822 2:      jmp common_interrupt
 823 .endr
 824 END(irq_entries_start)
 825
 826 .previous
 827 END(interrupt)
 828 .previous
 829
 830 /*
 831  * the CPU automatically disables interrupts when executing an IRQ vector,
 832  * so IRQ-flags tracing has to follow that:
 833  */
 834         .p2align CONFIG_X86_L1_CACHE_SHIFT
 835 common_interrupt:
 836         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
 837         SAVE_ALL
 838         TRACE_IRQS_OFF
 839         movl %esp,%eax
 840         call do_IRQ
 841         jmp ret_from_intr
 842 ENDPROC(common_interrupt)
 843         CFI_ENDPROC
 844
 845 /*
 846  *  Irq entries should be protected against kprobes
 847  */
 848         .pushsection .kprobes.text, "ax"
 849 #define BUILD_INTERRUPT3(name, nr, fn)  \
 850 ENTRY(name)                             \
 851         RING0_INT_FRAME;                \
 852         pushl_cfi $~(nr);               \
 853         SAVE_ALL;                       \
 854         TRACE_IRQS_OFF                  \
 855         movl %esp,%eax;                 \
 856         call fn;                        \
 857         jmp ret_from_intr;              \
 858         CFI_ENDPROC;                    \
 859 ENDPROC(name)
 860
 861 #define BUILD_INTERRUPT(name, nr)       BUILD_INTERRUPT3(name, nr, smp_##name)
 862
 863 /* The include is where all of the SMP etc. interrupts come from */
 864 #include <asm/entry_arch.h>
 865
 866 ENTRY(coprocessor_error)
 867         RING0_INT_FRAME
 868         pushl_cfi $0
 869         pushl_cfi $do_coprocessor_error
 870         jmp error_code
 871         CFI_ENDPROC
 872 END(coprocessor_error)
 873
 874 ENTRY(simd_coprocessor_error)
 875         RING0_INT_FRAME
 876         pushl_cfi $0
 877 #ifdef CONFIG_X86_INVD_BUG
 878         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
 879 661:    pushl_cfi $do_general_protection
 880 662:
 881 .section .altinstructions,"a"
 882         altinstruction_entry 661b, 663f, X86_FEATURE_XMM, 662b-661b, 664f-663f
 883 .previous
 884 .section .altinstr_replacement,"ax"
 885 663:    pushl $do_simd_coprocessor_error
 886 664:
 887 .previous
 888 #else
 889         pushl_cfi $do_simd_coprocessor_error
 890 #endif
 891         jmp error_code
 892         CFI_ENDPROC
 893 END(simd_coprocessor_error)
 894
 895 ENTRY(device_not_available)
 896         RING0_INT_FRAME
 897         pushl_cfi $-1                   # mark this as an int
 898         pushl_cfi $do_device_not_available
 899         jmp error_code
 900         CFI_ENDPROC
 901 END(device_not_available)
 902
 903 #ifdef CONFIG_PARAVIRT
 904 ENTRY(native_iret)
 905         iret
 906 .section __ex_table,"a"
 907         .align 4
 908         .long native_iret, iret_exc
 909 .previous
 910 END(native_iret)
 911
 912 ENTRY(native_irq_enable_sysexit)
 913         sti
 914         sysexit
 915 END(native_irq_enable_sysexit)
 916 #endif
 917
 918 ENTRY(overflow)
 919         RING0_INT_FRAME
 920         pushl_cfi $0
 921         pushl_cfi $do_overflow
 922         jmp error_code
 923         CFI_ENDPROC
 924 END(overflow)
 925
 926 ENTRY(bounds)
 927         RING0_INT_FRAME
 928         pushl_cfi $0
 929         pushl_cfi $do_bounds
 930         jmp error_code
 931         CFI_ENDPROC
 932 END(bounds)
 933
 934 ENTRY(invalid_op)
 935         RING0_INT_FRAME
 936         pushl_cfi $0
 937         pushl_cfi $do_invalid_op
 938         jmp error_code
 939         CFI_ENDPROC
 940 END(invalid_op)
 941
 942 ENTRY(coprocessor_segment_overrun)
 943         RING0_INT_FRAME
 944         pushl_cfi $0
 945         pushl_cfi $do_coprocessor_segment_overrun
 946         jmp error_code
 947         CFI_ENDPROC
 948 END(coprocessor_segment_overrun)
 949
 950 ENTRY(invalid_TSS)
 951         RING0_EC_FRAME
 952         pushl_cfi $do_invalid_TSS
 953         jmp error_code
 954         CFI_ENDPROC
 955 END(invalid_TSS)
 956
 957 ENTRY(segment_not_present)
 958         RING0_EC_FRAME
 959         pushl_cfi $do_segment_not_present
 960         jmp error_code
 961         CFI_ENDPROC
 962 END(segment_not_present)
 963
 964 ENTRY(stack_segment)
 965         RING0_EC_FRAME
 966         pushl_cfi $do_stack_segment
 967         jmp error_code
 968         CFI_ENDPROC
 969 END(stack_segment)
 970
 971 ENTRY(alignment_check)
 972         RING0_EC_FRAME
 973         pushl_cfi $do_alignment_check
 974         jmp error_code
 975         CFI_ENDPROC
 976 END(alignment_check)
 977
 978 ENTRY(divide_error)
 979         RING0_INT_FRAME
 980         pushl_cfi $0                    # no error code
 981         pushl_cfi $do_divide_error
 982         jmp error_code
 983         CFI_ENDPROC
 984 END(divide_error)
 985
 986 #ifdef CONFIG_X86_MCE
 987 ENTRY(machine_check)
 988         RING0_INT_FRAME
 989         pushl_cfi $0
 990         pushl_cfi machine_check_vector
 991         jmp error_code
 992         CFI_ENDPROC
 993 END(machine_check)
 994 #endif
 995
 996 ENTRY(spurious_interrupt_bug)
 997         RING0_INT_FRAME
 998         pushl_cfi $0
 999         pushl_cfi $do_spurious_interrupt_bug
1000         jmp error_code
1001         CFI_ENDPROC
1002 END(spurious_interrupt_bug)
1003 /*
1004  * End of kprobes section
1005  */
1006         .popsection
1007
1008 ENTRY(kernel_thread_helper)
1009         pushl $0                # fake return address for unwinder
1010         CFI_STARTPROC
1011         movl %edi,%eax
1012         call *%esi
1013         call do_exit
1014         ud2                     # padding for call trace
1015         CFI_ENDPROC
1016 ENDPROC(kernel_thread_helper)
1017
1018 #ifdef CONFIG_XEN
1019 /* Xen doesn't set %esp to be precisely what the normal sysenter
1020    entrypoint expects, so fix it up before using the normal path. */
1021 ENTRY(xen_sysenter_target)
1022         RING0_INT_FRAME
1023         addl $5*4, %esp         /* remove xen-provided frame */
1024         CFI_ADJUST_CFA_OFFSET -5*4
1025         jmp sysenter_past_esp
1026         CFI_ENDPROC
1027
1028 ENTRY(xen_hypervisor_callback)
1029         CFI_STARTPROC
1030         pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1031         SAVE_ALL
1032         TRACE_IRQS_OFF
1033
1034         /* Check to see if we got the event in the critical
1035            region in xen_iret_direct, after we've reenabled
1036            events and checked for pending events.  This simulates
1037            iret instruction's behaviour where it delivers a
1038            pending interrupt when enabling interrupts. */
1039         movl PT_EIP(%esp),%eax
1040         cmpl $xen_iret_start_crit,%eax
1041         jb   1f
1042         cmpl $xen_iret_end_crit,%eax
1043         jae  1f
1044
1045         jmp  xen_iret_crit_fixup
1046
1047 ENTRY(xen_do_upcall)
1048 1:      mov %esp, %eax
1049         call xen_evtchn_do_upcall
1050         jmp  ret_from_intr
1051         CFI_ENDPROC
1052 ENDPROC(xen_hypervisor_callback)
1053
1054 # Hypervisor uses this for application faults while it executes.
1055 # We get here for two reasons:
1056 #  1. Fault while reloading DS, ES, FS or GS
1057 #  2. Fault while executing IRET
1058 # Category 1 we fix up by reattempting the load, and zeroing the segment
1059 # register if the load fails.
1060 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1061 # normal Linux return path in this case because if we use the IRET hypercall
1062 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1063 # We distinguish between categories by maintaining a status value in EAX.
1064 ENTRY(xen_failsafe_callback)
1065         CFI_STARTPROC
1066         pushl_cfi %eax
1067         movl $1,%eax
1068 1:      mov 4(%esp),%ds
1069 2:      mov 8(%esp),%es
1070 3:      mov 12(%esp),%fs
1071 4:      mov 16(%esp),%gs
1072         /* EAX == 0 => Category 1 (Bad segment)
1073            EAX != 0 => Category 2 (Bad IRET) */
1074         testl %eax,%eax
1075         popl_cfi %eax
1076         lea 16(%esp),%esp
1077         CFI_ADJUST_CFA_OFFSET -16
1078         jz 5f
1079         jmp iret_exc
1080 5:      pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1081         SAVE_ALL
1082         jmp ret_from_exception
1083         CFI_ENDPROC
1084
1085 .section .fixup,"ax"
1086 6:      xorl %eax,%eax
1087         movl %eax,4(%esp)
1088         jmp 1b
1089 7:      xorl %eax,%eax
1090         movl %eax,8(%esp)
1091         jmp 2b
1092 8:      xorl %eax,%eax
1093         movl %eax,12(%esp)
1094         jmp 3b
1095 9:      xorl %eax,%eax
1096         movl %eax,16(%esp)
1097         jmp 4b
1098 .previous
1099 .section __ex_table,"a"
1100         .align 4
1101         .long 1b,6b
1102         .long 2b,7b
1103         .long 3b,8b
1104         .long 4b,9b
1105 .previous
1106 ENDPROC(xen_failsafe_callback)
1107
1108 BUILD_INTERRUPT3(xen_hvm_callback_vector, XEN_HVM_EVTCHN_CALLBACK,
1109                 xen_evtchn_do_upcall)
1110
1111 #endif  /* CONFIG_XEN */
1112
1113 #ifdef CONFIG_FUNCTION_TRACER
1114 #ifdef CONFIG_DYNAMIC_FTRACE
1115
1116 ENTRY(mcount)
1117         ret
1118 END(mcount)
1119
1120 ENTRY(ftrace_caller)
1121         cmpl $0, function_trace_stop
1122         jne  ftrace_stub
1123
1124         pushl %eax
1125         pushl %ecx
1126         pushl %edx
1127         movl 0xc(%esp), %eax
1128         movl 0x4(%ebp), %edx
1129         subl $MCOUNT_INSN_SIZE, %eax
1130
1131 .globl ftrace_call
1132 ftrace_call:
1133         call ftrace_stub
1134
1135         popl %edx
1136         popl %ecx
1137         popl %eax
1138 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1139 .globl ftrace_graph_call
1140 ftrace_graph_call:
1141         jmp ftrace_stub
1142 #endif
1143
1144 .globl ftrace_stub
1145 ftrace_stub:
1146         ret
1147 END(ftrace_caller)
1148
1149 #else /* ! CONFIG_DYNAMIC_FTRACE */
1150
1151 ENTRY(mcount)
1152         cmpl $0, function_trace_stop
1153         jne  ftrace_stub
1154
1155         cmpl $ftrace_stub, ftrace_trace_function
1156         jnz trace
1157 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1158         cmpl $ftrace_stub, ftrace_graph_return
1159         jnz ftrace_graph_caller
1160
1161         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1162         jnz ftrace_graph_caller
1163 #endif
1164 .globl ftrace_stub
1165 ftrace_stub:
1166         ret
1167
1168         /* taken from glibc */
1169 trace:
1170         pushl %eax
1171         pushl %ecx
1172         pushl %edx
1173         movl 0xc(%esp), %eax
1174         movl 0x4(%ebp), %edx
1175         subl $MCOUNT_INSN_SIZE, %eax
1176
1177         call *ftrace_trace_function
1178
1179         popl %edx
1180         popl %ecx
1181         popl %eax
1182         jmp ftrace_stub
1183 END(mcount)
1184 #endif /* CONFIG_DYNAMIC_FTRACE */
1185 #endif /* CONFIG_FUNCTION_TRACER */
1186
1187 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1188 ENTRY(ftrace_graph_caller)
1189         cmpl $0, function_trace_stop
1190         jne ftrace_stub
1191
1192         pushl %eax
1193         pushl %ecx
1194         pushl %edx
1195         movl 0xc(%esp), %edx
1196         lea 0x4(%ebp), %eax
1197         movl (%ebp), %ecx
1198         subl $MCOUNT_INSN_SIZE, %edx
1199         call prepare_ftrace_return
1200         popl %edx
1201         popl %ecx
1202         popl %eax
1203         ret
1204 END(ftrace_graph_caller)
1205
1206 .globl return_to_handler
1207 return_to_handler:
1208         pushl %eax
1209         pushl %edx
1210         movl %ebp, %eax
1211         call ftrace_return_to_handler
1212         movl %eax, %ecx
1213         popl %edx
1214         popl %eax
1215         jmp *%ecx
1216 #endif
1217
1218 .section .rodata,"a"
1219 #include "syscall_table_32.S"
1220
1221 syscall_table_size=(.-sys_call_table)
1222
1223 /*
1224  * Some functions should be protected against kprobes
1225  */
1226         .pushsection .kprobes.text, "ax"
1227
1228 ENTRY(page_fault)
1229         RING0_EC_FRAME
1230         pushl_cfi $do_page_fault
1231         ALIGN
1232 error_code:
1233         /* the function address is in %gs's slot on the stack */
1234         pushl_cfi %fs
1235         /*CFI_REL_OFFSET fs, 0*/
1236         pushl_cfi %es
1237         /*CFI_REL_OFFSET es, 0*/
1238         pushl_cfi %ds
1239         /*CFI_REL_OFFSET ds, 0*/
1240         pushl_cfi %eax
1241         CFI_REL_OFFSET eax, 0
1242         pushl_cfi %ebp
1243         CFI_REL_OFFSET ebp, 0
1244         pushl_cfi %edi
1245         CFI_REL_OFFSET edi, 0
1246         pushl_cfi %esi
1247         CFI_REL_OFFSET esi, 0
1248         pushl_cfi %edx
1249         CFI_REL_OFFSET edx, 0
1250         pushl_cfi %ecx
1251         CFI_REL_OFFSET ecx, 0
1252         pushl_cfi %ebx
1253         CFI_REL_OFFSET ebx, 0
1254         cld
1255         movl $(__KERNEL_PERCPU), %ecx
1256         movl %ecx, %fs
1257         UNWIND_ESPFIX_STACK
1258         GS_TO_REG %ecx
1259         movl PT_GS(%esp), %edi          # get the function address
1260         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1261         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1262         REG_TO_PTGS %ecx
1263         SET_KERNEL_GS %ecx
1264         movl $(__USER_DS), %ecx
1265         movl %ecx, %ds
1266         movl %ecx, %es
1267         TRACE_IRQS_OFF
1268         movl %esp,%eax                  # pt_regs pointer
1269         call *%edi
1270         jmp ret_from_exception
1271         CFI_ENDPROC
1272 END(page_fault)
1273
1274 /*
1275  * Debug traps and NMI can happen at the one SYSENTER instruction
1276  * that sets up the real kernel stack. Check here, since we can't
1277  * allow the wrong stack to be used.
1278  *
1279  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1280  * already pushed 3 words if it hits on the sysenter instruction:
1281  * eflags, cs and eip.
1282  *
1283  * We just load the right stack, and push the three (known) values
1284  * by hand onto the new stack - while updating the return eip past
1285  * the instruction that would have done it for sysenter.
1286  */
1287 .macro FIX_STACK offset ok label
1288         cmpw $__KERNEL_CS, 4(%esp)
1289         jne \ok
1290 \label:
1291         movl TSS_sysenter_sp0 + \offset(%esp), %esp
1292         CFI_DEF_CFA esp, 0
1293         CFI_UNDEFINED eip
1294         pushfl_cfi
1295         pushl_cfi $__KERNEL_CS
1296         pushl_cfi $sysenter_past_esp
1297         CFI_REL_OFFSET eip, 0
1298 .endm
1299
1300 ENTRY(debug)
1301         RING0_INT_FRAME
1302         cmpl $ia32_sysenter_target,(%esp)
1303         jne debug_stack_correct
1304         FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1305 debug_stack_correct:
1306         pushl_cfi $-1                   # mark this as an int
1307         SAVE_ALL
1308         TRACE_IRQS_OFF
1309         xorl %edx,%edx                  # error code 0
1310         movl %esp,%eax                  # pt_regs pointer
1311         call do_debug
1312         jmp ret_from_exception
1313         CFI_ENDPROC
1314 END(debug)
1315
1316 /*
1317  * NMI is doubly nasty. It can happen _while_ we're handling
1318  * a debug fault, and the debug fault hasn't yet been able to
1319  * clear up the stack. So we first check whether we got  an
1320  * NMI on the sysenter entry path, but after that we need to
1321  * check whether we got an NMI on the debug path where the debug
1322  * fault happened on the sysenter path.
1323  */
1324 ENTRY(nmi)
1325         RING0_INT_FRAME
1326         pushl_cfi %eax
1327         movl %ss, %eax
1328         cmpw $__ESPFIX_SS, %ax
1329         popl_cfi %eax
1330         je nmi_espfix_stack
1331         cmpl $ia32_sysenter_target,(%esp)
1332         je nmi_stack_fixup
1333         pushl_cfi %eax
1334         movl %esp,%eax
1335         /* Do not access memory above the end of our stack page,
1336          * it might not exist.
1337          */
1338         andl $(THREAD_SIZE-1),%eax
1339         cmpl $(THREAD_SIZE-20),%eax
1340         popl_cfi %eax
1341         jae nmi_stack_correct
1342         cmpl $ia32_sysenter_target,12(%esp)
1343         je nmi_debug_stack_check
1344 nmi_stack_correct:
1345         /* We have a RING0_INT_FRAME here */
1346         pushl_cfi %eax
1347         SAVE_ALL
1348         xorl %edx,%edx          # zero error code
1349         movl %esp,%eax          # pt_regs pointer
1350         call do_nmi
1351         jmp restore_all_notrace
1352         CFI_ENDPROC
1353
1354 nmi_stack_fixup:
1355         RING0_INT_FRAME
1356         FIX_STACK 12, nmi_stack_correct, 1
1357         jmp nmi_stack_correct
1358
1359 nmi_debug_stack_check:
1360         /* We have a RING0_INT_FRAME here */
1361         cmpw $__KERNEL_CS,16(%esp)
1362         jne nmi_stack_correct
1363         cmpl $debug,(%esp)
1364         jb nmi_stack_correct
1365         cmpl $debug_esp_fix_insn,(%esp)
1366         ja nmi_stack_correct
1367         FIX_STACK 24, nmi_stack_correct, 1
1368         jmp nmi_stack_correct
1369
1370 nmi_espfix_stack:
1371         /* We have a RING0_INT_FRAME here.
1372          *
1373          * create the pointer to lss back
1374          */
1375         pushl_cfi %ss
1376         pushl_cfi %esp
1377         addl $4, (%esp)
1378         /* copy the iret frame of 12 bytes */
1379         .rept 3
1380         pushl_cfi 16(%esp)
1381         .endr
1382         pushl_cfi %eax
1383         SAVE_ALL
1384         FIXUP_ESPFIX_STACK              # %eax == %esp
1385         xorl %edx,%edx                  # zero error code
1386         call do_nmi
1387         RESTORE_REGS
1388         lss 12+4(%esp), %esp            # back to espfix stack
1389         CFI_ADJUST_CFA_OFFSET -24
1390         jmp irq_return
1391         CFI_ENDPROC
1392 END(nmi)
1393
1394 ENTRY(int3)
1395         RING0_INT_FRAME
1396         pushl_cfi $-1                   # mark this as an int
1397         SAVE_ALL
1398         TRACE_IRQS_OFF
1399         xorl %edx,%edx          # zero error code
1400         movl %esp,%eax          # pt_regs pointer
1401         call do_int3
1402         jmp ret_from_exception
1403         CFI_ENDPROC
1404 END(int3)
1405
1406 ENTRY(general_protection)
1407         RING0_EC_FRAME
1408         pushl_cfi $do_general_protection
1409         jmp error_code
1410         CFI_ENDPROC
1411 END(general_protection)
1412
1413 #ifdef CONFIG_KVM_GUEST
1414 ENTRY(async_page_fault)
1415         RING0_EC_FRAME
1416         pushl_cfi $do_async_page_fault
1417         jmp error_code
1418         CFI_ENDPROC
1419 END(async_page_fault)
1420 #endif
1421
1422 /*
1423  * End of kprobes section
1424  */
1425         .popsection