arch/powerpc/kernel/vmlinux.lds.S

   1 #ifdef CONFIG_PPC64
   2 #define PROVIDE32(x)    PROVIDE(__unused__##x)
   3 #else
   4 #define PROVIDE32(x)    PROVIDE(x)
   5 #endif
   6 #include <asm/page.h>
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/cache.h>
   9
  10 ENTRY(_stext)
  11
  12 #ifdef CONFIG_PPC64
  13 OUTPUT_ARCH(powerpc:common64)
  14 jiffies = jiffies_64;
  15 #else
  16 OUTPUT_ARCH(powerpc:common)
  17 jiffies = jiffies_64 + 4;
  18 #endif
  19 SECTIONS
  20 {
  21         /* Sections to be discarded. */
  22         /DISCARD/ : {
  23         *(.exitcall.exit)
  24         EXIT_DATA
  25         }
  26
  27         . = KERNELBASE;
  28
  29 /*
  30  * Text, read only data and other permanent read-only sections
  31  */
  32
  33         /* Text and gots */
  34         .text : AT(ADDR(.text) - LOAD_OFFSET) {
  35                 ALIGN_FUNCTION();
  36                 *(.text.head)
  37                 _text = .;
  38                 *(.text .fixup .text.init.refok .exit.text.refok)
  39                 SCHED_TEXT
  40                 LOCK_TEXT
  41                 KPROBES_TEXT
  42
  43 #ifdef CONFIG_PPC32
  44                 *(.got1)
  45                 __got2_start = .;
  46                 *(.got2)
  47                 __got2_end = .;
  48 #endif /* CONFIG_PPC32 */
  49
  50                 . = ALIGN(PAGE_SIZE);
  51                 _etext = .;
  52                 PROVIDE32 (etext = .);
  53         }
  54
  55         /* Read-only data */
  56         RODATA
  57
  58         /* Exception & bug tables */
  59         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
  60                 __start___ex_table = .;
  61                 *(__ex_table)
  62                 __stop___ex_table = .;
  63         }
  64
  65         NOTES
  66
  67 /*
  68  * Init sections discarded at runtime
  69  */
  70         . = ALIGN(PAGE_SIZE);
  71         __init_begin = .;
  72
  73         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  74                 _sinittext = .;
  75                 INIT_TEXT
  76                 _einittext = .;
  77         }
  78
  79         /* .exit.text is discarded at runtime, not link time,
  80          * to deal with references from __bug_table
  81          */
  82         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
  83                 EXIT_TEXT
  84         }
  85
  86         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
  87                 INIT_DATA
  88                 __vtop_table_begin = .;
  89                 *(.vtop_fixup);
  90                 __vtop_table_end = .;
  91                 __ptov_table_begin = .;
  92                 *(.ptov_fixup);
  93                 __ptov_table_end = .;
  94 #ifdef CONFIG_PPC_ISERIES
  95                 __dt_strings_start = .;
  96                 *(.dt_strings);
  97                 __dt_strings_end = .;
  98 #endif
  99         }
 100
 101         . = ALIGN(16);
 102         .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
 103                 __setup_start = .;
 104                 *(.init.setup)
 105                 __setup_end = .;
 106         }
 107
 108         .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 109                 __initcall_start = .;
 110                 INITCALLS
 111                 __initcall_end = .;
 112                 }
 113
 114         .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 115                 __con_initcall_start = .;
 116                 *(.con_initcall.init)
 117                 __con_initcall_end = .;
 118         }
 119
 120         SECURITY_INIT
 121
 122         . = ALIGN(8);
 123         __ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
 124                 __start___ftr_fixup = .;
 125                 *(__ftr_fixup)
 126                 __stop___ftr_fixup = .;
 127         }
 128 #ifdef CONFIG_PPC64
 129         . = ALIGN(8);
 130         __fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
 131                 __start___fw_ftr_fixup = .;
 132                 *(__fw_ftr_fixup)
 133                 __stop___fw_ftr_fixup = .;
 134         }
 135 #endif
 136 #ifdef CONFIG_BLK_DEV_INITRD
 137         . = ALIGN(PAGE_SIZE);
 138         .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
 139                 __initramfs_start = .;
 140                 *(.init.ramfs)
 141                 __initramfs_end = .;
 142         }
 143 #endif
 144         . = ALIGN(PAGE_SIZE);
 145         .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) {
 146                 __per_cpu_start = .;
 147                 *(.data.percpu)
 148                 *(.data.percpu.shared_aligned)
 149                 __per_cpu_end = .;
 150         }
 151
 152         . = ALIGN(8);
 153         .machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
 154                 __machine_desc_start = . ;
 155                 *(.machine.desc)
 156                 __machine_desc_end = . ;
 157         }
 158
 159         /* freed after init ends here */
 160         . = ALIGN(PAGE_SIZE);
 161         __init_end = .;
 162
 163 /*
 164  * And now the various read/write data
 165  */
 166
 167         . = ALIGN(PAGE_SIZE);
 168         _sdata = .;
 169
 170 #ifdef CONFIG_PPC32
 171         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 172                 DATA_DATA
 173                 *(.sdata)
 174                 *(.got.plt) *(.got)
 175         }
 176 #else
 177         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 178                 DATA_DATA
 179                 *(.data.rel*)
 180                 *(.toc1)
 181                 *(.branch_lt)
 182         }
 183
 184         .opd : AT(ADDR(.opd) - LOAD_OFFSET) {
 185                 *(.opd)
 186         }
 187
 188         .got : AT(ADDR(.got) - LOAD_OFFSET) {
 189                 __toc_start = .;
 190                 *(.got)
 191                 *(.toc)
 192         }
 193 #endif
 194
 195         . = ALIGN(PAGE_SIZE);
 196         _edata  =  .;
 197         PROVIDE32 (edata = .);
 198
 199         /* The initial task and kernel stack */
 200 #ifdef CONFIG_PPC32
 201         . = ALIGN(8192);
 202 #else
 203         . = ALIGN(16384);
 204 #endif
 205         .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 206                 *(.data.init_task)
 207         }
 208
 209         . = ALIGN(PAGE_SIZE);
 210         .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 211                 *(.data.page_aligned)
 212         }
 213
 214         .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
 215                 *(.data.cacheline_aligned)
 216         }
 217
 218         . = ALIGN(L1_CACHE_BYTES);
 219         .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
 220                 *(.data.read_mostly)
 221         }
 222
 223         . = ALIGN(PAGE_SIZE);
 224         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 225                 __nosave_begin = .;
 226                 *(.data.nosave)
 227                 . = ALIGN(PAGE_SIZE);
 228                 __nosave_end = .;
 229         }
 230
 231 /*
 232  * And finally the bss
 233  */
 234
 235         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 236                 __bss_start = .;
 237                 *(.sbss) *(.scommon)
 238                 *(.dynbss)
 239                 *(.bss)
 240                 *(COMMON)
 241                 __bss_stop = .;
 242         }
 243
 244         . = ALIGN(PAGE_SIZE);
 245         _end = . ;
 246         PROVIDE32 (end = .);
 247 }