arch/s390/kernel/entry64.S

   1 /*
   2  *  arch/s390/kernel/entry64.S
   3  *    S390 low-level entry points.
   4  *
   5  *    Copyright (C) IBM Corp. 1999,2010
   6  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   7  *               Hartmut Penner (hp@de.ibm.com),
   8  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
  10  */
  11
  12 #include <linux/init.h>
  13 #include <linux/linkage.h>
  14 #include <asm/cache.h>
  15 #include <asm/errno.h>
  16 #include <asm/ptrace.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/asm-offsets.h>
  19 #include <asm/unistd.h>
  20 #include <asm/page.h>
  21
  22 /*
  23  * Stack layout for the system_call stack entry.
  24  * The first few entries are identical to the user_regs_struct.
  25  */
  26 SP_PTREGS    =  STACK_FRAME_OVERHEAD
  27 SP_ARGS      =  STACK_FRAME_OVERHEAD + __PT_ARGS
  28 SP_PSW       =  STACK_FRAME_OVERHEAD + __PT_PSW
  29 SP_R0        =  STACK_FRAME_OVERHEAD + __PT_GPRS
  30 SP_R1        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 8
  31 SP_R2        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 16
  32 SP_R3        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 24
  33 SP_R4        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 32
  34 SP_R5        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 40
  35 SP_R6        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 48
  36 SP_R7        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 56
  37 SP_R8        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 64
  38 SP_R9        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 72
  39 SP_R10       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 80
  40 SP_R11       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 88
  41 SP_R12       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 96
  42 SP_R13       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 104
  43 SP_R14       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 112
  44 SP_R15       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 120
  45 SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
  46 SP_SVC_CODE  =  STACK_FRAME_OVERHEAD + __PT_SVC_CODE
  47 SP_SIZE      =  STACK_FRAME_OVERHEAD + __PT_SIZE
  48
  49 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  50 STACK_SIZE  = 1 << STACK_SHIFT
  51
  52 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  53                  _TIF_MCCK_PENDING | _TIF_PER_TRAP )
  54 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  55                  _TIF_MCCK_PENDING)
  56 _TIF_TRACE    = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
  57                  _TIF_SYSCALL_TRACEPOINT)
  58 _TIF_EXIT_SIE = (_TIF_SIGPENDING | _TIF_NEED_RESCHED | _TIF_MCCK_PENDING)
  59
  60 #define BASED(name) name-system_call(%r13)
  61
  62         .macro SPP newpp
  63 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
  64         tm      __LC_MACHINE_FLAGS+6,0x20       # MACHINE_FLAG_SPP
  65         jz      .+8
  66         .insn   s,0xb2800000,\newpp
  67 #endif
  68         .endm
  69
  70         .macro  HANDLE_SIE_INTERCEPT
  71 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
  72         tm      __TI_flags+6(%r12),_TIF_SIE>>8
  73         jz      0f
  74         SPP     __LC_CMF_HPP                    # set host id
  75         clc     SP_PSW+8(8,%r15),BASED(.Lsie_loop)
  76         jl      0f
  77         clc     SP_PSW+8(8,%r15),BASED(.Lsie_done)
  78         jhe     0f
  79         mvc     SP_PSW+8(8,%r15),BASED(.Lsie_loop)
  80 0:
  81 #endif
  82         .endm
  83
  84 #ifdef CONFIG_TRACE_IRQFLAGS
  85         .macro  TRACE_IRQS_ON
  86         basr    %r2,%r0
  87         brasl   %r14,trace_hardirqs_on_caller
  88         .endm
  89
  90         .macro  TRACE_IRQS_OFF
  91         basr    %r2,%r0
  92         brasl   %r14,trace_hardirqs_off_caller
  93         .endm
  94 #else
  95 #define TRACE_IRQS_ON
  96 #define TRACE_IRQS_OFF
  97 #endif
  98
  99 #ifdef CONFIG_LOCKDEP
 100         .macro  LOCKDEP_SYS_EXIT
 101         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 102         jz      0f
 103         brasl   %r14,lockdep_sys_exit
 104 0:
 105         .endm
 106 #else
 107 #define LOCKDEP_SYS_EXIT
 108 #endif
 109
 110         .macro  UPDATE_VTIME lc_from,lc_to,lc_sum
 111         lg      %r10,\lc_from
 112         slg     %r10,\lc_to
 113         alg     %r10,\lc_sum
 114         stg     %r10,\lc_sum
 115         .endm
 116
 117 /*
 118  * Register usage in interrupt handlers:
 119  *    R9  - pointer to current task structure
 120  *    R13 - pointer to literal pool
 121  *    R14 - return register for function calls
 122  *    R15 - kernel stack pointer
 123  */
 124
 125         .macro  SAVE_ALL_SVC psworg,savearea
 126         stmg    %r11,%r15,\savearea
 127         lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 128         aghi    %r15,-SP_SIZE           # make room for registers & psw
 129         lg      %r11,__LC_LAST_BREAK
 130         .endm
 131
 132         .macro  SAVE_ALL_PGM psworg,savearea
 133         stmg    %r11,%r15,\savearea
 134         tm      \psworg+1,0x01          # test problem state bit
 135 #ifdef CONFIG_CHECK_STACK
 136         jnz     1f
 137         tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 138         jnz     2f
 139         la      %r12,\psworg
 140         j       stack_overflow
 141 #else
 142         jz      2f
 143 #endif
 144 1:      lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 145 2:      aghi    %r15,-SP_SIZE           # make room for registers & psw
 146         larl    %r13,system_call
 147         lg      %r11,__LC_LAST_BREAK
 148         .endm
 149
 150         .macro  SAVE_ALL_ASYNC psworg,savearea
 151         stmg    %r11,%r15,\savearea
 152         larl    %r13,system_call
 153         lg      %r11,__LC_LAST_BREAK
 154         la      %r12,\psworg
 155         tm      \psworg+1,0x01          # test problem state bit
 156         jnz     1f                      # from user -> load kernel stack
 157         clc     \psworg+8(8),BASED(.Lcritical_end)
 158         jhe     0f
 159         clc     \psworg+8(8),BASED(.Lcritical_start)
 160         jl      0f
 161         brasl   %r14,cleanup_critical
 162         tm      1(%r12),0x01            # retest problem state after cleanup
 163         jnz     1f
 164 0:      lg      %r14,__LC_ASYNC_STACK   # are we already on the async. stack ?
 165         slgr    %r14,%r15
 166         srag    %r14,%r14,STACK_SHIFT
 167 #ifdef CONFIG_CHECK_STACK
 168         jnz     1f
 169         tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 170         jnz     2f
 171         j       stack_overflow
 172 #else
 173         jz      2f
 174 #endif
 175 1:      lg      %r15,__LC_ASYNC_STACK   # load async stack
 176 2:      aghi    %r15,-SP_SIZE           # make room for registers & psw
 177         .endm
 178
 179         .macro  CREATE_STACK_FRAME savearea
 180         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 181         stg     %r2,SP_ORIG_R2(%r15)    # store original content of gpr 2
 182         mvc     SP_R11(40,%r15),\savearea # move %r11-%r15 to stack
 183         stmg    %r0,%r10,SP_R0(%r15)    # store gprs %r0-%r10 to kernel stack
 184         .endm
 185
 186         .macro  RESTORE_ALL psworg,sync
 187         mvc     \psworg(16),SP_PSW(%r15) # move user PSW to lowcore
 188         .if !\sync
 189         ni      \psworg+1,0xfd          # clear wait state bit
 190         .endif
 191         lg      %r14,__LC_VDSO_PER_CPU
 192         lmg     %r0,%r13,SP_R0(%r15)    # load gprs 0-13 of user
 193         stpt    __LC_EXIT_TIMER
 194         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 195         lmg     %r14,%r15,SP_R14(%r15)  # load grps 14-15 of user
 196         lpswe   \psworg                 # back to caller
 197         .endm
 198
 199         .macro  LAST_BREAK
 200         srag    %r10,%r11,23
 201         jz      0f
 202         stg     %r11,__TI_last_break(%r12)
 203 0:
 204         .endm
 205
 206         .macro REENABLE_IRQS
 207         mvc     __SF_EMPTY(1,%r15),SP_PSW(%r15)
 208         ni      __SF_EMPTY(%r15),0xbf
 209         ssm     __SF_EMPTY(%r15)
 210         .endm
 211
 212         .section .kprobes.text, "ax"
 213
 214 /*
 215  * Scheduler resume function, called by switch_to
 216  *  gpr2 = (task_struct *) prev
 217  *  gpr3 = (task_struct *) next
 218  * Returns:
 219  *  gpr2 = prev
 220  */
 221 ENTRY(__switch_to)
 222         lg      %r4,__THREAD_info(%r2)          # get thread_info of prev
 223         lg      %r5,__THREAD_info(%r3)          # get thread_info of next
 224         tm      __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
 225         jz      0f
 226         ni      __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 227         oi      __TI_flags+7(%r5),_TIF_MCCK_PENDING     # set it in next
 228 0:      stmg    %r6,%r15,__SF_GPRS(%r15)        # store gprs of prev task
 229         stg     %r15,__THREAD_ksp(%r2)          # store kernel stack of prev
 230         lg      %r15,__THREAD_ksp(%r3)          # load kernel stack of next
 231         lctl    %c4,%c4,__TASK_pid(%r3)         # load pid to control reg. 4
 232         lmg     %r6,%r15,__SF_GPRS(%r15)        # load gprs of next task
 233         stg     %r3,__LC_CURRENT                # store task struct of next
 234         mvc     __LC_CURRENT_PID+4(4,%r0),__TASK_pid(%r3) # store pid of next
 235         stg     %r5,__LC_THREAD_INFO            # store thread info of next
 236         aghi    %r5,STACK_SIZE                  # end of kernel stack of next
 237         stg     %r5,__LC_KERNEL_STACK           # store end of kernel stack
 238         br      %r14
 239
 240 __critical_start:
 241 /*
 242  * SVC interrupt handler routine. System calls are synchronous events and
 243  * are executed with interrupts enabled.
 244  */
 245
 246 ENTRY(system_call)
 247         stpt    __LC_SYNC_ENTER_TIMER
 248 sysc_saveall:
 249         SAVE_ALL_SVC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 250         CREATE_STACK_FRAME __LC_SAVE_AREA
 251         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 252         mvc     SP_PSW(16,%r15),__LC_SVC_OLD_PSW
 253         mvc     SP_SVC_CODE(4,%r15),__LC_SVC_ILC
 254         oi      __TI_flags+7(%r12),_TIF_SYSCALL
 255 sysc_vtime:
 256         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 257 sysc_stime:
 258         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 259 sysc_update:
 260         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 261         LAST_BREAK
 262 sysc_do_svc:
 263         llgh    %r7,SP_SVC_CODE+2(%r15)
 264         slag    %r7,%r7,2       # shift and test for svc 0
 265         jnz     sysc_nr_ok
 266         # svc 0: system call number in %r1
 267         llgfr   %r1,%r1         # clear high word in r1
 268         cghi    %r1,NR_syscalls
 269         jnl     sysc_nr_ok
 270         sth     %r1,SP_SVC_CODE+2(%r15)
 271         slag    %r7,%r1,2       # shift and test for svc 0
 272 sysc_nr_ok:
 273         larl    %r10,sys_call_table
 274 #ifdef CONFIG_COMPAT
 275         tm      __TI_flags+5(%r12),(_TIF_31BIT>>16)  # running in 31 bit mode ?
 276         jno     sysc_noemu
 277         larl    %r10,sys_call_table_emu  # use 31 bit emulation system calls
 278 sysc_noemu:
 279 #endif
 280         tm      __TI_flags+6(%r12),_TIF_TRACE >> 8
 281         mvc     SP_ARGS(8,%r15),SP_R7(%r15)
 282         lgf     %r8,0(%r7,%r10) # load address of system call routine
 283         jnz     sysc_tracesys
 284         basr    %r14,%r8        # call sys_xxxx
 285         stg     %r2,SP_R2(%r15) # store return value (change R2 on stack)
 286
 287 sysc_return:
 288         LOCKDEP_SYS_EXIT
 289 sysc_tif:
 290         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 291         jno     sysc_restore
 292         tm      __TI_flags+7(%r12),_TIF_WORK_SVC
 293         jnz     sysc_work       # there is work to do (signals etc.)
 294         ni      __TI_flags+7(%r12),255-_TIF_SYSCALL
 295 sysc_restore:
 296         RESTORE_ALL __LC_RETURN_PSW,1
 297 sysc_done:
 298
 299 #
 300 # One of the work bits is on. Find out which one.
 301 #
 302 sysc_work:
 303         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 304         jo      sysc_mcck_pending
 305         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 306         jo      sysc_reschedule
 307         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
 308         jo      sysc_sigpending
 309         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
 310         jo      sysc_notify_resume
 311         tm      __TI_flags+7(%r12),_TIF_PER_TRAP
 312         jo      sysc_singlestep
 313         j       sysc_return             # beware of critical section cleanup
 314
 315 #
 316 # _TIF_NEED_RESCHED is set, call schedule
 317 #
 318 sysc_reschedule:
 319         larl    %r14,sysc_return
 320         jg      schedule                # return point is sysc_return
 321
 322 #
 323 # _TIF_MCCK_PENDING is set, call handler
 324 #
 325 sysc_mcck_pending:
 326         larl    %r14,sysc_return
 327         jg      s390_handle_mcck        # TIF bit will be cleared by handler
 328
 329 #
 330 # _TIF_SIGPENDING is set, call do_signal
 331 #
 332 sysc_sigpending:
 333         ni      __TI_flags+7(%r12),255-_TIF_PER_TRAP # clear TIF_PER_TRAP
 334         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 335         brasl   %r14,do_signal          # call do_signal
 336         tm      __TI_flags+7(%r12),_TIF_SYSCALL
 337         jno     sysc_return
 338         lmg     %r2,%r6,SP_R2(%r15)     # load svc arguments
 339         lghi    %r7,0                   # svc 0 returns -ENOSYS
 340         lh      %r1,SP_SVC_CODE+2(%r15) # load new svc number
 341         cghi    %r1,NR_syscalls
 342         jnl     sysc_nr_ok              # invalid svc number -> do svc 0
 343         slag    %r7,%r1,2
 344         j       sysc_nr_ok              # restart svc
 345
 346 #
 347 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 348 #
 349 sysc_notify_resume:
 350         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 351         larl    %r14,sysc_return
 352         jg      do_notify_resume        # call do_notify_resume
 353
 354 #
 355 # _TIF_PER_TRAP is set, call do_per_trap
 356 #
 357 sysc_singlestep:
 358         ni      __TI_flags+7(%r12),255-(_TIF_SYSCALL | _TIF_PER_TRAP)
 359         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 360         larl    %r14,sysc_return        # load adr. of system return
 361         jg      do_per_trap
 362
 363 #
 364 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 365 # and after the system call
 366 #
 367 sysc_tracesys:
 368         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 369         la      %r3,0
 370         llgh    %r0,SP_SVC_CODE+2(%r15)
 371         stg     %r0,SP_R2(%r15)
 372         brasl   %r14,do_syscall_trace_enter
 373         lghi    %r0,NR_syscalls
 374         clgr    %r0,%r2
 375         jnh     sysc_tracenogo
 376         sllg    %r7,%r2,2               # svc number *4
 377         lgf     %r8,0(%r7,%r10)
 378 sysc_tracego:
 379         lmg     %r3,%r6,SP_R3(%r15)
 380         mvc     SP_ARGS(8,%r15),SP_R7(%r15)
 381         lg      %r2,SP_ORIG_R2(%r15)
 382         basr    %r14,%r8                # call sys_xxx
 383         stg     %r2,SP_R2(%r15)         # store return value
 384 sysc_tracenogo:
 385         tm      __TI_flags+6(%r12),_TIF_TRACE >> 8
 386         jz      sysc_return
 387         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 388         larl    %r14,sysc_return        # return point is sysc_return
 389         jg      do_syscall_trace_exit
 390
 391 #
 392 # a new process exits the kernel with ret_from_fork
 393 #
 394 ENTRY(ret_from_fork)
 395         lg      %r13,__LC_SVC_NEW_PSW+8
 396         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 397         tm      SP_PSW+1(%r15),0x01     # forking a kernel thread ?
 398         jo      0f
 399         stg     %r15,SP_R15(%r15)       # store stack pointer for new kthread
 400 0:      brasl   %r14,schedule_tail
 401         TRACE_IRQS_ON
 402         stosm   24(%r15),0x03           # reenable interrupts
 403         j       sysc_tracenogo
 404
 405 #
 406 # kernel_execve function needs to deal with pt_regs that is not
 407 # at the usual place
 408 #
 409 ENTRY(kernel_execve)
 410         stmg    %r12,%r15,96(%r15)
 411         lgr     %r14,%r15
 412         aghi    %r15,-SP_SIZE
 413         stg     %r14,__SF_BACKCHAIN(%r15)
 414         la      %r12,SP_PTREGS(%r15)
 415         xc      0(__PT_SIZE,%r12),0(%r12)
 416         lgr     %r5,%r12
 417         brasl   %r14,do_execve
 418         ltgfr   %r2,%r2
 419         je      0f
 420         aghi    %r15,SP_SIZE
 421         lmg     %r12,%r15,96(%r15)
 422         br      %r14
 423         # execve succeeded.
 424 0:      stnsm   __SF_EMPTY(%r15),0xfc   # disable interrupts
 425         lg      %r15,__LC_KERNEL_STACK  # load ksp
 426         aghi    %r15,-SP_SIZE           # make room for registers & psw
 427         lg      %r13,__LC_SVC_NEW_PSW+8
 428         mvc     SP_PTREGS(__PT_SIZE,%r15),0(%r12)       # copy pt_regs
 429         lg      %r12,__LC_THREAD_INFO
 430         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 431         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 432         brasl   %r14,execve_tail
 433         j       sysc_return
 434
 435 /*
 436  * Program check handler routine
 437  */
 438
 439 ENTRY(pgm_check_handler)
 440 /*
 441  * First we need to check for a special case:
 442  * Single stepping an instruction that disables the PER event mask will
 443  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
 444  * For a single stepped SVC the program check handler gets control after
 445  * the SVC new PSW has been loaded. But we want to execute the SVC first and
 446  * then handle the PER event. Therefore we update the SVC old PSW to point
 447  * to the pgm_check_handler and branch to the SVC handler after we checked
 448  * if we have to load the kernel stack register.
 449  * For every other possible cause for PER event without the PER mask set
 450  * we just ignore the PER event (FIXME: is there anything we have to do
 451  * for LPSW?).
 452  */
 453         stpt    __LC_SYNC_ENTER_TIMER
 454         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
 455         jnz     pgm_per                  # got per exception -> special case
 456         SAVE_ALL_PGM __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 457         CREATE_STACK_FRAME __LC_SAVE_AREA
 458         mvc     SP_PSW(16,%r15),__LC_PGM_OLD_PSW
 459         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 460         HANDLE_SIE_INTERCEPT
 461         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 462         jz      pgm_no_vtime
 463         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 464         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 465         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 466         LAST_BREAK
 467 pgm_no_vtime:
 468         stg     %r11,SP_ARGS(%r15)
 469         lgf     %r3,__LC_PGM_ILC        # load program interruption code
 470         lg      %r4,__LC_TRANS_EXC_CODE
 471         REENABLE_IRQS
 472         lghi    %r8,0x7f
 473         ngr     %r8,%r3
 474         sll     %r8,3
 475         larl    %r1,pgm_check_table
 476         lg      %r1,0(%r8,%r1)          # load address of handler routine
 477         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 478         basr    %r14,%r1                # branch to interrupt-handler
 479 pgm_exit:
 480         j       sysc_return
 481
 482 #
 483 # handle per exception
 484 #
 485 pgm_per:
 486         tm      __LC_PGM_OLD_PSW,0x40   # test if per event recording is on
 487         jnz     pgm_per_std             # ok, normal per event from user space
 488 # ok its one of the special cases, now we need to find out which one
 489         clc     __LC_PGM_OLD_PSW(16),__LC_SVC_NEW_PSW
 490         je      pgm_svcper
 491 # no interesting special case, ignore PER event
 492         lpswe   __LC_PGM_OLD_PSW
 493
 494 #
 495 # Normal per exception
 496 #
 497 pgm_per_std:
 498         SAVE_ALL_PGM __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 499         CREATE_STACK_FRAME __LC_SAVE_AREA
 500         mvc     SP_PSW(16,%r15),__LC_PGM_OLD_PSW
 501         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 502         HANDLE_SIE_INTERCEPT
 503         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 504         jz      pgm_no_vtime2
 505         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 506         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 507         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 508         LAST_BREAK
 509 pgm_no_vtime2:
 510         lg      %r1,__TI_task(%r12)
 511         tm      SP_PSW+1(%r15),0x01     # kernel per event ?
 512         jz      kernel_per
 513         mvc     __THREAD_per_cause(2,%r1),__LC_PER_CAUSE
 514         mvc     __THREAD_per_address(8,%r1),__LC_PER_ADDRESS
 515         mvc     __THREAD_per_paid(1,%r1),__LC_PER_PAID
 516         oi      __TI_flags+7(%r12),_TIF_PER_TRAP # set TIF_PER_TRAP
 517         lgf     %r3,__LC_PGM_ILC        # load program interruption code
 518         lg      %r4,__LC_TRANS_EXC_CODE
 519         REENABLE_IRQS
 520         lghi    %r8,0x7f
 521         ngr     %r8,%r3                 # clear per-event-bit and ilc
 522         je      pgm_exit2
 523         sll     %r8,3
 524         larl    %r1,pgm_check_table
 525         lg      %r1,0(%r8,%r1)          # load address of handler routine
 526         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 527         basr    %r14,%r1                # branch to interrupt-handler
 528 pgm_exit2:
 529         j       sysc_return
 530
 531 #
 532 # it was a single stepped SVC that is causing all the trouble
 533 #
 534 pgm_svcper:
 535         SAVE_ALL_PGM __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 536         CREATE_STACK_FRAME __LC_SAVE_AREA
 537         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 538         mvc     SP_PSW(16,%r15),__LC_SVC_OLD_PSW
 539         mvc     SP_SVC_CODE(4,%r15),__LC_SVC_ILC
 540         oi      __TI_flags+7(%r12),(_TIF_SYSCALL | _TIF_PER_TRAP)
 541         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 542         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 543         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 544         LAST_BREAK
 545         lg      %r8,__TI_task(%r12)
 546         mvc     __THREAD_per_cause(2,%r8),__LC_PER_CAUSE
 547         mvc     __THREAD_per_address(8,%r8),__LC_PER_ADDRESS
 548         mvc     __THREAD_per_paid(1,%r8),__LC_PER_PAID
 549         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 550         lmg     %r2,%r6,SP_R2(%r15)     # load svc arguments
 551         j       sysc_do_svc
 552
 553 #
 554 # per was called from kernel, must be kprobes
 555 #
 556 kernel_per:
 557         REENABLE_IRQS
 558         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 559         brasl   %r14,do_per_trap
 560         j       pgm_exit
 561
 562 /*
 563  * IO interrupt handler routine
 564  */
 565 ENTRY(io_int_handler)
 566         stck    __LC_INT_CLOCK
 567         stpt    __LC_ASYNC_ENTER_TIMER
 568         SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+40
 569         CREATE_STACK_FRAME __LC_SAVE_AREA+40
 570         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
 571         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 572         HANDLE_SIE_INTERCEPT
 573         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 574         jz      io_no_vtime
 575         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 576         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 577         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 578         LAST_BREAK
 579 io_no_vtime:
 580         TRACE_IRQS_OFF
 581         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 582         brasl   %r14,do_IRQ             # call standard irq handler
 583 io_return:
 584         LOCKDEP_SYS_EXIT
 585         TRACE_IRQS_ON
 586 io_tif:
 587         tm      __TI_flags+7(%r12),_TIF_WORK_INT
 588         jnz     io_work                 # there is work to do (signals etc.)
 589 io_restore:
 590         RESTORE_ALL __LC_RETURN_PSW,0
 591 io_done:
 592
 593 #
 594 # There is work todo, find out in which context we have been interrupted:
 595 # 1) if we return to user space we can do all _TIF_WORK_INT work
 596 # 2) if we return to kernel code and kvm is enabled check if we need to
 597 #    modify the psw to leave SIE
 598 # 3) if we return to kernel code and preemptive scheduling is enabled check
 599 #    the preemption counter and if it is zero call preempt_schedule_irq
 600 # Before any work can be done, a switch to the kernel stack is required.
 601 #
 602 io_work:
 603         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 604         jo      io_work_user            # yes -> do resched & signal
 605 #ifdef CONFIG_PREEMPT
 606         # check for preemptive scheduling
 607         icm     %r0,15,__TI_precount(%r12)
 608         jnz     io_restore              # preemption is disabled
 609         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 610         jno     io_restore
 611         # switch to kernel stack
 612         lg      %r1,SP_R15(%r15)
 613         aghi    %r1,-SP_SIZE
 614         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 615         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 616         lgr     %r15,%r1
 617         # TRACE_IRQS_ON already done at io_return, call
 618         # TRACE_IRQS_OFF to keep things symmetrical
 619         TRACE_IRQS_OFF
 620         brasl   %r14,preempt_schedule_irq
 621         j       io_return
 622 #else
 623         j       io_restore
 624 #endif
 625
 626 #
 627 # Need to do work before returning to userspace, switch to kernel stack
 628 #
 629 io_work_user:
 630         lg      %r1,__LC_KERNEL_STACK
 631         aghi    %r1,-SP_SIZE
 632         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 633         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 634         lgr     %r15,%r1
 635
 636 #
 637 # One of the work bits is on. Find out which one.
 638 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
 639 #              and _TIF_MCCK_PENDING
 640 #
 641 io_work_tif:
 642         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 643         jo      io_mcck_pending
 644         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 645         jo      io_reschedule
 646         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
 647         jo      io_sigpending
 648         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
 649         jo      io_notify_resume
 650         j       io_return               # beware of critical section cleanup
 651
 652 #
 653 # _TIF_MCCK_PENDING is set, call handler
 654 #
 655 io_mcck_pending:
 656         # TRACE_IRQS_ON already done at io_return
 657         brasl   %r14,s390_handle_mcck   # TIF bit will be cleared by handler
 658         TRACE_IRQS_OFF
 659         j       io_return
 660
 661 #
 662 # _TIF_NEED_RESCHED is set, call schedule
 663 #
 664 io_reschedule:
 665         # TRACE_IRQS_ON already done at io_return
 666         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 667         brasl   %r14,schedule           # call scheduler
 668         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 669         TRACE_IRQS_OFF
 670         j       io_return
 671
 672 #
 673 # _TIF_SIGPENDING or is set, call do_signal
 674 #
 675 io_sigpending:
 676         # TRACE_IRQS_ON already done at io_return
 677         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 678         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 679         brasl   %r14,do_signal          # call do_signal
 680         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 681         TRACE_IRQS_OFF
 682         j       io_return
 683
 684 #
 685 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
 686 #
 687 io_notify_resume:
 688         # TRACE_IRQS_ON already done at io_return
 689         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 690         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 691         brasl   %r14,do_notify_resume   # call do_notify_resume
 692         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 693         TRACE_IRQS_OFF
 694         j       io_return
 695
 696 /*
 697  * External interrupt handler routine
 698  */
 699 ENTRY(ext_int_handler)
 700         stck    __LC_INT_CLOCK
 701         stpt    __LC_ASYNC_ENTER_TIMER
 702         SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+40
 703         CREATE_STACK_FRAME __LC_SAVE_AREA+40
 704         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
 705         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 706         HANDLE_SIE_INTERCEPT
 707         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 708         jz      ext_no_vtime
 709         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 710         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 711         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 712         LAST_BREAK
 713 ext_no_vtime:
 714         TRACE_IRQS_OFF
 715         lghi    %r1,4096
 716         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 717         llgf    %r3,__LC_CPU_ADDRESS    # get cpu address + interruption code
 718         llgf    %r4,__LC_EXT_PARAMS     # get external parameter
 719         lg      %r5,__LC_EXT_PARAMS2-4096(%r1)  # get 64 bit external parameter
 720         brasl   %r14,do_extint
 721         j       io_return
 722
 723 __critical_end:
 724
 725 /*
 726  * Machine check handler routines
 727  */
 728 ENTRY(mcck_int_handler)
 729         stck    __LC_MCCK_CLOCK
 730         la      %r1,4095                # revalidate r1
 731         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
 732         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
 733         stmg    %r11,%r15,__LC_SAVE_AREA+80
 734         larl    %r13,system_call
 735         lg      %r11,__LC_LAST_BREAK
 736         la      %r12,__LC_MCK_OLD_PSW
 737         tm      __LC_MCCK_CODE,0x80     # system damage?
 738         jo      mcck_int_main           # yes -> rest of mcck code invalid
 739         la      %r14,4095
 740         mvc     __LC_MCCK_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA-4095(%r14)
 741         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 742         jo      1f
 743         la      %r14,__LC_SYNC_ENTER_TIMER
 744         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 745         jl      0f
 746         la      %r14,__LC_ASYNC_ENTER_TIMER
 747 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 748         jl      0f
 749         la      %r14,__LC_EXIT_TIMER
 750 0:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 751         jl      0f
 752         la      %r14,__LC_LAST_UPDATE_TIMER
 753 0:      spt     0(%r14)
 754         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 755 1:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 756         jno     mcck_int_main           # no -> skip cleanup critical
 757         tm      __LC_MCK_OLD_PSW+1,0x01 # test problem state bit
 758         jnz     mcck_int_main           # from user -> load kernel stack
 759         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_end)
 760         jhe     mcck_int_main
 761         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_start)
 762         jl      mcck_int_main
 763         brasl   %r14,cleanup_critical
 764 mcck_int_main:
 765         lg      %r14,__LC_PANIC_STACK   # are we already on the panic stack?
 766         slgr    %r14,%r15
 767         srag    %r14,%r14,PAGE_SHIFT
 768         jz      0f
 769         lg      %r15,__LC_PANIC_STACK   # load panic stack
 770 0:      aghi    %r15,-SP_SIZE           # make room for registers & psw
 771         CREATE_STACK_FRAME __LC_SAVE_AREA+80
 772         mvc     SP_PSW(16,%r15),0(%r12)
 773         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 774         tm      __LC_MCCK_CODE+2,0x08   # mwp of old psw valid?
 775         jno     mcck_no_vtime           # no -> no timer update
 776         HANDLE_SIE_INTERCEPT
 777         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 778         jz      mcck_no_vtime
 779         UPDATE_VTIME __LC_EXIT_TIMER,__LC_MCCK_ENTER_TIMER,__LC_USER_TIMER
 780         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 781         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_MCCK_ENTER_TIMER
 782         LAST_BREAK
 783 mcck_no_vtime:
 784         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 785         brasl   %r14,s390_do_machine_check
 786         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 787         jno     mcck_return
 788         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
 789         aghi    %r1,-SP_SIZE
 790         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 791         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 792         lgr     %r15,%r1
 793         stosm   __SF_EMPTY(%r15),0x04   # turn dat on
 794         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 795         jno     mcck_return
 796         TRACE_IRQS_OFF
 797         brasl   %r14,s390_handle_mcck
 798         TRACE_IRQS_ON
 799 mcck_return:
 800         mvc     __LC_RETURN_MCCK_PSW(16),SP_PSW(%r15) # move return PSW
 801         ni      __LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
 802         lmg     %r0,%r15,SP_R0(%r15)    # load gprs 0-15
 803         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 804         jno     0f
 805         stpt    __LC_EXIT_TIMER
 806 0:      lpswe   __LC_RETURN_MCCK_PSW    # back to caller
 807 mcck_done:
 808
 809 /*
 810  * Restart interruption handler, kick starter for additional CPUs
 811  */
 812 #ifdef CONFIG_SMP
 813         __CPUINIT
 814 ENTRY(restart_int_handler)
 815         basr    %r1,0
 816 restart_base:
 817         spt     restart_vtime-restart_base(%r1)
 818         stck    __LC_LAST_UPDATE_CLOCK
 819         mvc     __LC_LAST_UPDATE_TIMER(8),restart_vtime-restart_base(%r1)
 820         mvc     __LC_EXIT_TIMER(8),restart_vtime-restart_base(%r1)
 821         lg      %r15,__LC_SAVE_AREA+120 # load ksp
 822         lghi    %r10,__LC_CREGS_SAVE_AREA
 823         lctlg   %c0,%c15,0(%r10) # get new ctl regs
 824         lghi    %r10,__LC_AREGS_SAVE_AREA
 825         lam     %a0,%a15,0(%r10)
 826         lmg     %r6,%r15,__SF_GPRS(%r15) # load registers from clone
 827         lg      %r1,__LC_THREAD_INFO
 828         mvc     __LC_USER_TIMER(8),__TI_user_timer(%r1)
 829         mvc     __LC_SYSTEM_TIMER(8),__TI_system_timer(%r1)
 830         xc      __LC_STEAL_TIMER(8),__LC_STEAL_TIMER
 831         stosm   __SF_EMPTY(%r15),0x04   # now we can turn dat on
 832         brasl   %r14,start_secondary
 833         .align  8
 834 restart_vtime:
 835         .long   0x7fffffff,0xffffffff
 836         .previous
 837 #else
 838 /*
 839  * If we do not run with SMP enabled, let the new CPU crash ...
 840  */
 841 ENTRY(restart_int_handler)
 842         basr    %r1,0
 843 restart_base:
 844         lpswe   restart_crash-restart_base(%r1)
 845         .align 8
 846 restart_crash:
 847         .long  0x000a0000,0x00000000,0x00000000,0x00000000
 848 restart_go:
 849 #endif
 850
 851 #
 852 # PSW restart interrupt handler
 853 #
 854 ENTRY(psw_restart_int_handler)
 855         stg     %r15,__LC_SAVE_AREA+120(%r0)    # save r15
 856         larl    %r15,restart_stack              # load restart stack
 857         lg      %r15,0(%r15)
 858         aghi    %r15,-SP_SIZE                   # make room for pt_regs
 859         stmg    %r0,%r14,SP_R0(%r15)            # store gprs %r0-%r14 to stack
 860         mvc     SP_R15(8,%r15),__LC_SAVE_AREA+120(%r0)# store saved %r15 to stack
 861         mvc     SP_PSW(16,%r15),__LC_RST_OLD_PSW(%r0)# store restart old psw
 862         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15) # set backchain to 0
 863         brasl   %r14,do_restart
 864
 865         larl    %r14,restart_psw_crash          # load disabled wait PSW if
 866         lpswe   0(%r14)                         # do_restart returns
 867         .align 8
 868 restart_psw_crash:
 869         .quad   0x0002000080000000,0x0000000000000000 + restart_psw_crash
 870
 871         .section .kprobes.text, "ax"
 872
 873 #ifdef CONFIG_CHECK_STACK
 874 /*
 875  * The synchronous or the asynchronous stack overflowed. We are dead.
 876  * No need to properly save the registers, we are going to panic anyway.
 877  * Setup a pt_regs so that show_trace can provide a good call trace.
 878  */
 879 stack_overflow:
 880         lg      %r15,__LC_PANIC_STACK   # change to panic stack
 881         aghi    %r15,-SP_SIZE
 882         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
 883         stmg    %r0,%r10,SP_R0(%r15)    # store gprs %r0-%r10 to kernel stack
 884         la      %r1,__LC_SAVE_AREA
 885         chi     %r12,__LC_SVC_OLD_PSW
 886         je      0f
 887         chi     %r12,__LC_PGM_OLD_PSW
 888         je      0f
 889         la      %r1,__LC_SAVE_AREA+40
 890 0:      mvc     SP_R11(40,%r15),0(%r1)  # move %r11-%r15 to stack
 891         mvc     SP_ARGS(8,%r15),__LC_LAST_BREAK
 892         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15) # clear back chain
 893         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 894         jg      kernel_stack_overflow
 895 #endif
 896
 897 cleanup_table_system_call:
 898         .quad   system_call, sysc_do_svc
 899 cleanup_table_sysc_tif:
 900         .quad   sysc_tif, sysc_restore
 901 cleanup_table_sysc_restore:
 902         .quad   sysc_restore, sysc_done
 903 cleanup_table_io_tif:
 904         .quad   io_tif, io_restore
 905 cleanup_table_io_restore:
 906         .quad   io_restore, io_done
 907
 908 cleanup_critical:
 909         clc     8(8,%r12),BASED(cleanup_table_system_call)
 910         jl      0f
 911         clc     8(8,%r12),BASED(cleanup_table_system_call+8)
 912         jl      cleanup_system_call
 913 0:
 914         clc     8(8,%r12),BASED(cleanup_table_sysc_tif)
 915         jl      0f
 916         clc     8(8,%r12),BASED(cleanup_table_sysc_tif+8)
 917         jl      cleanup_sysc_tif
 918 0:
 919         clc     8(8,%r12),BASED(cleanup_table_sysc_restore)
 920         jl      0f
 921         clc     8(8,%r12),BASED(cleanup_table_sysc_restore+8)
 922         jl      cleanup_sysc_restore
 923 0:
 924         clc     8(8,%r12),BASED(cleanup_table_io_tif)
 925         jl      0f
 926         clc     8(8,%r12),BASED(cleanup_table_io_tif+8)
 927         jl      cleanup_io_tif
 928 0:
 929         clc     8(8,%r12),BASED(cleanup_table_io_restore)
 930         jl      0f
 931         clc     8(8,%r12),BASED(cleanup_table_io_restore+8)
 932         jl      cleanup_io_restore
 933 0:
 934         br      %r14
 935
 936 cleanup_system_call:
 937         mvc     __LC_RETURN_PSW(16),0(%r12)
 938         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+8)
 939         jh      0f
 940         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
 941         cghi    %r12,__LC_MCK_OLD_PSW
 942         je      0f
 943         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 944 0:      cghi    %r12,__LC_MCK_OLD_PSW
 945         la      %r12,__LC_SAVE_AREA+80
 946         je      0f
 947         la      %r12,__LC_SAVE_AREA+40
 948 0:      clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+16)
 949         jhe     cleanup_vtime
 950         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn)
 951         jh      0f
 952         mvc     __LC_SAVE_AREA(40),0(%r12)
 953 0:      lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 954         aghi    %r15,-SP_SIZE           # make room for registers & psw
 955         stg     %r15,32(%r12)
 956         stg     %r11,0(%r12)
 957         CREATE_STACK_FRAME __LC_SAVE_AREA
 958         mvc     8(8,%r12),__LC_THREAD_INFO
 959         lg      %r12,__LC_THREAD_INFO
 960         mvc     SP_PSW(16,%r15),__LC_SVC_OLD_PSW
 961         mvc     SP_SVC_CODE(4,%r15),__LC_SVC_ILC
 962         oi      __TI_flags+7(%r12),_TIF_SYSCALL
 963 cleanup_vtime:
 964         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+24)
 965         jhe     cleanup_stime
 966         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 967 cleanup_stime:
 968         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+32)
 969         jh      cleanup_update
 970         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 971 cleanup_update:
 972         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 973         srag    %r12,%r11,23
 974         lg      %r12,__LC_THREAD_INFO
 975         jz      0f
 976         stg     %r11,__TI_last_break(%r12)
 977 0:      mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_system_call+8)
 978         la      %r12,__LC_RETURN_PSW
 979         br      %r14
 980 cleanup_system_call_insn:
 981         .quad   sysc_saveall
 982         .quad   system_call
 983         .quad   sysc_vtime
 984         .quad   sysc_stime
 985         .quad   sysc_update
 986
 987 cleanup_sysc_tif:
 988         mvc     __LC_RETURN_PSW(8),0(%r12)
 989         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_sysc_tif)
 990         la      %r12,__LC_RETURN_PSW
 991         br      %r14
 992
 993 cleanup_sysc_restore:
 994         clc     8(8,%r12),BASED(cleanup_sysc_restore_insn)
 995         je      2f
 996         clc     8(8,%r12),BASED(cleanup_sysc_restore_insn+8)
 997         jhe     0f
 998         mvc     __LC_EXIT_TIMER(8),__LC_MCCK_ENTER_TIMER
 999         cghi    %r12,__LC_MCK_OLD_PSW
