arch/sparc/kernel/rtrap.S

   1 /*
   2  * rtrap.S: Return from Sparc trap low-level code.
   3  *
   4  * Copyright (C) 1995 David S. Miller (davem@caip.rutgers.edu)
   5  */
   6
   7 #include <asm/page.h>
   8 #include <asm/ptrace.h>
   9 #include <asm/psr.h>
  10 #include <asm/asi.h>
  11 #include <asm/smp.h>
  12 #include <asm/contregs.h>
  13 #include <asm/winmacro.h>
  14 #include <asm/asmmacro.h>
  15 #include <asm/thread_info.h>
  16
  17 #define t_psr     l0
  18 #define t_pc      l1
  19 #define t_npc     l2
  20 #define t_wim     l3
  21 #define twin_tmp1 l4
  22 #define glob_tmp  g4
  23 #define curptr    g6
  24
  25         /* 7 WINDOW SPARC PATCH INSTRUCTIONS */
  26         .globl  rtrap_7win_patch1, rtrap_7win_patch2, rtrap_7win_patch3
  27         .globl  rtrap_7win_patch4, rtrap_7win_patch5
  28 rtrap_7win_patch1:      srl     %t_wim, 0x6, %glob_tmp
  29 rtrap_7win_patch2:      and     %glob_tmp, 0x7f, %glob_tmp
  30 rtrap_7win_patch3:      srl     %g1, 7, %g2
  31 rtrap_7win_patch4:      srl     %g2, 6, %g2
  32 rtrap_7win_patch5:      and     %g1, 0x7f, %g1
  33         /* END OF PATCH INSTRUCTIONS */
  34
  35         /* We need to check for a few things which are:
  36          * 1) The need to call schedule() because this
  37          *    processes quantum is up.
  38          * 2) Pending signals for this process, if any
  39          *    exist we need to call do_signal() to do
  40          *    the needy.
  41          *
  42          * Else we just check if the rett would land us
  43          * in an invalid window, if so we need to grab
  44          * it off the user/kernel stack first.
  45          */
  46
  47         .globl  ret_trap_entry, rtrap_patch1, rtrap_patch2
  48         .globl  rtrap_patch3, rtrap_patch4, rtrap_patch5
  49         .globl  ret_trap_lockless_ipi
  50 ret_trap_entry:
  51 ret_trap_lockless_ipi:
  52         andcc   %t_psr, PSR_PS, %g0
  53         sethi   %hi(PSR_SYSCALL), %g1
  54         be      1f
  55          andn   %t_psr, %g1, %t_psr
  56
  57         wr      %t_psr, 0x0, %psr
  58         b       ret_trap_kernel
  59          nop
  60
  61 1:
  62         ld      [%curptr + TI_FLAGS], %g2
  63         andcc   %g2, (_TIF_NEED_RESCHED), %g0
  64         be      signal_p
  65          nop
  66
  67         call    schedule
  68          nop
  69
  70         ld      [%curptr + TI_FLAGS], %g2
  71 signal_p:
  72         andcc   %g2, (_TIF_SIGPENDING|_TIF_RESTORE_SIGMASK), %g0
  73         bz,a    ret_trap_continue
  74          ld     [%sp + STACKFRAME_SZ + PT_PSR], %t_psr
  75
  76         mov     %l5, %o1
  77         call    do_signal
  78          add    %sp, STACKFRAME_SZ, %o0 ! pt_regs ptr
  79
  80         /* Fall through. */
  81         ld      [%sp + STACKFRAME_SZ + PT_PSR], %t_psr
  82         clr     %l6
  83 ret_trap_continue:
  84         sethi   %hi(PSR_SYSCALL), %g1
  85         andn    %t_psr, %g1, %t_psr
  86         wr      %t_psr, 0x0, %psr
  87         WRITE_PAUSE
  88
  89         ld      [%curptr + TI_W_SAVED], %twin_tmp1
  90         orcc    %g0, %twin_tmp1, %g0
  91         be      ret_trap_nobufwins
  92          nop
  93
  94         wr      %t_psr, PSR_ET, %psr
  95         WRITE_PAUSE
  96
  97         mov     1, %o1
  98         call    try_to_clear_window_buffer
  99          add    %sp, STACKFRAME_SZ, %o0
 100
 101         b       signal_p
 102          ld     [%curptr + TI_FLAGS], %g2
 103
 104 ret_trap_nobufwins:
 105         /* Load up the user's out registers so we can pull
 106          * a window from the stack, if necessary.
 107          */
 108         LOAD_PT_INS(sp)
 109
 110         /* If there are already live user windows in the
 111          * set we can return from trap safely.
 112          */
 113         ld      [%curptr + TI_UWINMASK], %twin_tmp1
 114         orcc    %g0, %twin_tmp1, %g0
 115         bne     ret_trap_userwins_ok
 116          nop
 117
 118                 /* Calculate new %wim, we have to pull a register
 119                  * window from the users stack.
 120                  */
 121 ret_trap_pull_one_window:
 122                 rd      %wim, %t_wim
 123                 sll     %t_wim, 0x1, %twin_tmp1
 124 rtrap_patch1:   srl     %t_wim, 0x7, %glob_tmp
 125                 or      %glob_tmp, %twin_tmp1, %glob_tmp
 126 rtrap_patch2:   and     %glob_tmp, 0xff, %glob_tmp
 127
 128                 wr      %glob_tmp, 0x0, %wim
 129
 130                                 /* Here comes the architecture specific
 131                                  * branch to the user stack checking routine
 132                                  * for return from traps.
 133                                  */
 134                                 .globl  rtrap_mmu_patchme
 135 rtrap_mmu_patchme:      b       sun4c_rett_stackchk
 136                                  andcc  %fp, 0x7, %g0
 137
 138 ret_trap_userwins_ok:
 139         LOAD_PT_PRIV(sp, t_psr, t_pc, t_npc)
 140         or      %t_pc, %t_npc, %g2
 141         andcc   %g2, 0x3, %g0
 142         sethi   %hi(PSR_SYSCALL), %g2
 143         be      1f
 144          andn   %t_psr, %g2, %t_psr
 145
 146         b       ret_trap_unaligned_pc
 147          add    %sp, STACKFRAME_SZ, %o0
 148
 149 1:
 150         LOAD_PT_YREG(sp, g1)
 151         LOAD_PT_GLOBALS(sp)
 152
 153         wr      %t_psr, 0x0, %psr
 154         WRITE_PAUSE
 155
 156         jmp     %t_pc
 157         rett    %t_npc
 158
 159 ret_trap_unaligned_pc:
 160         ld      [%sp + STACKFRAME_SZ + PT_PC], %o1
 161         ld      [%sp + STACKFRAME_SZ + PT_NPC], %o2
 162         ld      [%sp + STACKFRAME_SZ + PT_PSR], %o3
 163
 164         wr      %t_wim, 0x0, %wim               ! or else...
 165
 166         wr      %t_psr, PSR_ET, %psr
 167         WRITE_PAUSE
 168
 169         call    do_memaccess_unaligned
 170          nop
 171
 172         b       signal_p
 173          ld     [%curptr + TI_FLAGS], %g2
 174
 175 ret_trap_kernel:
 176                 /* Will the rett land us in the invalid window? */
 177                 mov     2, %g1
 178                 sll     %g1, %t_psr, %g1
 179 rtrap_patch3:   srl     %g1, 8, %g2
 180                 or      %g1, %g2, %g1
 181                 rd      %wim, %g2
 182                 andcc   %g2, %g1, %g0
 183                 be      1f              ! Nope, just return from the trap
 184                  sll    %g2, 0x1, %g1
 185
 186                 /* We have to grab a window before returning. */
 187 rtrap_patch4:   srl     %g2, 7,  %g2
 188                 or      %g1, %g2, %g1
 189 rtrap_patch5:   and     %g1, 0xff, %g1
 190
 191         wr      %g1, 0x0, %wim
 192
 193         /* Grrr, make sure we load from the right %sp... */
 194         LOAD_PT_ALL(sp, t_psr, t_pc, t_npc, g1)
 195
 196         restore %g0, %g0, %g0
 197         LOAD_WINDOW(sp)
 198         b       2f
 199          save   %g0, %g0, %g0
 200
 201         /* Reload the entire frame in case this is from a
 202          * kernel system call or whatever...
 203          */
 204 1:
 205         LOAD_PT_ALL(sp, t_psr, t_pc, t_npc, g1)
 206 2:
 207         sethi   %hi(PSR_SYSCALL), %twin_tmp1
 208         andn    %t_psr, %twin_tmp1, %t_psr
 209         wr      %t_psr, 0x0, %psr
 210         WRITE_PAUSE
 211
 212         jmp     %t_pc
 213         rett    %t_npc
 214
 215 ret_trap_user_stack_is_bolixed:
 216         wr      %t_wim, 0x0, %wim
 217
 218         wr      %t_psr, PSR_ET, %psr
 219         WRITE_PAUSE
 220
 221         call    window_ret_fault
 222          add    %sp, STACKFRAME_SZ, %o0
 223
 224         b       signal_p
 225          ld     [%curptr + TI_FLAGS], %g2
 226
 227 sun4c_rett_stackchk:
 228         be      1f
 229          and    %fp, 0xfff, %g1         ! delay slot
 230
 231         b       ret_trap_user_stack_is_bolixed + 0x4
 232          wr     %t_wim, 0x0, %wim
 233
 234         /* See if we have to check the sanity of one page or two */
 235 1:
 236         add     %g1, 0x38, %g1
 237         sra     %fp, 29, %g2
 238         add     %g2, 0x1, %g2
 239         andncc  %g2, 0x1, %g0
 240         be      1f
 241          andncc %g1, 0xff8, %g0
 242
 243         /* %sp is in vma hole, yuck */
 244         b       ret_trap_user_stack_is_bolixed + 0x4
 245          wr     %t_wim, 0x0, %wim
 246
 247 1:
 248         be      sun4c_rett_onepage      /* Only one page to check */
 249          lda    [%fp] ASI_PTE, %g2
 250
 251 sun4c_rett_twopages:
 252         add     %fp, 0x38, %g1
 253         sra     %g1, 29, %g2
 254         add     %g2, 0x1, %g2
 255         andncc  %g2, 0x1, %g0
 256         be      1f
 257          lda    [%g1] ASI_PTE, %g2
 258
 259         /* Second page is in vma hole */
 260         b       ret_trap_user_stack_is_bolixed + 0x4
 261          wr     %t_wim, 0x0, %wim
 262
 263 1:
 264         srl     %g2, 29, %g2
 265         andcc   %g2, 0x4, %g0
 266         bne     sun4c_rett_onepage
 267          lda    [%fp] ASI_PTE, %g2
 268
 269         /* Second page has bad perms */
 270         b       ret_trap_user_stack_is_bolixed + 0x4
 271          wr     %t_wim, 0x0, %wim
 272
 273 sun4c_rett_onepage:
 274         srl     %g2, 29, %g2
 275         andcc   %g2, 0x4, %g0
 276         bne,a   1f
 277          restore %g0, %g0, %g0
 278
 279         /* A page had bad page permissions, losing... */
 280         b       ret_trap_user_stack_is_bolixed + 0x4
 281          wr     %t_wim, 0x0, %wim
 282
 283         /* Whee, things are ok, load the window and continue. */
 284 1:
 285         LOAD_WINDOW(sp)
 286
 287         b       ret_trap_userwins_ok
 288          save   %g0, %g0, %g0
 289
 290         .globl  srmmu_rett_stackchk
 291 srmmu_rett_stackchk:
 292         bne     ret_trap_user_stack_is_bolixed
 293          sethi   %hi(PAGE_OFFSET), %g1
 294         cmp     %g1, %fp
 295         bleu    ret_trap_user_stack_is_bolixed
 296          mov    AC_M_SFSR, %g1
 297         lda     [%g1] ASI_M_MMUREGS, %g0
 298
 299         lda     [%g0] ASI_M_MMUREGS, %g1
 300         or      %g1, 0x2, %g1
 301         sta     %g1, [%g0] ASI_M_MMUREGS
 302
 303         restore %g0, %g0, %g0
 304
 305         LOAD_WINDOW(sp)
 306
 307         save    %g0, %g0, %g0
 308
 309         andn    %g1, 0x2, %g1
 310         sta     %g1, [%g0] ASI_M_MMUREGS
 311
 312         mov     AC_M_SFAR, %g2
 313         lda     [%g2] ASI_M_MMUREGS, %g2
 314
 315         mov     AC_M_SFSR, %g1
 316         lda     [%g1] ASI_M_MMUREGS, %g1
 317         andcc   %g1, 0x2, %g0
 318         be      ret_trap_userwins_ok
 319          nop
 320
 321         b,a     ret_trap_user_stack_is_bolixed