arch/s390/kernel/entry64.S

   1 /*
   2  *  arch/s390/kernel/entry64.S
   3  *    S390 low-level entry points.
   4  *
   5  *    Copyright (C) IBM Corp. 1999,2010
   6  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   7  *               Hartmut Penner (hp@de.ibm.com),
   8  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
  10  */
  11
  12 #include <linux/linkage.h>
  13 #include <linux/init.h>
  14 #include <asm/cache.h>
  15 #include <asm/errno.h>
  16 #include <asm/ptrace.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/asm-offsets.h>
  19 #include <asm/unistd.h>
  20 #include <asm/page.h>
  21
  22 /*
  23  * Stack layout for the system_call stack entry.
  24  * The first few entries are identical to the user_regs_struct.
  25  */
  26 SP_PTREGS    =  STACK_FRAME_OVERHEAD
  27 SP_ARGS      =  STACK_FRAME_OVERHEAD + __PT_ARGS
  28 SP_PSW       =  STACK_FRAME_OVERHEAD + __PT_PSW
  29 SP_R0        =  STACK_FRAME_OVERHEAD + __PT_GPRS
  30 SP_R1        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 8
  31 SP_R2        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 16
  32 SP_R3        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 24
  33 SP_R4        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 32
  34 SP_R5        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 40
  35 SP_R6        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 48
  36 SP_R7        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 56
  37 SP_R8        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 64
  38 SP_R9        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 72
  39 SP_R10       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 80
  40 SP_R11       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 88
  41 SP_R12       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 96
  42 SP_R13       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 104
  43 SP_R14       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 112
  44 SP_R15       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 120
  45 SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
  46 SP_ILC       =  STACK_FRAME_OVERHEAD + __PT_ILC
  47 SP_SVCNR      = STACK_FRAME_OVERHEAD + __PT_SVCNR
  48 SP_SIZE      =  STACK_FRAME_OVERHEAD + __PT_SIZE
  49
  50 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  51 STACK_SIZE  = 1 << STACK_SHIFT
  52
  53 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  54                  _TIF_MCCK_PENDING | _TIF_RESTART_SVC | _TIF_SINGLE_STEP )
  55 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  56                  _TIF_MCCK_PENDING)
  57 _TIF_SYSCALL = (_TIF_SYSCALL_TRACE>>8 | _TIF_SYSCALL_AUDIT>>8 | \
  58                 _TIF_SECCOMP>>8 | _TIF_SYSCALL_TRACEPOINT>>8)
  59
  60 #define BASED(name) name-system_call(%r13)
  61
  62         .macro  HANDLE_SIE_INTERCEPT
  63 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
  64         lg      %r3,__LC_SIE_HOOK
  65         ltgr    %r3,%r3
  66         jz      0f
  67         basr    %r14,%r3
  68 0:
  69 #endif
  70         .endm
  71
  72 #ifdef CONFIG_TRACE_IRQFLAGS
  73         .macro  TRACE_IRQS_ON
  74         basr    %r2,%r0
  75         brasl   %r14,trace_hardirqs_on_caller
  76         .endm
  77
  78         .macro  TRACE_IRQS_OFF
  79         basr    %r2,%r0
  80         brasl   %r14,trace_hardirqs_off_caller
  81         .endm
  82
  83         .macro TRACE_IRQS_CHECK_ON
  84         tm      SP_PSW(%r15),0x03       # irqs enabled?
  85         jz      0f
  86         TRACE_IRQS_ON
  87 0:
  88         .endm
  89
  90         .macro TRACE_IRQS_CHECK_OFF
  91         tm      SP_PSW(%r15),0x03       # irqs enabled?
  92         jz      0f
  93         TRACE_IRQS_OFF
  94 0:
  95         .endm
  96 #else
  97 #define TRACE_IRQS_ON
  98 #define TRACE_IRQS_OFF
  99 #define TRACE_IRQS_CHECK_ON
 100 #define TRACE_IRQS_CHECK_OFF
 101 #endif
 102
 103 #ifdef CONFIG_LOCKDEP
 104         .macro  LOCKDEP_SYS_EXIT
 105         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 106         jz      0f
 107         brasl   %r14,lockdep_sys_exit
 108 0:
 109         .endm
 110 #else
 111 #define LOCKDEP_SYS_EXIT
 112 #endif
 113
 114         .macro  UPDATE_VTIME lc_from,lc_to,lc_sum
 115         lg      %r10,\lc_from
 116         slg     %r10,\lc_to
 117         alg     %r10,\lc_sum
 118         stg     %r10,\lc_sum
 119         .endm
 120
 121 /*
 122  * Register usage in interrupt handlers:
 123  *    R9  - pointer to current task structure
 124  *    R13 - pointer to literal pool
 125  *    R14 - return register for function calls
 126  *    R15 - kernel stack pointer
 127  */
 128
 129         .macro  SAVE_ALL_SVC psworg,savearea
 130         stmg    %r11,%r15,\savearea
 131         lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 132         aghi    %r15,-SP_SIZE           # make room for registers & psw
 133         lg      %r11,__LC_LAST_BREAK
 134         .endm
 135
 136         .macro  SAVE_ALL_PGM psworg,savearea
 137         stmg    %r11,%r15,\savearea
 138         tm      \psworg+1,0x01          # test problem state bit
 139 #ifdef CONFIG_CHECK_STACK
 140         jnz     1f
 141         tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 142         jnz     2f
 143         la      %r12,\psworg
 144         j       stack_overflow
 145 #else
 146         jz      2f
 147 #endif
 148 1:      lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 149 2:      aghi    %r15,-SP_SIZE           # make room for registers & psw
 150         larl    %r13,system_call
 151         lg      %r11,__LC_LAST_BREAK
 152         .endm
 153
 154         .macro  SAVE_ALL_ASYNC psworg,savearea
 155         stmg    %r11,%r15,\savearea
 156         larl    %r13,system_call
 157         lg      %r11,__LC_LAST_BREAK
 158         la      %r12,\psworg
 159         tm      \psworg+1,0x01          # test problem state bit
 160         jnz     1f                      # from user -> load kernel stack
 161         clc     \psworg+8(8),BASED(.Lcritical_end)
 162         jhe     0f
 163         clc     \psworg+8(8),BASED(.Lcritical_start)
 164         jl      0f
 165         brasl   %r14,cleanup_critical
 166         tm      1(%r12),0x01            # retest problem state after cleanup
 167         jnz     1f
 168 0:      lg      %r14,__LC_ASYNC_STACK   # are we already on the async. stack ?
 169         slgr    %r14,%r15
 170         srag    %r14,%r14,STACK_SHIFT
 171 #ifdef CONFIG_CHECK_STACK
 172         jnz     1f
 173         tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 174         jnz     2f
 175         j       stack_overflow
 176 #else
 177         jz      2f
 178 #endif
 179 1:      lg      %r15,__LC_ASYNC_STACK   # load async stack
 180 2:      aghi    %r15,-SP_SIZE           # make room for registers & psw
 181         .endm
 182
 183         .macro  CREATE_STACK_FRAME savearea
 184         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 185         stg     %r2,SP_ORIG_R2(%r15)    # store original content of gpr 2
 186         mvc     SP_R11(40,%r15),\savearea # move %r11-%r15 to stack
 187         stmg    %r0,%r10,SP_R0(%r15)    # store gprs %r0-%r10 to kernel stack
 188         .endm
 189
 190         .macro  RESTORE_ALL psworg,sync
 191         mvc     \psworg(16),SP_PSW(%r15) # move user PSW to lowcore
 192         .if !\sync
 193         ni      \psworg+1,0xfd          # clear wait state bit
 194         .endif
 195         lg      %r14,__LC_VDSO_PER_CPU
 196         lmg     %r0,%r13,SP_R0(%r15)    # load gprs 0-13 of user
 197         stpt    __LC_EXIT_TIMER
 198         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 199         lmg     %r14,%r15,SP_R14(%r15)  # load grps 14-15 of user
 200         lpswe   \psworg                 # back to caller
 201         .endm
 202
 203         .macro  LAST_BREAK
 204         srag    %r10,%r11,23
 205         jz      0f
 206         stg     %r11,__TI_last_break(%r12)
 207 0:
 208         .endm
 209
 210 /*
 211  * Scheduler resume function, called by switch_to
 212  *  gpr2 = (task_struct *) prev
 213  *  gpr3 = (task_struct *) next
 214  * Returns:
 215  *  gpr2 = prev
 216  */
 217         .globl  __switch_to
 218 __switch_to:
 219         tm      __THREAD_per+4(%r3),0xe8 # is the new process using per ?
 220         jz      __switch_to_noper               # if not we're fine
 221         stctg   %c9,%c11,__SF_EMPTY(%r15)# We are using per stuff
 222         clc     __THREAD_per(24,%r3),__SF_EMPTY(%r15)
 223         je      __switch_to_noper            # we got away without bashing TLB's
 224         lctlg   %c9,%c11,__THREAD_per(%r3)      # Nope we didn't
 225 __switch_to_noper:
 226         lg      %r4,__THREAD_info(%r2)              # get thread_info of prev
 227         tm      __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
 228         jz      __switch_to_no_mcck
 229         ni      __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 230         lg      %r4,__THREAD_info(%r3)              # get thread_info of next
 231         oi      __TI_flags+7(%r4),_TIF_MCCK_PENDING # set it in next
 232 __switch_to_no_mcck:
 233         stmg    %r6,%r15,__SF_GPRS(%r15)# store __switch_to registers of prev task
 234         stg     %r15,__THREAD_ksp(%r2)  # store kernel stack to prev->tss.ksp
 235         lg      %r15,__THREAD_ksp(%r3)  # load kernel stack from next->tss.ksp
 236         lmg     %r6,%r15,__SF_GPRS(%r15)# load __switch_to registers of next task
 237         stg     %r3,__LC_CURRENT        # __LC_CURRENT = current task struct
 238         lctl    %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
 239         lg      %r3,__THREAD_info(%r3)  # load thread_info from task struct
 240         stg     %r3,__LC_THREAD_INFO
 241         aghi    %r3,STACK_SIZE
 242         stg     %r3,__LC_KERNEL_STACK   # __LC_KERNEL_STACK = new kernel stack
 243         br      %r14
 244
 245 __critical_start:
 246 /*
 247  * SVC interrupt handler routine. System calls are synchronous events and
 248  * are executed with interrupts enabled.
 249  */
 250
 251         .globl  system_call
 252 system_call:
 253         stpt    __LC_SYNC_ENTER_TIMER
 254 sysc_saveall:
 255         SAVE_ALL_SVC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 256         CREATE_STACK_FRAME __LC_SAVE_AREA
 257         mvc     SP_PSW(16,%r15),__LC_SVC_OLD_PSW
 258         mvc     SP_ILC(4,%r15),__LC_SVC_ILC
 259         stg     %r7,SP_ARGS(%r15)
 260         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 261 sysc_vtime:
 262         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 263 sysc_stime:
 264         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 265 sysc_update:
 266         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 267         LAST_BREAK
 268 sysc_do_svc:
 269         llgh    %r7,SP_SVCNR(%r15)
 270         slag    %r7,%r7,2       # shift and test for svc 0
 271         jnz     sysc_nr_ok
 272         # svc 0: system call number in %r1
 273         llgfr   %r1,%r1         # clear high word in r1
 274         cghi    %r1,NR_syscalls
 275         jnl     sysc_nr_ok
 276         sth     %r1,SP_SVCNR(%r15)
 277         slag    %r7,%r1,2       # shift and test for svc 0
 278 sysc_nr_ok:
 279         larl    %r10,sys_call_table
 280 #ifdef CONFIG_COMPAT
 281         tm      __TI_flags+5(%r12),(_TIF_31BIT>>16)  # running in 31 bit mode ?
 282         jno     sysc_noemu
 283         larl    %r10,sys_call_table_emu  # use 31 bit emulation system calls
 284 sysc_noemu:
 285 #endif
 286         tm      __TI_flags+6(%r12),_TIF_SYSCALL
 287         lgf     %r8,0(%r7,%r10) # load address of system call routine
 288         jnz     sysc_tracesys
 289         basr    %r14,%r8        # call sys_xxxx
 290         stg     %r2,SP_R2(%r15) # store return value (change R2 on stack)
 291
 292 sysc_return:
 293         LOCKDEP_SYS_EXIT
 294 sysc_tif:
 295         tm      __TI_flags+7(%r12),_TIF_WORK_SVC
 296         jnz     sysc_work       # there is work to do (signals etc.)
 297 sysc_restore:
 298         RESTORE_ALL __LC_RETURN_PSW,1
 299 sysc_done:
 300
 301 #
 302 # There is work to do, but first we need to check if we return to userspace.
 303 #
 304 sysc_work:
 305         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 306         jno     sysc_restore
 307
 308 #
 309 # One of the work bits is on. Find out which one.
 310 #
 311 sysc_work_tif:
 312         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 313         jo      sysc_mcck_pending
 314         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 315         jo      sysc_reschedule
 316         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
 317         jo      sysc_sigpending
 318         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
 319         jo      sysc_notify_resume
 320         tm      __TI_flags+7(%r12),_TIF_RESTART_SVC
 321         jo      sysc_restart
 322         tm      __TI_flags+7(%r12),_TIF_SINGLE_STEP
 323         jo      sysc_singlestep
 324         j       sysc_return             # beware of critical section cleanup
 325
 326 #
 327 # _TIF_NEED_RESCHED is set, call schedule
 328 #
 329 sysc_reschedule:
 330         larl    %r14,sysc_return
 331         jg      schedule                # return point is sysc_return
 332
 333 #
 334 # _TIF_MCCK_PENDING is set, call handler
 335 #
 336 sysc_mcck_pending:
 337         larl    %r14,sysc_return
 338         jg      s390_handle_mcck        # TIF bit will be cleared by handler
 339
 340 #
 341 # _TIF_SIGPENDING is set, call do_signal
 342 #
 343 sysc_sigpending:
 344         ni      __TI_flags+7(%r12),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 345         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 346         brasl   %r14,do_signal          # call do_signal
 347         tm      __TI_flags+7(%r12),_TIF_RESTART_SVC
 348         jo      sysc_restart
 349         tm      __TI_flags+7(%r12),_TIF_SINGLE_STEP
 350         jo      sysc_singlestep
 351         j       sysc_return
 352
 353 #
 354 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 355 #
 356 sysc_notify_resume:
 357         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 358         larl    %r14,sysc_return
 359         jg      do_notify_resume        # call do_notify_resume
 360
 361 #
 362 # _TIF_RESTART_SVC is set, set up registers and restart svc
 363 #
 364 sysc_restart:
 365         ni      __TI_flags+7(%r12),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
 366         lg      %r7,SP_R2(%r15)         # load new svc number
 367         mvc     SP_R2(8,%r15),SP_ORIG_R2(%r15) # restore first argument
 368         lmg     %r2,%r6,SP_R2(%r15)     # load svc arguments
 369         sth     %r7,SP_SVCNR(%r15)
 370         slag    %r7,%r7,2
 371         j       sysc_nr_ok              # restart svc
 372
 373 #
 374 # _TIF_SINGLE_STEP is set, call do_single_step
 375 #
 376 sysc_singlestep:
 377         ni      __TI_flags+7(%r12),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 378         xc      SP_SVCNR(2,%r15),SP_SVCNR(%r15)         # clear svc number
 379         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 380         larl    %r14,sysc_return        # load adr. of system return
 381         jg      do_single_step          # branch to do_sigtrap
 382
 383 #
 384 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 385 # and after the system call
 386 #
 387 sysc_tracesys:
 388         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 389         la      %r3,0
 390         llgh    %r0,SP_SVCNR(%r15)
 391         stg     %r0,SP_R2(%r15)
 392         brasl   %r14,do_syscall_trace_enter
 393         lghi    %r0,NR_syscalls
 394         clgr    %r0,%r2
 395         jnh     sysc_tracenogo
 396         sllg    %r7,%r2,2               # svc number *4
 397         lgf     %r8,0(%r7,%r10)
 398 sysc_tracego:
 399         lmg     %r3,%r6,SP_R3(%r15)
 400         lg      %r2,SP_ORIG_R2(%r15)
 401         basr    %r14,%r8                # call sys_xxx
 402         stg     %r2,SP_R2(%r15)         # store return value
 403 sysc_tracenogo:
 404         tm      __TI_flags+6(%r12),_TIF_SYSCALL
 405         jz      sysc_return
 406         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 407         larl    %r14,sysc_return        # return point is sysc_return
 408         jg      do_syscall_trace_exit
 409
 410 #
 411 # a new process exits the kernel with ret_from_fork
 412 #
 413         .globl  ret_from_fork
 414 ret_from_fork:
 415         lg      %r13,__LC_SVC_NEW_PSW+8
 416         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 417         tm      SP_PSW+1(%r15),0x01     # forking a kernel thread ?
 418         jo      0f
 419         stg     %r15,SP_R15(%r15)       # store stack pointer for new kthread
 420 0:      brasl   %r14,schedule_tail
 421         TRACE_IRQS_ON
 422         stosm   24(%r15),0x03           # reenable interrupts
 423         j       sysc_tracenogo
 424
 425 #
 426 # kernel_execve function needs to deal with pt_regs that is not
 427 # at the usual place
 428 #
 429         .globl  kernel_execve
 430 kernel_execve:
 431         stmg    %r12,%r15,96(%r15)
 432         lgr     %r14,%r15
 433         aghi    %r15,-SP_SIZE
 434         stg     %r14,__SF_BACKCHAIN(%r15)
 435         la      %r12,SP_PTREGS(%r15)
 436         xc      0(__PT_SIZE,%r12),0(%r12)
 437         lgr     %r5,%r12
 438         brasl   %r14,do_execve
 439         ltgfr   %r2,%r2
 440         je      0f
 441         aghi    %r15,SP_SIZE
 442         lmg     %r12,%r15,96(%r15)
 443         br      %r14
 444         # execve succeeded.
 445 0:      stnsm   __SF_EMPTY(%r15),0xfc   # disable interrupts
 446 #       TRACE_IRQS_OFF
 447         lg      %r15,__LC_KERNEL_STACK  # load ksp
 448         aghi    %r15,-SP_SIZE           # make room for registers & psw
 449         lg      %r13,__LC_SVC_NEW_PSW+8
 450         mvc     SP_PTREGS(__PT_SIZE,%r15),0(%r12)       # copy pt_regs
 451         lg      %r12,__LC_THREAD_INFO
 452         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 453 #       TRACE_IRQS_ON
 454         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 455         brasl   %r14,execve_tail
 456         j       sysc_return
 457
 458 /*
 459  * Program check handler routine
 460  */
 461
 462         .globl  pgm_check_handler
 463 pgm_check_handler:
 464 /*
 465  * First we need to check for a special case:
 466  * Single stepping an instruction that disables the PER event mask will
 467  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
 468  * For a single stepped SVC the program check handler gets control after
 469  * the SVC new PSW has been loaded. But we want to execute the SVC first and
 470  * then handle the PER event. Therefore we update the SVC old PSW to point
 471  * to the pgm_check_handler and branch to the SVC handler after we checked
 472  * if we have to load the kernel stack register.
 473  * For every other possible cause for PER event without the PER mask set
 474  * we just ignore the PER event (FIXME: is there anything we have to do
 475  * for LPSW?).
 476  */
 477         stpt    __LC_SYNC_ENTER_TIMER
 478         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
 479         jnz     pgm_per                  # got per exception -> special case
 480         SAVE_ALL_PGM __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 481         CREATE_STACK_FRAME __LC_SAVE_AREA
 482         xc      SP_ILC(4,%r15),SP_ILC(%r15)
 483         mvc     SP_PSW(16,%r15),__LC_PGM_OLD_PSW
 484         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 485         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 486         jz      pgm_no_vtime
 487         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 488         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 489         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 490         LAST_BREAK
 491 pgm_no_vtime:
 492         HANDLE_SIE_INTERCEPT
 493         TRACE_IRQS_CHECK_OFF
 494         stg     %r11,SP_ARGS(%r15)
 495         lgf     %r3,__LC_PGM_ILC        # load program interruption code
 496         lghi    %r8,0x7f
 497         ngr     %r8,%r3
 498 pgm_do_call:
 499         sll     %r8,3
 500         larl    %r1,pgm_check_table
 501         lg      %r1,0(%r8,%r1)          # load address of handler routine
 502         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 503         basr    %r14,%r1                # branch to interrupt-handler
 504 pgm_exit:
 505         TRACE_IRQS_CHECK_ON
 506         j       sysc_return
 507
 508 #
 509 # handle per exception
 510 #
 511 pgm_per:
 512         tm      __LC_PGM_OLD_PSW,0x40   # test if per event recording is on
 513         jnz     pgm_per_std             # ok, normal per event from user space
 514 # ok its one of the special cases, now we need to find out which one
 515         clc     __LC_PGM_OLD_PSW(16),__LC_SVC_NEW_PSW
 516         je      pgm_svcper
 517 # no interesting special case, ignore PER event
 518         lpswe   __LC_PGM_OLD_PSW
 519
 520 #
 521 # Normal per exception
 522 #
 523 pgm_per_std:
 524         SAVE_ALL_PGM __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 525         CREATE_STACK_FRAME __LC_SAVE_AREA
 526         mvc     SP_PSW(16,%r15),__LC_PGM_OLD_PSW
 527         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 528         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 529         jz      pgm_no_vtime2
 530         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 531         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 532         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 533         LAST_BREAK
 534 pgm_no_vtime2:
 535         HANDLE_SIE_INTERCEPT
 536         TRACE_IRQS_CHECK_OFF
 537         lg      %r1,__TI_task(%r12)
 538         tm      SP_PSW+1(%r15),0x01     # kernel per event ?
 539         jz      kernel_per
 540         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
 541         mvc     __THREAD_per+__PER_address(8,%r1),__LC_PER_ADDRESS
 542         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
 543         oi      __TI_flags+7(%r12),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 544         lgf     %r3,__LC_PGM_ILC        # load program interruption code
 545         lghi    %r8,0x7f
 546         ngr     %r8,%r3                 # clear per-event-bit and ilc
 547         je      pgm_exit
 548         j       pgm_do_call
 549
 550 #
 551 # it was a single stepped SVC that is causing all the trouble
 552 #
 553 pgm_svcper:
 554         SAVE_ALL_PGM __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 555         CREATE_STACK_FRAME __LC_SAVE_AREA
 556         mvc     SP_PSW(16,%r15),__LC_SVC_OLD_PSW
 557         mvc     SP_ILC(4,%r15),__LC_SVC_ILC
 558         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 559         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 560         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 561         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 562         LAST_BREAK
 563         TRACE_IRQS_OFF
 564         lg      %r8,__TI_task(%r12)
 565         mvc     __THREAD_per+__PER_atmid(2,%r8),__LC_PER_ATMID
 566         mvc     __THREAD_per+__PER_address(8,%r8),__LC_PER_ADDRESS
 567         mvc     __THREAD_per+__PER_access_id(1,%r8),__LC_PER_ACCESS_ID
 568         oi      __TI_flags+7(%r12),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 569         TRACE_IRQS_ON
 570         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 571         lmg     %r2,%r6,SP_R2(%r15)     # load svc arguments
 572         j       sysc_do_svc
 573
 574 #
 575 # per was called from kernel, must be kprobes
 576 #
 577 kernel_per:
 578         xc      SP_SVCNR(2,%r15),SP_SVCNR(%r15) # clear svc number
 579         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 580         brasl   %r14,do_single_step
 581         j       pgm_exit
 582
 583 /*
 584  * IO interrupt handler routine
 585  */
 586         .globl io_int_handler
 587 io_int_handler:
 588         stck    __LC_INT_CLOCK
 589         stpt    __LC_ASYNC_ENTER_TIMER
 590         SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+40
 591         CREATE_STACK_FRAME __LC_SAVE_AREA+40
 592         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
 593         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 594         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 595         jz      io_no_vtime
 596         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 597         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 598         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 599         LAST_BREAK
 600 io_no_vtime:
 601         HANDLE_SIE_INTERCEPT
 602         TRACE_IRQS_OFF
 603         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 604         brasl   %r14,do_IRQ             # call standard irq handler
 605 io_return:
 606         LOCKDEP_SYS_EXIT
 607         TRACE_IRQS_ON
 608 io_tif:
 609         tm      __TI_flags+7(%r12),_TIF_WORK_INT
 610         jnz     io_work                 # there is work to do (signals etc.)
 611 io_restore:
 612         RESTORE_ALL __LC_RETURN_PSW,0
 613 io_done:
 614
 615 #
 616 # There is work todo, find out in which context we have been interrupted:
 617 # 1) if we return to user space we can do all _TIF_WORK_INT work
 618 # 2) if we return to kernel code and kvm is enabled check if we need to
 619 #    modify the psw to leave SIE
 620 # 3) if we return to kernel code and preemptive scheduling is enabled check
 621 #    the preemption counter and if it is zero call preempt_schedule_irq
 622 # Before any work can be done, a switch to the kernel stack is required.
 623 #
 624 io_work:
 625         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 626         jo      io_work_user            # yes -> do resched & signal
 627 #ifdef CONFIG_PREEMPT
 628         # check for preemptive scheduling
 629         icm     %r0,15,__TI_precount(%r12)
 630         jnz     io_restore              # preemption is disabled
 631         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 632         jno     io_restore
 633         # switch to kernel stack
 634         lg      %r1,SP_R15(%r15)
 635         aghi    %r1,-SP_SIZE
 636         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 637         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 638         lgr     %r15,%r1
 639         # TRACE_IRQS_ON already done at io_return, call
 640         # TRACE_IRQS_OFF to keep things symmetrical
 641         TRACE_IRQS_OFF
 642         brasl   %r14,preempt_schedule_irq
 643         j       io_return
 644 #else
 645         j       io_restore
 646 #endif
 647
 648 #
 649 # Need to do work before returning to userspace, switch to kernel stack
 650 #
 651 io_work_user:
 652         lg      %r1,__LC_KERNEL_STACK
 653         aghi    %r1,-SP_SIZE
 654         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 655         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 656         lgr     %r15,%r1
 657
 658 #
 659 # One of the work bits is on. Find out which one.
 660 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
 661 #              and _TIF_MCCK_PENDING
 662 #
 663 io_work_tif:
 664         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 665         jo      io_mcck_pending
 666         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 667         jo      io_reschedule
 668         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
 669         jo      io_sigpending
 670         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
 671         jo      io_notify_resume
 672         j       io_return               # beware of critical section cleanup
 673
 674 #
 675 # _TIF_MCCK_PENDING is set, call handler
 676 #
 677 io_mcck_pending:
 678         # TRACE_IRQS_ON already done at io_return
 679         brasl   %r14,s390_handle_mcck   # TIF bit will be cleared by handler
 680         TRACE_IRQS_OFF
 681         j       io_return
 682
 683 #
 684 # _TIF_NEED_RESCHED is set, call schedule
 685 #
 686 io_reschedule:
 687         # TRACE_IRQS_ON already done at io_return
 688         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 689         brasl   %r14,schedule           # call scheduler
 690         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 691         TRACE_IRQS_OFF
 692         j       io_return
 693
 694 #
 695 # _TIF_SIGPENDING or is set, call do_signal
 696 #
 697 io_sigpending:
 698         # TRACE_IRQS_ON already done at io_return
 699         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 700         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 701         brasl   %r14,do_signal          # call do_signal
 702         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 703         TRACE_IRQS_OFF
 704         j       io_return
 705
 706 #
 707 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
 708 #
 709 io_notify_resume:
 710         # TRACE_IRQS_ON already done at io_return
 711         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 712         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 713         brasl   %r14,do_notify_resume   # call do_notify_resume
 714         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 715         TRACE_IRQS_OFF
 716         j       io_return
 717
 718 /*
 719  * External interrupt handler routine
 720  */
 721         .globl  ext_int_handler
 722 ext_int_handler:
 723         stck    __LC_INT_CLOCK
 724         stpt    __LC_ASYNC_ENTER_TIMER
 725         SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+40
 726         CREATE_STACK_FRAME __LC_SAVE_AREA+40
 727         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
 728         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 729         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 730         jz      ext_no_vtime
 731         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 732         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 733         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 734         LAST_BREAK
 735 ext_no_vtime:
 736         HANDLE_SIE_INTERCEPT
 737         TRACE_IRQS_OFF
 738         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 739         llgh    %r3,__LC_EXT_INT_CODE   # get interruption code
 740         brasl   %r14,do_extint
 741         j       io_return
 742
 743 __critical_end:
 744
 745 /*
 746  * Machine check handler routines
 747  */
 748         .globl mcck_int_handler
 749 mcck_int_handler:
 750         stck    __LC_MCCK_CLOCK
 751         la      %r1,4095                # revalidate r1
 752         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
 753         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
 754         stmg    %r11,%r15,__LC_SAVE_AREA+80
 755         larl    %r13,system_call
 756         lg      %r11,__LC_LAST_BREAK
 757         la      %r12,__LC_MCK_OLD_PSW
 758         tm      __LC_MCCK_CODE,0x80     # system damage?
 759         jo      mcck_int_main           # yes -> rest of mcck code invalid
 760         la      %r14,4095
 761         mvc     __LC_MCCK_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA-4095(%r14)
 762         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 763         jo      1f
 764         la      %r14,__LC_SYNC_ENTER_TIMER
 765         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 766         jl      0f
 767         la      %r14,__LC_ASYNC_ENTER_TIMER
 768 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 769         jl      0f
 770         la      %r14,__LC_EXIT_TIMER
 771 0:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 772         jl      0f
 773         la      %r14,__LC_LAST_UPDATE_TIMER
 774 0:      spt     0(%r14)
 775         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 776 1:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 777         jno     mcck_int_main           # no -> skip cleanup critical
 778         tm      __LC_MCK_OLD_PSW+1,0x01 # test problem state bit
 779         jnz     mcck_int_main           # from user -> load kernel stack
 780         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_end)
 781         jhe     mcck_int_main
 782         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_start)
 783         jl      mcck_int_main
 784         brasl   %r14,cleanup_critical
 785 mcck_int_main:
 786         lg      %r14,__LC_PANIC_STACK   # are we already on the panic stack?
 787         slgr    %r14,%r15
 788         srag    %r14,%r14,PAGE_SHIFT
 789         jz      0f
 790         lg      %r15,__LC_PANIC_STACK   # load panic stack
 791 0:      aghi    %r15,-SP_SIZE           # make room for registers & psw
 792         CREATE_STACK_FRAME __LC_SAVE_AREA+80
 793         mvc     SP_PSW(16,%r15),0(%r12)
 794         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 795         tm      __LC_MCCK_CODE+2,0x08   # mwp of old psw valid?
 796         jno     mcck_no_vtime           # no -> no timer update
 797         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 798         jz      mcck_no_vtime
 799         UPDATE_VTIME __LC_EXIT_TIMER,__LC_MCCK_ENTER_TIMER,__LC_USER_TIMER
 800         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 801         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_MCCK_ENTER_TIMER
 802         LAST_BREAK
 803 mcck_no_vtime:
 804         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 805         brasl   %r14,s390_do_machine_check
 806         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 807         jno     mcck_return
 808         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
 809         aghi    %r1,-SP_SIZE
 810         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 811         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 812         lgr     %r15,%r1
 813         stosm   __SF_EMPTY(%r15),0x04   # turn dat on
 814         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 815         jno     mcck_return
 816         HANDLE_SIE_INTERCEPT
 817         TRACE_IRQS_OFF
 818         brasl   %r14,s390_handle_mcck
 819         TRACE_IRQS_ON
 820 mcck_return:
 821         mvc     __LC_RETURN_MCCK_PSW(16),SP_PSW(%r15) # move return PSW
 822         ni      __LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
 823         lmg     %r0,%r15,SP_R0(%r15)    # load gprs 0-15
 824         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 825         jno     0f
 826         stpt    __LC_EXIT_TIMER
 827 0:      lpswe   __LC_RETURN_MCCK_PSW    # back to caller
 828 mcck_done:
 829
 830 /*
 831  * Restart interruption handler, kick starter for additional CPUs
 832  */
 833 #ifdef CONFIG_SMP
 834         __CPUINIT
 835         .globl restart_int_handler
 836 restart_int_handler:
 837         basr    %r1,0
 838 restart_base:
 839         spt     restart_vtime-restart_base(%r1)
 840         stck    __LC_LAST_UPDATE_CLOCK
 841         mvc     __LC_LAST_UPDATE_TIMER(8),restart_vtime-restart_base(%r1)
 842         mvc     __LC_EXIT_TIMER(8),restart_vtime-restart_base(%r1)
 843         lg      %r15,__LC_SAVE_AREA+120 # load ksp
 844         lghi    %r10,__LC_CREGS_SAVE_AREA
 845         lctlg   %c0,%c15,0(%r10) # get new ctl regs
 846         lghi    %r10,__LC_AREGS_SAVE_AREA
 847         lam     %a0,%a15,0(%r10)
 848         lmg     %r6,%r15,__SF_GPRS(%r15) # load registers from clone
 849         lg      %r1,__LC_THREAD_INFO
 850         mvc     __LC_USER_TIMER(8),__TI_user_timer(%r1)
 851         mvc     __LC_SYSTEM_TIMER(8),__TI_system_timer(%r1)
 852         xc      __LC_STEAL_TIMER(8),__LC_STEAL_TIMER
 853         stosm   __SF_EMPTY(%r15),0x04   # now we can turn dat on
 854         jg      start_secondary
 855         .align  8
 856 restart_vtime:
 857         .long   0x7fffffff,0xffffffff
 858         .previous
 859 #else
 860 /*
 861  * If we do not run with SMP enabled, let the new CPU crash ...
 862  */
 863         .globl restart_int_handler
 864 restart_int_handler:
 865         basr    %r1,0
 866 restart_base:
 867         lpswe   restart_crash-restart_base(%r1)
 868         .align 8
 869 restart_crash:
 870         .long  0x000a0000,0x00000000,0x00000000,0x00000000
 871 restart_go:
 872 #endif
 873
 874 #ifdef CONFIG_CHECK_STACK
 875 /*
 876  * The synchronous or the asynchronous stack overflowed. We are dead.
 877  * No need to properly save the registers, we are going to panic anyway.
 878  * Setup a pt_regs so that show_trace can provide a good call trace.
 879  */
 880 stack_overflow:
 881         lg      %r15,__LC_PANIC_STACK   # change to panic stack
 882         aghi    %r15,-SP_SIZE
 883         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
 884         stmg    %r0,%r10,SP_R0(%r15)    # store gprs %r0-%r10 to kernel stack
 885         la      %r1,__LC_SAVE_AREA
 886         chi     %r12,__LC_SVC_OLD_PSW
 887         je      0f
 888         chi     %r12,__LC_PGM_OLD_PSW
 889         je      0f
 890         la      %r1,__LC_SAVE_AREA+40
 891 0:      mvc     SP_R11(40,%r15),0(%r1)  # move %r11-%r15 to stack
 892         mvc     SP_ARGS(8,%r15),__LC_LAST_BREAK
 893         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15) # clear back chain
 894         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 895         jg      kernel_stack_overflow
 896 #endif
 897
 898 cleanup_table_system_call:
 899         .quad   system_call, sysc_do_svc
 900 cleanup_table_sysc_tif:
 901         .quad   sysc_tif, sysc_restore
 902 cleanup_table_sysc_restore:
 903         .quad   sysc_restore, sysc_done
 904 cleanup_table_io_tif:
 905         .quad   io_tif, io_restore
 906 cleanup_table_io_restore:
 907         .quad   io_restore, io_done
 908
 909 cleanup_critical:
 910         clc     8(8,%r12),BASED(cleanup_table_system_call)
 911         jl      0f
 912         clc     8(8,%r12),BASED(cleanup_table_system_call+8)
 913         jl      cleanup_system_call
 914 0:
 915         clc     8(8,%r12),BASED(cleanup_table_sysc_tif)
 916         jl      0f
 917         clc     8(8,%r12),BASED(cleanup_table_sysc_tif+8)
 918         jl      cleanup_sysc_tif
 919 0:
 920         clc     8(8,%r12),BASED(cleanup_table_sysc_restore)
 921         jl      0f
 922         clc     8(8,%r12),BASED(cleanup_table_sysc_restore+8)
 923         jl      cleanup_sysc_restore
 924 0:
 925         clc     8(8,%r12),BASED(cleanup_table_io_tif)
 926         jl      0f
 927         clc     8(8,%r12),BASED(cleanup_table_io_tif+8)
 928         jl      cleanup_io_tif
 929 0:
 930         clc     8(8,%r12),BASED(cleanup_table_io_restore)
 931         jl      0f
 932         clc     8(8,%r12),BASED(cleanup_table_io_restore+8)
 933         jl      cleanup_io_restore
 934 0:
 935         br      %r14
 936
 937 cleanup_system_call:
 938         mvc     __LC_RETURN_PSW(16),0(%r12)
 939         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+8)
 940         jh      0f
 941         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
 942         cghi    %r12,__LC_MCK_OLD_PSW
 943         je      0f
 944         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 945 0:      cghi    %r12,__LC_MCK_OLD_PSW
 946         la      %r12,__LC_SAVE_AREA+80
 947         je      0f
 948         la      %r12,__LC_SAVE_AREA+40
 949 0:      clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+16)
 950         jhe     cleanup_vtime
 951         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn)
 952         jh      0f
 953         mvc     __LC_SAVE_AREA(40),0(%r12)
 954 0:      lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 955         aghi    %r15,-SP_SIZE           # make room for registers & psw
 956         stg     %r15,32(%r12)
 957         stg     %r11,0(%r12)
 958         CREATE_STACK_FRAME __LC_SAVE_AREA
 959         mvc     SP_PSW(16,%r15),__LC_SVC_OLD_PSW
 960         mvc     SP_ILC(4,%r15),__LC_SVC_ILC
 961         stg     %r7,SP_ARGS(%r15)
 962         mvc     8(8,%r12),__LC_THREAD_INFO
 963 cleanup_vtime:
 964         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+24)
 965         jhe     cleanup_stime
 966         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 967 cleanup_stime:
 968         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+32)
 969         jh      cleanup_update
 970         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 971 cleanup_update:
 972         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 973         srag    %r12,%r11,23
 974         lg      %r12,__LC_THREAD_INFO
 975         jz      0f
 976         stg     %r11,__TI_last_break(%r12)
 977 0:      mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_system_call+8)
 978         la      %r12,__LC_RETURN_PSW
 979         br      %r14
 980 cleanup_system_call_insn:
 981         .quad   sysc_saveall
 982         .quad   system_call
 983         .quad   sysc_vtime
 984         .quad   sysc_stime
 985         .quad   sysc_update
 986
 987 cleanup_sysc_tif:
 988         mvc     __LC_RETURN_PSW(8),0(%r12)
 989         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_sysc_tif)
 990         la      %r12,__LC_RETURN_PSW
 991         br      %r14
 992
 993 cleanup_sysc_restore:
 994         clc     8(8,%r12),BASED(cleanup_sysc_restore_insn)
 995         je      2f
 996         clc     8(8,%r12),BASED(cleanup_sysc_restore_insn+8)
 997         jhe     0f
 998         mvc     __LC_EXIT_TIMER(8),__LC_MCCK_ENTER_TIMER
 999         cghi    %r12,__LC_MCK_OLD_PSW
