arch/s390/kernel/entry64.S

   1 /*
   2  *  arch/s390/kernel/entry64.S
   3  *    S390 low-level entry points.
   4  *
   5  *    Copyright (C) IBM Corp. 1999,2006
   6  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   7  *               Hartmut Penner (hp@de.ibm.com),
   8  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
  10  */
  11
  12 #include <linux/sys.h>
  13 #include <linux/linkage.h>
  14 #include <linux/config.h>
  15 #include <asm/cache.h>
  16 #include <asm/lowcore.h>
  17 #include <asm/errno.h>
  18 #include <asm/ptrace.h>
  19 #include <asm/thread_info.h>
  20 #include <asm/asm-offsets.h>
  21 #include <asm/unistd.h>
  22 #include <asm/page.h>
  23
  24 /*
  25  * Stack layout for the system_call stack entry.
  26  * The first few entries are identical to the user_regs_struct.
  27  */
  28 SP_PTREGS    =  STACK_FRAME_OVERHEAD
  29 SP_ARGS      =  STACK_FRAME_OVERHEAD + __PT_ARGS
  30 SP_PSW       =  STACK_FRAME_OVERHEAD + __PT_PSW
  31 SP_R0        =  STACK_FRAME_OVERHEAD + __PT_GPRS
  32 SP_R1        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 8
  33 SP_R2        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 16
  34 SP_R3        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 24
  35 SP_R4        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 32
  36 SP_R5        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 40
  37 SP_R6        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 48
  38 SP_R7        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 56
  39 SP_R8        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 64
  40 SP_R9        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 72
  41 SP_R10       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 80
  42 SP_R11       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 88
  43 SP_R12       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 96
  44 SP_R13       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 104
  45 SP_R14       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 112
  46 SP_R15       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 120
  47 SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
  48 SP_ILC       =  STACK_FRAME_OVERHEAD + __PT_ILC
  49 SP_TRAP      =  STACK_FRAME_OVERHEAD + __PT_TRAP
  50 SP_SIZE      =  STACK_FRAME_OVERHEAD + __PT_SIZE
  51
  52 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  53 STACK_SIZE  = 1 << STACK_SHIFT
  54
  55 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_RESTORE_SIGMASK | _TIF_NEED_RESCHED | \
  56                  _TIF_MCCK_PENDING | _TIF_RESTART_SVC | _TIF_SINGLE_STEP )
  57 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_RESTORE_SIGMASK | _TIF_NEED_RESCHED | \
  58                  _TIF_MCCK_PENDING)
  59
  60 #define BASED(name) name-system_call(%r13)
  61
  62         .macro  STORE_TIMER lc_offset
  63 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  64         stpt    \lc_offset
  65 #endif
  66         .endm
  67
  68 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  69         .macro  UPDATE_VTIME lc_from,lc_to,lc_sum
  70         lg      %r10,\lc_from
  71         slg     %r10,\lc_to
  72         alg     %r10,\lc_sum
  73         stg     %r10,\lc_sum
  74         .endm
  75 #endif
  76
  77 /*
  78  * Register usage in interrupt handlers:
  79  *    R9  - pointer to current task structure
  80  *    R13 - pointer to literal pool
  81  *    R14 - return register for function calls
  82  *    R15 - kernel stack pointer
  83  */
  84
  85         .macro  SAVE_ALL_BASE savearea
  86         stmg    %r12,%r15,\savearea
  87         larl    %r13,system_call
  88         .endm
  89
  90         .macro  SAVE_ALL_SYNC psworg,savearea
  91         la      %r12,\psworg
  92         tm      \psworg+1,0x01          # test problem state bit
  93         jz      2f                      # skip stack setup save
  94         lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
  95 #ifdef CONFIG_CHECK_STACK
  96         j       3f
  97 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
  98         jz      stack_overflow
  99 3:
 100 #endif
 101 2:
 102         .endm
 103
 104         .macro  SAVE_ALL_ASYNC psworg,savearea
 105         la      %r12,\psworg
 106         tm      \psworg+1,0x01          # test problem state bit
 107         jnz     1f                      # from user -> load kernel stack
 108         clc     \psworg+8(8),BASED(.Lcritical_end)
 109         jhe     0f
 110         clc     \psworg+8(8),BASED(.Lcritical_start)
 111         jl      0f
 112         brasl   %r14,cleanup_critical
 113         tm      1(%r12),0x01            # retest problem state after cleanup
 114         jnz     1f
 115 0:      lg      %r14,__LC_ASYNC_STACK   # are we already on the async. stack ?
 116         slgr    %r14,%r15
 117         srag    %r14,%r14,STACK_SHIFT
 118         jz      2f
 119 1:      lg      %r15,__LC_ASYNC_STACK   # load async stack
 120 #ifdef CONFIG_CHECK_STACK
 121         j       3f
 122 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 123         jz      stack_overflow
 124 3:
 125 #endif
 126 2:
 127         .endm
 128
 129         .macro  CREATE_STACK_FRAME psworg,savearea
 130         aghi    %r15,-SP_SIZE           # make room for registers & psw
 131         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
 132         la      %r12,\psworg
 133         stg     %r2,SP_ORIG_R2(%r15)    # store original content of gpr 2
 134         icm     %r12,12,__LC_SVC_ILC
 135         stmg    %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 136         st      %r12,SP_ILC(%r15)
 137         mvc     SP_R12(32,%r15),\savearea # move %r12-%r15 to stack
 138         la      %r12,0
 139         stg     %r12,__SF_BACKCHAIN(%r15)
 140         .endm
 141
 142         .macro  RESTORE_ALL psworg,sync
 143         mvc     \psworg(16),SP_PSW(%r15) # move user PSW to lowcore
 144         .if !\sync
 145         ni      \psworg+1,0xfd          # clear wait state bit
 146         .endif
 147         lmg     %r0,%r15,SP_R0(%r15)    # load gprs 0-15 of user
 148         STORE_TIMER __LC_EXIT_TIMER
 149         lpswe   \psworg                 # back to caller
 150         .endm
 151
 152 /*
 153  * Scheduler resume function, called by switch_to
 154  *  gpr2 = (task_struct *) prev
 155  *  gpr3 = (task_struct *) next
 156  * Returns:
 157  *  gpr2 = prev
 158  */
 159         .globl  __switch_to
 160 __switch_to:
 161         tm      __THREAD_per+4(%r3),0xe8 # is the new process using per ?
 162         jz      __switch_to_noper               # if not we're fine
 163         stctg   %c9,%c11,__SF_EMPTY(%r15)# We are using per stuff
 164         clc     __THREAD_per(24,%r3),__SF_EMPTY(%r15)
 165         je      __switch_to_noper            # we got away without bashing TLB's
 166         lctlg   %c9,%c11,__THREAD_per(%r3)      # Nope we didn't
 167 __switch_to_noper:
 168         lg      %r4,__THREAD_info(%r2)              # get thread_info of prev
 169         tm      __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
 170         jz      __switch_to_no_mcck
 171         ni      __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 172         lg      %r4,__THREAD_info(%r3)              # get thread_info of next
 173         oi      __TI_flags+7(%r4),_TIF_MCCK_PENDING # set it in next
 174 __switch_to_no_mcck:
 175         stmg    %r6,%r15,__SF_GPRS(%r15)# store __switch_to registers of prev task
 176         stg     %r15,__THREAD_ksp(%r2)  # store kernel stack to prev->tss.ksp
 177         lg      %r15,__THREAD_ksp(%r3)  # load kernel stack from next->tss.ksp
 178         lmg     %r6,%r15,__SF_GPRS(%r15)# load __switch_to registers of next task
 179         stg     %r3,__LC_CURRENT        # __LC_CURRENT = current task struct
 180         lctl    %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
 181         lg      %r3,__THREAD_info(%r3)  # load thread_info from task struct
 182         stg     %r3,__LC_THREAD_INFO
 183         aghi    %r3,STACK_SIZE
 184         stg     %r3,__LC_KERNEL_STACK   # __LC_KERNEL_STACK = new kernel stack
 185         br      %r14
 186
 187 __critical_start:
 188 /*
 189  * SVC interrupt handler routine. System calls are synchronous events and
 190  * are executed with interrupts enabled.
 191  */
 192
 193         .globl  system_call
 194 system_call:
 195         STORE_TIMER __LC_SYNC_ENTER_TIMER
 196 sysc_saveall:
 197         SAVE_ALL_BASE __LC_SAVE_AREA
 198         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 199         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 200         llgh    %r7,__LC_SVC_INT_CODE # get svc number from lowcore
 201 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 202 sysc_vtime:
 203         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 204         jz      sysc_do_svc
 205         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 206 sysc_stime:
 207         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 208 sysc_update:
 209         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 210 #endif
 211 sysc_do_svc:
 212         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 213         slag    %r7,%r7,2         # *4 and test for svc 0
 214         jnz     sysc_nr_ok
 215         # svc 0: system call number in %r1
 216         cl      %r1,BASED(.Lnr_syscalls)
 217         jnl     sysc_nr_ok
 218         lgfr    %r7,%r1           # clear high word in r1
 219         slag    %r7,%r7,2         # svc 0: system call number in %r1
 220 sysc_nr_ok:
 221         mvc     SP_ARGS(8,%r15),SP_R7(%r15)
 222 sysc_do_restart:
 223         larl    %r10,sys_call_table
 224 #ifdef CONFIG_COMPAT
 225         tm      __TI_flags+5(%r9),(_TIF_31BIT>>16)  # running in 31 bit mode ?
 226         jno     sysc_noemu
 227         larl    %r10,sys_call_table_emu  # use 31 bit emulation system calls
 228 sysc_noemu:
 229 #endif
 230         tm      __TI_flags+7(%r9),(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT)
 231         lgf     %r8,0(%r7,%r10)   # load address of system call routine
 232         jnz     sysc_tracesys
 233         basr    %r14,%r8          # call sys_xxxx
 234         stg     %r2,SP_R2(%r15)   # store return value (change R2 on stack)
 235                                   # ATTENTION: check sys_execve_glue before
 236                                   # changing anything here !!
 237
 238 sysc_return:
 239         tm      SP_PSW+1(%r15),0x01    # returning to user ?
 240         jno     sysc_leave
 241         tm      __TI_flags+7(%r9),_TIF_WORK_SVC
 242         jnz     sysc_work         # there is work to do (signals etc.)
 243 sysc_leave:
 244         RESTORE_ALL __LC_RETURN_PSW,1
 245
 246 #
 247 # recheck if there is more work to do
 248 #
 249 sysc_work_loop:
 250         tm      __TI_flags+7(%r9),_TIF_WORK_SVC
 251         jz      sysc_leave        # there is no work to do
 252 #
 253 # One of the work bits is on. Find out which one.
 254 #
 255 sysc_work:
 256         tm      __TI_flags+7(%r9),_TIF_MCCK_PENDING
 257         jo      sysc_mcck_pending
 258         tm      __TI_flags+7(%r9),_TIF_NEED_RESCHED
 259         jo      sysc_reschedule
 260         tm      __TI_flags+7(%r9),(_TIF_SIGPENDING | _TIF_RESTORE_SIGMASK)
 261         jnz     sysc_sigpending
 262         tm      __TI_flags+7(%r9),_TIF_RESTART_SVC
 263         jo      sysc_restart
 264         tm      __TI_flags+7(%r9),_TIF_SINGLE_STEP
 265         jo      sysc_singlestep
 266         j       sysc_leave
 267
 268 #
 269 # _TIF_NEED_RESCHED is set, call schedule
 270 #
 271 sysc_reschedule:
 272         larl    %r14,sysc_work_loop
 273         jg      schedule            # return point is sysc_return
 274
 275 #
 276 # _TIF_MCCK_PENDING is set, call handler
 277 #
 278 sysc_mcck_pending:
 279         larl    %r14,sysc_work_loop
 280         jg      s390_handle_mcck    # TIF bit will be cleared by handler
 281
 282 #
 283 # _TIF_SIGPENDING or _TIF_RESTORE_SIGMASK is set, call do_signal
 284 #
 285 sysc_sigpending:
 286         ni      __TI_flags+7(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 287         la      %r2,SP_PTREGS(%r15) # load pt_regs
 288         brasl   %r14,do_signal    # call do_signal
 289         tm      __TI_flags+7(%r9),_TIF_RESTART_SVC
 290         jo      sysc_restart
 291         tm      __TI_flags+7(%r9),_TIF_SINGLE_STEP
 292         jo      sysc_singlestep
 293         j       sysc_work_loop
 294
 295 #
 296 # _TIF_RESTART_SVC is set, set up registers and restart svc
 297 #
 298 sysc_restart:
 299         ni      __TI_flags+7(%r9),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
 300         lg      %r7,SP_R2(%r15)        # load new svc number
 301         slag    %r7,%r7,2              # *4
 302         mvc     SP_R2(8,%r15),SP_ORIG_R2(%r15) # restore first argument
 303         lmg     %r2,%r6,SP_R2(%r15)    # load svc arguments
 304         j       sysc_do_restart        # restart svc
 305
 306 #
 307 # _TIF_SINGLE_STEP is set, call do_single_step
 308 #
 309 sysc_singlestep:
 310         ni      __TI_flags+7(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 311         lhi     %r0,__LC_PGM_OLD_PSW
 312         sth     %r0,SP_TRAP(%r15)       # set trap indication to pgm check
 313         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 314         larl    %r14,sysc_return        # load adr. of system return
 315         jg      do_single_step          # branch to do_sigtrap
 316
 317
 318 #
 319 # call syscall_trace before and after system call
 320 # special linkage: %r12 contains the return address for trace_svc
 321 #
 322 sysc_tracesys:
 323         la      %r2,SP_PTREGS(%r15)    # load pt_regs
 324         la      %r3,0
 325         srl     %r7,2
 326         stg     %r7,SP_R2(%r15)
 327         brasl   %r14,syscall_trace
 328         lghi    %r0,NR_syscalls
 329         clg     %r0,SP_R2(%r15)
 330         jnh     sysc_tracenogo
 331         lg      %r7,SP_R2(%r15)   # strace might have changed the
 332         sll     %r7,2             #  system call
 333         lgf     %r8,0(%r7,%r10)
 334 sysc_tracego:
 335         lmg     %r3,%r6,SP_R3(%r15)
 336         lg      %r2,SP_ORIG_R2(%r15)
 337         basr    %r14,%r8            # call sys_xxx
 338         stg     %r2,SP_R2(%r15)     # store return value
 339 sysc_tracenogo:
 340         tm      __TI_flags+7(%r9),(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT)
 341         jz      sysc_return
 342         la      %r2,SP_PTREGS(%r15)    # load pt_regs
 343         la      %r3,1
 344         larl    %r14,sysc_return    # return point is sysc_return
 345         jg      syscall_trace
 346
 347 #
 348 # a new process exits the kernel with ret_from_fork
 349 #
 350         .globl  ret_from_fork
 351 ret_from_fork:
 352         lg      %r13,__LC_SVC_NEW_PSW+8
 353         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 354         tm      SP_PSW+1(%r15),0x01     # forking a kernel thread ?
 355         jo      0f
 356         stg     %r15,SP_R15(%r15)       # store stack pointer for new kthread
 357 0:      brasl   %r14,schedule_tail
 358         stosm   24(%r15),0x03     # reenable interrupts
 359         j       sysc_return
 360
 361 #
 362 # clone, fork, vfork, exec and sigreturn need glue,
 363 # because they all expect pt_regs as parameter,
 364 # but are called with different parameter.
 365 # return-address is set up above
 366 #
 367 sys_clone_glue:
 368         la      %r2,SP_PTREGS(%r15)    # load pt_regs
 369         jg      sys_clone              # branch to sys_clone
 370
 371 #ifdef CONFIG_COMPAT
 372 sys32_clone_glue:
 373         la      %r2,SP_PTREGS(%r15)    # load pt_regs
 374         jg      sys32_clone            # branch to sys32_clone
 375 #endif
 376
 377 sys_fork_glue:
 378         la      %r2,SP_PTREGS(%r15)    # load pt_regs
 379         jg      sys_fork               # branch to sys_fork
 380
 381 sys_vfork_glue:
 382         la      %r2,SP_PTREGS(%r15)    # load pt_regs
 383         jg      sys_vfork              # branch to sys_vfork
 384
 385 sys_execve_glue:
 386         la      %r2,SP_PTREGS(%r15)   # load pt_regs
 387         lgr     %r12,%r14             # save return address
 388         brasl   %r14,sys_execve       # call sys_execve
 389         ltgr    %r2,%r2               # check if execve failed
 390         bnz     0(%r12)               # it did fail -> store result in gpr2
 391         b       6(%r12)               # SKIP STG 2,SP_R2(15) in
 392                                       # system_call/sysc_tracesys
 393 #ifdef CONFIG_COMPAT
 394 sys32_execve_glue:
 395         la      %r2,SP_PTREGS(%r15)   # load pt_regs
 396         lgr     %r12,%r14             # save return address
 397         brasl   %r14,sys32_execve     # call sys32_execve
 398         ltgr    %r2,%r2               # check if execve failed
 399         bnz     0(%r12)               # it did fail -> store result in gpr2
 400         b       6(%r12)               # SKIP STG 2,SP_R2(15) in
 401                                       # system_call/sysc_tracesys
 402 #endif
 403
 404 sys_sigreturn_glue:
 405         la      %r2,SP_PTREGS(%r15)   # load pt_regs as parameter
 406         jg      sys_sigreturn         # branch to sys_sigreturn
 407
 408 #ifdef CONFIG_COMPAT
 409 sys32_sigreturn_glue:
 410         la      %r2,SP_PTREGS(%r15)   # load pt_regs as parameter
 411         jg      sys32_sigreturn       # branch to sys32_sigreturn
 412 #endif
 413
 414 sys_rt_sigreturn_glue:
 415         la      %r2,SP_PTREGS(%r15)   # load pt_regs as parameter
 416         jg      sys_rt_sigreturn      # branch to sys_sigreturn
 417
 418 #ifdef CONFIG_COMPAT
 419 sys32_rt_sigreturn_glue:
 420         la      %r2,SP_PTREGS(%r15)   # load pt_regs as parameter
 421         jg      sys32_rt_sigreturn    # branch to sys32_sigreturn
 422 #endif
 423
 424 sys_sigaltstack_glue:
 425         la      %r4,SP_PTREGS(%r15)   # load pt_regs as parameter
 426         jg      sys_sigaltstack       # branch to sys_sigreturn
 427
 428 #ifdef CONFIG_COMPAT
 429 sys32_sigaltstack_glue:
 430         la      %r4,SP_PTREGS(%r15)   # load pt_regs as parameter
 431         jg      sys32_sigaltstack_wrapper # branch to sys_sigreturn
 432 #endif
 433
 434 /*
 435  * Program check handler routine
 436  */
 437
 438         .globl  pgm_check_handler
 439 pgm_check_handler:
 440 /*
 441  * First we need to check for a special case:
 442  * Single stepping an instruction that disables the PER event mask will
 443  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
 444  * For a single stepped SVC the program check handler gets control after
 445  * the SVC new PSW has been loaded. But we want to execute the SVC first and
 446  * then handle the PER event. Therefore we update the SVC old PSW to point
 447  * to the pgm_check_handler and branch to the SVC handler after we checked
 448  * if we have to load the kernel stack register.
 449  * For every other possible cause for PER event without the PER mask set
 450  * we just ignore the PER event (FIXME: is there anything we have to do
 451  * for LPSW?).
 452  */
 453         STORE_TIMER __LC_SYNC_ENTER_TIMER
 454         SAVE_ALL_BASE __LC_SAVE_AREA
 455         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
 456         jnz     pgm_per                  # got per exception -> special case
 457         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 458         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 459 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 460         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 461         jz      pgm_no_vtime
 462         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 463         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 464         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 465 pgm_no_vtime:
 466 #endif
 467         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 468         lgf     %r3,__LC_PGM_ILC         # load program interruption code
 469         lghi    %r8,0x7f
 470         ngr     %r8,%r3
 471 pgm_do_call:
 472         sll     %r8,3
 473         larl    %r1,pgm_check_table
 474         lg      %r1,0(%r8,%r1)           # load address of handler routine
 475         la      %r2,SP_PTREGS(%r15)      # address of register-save area
 476         larl    %r14,sysc_return
 477         br      %r1                      # branch to interrupt-handler
 478
 479 #
 480 # handle per exception
 481 #
 482 pgm_per:
 483         tm      __LC_PGM_OLD_PSW,0x40    # test if per event recording is on
 484         jnz     pgm_per_std              # ok, normal per event from user space
 485 # ok its one of the special cases, now we need to find out which one
 486         clc     __LC_PGM_OLD_PSW(16),__LC_SVC_NEW_PSW
 487         je      pgm_svcper
 488 # no interesting special case, ignore PER event
 489         lmg     %r12,%r15,__LC_SAVE_AREA
 490         lpswe   __LC_PGM_OLD_PSW
 491
 492 #
 493 # Normal per exception
 494 #
 495 pgm_per_std:
 496         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 497         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 498 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 499         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 500         jz      pgm_no_vtime2
 501         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 502         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 503         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 504 pgm_no_vtime2:
 505 #endif
 506         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 507         lg      %r1,__TI_task(%r9)
 508         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
 509         mvc     __THREAD_per+__PER_address(8,%r1),__LC_PER_ADDRESS
 510         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
 511         oi      __TI_flags+7(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 512         lgf     %r3,__LC_PGM_ILC         # load program interruption code
 513         lghi    %r8,0x7f
 514         ngr     %r8,%r3                  # clear per-event-bit and ilc
 515         je      sysc_return
 516         j       pgm_do_call
 517
 518 #
 519 # it was a single stepped SVC that is causing all the trouble
 520 #
 521 pgm_svcper:
 522         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 523         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 524 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 525         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 526         jz      pgm_no_vtime3
 527         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 528         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 529         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 530 pgm_no_vtime3:
 531 #endif
 532         llgh    %r7,__LC_SVC_INT_CODE   # get svc number from lowcore
 533         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 534         lg      %r1,__TI_task(%r9)
 535         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
 536         mvc     __THREAD_per+__PER_address(8,%r1),__LC_PER_ADDRESS
 537         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
 538         oi      __TI_flags+7(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 539         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 540         j       sysc_do_svc
 541
 542 /*
 543  * IO interrupt handler routine
 544  */
 545         .globl io_int_handler
 546 io_int_handler:
 547         STORE_TIMER __LC_ASYNC_ENTER_TIMER
 548         stck    __LC_INT_CLOCK
 549         SAVE_ALL_BASE __LC_SAVE_AREA+32
 550         SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+32
 551         CREATE_STACK_FRAME __LC_IO_OLD_PSW,__LC_SAVE_AREA+32
 552 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 553         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 554         jz      io_no_vtime
 555         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 556         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 557         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 558 io_no_vtime:
 559 #endif
 560         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 561         la      %r2,SP_PTREGS(%r15)    # address of register-save area
 562         brasl   %r14,do_IRQ            # call standard irq handler
 563
 564 io_return:
 565         tm      SP_PSW+1(%r15),0x01    # returning to user ?
 566 #ifdef CONFIG_PREEMPT
 567         jno     io_preempt             # no -> check for preemptive scheduling
 568 #else
 569         jno     io_leave               # no-> skip resched & signal
 570 #endif
 571         tm      __TI_flags+7(%r9),_TIF_WORK_INT
 572         jnz     io_work                # there is work to do (signals etc.)
 573 io_leave:
 574         RESTORE_ALL __LC_RETURN_PSW,0
 575 io_done:
 576
 577 #ifdef CONFIG_PREEMPT
 578 io_preempt:
 579         icm     %r0,15,__TI_precount(%r9)
 580         jnz     io_leave
 581         # switch to kernel stack
 582         lg      %r1,SP_R15(%r15)
 583         aghi    %r1,-SP_SIZE
 584         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 585         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 586         lgr     %r15,%r1
 587 io_resume_loop:
 588         tm      __TI_flags+7(%r9),_TIF_NEED_RESCHED
 589         jno     io_leave
 590         larl    %r1,.Lc_pactive
 591         mvc     __TI_precount(4,%r9),0(%r1)
 592         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 593         brasl   %r14,schedule          # call schedule
 594         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 595         xc      __TI_precount(4,%r9),__TI_precount(%r9)
 596         j       io_resume_loop
 597 #endif
 598
 599 #
 600 # switch to kernel stack, then check TIF bits
 601 #
 602 io_work:
 603         lg      %r1,__LC_KERNEL_STACK
 604         aghi    %r1,-SP_SIZE
 605         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 606         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 607         lgr     %r15,%r1
 608 #
 609 # One of the work bits is on. Find out which one.
 610 # Checked are: _TIF_SIGPENDING, _TIF_RESTORE_SIGPENDING, _TIF_NEED_RESCHED
 611 #              and _TIF_MCCK_PENDING
 612 #
 613 io_work_loop:
 614         tm      __TI_flags+7(%r9),_TIF_MCCK_PENDING
 615         jo      io_mcck_pending
 616         tm      __TI_flags+7(%r9),_TIF_NEED_RESCHED
 617         jo      io_reschedule
 618         tm      __TI_flags+7(%r9),(_TIF_SIGPENDING | _TIF_RESTORE_SIGMASK)
 619         jnz     io_sigpending
 620         j       io_leave
 621
 622 #
 623 # _TIF_MCCK_PENDING is set, call handler
 624 #
 625 io_mcck_pending:
 626         larl    %r14,io_work_loop
 627         jg      s390_handle_mcck        # TIF bit will be cleared by handler
 628
 629 #
 630 # _TIF_NEED_RESCHED is set, call schedule
 631 #
 632 io_reschedule:
 633         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 634         brasl   %r14,schedule           # call scheduler
 635         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 636         tm      __TI_flags+7(%r9),_TIF_WORK_INT
 637         jz      io_leave                # there is no work to do
 638         j       io_work_loop
 639
 640 #
 641 # _TIF_SIGPENDING or _TIF_RESTORE_SIGMASK is set, call do_signal
 642 #
 643 io_sigpending:
 644         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 645         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 646         brasl   %r14,do_signal          # call do_signal
 647         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 648         j       io_work_loop
 649
 650 /*
 651  * External interrupt handler routine
 652  */
 653         .globl  ext_int_handler
 654 ext_int_handler:
 655         STORE_TIMER __LC_ASYNC_ENTER_TIMER
 656         stck    __LC_INT_CLOCK
 657         SAVE_ALL_BASE __LC_SAVE_AREA+32
 658         SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+32
 659         CREATE_STACK_FRAME __LC_EXT_OLD_PSW,__LC_SAVE_AREA+32
 660 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 661         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 662         jz      ext_no_vtime
 663         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 664         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 665         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 666 ext_no_vtime:
 667 #endif
 668         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 669         la      %r2,SP_PTREGS(%r15)    # address of register-save area
 670         llgh    %r3,__LC_EXT_INT_CODE  # get interruption code
 671         brasl   %r14,do_extint
 672         j       io_return
 673
 674 __critical_end:
 675
 676 /*
 677  * Machine check handler routines
 678  */
 679         .globl mcck_int_handler
 680 mcck_int_handler:
 681         la      %r1,4095                # revalidate r1
 682         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
 683         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
 684         SAVE_ALL_BASE __LC_SAVE_AREA+64
 685         la      %r12,__LC_MCK_OLD_PSW
 686         tm      __LC_MCCK_CODE,0x80     # system damage?
 687         jo      mcck_int_main           # yes -> rest of mcck code invalid
 688 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 689         la      %r14,4095
 690         mvc     __LC_SAVE_AREA+104(8),__LC_ASYNC_ENTER_TIMER
 691         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA-4095(%r14)
 692         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 693         jo      1f
 694         la      %r14,__LC_SYNC_ENTER_TIMER
 695         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 696         jl      0f
 697         la      %r14,__LC_ASYNC_ENTER_TIMER
 698 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 699         jl      0f
 700         la      %r14,__LC_EXIT_TIMER
 701 0:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 702         jl      0f
 703         la      %r14,__LC_LAST_UPDATE_TIMER
 704 0:      spt     0(%r14)
 705         mvc     __LC_ASYNC_ENTER_TIMER(8),0(%r14)
 706 1:
 707 #endif
 708         tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 709         jno     mcck_int_main           # no -> skip cleanup critical
 710         tm      __LC_MCK_OLD_PSW+1,0x01 # test problem state bit
 711         jnz     mcck_int_main           # from user -> load kernel stack
 712         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_end)
 713         jhe     mcck_int_main
 714         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_start)
 715         jl      mcck_int_main
 716         brasl   %r14,cleanup_critical
 717 mcck_int_main:
 718         lg      %r14,__LC_PANIC_STACK   # are we already on the panic stack?
 719         slgr    %r14,%r15
 720         srag    %r14,%r14,PAGE_SHIFT
 721         jz      0f
 722         lg      %r15,__LC_PANIC_STACK   # load panic stack
 723 0:      CREATE_STACK_FRAME __LC_MCK_OLD_PSW,__LC_SAVE_AREA+64
 724 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 725         tm      __LC_MCCK_CODE+2,0x08   # mwp of old psw valid?
 726         jno     mcck_no_vtime           # no -> no timer update
 727         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 728         jz      mcck_no_vtime
 729         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 730         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 731         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 732 mcck_no_vtime:
 733 #endif
 734         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 735         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 736         brasl   %r14,s390_do_machine_check
 737         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 738         jno     mcck_return
 739         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
 740         aghi    %r1,-SP_SIZE
 741         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 742         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 743         lgr     %r15,%r1
 744         stosm   __SF_EMPTY(%r15),0x04   # turn dat on
 745         tm      __TI_flags+7(%r9),_TIF_MCCK_PENDING
 746         jno     mcck_return
 747         brasl   %r14,s390_handle_mcck
 748 mcck_return:
 749         mvc     __LC_RETURN_MCCK_PSW(16),SP_PSW(%r15) # move return PSW
 750         ni      __LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
 751         lmg     %r0,%r15,SP_R0(%r15)    # load gprs 0-15
 752 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 753         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_SAVE_AREA+104
 754         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 755         jno     0f
 756         stpt    __LC_EXIT_TIMER
 757 0:
 758 #endif
 759         lpswe   __LC_RETURN_MCCK_PSW    # back to caller
 760
 761 #ifdef CONFIG_SMP
 762 /*
 763  * Restart interruption handler, kick starter for additional CPUs
 764  */
 765         .globl restart_int_handler
 766 restart_int_handler:
 767         lg      %r15,__LC_SAVE_AREA+120 # load ksp
 768         lghi    %r10,__LC_CREGS_SAVE_AREA
 769         lctlg   %c0,%c15,0(%r10) # get new ctl regs
 770         lghi    %r10,__LC_AREGS_SAVE_AREA
 771         lam     %a0,%a15,0(%r10)
 772         lmg     %r6,%r15,__SF_GPRS(%r15) # load registers from clone
 773         stosm   __SF_EMPTY(%r15),0x04    # now we can turn dat on
 774         jg      start_secondary
 775 #else
 776 /*
 777  * If we do not run with SMP enabled, let the new CPU crash ...
 778  */
 779         .globl restart_int_handler
 780 restart_int_handler:
 781         basr    %r1,0
 782 restart_base:
 783         lpswe   restart_crash-restart_base(%r1)
 784         .align 8
 785 restart_crash:
 786         .long  0x000a0000,0x00000000,0x00000000,0x00000000
 787 restart_go:
 788 #endif
 789
 790 #ifdef CONFIG_CHECK_STACK
 791 /*
 792  * The synchronous or the asynchronous stack overflowed. We are dead.
 793  * No need to properly save the registers, we are going to panic anyway.
 794  * Setup a pt_regs so that show_trace can provide a good call trace.
 795  */
 796 stack_overflow:
 797         lg      %r15,__LC_PANIC_STACK   # change to panic stack
 798         aghi    %r1,-SP_SIZE
 799         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
 800         stmg    %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 801         la      %r1,__LC_SAVE_AREA
 802         chi     %r12,__LC_SVC_OLD_PSW
 803         je      0f
 804         chi     %r12,__LC_PGM_OLD_PSW
 805         je      0f
 806         la      %r1,__LC_SAVE_AREA+16
 807 0:      mvc     SP_R12(32,%r15),0(%r1)  # move %r12-%r15 to stack
 808         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15) # clear back chain
 809         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 810         jg      kernel_stack_overflow
 811 #endif
 812
 813 cleanup_table_system_call:
 814         .quad   system_call, sysc_do_svc
 815 cleanup_table_sysc_return:
 816         .quad   sysc_return, sysc_leave
 817 cleanup_table_sysc_leave:
 818         .quad   sysc_leave, sysc_work_loop
 819 cleanup_table_sysc_work_loop:
 820         .quad   sysc_work_loop, sysc_reschedule
 821 cleanup_table_io_return:
 822         .quad   io_return, io_leave
 823 cleanup_table_io_leave:
 824         .quad   io_leave, io_done
 825 cleanup_table_io_work_loop:
 826         .quad   io_work_loop, io_mcck_pending
 827
 828 cleanup_critical:
 829         clc     8(8,%r12),BASED(cleanup_table_system_call)
 830         jl      0f
 831         clc     8(8,%r12),BASED(cleanup_table_system_call+8)
 832         jl      cleanup_system_call
 833 0:
 834         clc     8(8,%r12),BASED(cleanup_table_sysc_return)
 835         jl      0f
 836         clc     8(8,%r12),BASED(cleanup_table_sysc_return+8)
 837         jl      cleanup_sysc_return
 838 0:
 839         clc     8(8,%r12),BASED(cleanup_table_sysc_leave)
 840         jl      0f
 841         clc     8(8,%r12),BASED(cleanup_table_sysc_leave+8)
 842         jl      cleanup_sysc_leave
 843 0:
 844         clc     8(8,%r12),BASED(cleanup_table_sysc_work_loop)
 845         jl      0f
 846         clc     8(8,%r12),BASED(cleanup_table_sysc_work_loop+8)
 847         jl      cleanup_sysc_return
 848 0:
 849         clc     8(8,%r12),BASED(cleanup_table_io_return)
 850         jl      0f
 851         clc     8(8,%r12),BASED(cleanup_table_io_return+8)
 852         jl      cleanup_io_return
 853 0:
 854         clc     8(8,%r12),BASED(cleanup_table_io_leave)
 855         jl      0f
 856         clc     8(8,%r12),BASED(cleanup_table_io_leave+8)
 857         jl      cleanup_io_leave
 858 0:
 859         clc     8(8,%r12),BASED(cleanup_table_io_work_loop)
 860         jl      0f
 861         clc     8(8,%r12),BASED(cleanup_table_io_work_loop+8)
 862         jl      cleanup_io_return
 863 0:
 864         br      %r14
 865
 866 cleanup_system_call:
 867         mvc     __LC_RETURN_PSW(16),0(%r12)
 868         cghi    %r12,__LC_MCK_OLD_PSW
 869         je      0f
 870         la      %r12,__LC_SAVE_AREA+32
 871         j       1f
 872 0:      la      %r12,__LC_SAVE_AREA+64
 873 1:
 874 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 875         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+8)
 876         jh      0f
 877         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 878 0:      clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+16)
 879         jhe     cleanup_vtime
 880 #endif
 881         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn)
 882         jh      0f
 883         mvc     __LC_SAVE_AREA(32),0(%r12)
 884 0:      stg     %r13,8(%r12)
 885         stg     %r12,__LC_SAVE_AREA+96  # argh
 886         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 887         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 888         lg      %r12,__LC_SAVE_AREA+96  # argh
 889         stg     %r15,24(%r12)
 890         llgh    %r7,__LC_SVC_INT_CODE
 891 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 892 cleanup_vtime:
 893         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+24)
 894         jhe     cleanup_stime
 895         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 896         jz      cleanup_novtime
 897         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 898 cleanup_stime:
 899         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+32)
 900         jh      cleanup_update
 901         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 902 cleanup_update:
 903         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 904 cleanup_novtime:
 905 #endif
 906         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_system_call+8)
 907         la      %r12,__LC_RETURN_PSW
 908         br      %r14
 909 cleanup_system_call_insn:
 910         .quad   sysc_saveall
 911 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 912         .quad   system_call
 913         .quad   sysc_vtime
 914         .quad   sysc_stime
 915         .quad   sysc_update
 916 #endif
 917
 918 cleanup_sysc_return:
 919         mvc     __LC_RETURN_PSW(8),0(%r12)
 920         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_sysc_return)
 921         la      %r12,__LC_RETURN_PSW
 922         br      %r14
 923
 924 cleanup_sysc_leave:
 925         clc     8(8,%r12),BASED(cleanup_sysc_leave_insn)
 926         je      2f
 927 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 928         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
 929         clc     8(8,%r12),BASED(cleanup_sysc_leave_insn+8)
 930         je      2f
 931 #endif
 932         mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
 933         cghi    %r12,__LC_MCK_OLD_PSW
 934         jne     0f
 935         mvc     __LC_SAVE_AREA+64(32),SP_R12(%r15)
 936         j       1f
 937 0:      mvc     __LC_SAVE_AREA+32(32),SP_R12(%r15)
 938 1:      lmg     %r0,%r11,SP_R0(%r15)
 939         lg      %r15,SP_R15(%r15)
 940 2:      la      %r12,__LC_RETURN_PSW
 941         br      %r14
 942 cleanup_sysc_leave_insn:
 943 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 944         .quad   sysc_leave + 16
 945 #endif
 946         .quad   sysc_leave + 12
 947
 948 cleanup_io_return:
 949         mvc     __LC_RETURN_PSW(8),0(%r12)
 950         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_io_work_loop)
 951         la      %r12,__LC_RETURN_PSW
 952         br      %r14
 953
 954 cleanup_io_leave:
 955         clc     8(8,%r12),BASED(cleanup_io_leave_insn)
 956         je      2f
 957 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 958         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
 959         clc     8(8,%r12),BASED(cleanup_io_leave_insn+8)
 960         je      2f
 961 #endif
 962         mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
 963         cghi    %r12,__LC_MCK_OLD_PSW
 964         jne     0f
 965         mvc     __LC_SAVE_AREA+64(32),SP_R12(%r15)
 966         j       1f
 967 0:      mvc     __LC_SAVE_AREA+32(32),SP_R12(%r15)
 968 1:      lmg     %r0,%r11,SP_R0(%r15)
 969         lg      %r15,SP_R15(%r15)
 970 2:      la      %r12,__LC_RETURN_PSW
 971         br      %r14
 972 cleanup_io_leave_insn:
 973 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 974         .quad   io_leave + 20
 975 #endif
 976         .quad   io_leave + 16
 977
 978 /*
 979  * Integer constants
 980  */
 981                .align 4
 982 .Lconst:
 983 .Lc_pactive:   .long  PREEMPT_ACTIVE
 984 .Lnr_syscalls: .long  NR_syscalls
 985 .L0x0130:      .short 0x130
 986 .L0x0140:      .short 0x140
 987 .L0x0150:      .short 0x150
 988 .L0x0160:      .short 0x160
 989 .L0x0170:      .short 0x170
 990 .Lcritical_start:
 991                .quad  __critical_start
 992 .Lcritical_end:
 993                .quad  __critical_end
 994
 995 #define SYSCALL(esa,esame,emu)  .long esame
 996 sys_call_table:
 997 #include "syscalls.S"
 998 #undef SYSCALL
 999
1000 #ifdef CONFIG_COMPAT
1001
1002 #define SYSCALL(esa,esame,emu)  .long emu
1003 sys_call_table_emu:
1004 #include "syscalls.S"
1005 #undef SYSCALL
1006 #endif