arch/s390/power/swsusp_asm64.S

   1 /*
   2  * S390 64-bit swsusp implementation
   3  *
   4  * Copyright IBM Corp. 2009
   5  *
   6  * Author(s): Hans-Joachim Picht <hans@linux.vnet.ibm.com>
   7  *            Michael Holzheu <holzheu@linux.vnet.ibm.com>
   8  */
   9
  10 #include <asm/page.h>
  11 #include <asm/ptrace.h>
  12 #include <asm/asm-offsets.h>
  13
  14 /*
  15  * Save register context in absolute 0 lowcore and call swsusp_save() to
  16  * create in-memory kernel image. The context is saved in the designated
  17  * "store status" memory locations (see POP).
  18  * We return from this function twice. The first time during the suspend to
  19  * disk process. The second time via the swsusp_arch_resume() function
  20  * (see below) in the resume process.
  21  * This function runs with disabled interrupts.
  22  */
  23         .section .text
  24         .align  2
  25         .globl swsusp_arch_suspend
  26 swsusp_arch_suspend:
  27         stmg    %r6,%r15,__SF_GPRS(%r15)
  28         lgr     %r1,%r15
  29         aghi    %r15,-STACK_FRAME_OVERHEAD
  30         stg     %r1,__SF_BACKCHAIN(%r15)
  31
  32         /* Deactivate DAT */
  33         stnsm   __SF_EMPTY(%r15),0xfb
  34
  35         /* Switch off lowcore protection */
  36         stctg   %c0,%c0,__SF_EMPTY(%r15)
  37         ni      __SF_EMPTY+4(%r15),0xef
  38         lctlg   %c0,%c0,__SF_EMPTY(%r15)
  39
  40         /* Store prefix register on stack */
  41         stpx    __SF_EMPTY(%r15)
  42
  43         /* Setup base register for lowcore (absolute 0) */
  44         llgf    %r1,__SF_EMPTY(%r15)
  45
  46         /* Get pointer to save area */
  47         aghi    %r1,0x1000
  48
  49         /* Store registers */
  50         mvc     0x318(4,%r1),__SF_EMPTY(%r15)   /* move prefix to lowcore */
  51         stfpc   0x31c(%r1)                      /* store fpu control */
  52         std     0,0x200(%r1)                    /* store f0 */
  53         std     1,0x208(%r1)                    /* store f1 */
  54         std     2,0x210(%r1)                    /* store f2 */
  55         std     3,0x218(%r1)                    /* store f3 */
  56         std     4,0x220(%r1)                    /* store f4 */
  57         std     5,0x228(%r1)                    /* store f5 */
  58         std     6,0x230(%r1)                    /* store f6 */
  59         std     7,0x238(%r1)                    /* store f7 */
  60         std     8,0x240(%r1)                    /* store f8 */
  61         std     9,0x248(%r1)                    /* store f9 */
  62         std     10,0x250(%r1)                   /* store f10 */
  63         std     11,0x258(%r1)                   /* store f11 */
  64         std     12,0x260(%r1)                   /* store f12 */
  65         std     13,0x268(%r1)                   /* store f13 */
  66         std     14,0x270(%r1)                   /* store f14 */
  67         std     15,0x278(%r1)                   /* store f15 */
  68         stam    %a0,%a15,0x340(%r1)             /* store access registers */
  69         stctg   %c0,%c15,0x380(%r1)             /* store control registers */
  70         stmg    %r0,%r15,0x280(%r1)             /* store general registers */
  71
  72         stpt    0x328(%r1)                      /* store timer */
  73         stckc   0x330(%r1)                      /* store clock comparator */
  74
  75         /* Activate DAT */
  76         stosm   __SF_EMPTY(%r15),0x04
  77
  78         /* Set prefix page to zero */
  79         xc      __SF_EMPTY(4,%r15),__SF_EMPTY(%r15)
  80         spx     __SF_EMPTY(%r15)
  81
  82         /* Setup lowcore */
  83         brasl   %r14,setup_lowcore_early
  84
  85         /* Save image */
  86         brasl   %r14,swsusp_save
  87
  88         /* Switch on lowcore protection */
  89         stctg   %c0,%c0,__SF_EMPTY(%r15)
  90         oi      __SF_EMPTY+4(%r15),0x10
  91         lctlg   %c0,%c0,__SF_EMPTY(%r15)
  92
  93         /* Restore prefix register and return */
  94         lghi    %r1,0x1000
  95         spx     0x318(%r1)
  96         lmg     %r6,%r15,STACK_FRAME_OVERHEAD + __SF_GPRS(%r15)
  97         lghi    %r2,0
  98         br      %r14
  99
 100 /*
 101  * Restore saved memory image to correct place and restore register context.
 102  * Then we return to the function that called swsusp_arch_suspend().
 103  * swsusp_arch_resume() runs with disabled interrupts.
 104  */
 105         .globl swsusp_arch_resume
 106 swsusp_arch_resume:
 107         stmg    %r6,%r15,__SF_GPRS(%r15)
 108         lgr     %r1,%r15
 109         aghi    %r15,-STACK_FRAME_OVERHEAD
 110         stg     %r1,__SF_BACKCHAIN(%r15)
 111
 112 #ifdef CONFIG_SMP
 113         /* Save boot cpu number */
 114         brasl   %r14,smp_get_phys_cpu_id
 115         lgr     %r10,%r2
 116 #endif
 117         /* Deactivate DAT */
 118         stnsm   __SF_EMPTY(%r15),0xfb
 119
 120         /* Switch off lowcore protection */
 121         stctg   %c0,%c0,__SF_EMPTY(%r15)
 122         ni      __SF_EMPTY+4(%r15),0xef
 123         lctlg   %c0,%c0,__SF_EMPTY(%r15)
 124
 125         /* Set prefix page to zero */
 126         xc      __SF_EMPTY(4,%r15),__SF_EMPTY(%r15)
 127         spx     __SF_EMPTY(%r15)
 128
 129         /* Restore saved image */
 130         larl    %r1,restore_pblist
 131         lg      %r1,0(%r1)
 132         ltgr    %r1,%r1
 133         jz      2f
 134 0:
 135         lg      %r2,8(%r1)
 136         lg      %r4,0(%r1)
 137         lghi    %r3,PAGE_SIZE
 138         lghi    %r5,PAGE_SIZE
 139 1:
 140         mvcle   %r2,%r4,0
 141         jo      1b
 142         lg      %r1,16(%r1)
 143         ltgr    %r1,%r1
 144         jnz     0b
 145 2:
 146         ptlb                            /* flush tlb */
 147
 148         /* Restore registers */
 149         lghi    %r13,0x1000             /* %r1 = pointer to save arae */
 150
 151         spt     0x328(%r13)             /* reprogram timer */
 152         //sckc  0x330(%r13)             /* set clock comparator */
 153
 154         lctlg   %c0,%c15,0x380(%r13)    /* load control registers */
 155         lam     %a0,%a15,0x340(%r13)    /* load access registers */
 156
 157         lfpc    0x31c(%r13)             /* load fpu control */
 158         ld      0,0x200(%r13)           /* load f0 */
 159         ld      1,0x208(%r13)           /* load f1 */
 160         ld      2,0x210(%r13)           /* load f2 */
 161         ld      3,0x218(%r13)           /* load f3 */
 162         ld      4,0x220(%r13)           /* load f4 */
 163         ld      5,0x228(%r13)           /* load f5 */
 164         ld      6,0x230(%r13)           /* load f6 */
 165         ld      7,0x238(%r13)           /* load f7 */
 166         ld      8,0x240(%r13)           /* load f8 */
 167         ld      9,0x248(%r13)           /* load f9 */
 168         ld      10,0x250(%r13)          /* load f10 */
 169         ld      11,0x258(%r13)          /* load f11 */
 170         ld      12,0x260(%r13)          /* load f12 */
 171         ld      13,0x268(%r13)          /* load f13 */
 172         ld      14,0x270(%r13)          /* load f14 */
 173         ld      15,0x278(%r13)          /* load f15 */
 174
 175         /* Load old stack */
 176         lg      %r15,0x2f8(%r13)
 177
 178         /* Pointer to save arae */
 179         lghi    %r13,0x1000
 180
 181 #ifdef CONFIG_SMP
 182         /* Switch CPUs */
 183         lgr     %r2,%r10                /* get cpu id */
 184         llgf    %r3,0x318(%r13)
 185         brasl   %r14,smp_switch_boot_cpu_in_resume
 186 #endif
 187         /* Restore prefix register */
 188         spx     0x318(%r13)
 189
 190         /* Switch on lowcore protection */
 191         stctg   %c0,%c0,__SF_EMPTY(%r15)
 192         oi      __SF_EMPTY+4(%r15),0x10
 193         lctlg   %c0,%c0,__SF_EMPTY(%r15)
 194
 195         /* Activate DAT */
 196         stosm   __SF_EMPTY(%r15),0x04
 197
 198         /* Return 0 */
 199         lmg     %r6,%r15,STACK_FRAME_OVERHEAD + __SF_GPRS(%r15)
 200         lghi    %r2,0
 201         br      %r14