1000         je      0f
1001         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
1002 0:      mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
1003         cghi    %r12,__LC_MCK_OLD_PSW
1004         la      %r12,__LC_SAVE_AREA+80
1005         je      1f
1006         la      %r12,__LC_SAVE_AREA+40
1007 1:      mvc     0(40,%r12),SP_R11(%r15)
1008         lmg     %r0,%r10,SP_R0(%r15)
1009         lg      %r15,SP_R15(%r15)
1010 2:      la      %r12,__LC_RETURN_PSW
1011         br      %r14
1012 cleanup_sysc_restore_insn:
1013         .quad   sysc_done - 4
1014         .quad   sysc_done - 16
1015
1016 cleanup_io_tif:
1017         mvc     __LC_RETURN_PSW(8),0(%r12)
1018         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_io_tif)
1019         la      %r12,__LC_RETURN_PSW
1020         br      %r14
1021
1022 cleanup_io_restore:
1023         clc     8(8,%r12),BASED(cleanup_io_restore_insn)
1024         je      1f
1025         clc     8(8,%r12),BASED(cleanup_io_restore_insn+8)
1026         jhe     0f
1027         mvc     __LC_EXIT_TIMER(8),__LC_MCCK_ENTER_TIMER
1028 0:      mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
1029         mvc     __LC_SAVE_AREA+80(40),SP_R11(%r15)
1030         lmg     %r0,%r10,SP_R0(%r15)
1031         lg      %r15,SP_R15(%r15)
1032 1:      la      %r12,__LC_RETURN_PSW
1033         br      %r14
1034 cleanup_io_restore_insn:
1035         .quad   io_done - 4
1036         .quad   io_done - 16
1037
1038 /*
1039  * Integer constants
1040  */
1041                 .align  4
1042 .Lcritical_start:
1043                 .quad   __critical_start
1044 .Lcritical_end:
1045                 .quad   __critical_end
1046
1047                 .section .rodata, "a"
1048 #define SYSCALL(esa,esame,emu)  .long esame
1049         .globl  sys_call_table
1050 sys_call_table:
1051 #include "syscalls.S"
1052 #undef SYSCALL
1053
1054 #ifdef CONFIG_COMPAT
1055
1056 #define SYSCALL(esa,esame,emu)  .long emu
1057 sys_call_table_emu:
1058 #include "syscalls.S"
1059 #undef SYSCALL
1060 #endif