arch/powerpc/kernel/vdso64/vdso64.lds.S

   1 /*
   2  * This is the infamous ld script for the 64 bits vdso
   3  * library
   4  */
   5 #include <asm/vdso.h>
   6
   7 OUTPUT_FORMAT("elf64-powerpc", "elf64-powerpc", "elf64-powerpc")
   8 OUTPUT_ARCH(powerpc:common64)
   9 ENTRY(_start)
  10
  11 SECTIONS
  12 {
  13         . = VDSO64_LBASE + SIZEOF_HEADERS;
  14
  15         .hash           : { *(.hash) }                  :text
  16         .gnu.hash       : { *(.gnu.hash) }
  17         .dynsym         : { *(.dynsym) }
  18         .dynstr         : { *(.dynstr) }
  19         .gnu.version    : { *(.gnu.version) }
  20         .gnu.version_d  : { *(.gnu.version_d) }
  21         .gnu.version_r  : { *(.gnu.version_r) }
  22
  23         .note           : { *(.note.*) }                :text   :note
  24
  25         . = ALIGN(16);
  26         .text           : {
  27                 *(.text .stub .text.* .gnu.linkonce.t.* __ftr_alt_*)
  28                 *(.sfpr .glink)
  29         }                                               :text
  30         PROVIDE(__etext = .);
  31         PROVIDE(_etext = .);
  32         PROVIDE(etext = .);
  33
  34         . = ALIGN(8);
  35         __ftr_fixup     : { *(__ftr_fixup) }
  36
  37         . = ALIGN(8);
  38         __lwsync_fixup  : { *(__lwsync_fixup) }
  39
  40         . = ALIGN(8);
  41         __fw_ftr_fixup  : { *(__fw_ftr_fixup) }
  42
  43         /*
  44          * Other stuff is appended to the text segment:
  45          */
  46         .rodata         : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  47         .rodata1        : { *(.rodata1) }
  48
  49         .dynamic        : { *(.dynamic) }               :text   :dynamic
  50
  51         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  52         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  53         .gcc_except_table : { *(.gcc_except_table) }
  54         .rela.dyn ALIGN(8) : { *(.rela.dyn) }
  55
  56         .opd ALIGN(8)   : { KEEP (*(.opd)) }
  57         .got ALIGN(8)   : { *(.got .toc) }
  58
  59         _end = .;
  60         PROVIDE(end = .);
  61
  62         /*
  63          * Stabs debugging sections are here too.
  64          */
  65         .stab          0 : { *(.stab) }
  66         .stabstr       0 : { *(.stabstr) }
  67         .stab.excl     0 : { *(.stab.excl) }
  68         .stab.exclstr  0 : { *(.stab.exclstr) }
  69         .stab.index    0 : { *(.stab.index) }
  70         .stab.indexstr 0 : { *(.stab.indexstr) }
  71         .comment       0 : { *(.comment) }
  72
  73         /*
  74          * DWARF debug sections.
  75          * Symbols in the DWARF debugging sections are relative to the beginning
  76          * of the section so we begin them at 0.
  77          */
  78         /* DWARF 1 */
  79         .debug          0 : { *(.debug) }
  80         .line           0 : { *(.line) }
  81         /* GNU DWARF 1 extensions */
  82         .debug_srcinfo  0 : { *(.debug_srcinfo) }
  83         .debug_sfnames  0 : { *(.debug_sfnames) }
  84         /* DWARF 1.1 and DWARF 2 */
  85         .debug_aranges  0 : { *(.debug_aranges) }
  86         .debug_pubnames 0 : { *(.debug_pubnames) }
  87         /* DWARF 2 */
  88         .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
  89         .debug_abbrev   0 : { *(.debug_abbrev) }
  90         .debug_line     0 : { *(.debug_line) }
  91         .debug_frame    0 : { *(.debug_frame) }
  92         .debug_str      0 : { *(.debug_str) }
  93         .debug_loc      0 : { *(.debug_loc) }
  94         .debug_macinfo  0 : { *(.debug_macinfo) }
  95         /* SGI/MIPS DWARF 2 extensions */
  96         .debug_weaknames 0 : { *(.debug_weaknames) }
  97         .debug_funcnames 0 : { *(.debug_funcnames) }
  98         .debug_typenames 0 : { *(.debug_typenames) }
  99         .debug_varnames  0 : { *(.debug_varnames) }
 100
 101         /DISCARD/       : {
 102                 *(.note.GNU-stack)
 103                 *(.branch_lt)
 104                 *(.data .data.* .gnu.linkonce.d.* .sdata*)
 105                 *(.bss .sbss .dynbss .dynsbss)
 106         }
 107 }
 108
 109 /*
 110  * Very old versions of ld do not recognize this name token; use the constant.
 111  */
 112 #define PT_GNU_EH_FRAME 0x6474e550
 113
 114 /*
 115  * We must supply the ELF program headers explicitly to get just one
 116  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 117  */
 118 PHDRS
 119 {
 120         text            PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
 121         dynamic         PT_DYNAMIC FLAGS(4);            /* PF_R */
 122         note            PT_NOTE FLAGS(4);               /* PF_R */
 123         eh_frame_hdr    PT_GNU_EH_FRAME;
 124 }
 125
 126 /*
 127  * This controls what symbols we export from the DSO.
 128  */
 129 VERSION
 130 {
 131         VDSO_VERSION_STRING {
 132         global:
 133                 /*
 134                  * Has to be there for the kernel to find
 135                  */
 136                 __kernel_datapage_offset;
 137
 138                 __kernel_get_syscall_map;
 139                 __kernel_gettimeofday;
 140                 __kernel_clock_gettime;
 141                 __kernel_clock_getres;
 142                 __kernel_get_tbfreq;
 143                 __kernel_sync_dicache;
 144                 __kernel_sync_dicache_p5;
 145                 __kernel_sigtramp_rt64;
 146
 147         local: *;
 148         };
 149 }