arch/s390/kernel/reipl.S

   1 /*
   2  *  arch/s390/kernel/reipl.S
   3  *
   4  *  S390 version
   5  *    Copyright (C) 2000 IBM Deutschland Entwicklung GmbH, IBM Corporation
   6  *    Author(s): Holger Smolinski (Holger.Smolinski@de.ibm.com)
   7  */
   8
   9 #include <asm/lowcore.h>
  10
  11                 .globl  do_reipl_asm
  12 do_reipl_asm:   basr    %r13,0
  13 .Lpg0:          lpsw    .Lnewpsw-.Lpg0(%r13)
  14 .Lpg1:          # do store status of all registers
  15
  16                 stm     %r0,%r15,__LC_GPREGS_SAVE_AREA
  17                 stctl   %c0,%c15,__LC_CREGS_SAVE_AREA
  18                 stam    %a0,%a15,__LC_AREGS_SAVE_AREA
  19                 stpx    __LC_PREFIX_SAVE_AREA
  20                 stckc   .Lclkcmp-.Lpg0(%r13)
  21                 mvc     __LC_CLOCK_COMP_SAVE_AREA(8),.Lclkcmp-.Lpg0(%r13)
  22                 stpt    __LC_CPU_TIMER_SAVE_AREA
  23                 st      %r13, __LC_PSW_SAVE_AREA+4
  24
  25                 lctl    %c6,%c6,.Lall-.Lpg0(%r13)
  26                 lr      %r1,%r2
  27                 mvc     __LC_PGM_NEW_PSW(8),.Lpcnew-.Lpg0(%r13)
  28                 stsch   .Lschib-.Lpg0(%r13)
  29                 oi      .Lschib+5-.Lpg0(%r13),0x84
  30 .Lecs:          xi      .Lschib+27-.Lpg0(%r13),0x01
  31                 msch    .Lschib-.Lpg0(%r13)
  32                 lhi     %r0,5
  33 .Lssch:         ssch    .Liplorb-.Lpg0(%r13)
  34                 jz      .L001
  35                 brct    %r0,.Lssch
  36                 bas     %r14,.Ldisab-.Lpg0(%r13)
  37 .L001:          mvc     __LC_IO_NEW_PSW(8),.Lionew-.Lpg0(%r13)
  38 .Ltpi:          lpsw    .Lwaitpsw-.Lpg0(%r13)
  39 .Lcont:         c       %r1,__LC_SUBCHANNEL_ID
  40                 jnz     .Ltpi
  41                 clc     __LC_IO_INT_PARM(4),.Liplorb-.Lpg0(%r13)
  42                 jnz     .Ltpi
  43                 tsch    .Liplirb-.Lpg0(%r13)
  44                 tm      .Liplirb+9-.Lpg0(%r13),0xbf
  45                 jz      .L002
  46                 bas     %r14,.Ldisab-.Lpg0(%r13)
  47 .L002:          tm      .Liplirb+8-.Lpg0(%r13),0xf3
  48                 jz      .L003
  49                 bas     %r14,.Ldisab-.Lpg0(%r13)
  50 .L003:          st      %r1,__LC_SUBCHANNEL_ID
  51                 lpsw    0
  52                 sigp    0,0,0(6)
  53 .Ldisab:        st      %r14,.Ldispsw+4-.Lpg0(%r13)
  54                 lpsw    .Ldispsw-.Lpg0(%r13)
  55                 .align  8
  56 .Lclkcmp:       .quad   0x0000000000000000
  57 .Lall:          .long   0xff000000
  58                 .align  8
  59 .Lnewpsw:       .long   0x00080000,0x80000000+.Lpg1
  60 .Lpcnew:        .long   0x00080000,0x80000000+.Lecs
  61 .Lionew:        .long   0x00080000,0x80000000+.Lcont
  62 .Lwaitpsw:      .long   0x020a0000,0x00000000+.Ltpi
  63 .Ldispsw:       .long   0x000a0000,0x00000000
  64 .Liplccws:      .long   0x02000000,0x60000018
  65                 .long   0x08000008,0x20000001
  66 .Liplorb:       .long   0x0049504c,0x0040ff80
  67                 .long   0x00000000+.Liplccws
  68 .Lschib:        .long   0x00000000,0x00000000
  69                 .long   0x00000000,0x00000000
  70                 .long   0x00000000,0x00000000
  71                 .long   0x00000000,0x00000000
  72                 .long   0x00000000,0x00000000
  73                 .long   0x00000000,0x00000000
  74 .Liplirb:       .long   0x00000000,0x00000000
  75                 .long   0x00000000,0x00000000
  76                 .long   0x00000000,0x00000000
  77                 .long   0x00000000,0x00000000
  78                 .long   0x00000000,0x00000000
  79                 .long   0x00000000,0x00000000
  80                 .long   0x00000000,0x00000000
  81                 .long   0x00000000,0x00000000