1000         je      0f
1001         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
1002 0:      mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
1003         cghi    %r12,__LC_MCK_OLD_PSW
1004         la      %r12,__LC_SAVE_AREA+80
1005         je      1f
1006         la      %r12,__LC_SAVE_AREA+40
1007 1:      mvc     0(40,%r12),SP_R11(%r15)
1008         lmg     %r0,%r10,SP_R0(%r15)
1009         lg      %r15,SP_R15(%r15)
1010 2:      la      %r12,__LC_RETURN_PSW
1011         br      %r14
1012 cleanup_sysc_restore_insn:
1013         .quad   sysc_done - 4
1014         .quad   sysc_done - 16
1015
1016 cleanup_io_tif:
1017         mvc     __LC_RETURN_PSW(8),0(%r12)
1018         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_io_tif)
1019         la      %r12,__LC_RETURN_PSW
1020         br      %r14
1021
1022 cleanup_io_restore:
1023         clc     8(8,%r12),BASED(cleanup_io_restore_insn)
1024         je      1f
1025         clc     8(8,%r12),BASED(cleanup_io_restore_insn+8)
1026         jhe     0f
1027         mvc     __LC_EXIT_TIMER(8),__LC_MCCK_ENTER_TIMER
1028 0:      mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
1029         mvc     __LC_SAVE_AREA+80(40),SP_R11(%r15)
1030         lmg     %r0,%r10,SP_R0(%r15)
1031         lg      %r15,SP_R15(%r15)
1032 1:      la      %r12,__LC_RETURN_PSW
1033         br      %r14
1034 cleanup_io_restore_insn:
1035         .quad   io_done - 4
1036         .quad   io_done - 16
1037
1038 /*
1039  * Integer constants
1040  */
1041                 .align  4
1042 .Lcritical_start:
1043                 .quad   __critical_start
1044 .Lcritical_end:
1045                 .quad   __critical_end
1046
1047 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
1048 /*
1049  * sie64a calling convention:
1050  * %r2 pointer to sie control block
1051  * %r3 guest register save area
1052  */
1053 ENTRY(sie64a)
1054         stmg    %r6,%r14,__SF_GPRS(%r15)        # save kernel registers
1055         stg     %r2,__SF_EMPTY(%r15)            # save control block pointer
1056         stg     %r3,__SF_EMPTY+8(%r15)          # save guest register save area
1057         lmg     %r0,%r13,0(%r3)                 # load guest gprs 0-13
1058         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
1059         oi      __TI_flags+6(%r14),_TIF_SIE>>8
1060 sie_loop:
1061         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
1062         tm      __TI_flags+7(%r14),_TIF_EXIT_SIE
1063         jnz     sie_exit
1064         lg      %r14,__LC_GMAP                  # get gmap pointer
1065         ltgr    %r14,%r14
1066         jz      sie_gmap
1067         lctlg   %c1,%c1,__GMAP_ASCE(%r14)       # load primary asce
1068 sie_gmap:
1069         lg      %r14,__SF_EMPTY(%r15)           # get control block pointer
1070         SPP     __SF_EMPTY(%r15)                # set guest id
1071         sie     0(%r14)
1072 sie_done:
1073         SPP     __LC_CMF_HPP                    # set host id
1074         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
1075 sie_exit:
1076         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
1077         ni      __TI_flags+6(%r14),255-(_TIF_SIE>>8)
1078         lg      %r14,__SF_EMPTY+8(%r15)         # load guest register save area
1079         stmg    %r0,%r13,0(%r14)                # save guest gprs 0-13
1080         lmg     %r6,%r14,__SF_GPRS(%r15)        # restore kernel registers
1081         lghi    %r2,0
1082         br      %r14
1083 sie_fault:
1084         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
1085         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
1086         ni      __TI_flags+6(%r14),255-(_TIF_SIE>>8)
1087         lg      %r14,__SF_EMPTY+8(%r15)         # load guest register save area
1088         stmg    %r0,%r13,0(%r14)                # save guest gprs 0-13
1089         lmg     %r6,%r14,__SF_GPRS(%r15)        # restore kernel registers
1090         lghi    %r2,-EFAULT
1091         br      %r14
1092
1093         .align  8
1094 .Lsie_loop:
1095         .quad   sie_loop
1096 .Lsie_done:
1097         .quad   sie_done
1098
1099         .section __ex_table,"a"
1100         .quad   sie_loop,sie_fault
1101         .previous
1102 #endif
1103
1104                 .section .rodata, "a"
1105 #define SYSCALL(esa,esame,emu)  .long esame
1106         .globl  sys_call_table
1107 sys_call_table:
1108 #include "syscalls.S"
1109 #undef SYSCALL
1110
1111 #ifdef CONFIG_COMPAT
1112
1113 #define SYSCALL(esa,esame,emu)  .long emu
1114 sys_call_table_emu:
1115 #include "syscalls.S"
1116 #undef SYSCALL
1117 #endif