arch/sh/kernel/vsyscall/vsyscall.lds.S

   1 /*
   2  * Linker script for vsyscall DSO.  The vsyscall page is an ELF shared
   3  * object prelinked to its virtual address, and with only one read-only
   4  * segment (that fits in one page).  This script controls its layout.
   5  */
   6 #include <asm/asm-offsets.h>
   7
   8 #ifdef CONFIG_CPU_LITTLE_ENDIAN
   9 OUTPUT_FORMAT("elf32-sh-linux", "elf32-sh-linux", "elf32-sh-linux")
  10 #else
  11 OUTPUT_FORMAT("elf32-shbig-linux", "elf32-shbig-linux", "elf32-shbig-linux")
  12 #endif
  13 OUTPUT_ARCH(sh)
  14
  15 /* The ELF entry point can be used to set the AT_SYSINFO value.  */
  16 ENTRY(__kernel_vsyscall);
  17
  18 SECTIONS
  19 {
  20         . = SIZEOF_HEADERS;
  21
  22         .hash           : { *(.hash) }                  :text
  23         .gnu.hash       : { *(.gnu.hash) }
  24         .dynsym         : { *(.dynsym) }
  25         .dynstr         : { *(.dynstr) }
  26         .gnu.version    : { *(.gnu.version) }
  27         .gnu.version_d  : { *(.gnu.version_d) }
  28         .gnu.version_r  : { *(.gnu.version_r) }
  29
  30         /*
  31          * This linker script is used both with -r and with -shared.
  32          * For the layouts to match, we need to skip more than enough
  33          * space for the dynamic symbol table et al.  If this amount
  34          * is insufficient, ld -shared will barf.  Just increase it here.
  35          */
  36         . = 0x400;
  37
  38         .text           : { *(.text) }                  :text   =0x90909090
  39         .note           : { *(.note.*) }                :text   :note
  40         .eh_frame_hdr   : { *(.eh_frame_hdr ) }         :text   :eh_frame_hdr
  41         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  42         .dynamic        : { *(.dynamic) }               :text   :dynamic
  43         .useless        : {
  44               *(.got.plt) *(.got)
  45               *(.data .data.* .gnu.linkonce.d.*)
  46               *(.dynbss)
  47               *(.bss .bss.* .gnu.linkonce.b.*)
  48         }                                               :text
  49 }
  50
  51 /*
  52  * Very old versions of ld do not recognize this name token; use the constant.
  53  */
  54 #define PT_GNU_EH_FRAME 0x6474e550
  55
  56 /*
  57  * We must supply the ELF program headers explicitly to get just one
  58  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
  59  */
  60 PHDRS
  61 {
  62         text            PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
  63         dynamic         PT_DYNAMIC FLAGS(4);            /* PF_R */
  64         note            PT_NOTE FLAGS(4);               /* PF_R */
  65         eh_frame_hdr    PT_GNU_EH_FRAME;
  66 }
  67
  68 /*
  69  * This controls what symbols we export from the DSO.
  70  */
  71 VERSION
  72 {
  73         LINUX_2.6 {
  74         global:
  75                 __kernel_vsyscall;
  76                 __kernel_sigreturn;
  77                 __kernel_rt_sigreturn;
  78
  79         local: *;
  80         };
  81 }