arch/powerpc/kernel/vdso32/vdso32.lds.S

   1
   2 /*
   3  * This is the infamous ld script for the 32 bits vdso
   4  * library
   5  */
   6 #include <asm/vdso.h>
   7
   8 /* Default link addresses for the vDSOs */
   9 OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc", "elf32-powerpc")
  10 OUTPUT_ARCH(powerpc:common)
  11 ENTRY(_start)
  12
  13 SECTIONS
  14 {
  15   . = VDSO32_LBASE + SIZEOF_HEADERS;
  16   .hash           : { *(.hash) }                        :text
  17   .gnu.hash       : { *(.gnu.hash) }
  18   .dynsym         : { *(.dynsym) }
  19   .dynstr         : { *(.dynstr) }
  20   .gnu.version    : { *(.gnu.version) }
  21   .gnu.version_d  : { *(.gnu.version_d) }
  22   .gnu.version_r  : { *(.gnu.version_r) }
  23
  24   .note           : { *(.note.*) }                      :text   :note
  25
  26   . = ALIGN (16);
  27   .text :
  28   {
  29     *(.text .stub .text.* .gnu.linkonce.t.*)
  30   }
  31   PROVIDE (__etext = .);
  32   PROVIDE (_etext = .);
  33   PROVIDE (etext = .);
  34
  35   /* Other stuff is appended to the text segment: */
  36   .rodata               : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  37   .rodata1              : { *(.rodata1) }
  38
  39   .eh_frame_hdr         : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  40   .eh_frame             : { KEEP (*(.eh_frame)) }       :text
  41   .gcc_except_table     : { *(.gcc_except_table) }
  42   .fixup                : { *(.fixup) }
  43
  44   .dynamic              : { *(.dynamic) }               :text   :dynamic
  45   .got : { *(.got) }
  46   .plt : { *(.plt) }
  47
  48   _end = .;
  49   __end = .;
  50   PROVIDE (end = .);
  51
  52
  53   /* Stabs debugging sections are here too
  54    */
  55   .stab 0 : { *(.stab) }
  56   .stabstr 0 : { *(.stabstr) }
  57   .stab.excl 0 : { *(.stab.excl) }
  58   .stab.exclstr 0 : { *(.stab.exclstr) }
  59   .stab.index 0 : { *(.stab.index) }
  60   .stab.indexstr 0 : { *(.stab.indexstr) }
  61   .comment 0 : { *(.comment) }
  62   .debug 0 : { *(.debug) }
  63   .line 0 : { *(.line) }
  64
  65   .debug_srcinfo 0 : { *(.debug_srcinfo) }
  66   .debug_sfnames 0 : { *(.debug_sfnames) }
  67
  68   .debug_aranges 0 : { *(.debug_aranges) }
  69   .debug_pubnames 0 : { *(.debug_pubnames) }
  70
  71   .debug_info 0 : { *(.debug_info .gnu.linkonce.wi.*) }
  72   .debug_abbrev 0 : { *(.debug_abbrev) }
  73   .debug_line 0 : { *(.debug_line) }
  74   .debug_frame 0 : { *(.debug_frame) }
  75   .debug_str 0 : { *(.debug_str) }
  76   .debug_loc 0 : { *(.debug_loc) }
  77   .debug_macinfo 0 : { *(.debug_macinfo) }
  78
  79   .debug_weaknames 0 : { *(.debug_weaknames) }
  80   .debug_funcnames 0 : { *(.debug_funcnames) }
  81   .debug_typenames 0 : { *(.debug_typenames) }
  82   .debug_varnames 0 : { *(.debug_varnames) }
  83
  84   /DISCARD/ : { *(.note.GNU-stack) }
  85   /DISCARD/ : { *(.data .data.* .gnu.linkonce.d.* .sdata*) }
  86   /DISCARD/ : { *(.bss .sbss .dynbss .dynsbss) }
  87 }
  88
  89
  90 PHDRS
  91 {
  92   text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
  93   note PT_NOTE FLAGS(4); /* PF_R */
  94   dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
  95   eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */
  96 }
  97
  98
  99 /*
 100  * This controls what symbols we export from the DSO.
 101  */
 102 VERSION
 103 {
 104   VDSO_VERSION_STRING {
 105     global:
 106         __kernel_datapage_offset; /* Has to be there for the kernel to find */
 107         __kernel_get_syscall_map;
 108         __kernel_gettimeofday;
 109         __kernel_clock_gettime;
 110         __kernel_clock_getres;
 111         __kernel_get_tbfreq;
 112         __kernel_sync_dicache;
 113         __kernel_sync_dicache_p5;
 114         __kernel_sigtramp32;
 115         __kernel_sigtramp_rt32;
 116     local: *;
 117   };
 118 }