arch/parisc/kernel/syscall.S

   1 /*
   2  * Linux/PA-RISC Project (http://www.parisc-linux.org/)
   3  *
   4  * System call entry code Copyright (c) Matthew Wilcox 1999 <willy@bofh.ai>
   5  * Licensed under the GNU GPL.
   6  * thanks to Philipp Rumpf, Mike Shaver and various others
   7  * sorry about the wall, puffin..
   8  */
   9
  10 #include <asm/asm-offsets.h>
  11 #include <asm/unistd.h>
  12 #include <asm/errno.h>
  13 #include <asm/psw.h>
  14 #include <asm/thread_info.h>
  15 #include <asm/assembly.h>
  16 #include <asm/processor.h>
  17
  18 #include <linux/linkage.h>
  19
  20         /* We fill the empty parts of the gateway page with
  21          * something that will kill the kernel or a
  22          * userspace application.
  23          */
  24 #define KILL_INSN       break   0,0
  25
  26         .level          LEVEL
  27
  28         .text
  29
  30         .import syscall_exit,code
  31         .import syscall_exit_rfi,code
  32
  33         /* Linux gateway page is aliased to virtual page 0 in the kernel
  34          * address space. Since it is a gateway page it cannot be
  35          * dereferenced, so null pointers will still fault. We start
  36          * the actual entry point at 0x100. We put break instructions
  37          * at the beginning of the page to trap null indirect function
  38          * pointers.
  39          */
  40
  41         .align ASM_PAGE_SIZE
  42 ENTRY(linux_gateway_page)
  43
  44         /* ADDRESS 0x00 to 0xb0 = 176 bytes / 4 bytes per insn = 44 insns */
  45         .rept 44
  46         KILL_INSN
  47         .endr
  48
  49         /* ADDRESS 0xb0 to 0xb4, lws uses 1 insns for entry */
  50         /* Light-weight-syscall entry must always be located at 0xb0 */
  51         /* WARNING: Keep this number updated with table size changes */
  52 #define __NR_lws_entries (2)
  53
  54 lws_entry:
  55         /* Unconditional branch to lws_start, located on the
  56            same gateway page */
  57         b,n     lws_start
  58
  59         /* Fill from 0xb4 to 0xe0 */
  60         .rept 11
  61         KILL_INSN
  62         .endr
  63
  64         /* This function MUST be located at 0xe0 for glibc's threading
  65         mechanism to work. DO NOT MOVE THIS CODE EVER! */
  66 set_thread_pointer:
  67         gate    .+8, %r0                /* increase privilege */
  68         depi    3, 31, 2, %r31          /* Ensure we return into user mode. */
  69         be      0(%sr7,%r31)            /* return to user space */
  70         mtctl   %r26, %cr27             /* move arg0 to the control register */
  71
  72         /* Increase the chance of trapping if random jumps occur to this
  73         address, fill from 0xf0 to 0x100 */
  74         .rept 4
  75         KILL_INSN
  76         .endr
  77
  78 /* This address must remain fixed at 0x100 for glibc's syscalls to work */
  79         .align 256
  80 linux_gateway_entry:
  81         gate    .+8, %r0                        /* become privileged */
  82         mtsp    %r0,%sr4                        /* get kernel space into sr4 */
  83         mtsp    %r0,%sr5                        /* get kernel space into sr5 */
  84         mtsp    %r0,%sr6                        /* get kernel space into sr6 */
  85         mfsp    %sr7,%r1                        /* save user sr7 */
  86         mtsp    %r1,%sr3                        /* and store it in sr3 */
  87
  88 #ifdef CONFIG_64BIT
  89         /* for now we can *always* set the W bit on entry to the syscall
  90          * since we don't support wide userland processes.  We could
  91          * also save the current SM other than in r0 and restore it on
  92          * exit from the syscall, and also use that value to know
  93          * whether to do narrow or wide syscalls. -PB
  94          */
  95         ssm     PSW_SM_W, %r1
  96         extrd,u %r1,PSW_W_BIT,1,%r1
  97         /* sp must be aligned on 4, so deposit the W bit setting into
  98          * the bottom of sp temporarily */
  99         or,ev   %r1,%r30,%r30
 100         b,n     1f
 101         /* The top halves of argument registers must be cleared on syscall
 102          * entry from narrow executable.
 103          */
 104         depdi   0, 31, 32, %r26
 105         depdi   0, 31, 32, %r25
 106         depdi   0, 31, 32, %r24
 107         depdi   0, 31, 32, %r23
 108         depdi   0, 31, 32, %r22
 109         depdi   0, 31, 32, %r21
 110 1:
 111 #endif
 112         mfctl   %cr30,%r1
 113         xor     %r1,%r30,%r30                   /* ye olde xor trick */
 114         xor     %r1,%r30,%r1
 115         xor     %r1,%r30,%r30
 116
 117         ldo     THREAD_SZ_ALGN+FRAME_SIZE(%r30),%r30  /* set up kernel stack */
 118
 119         /* N.B.: It is critical that we don't set sr7 to 0 until r30
 120          *       contains a valid kernel stack pointer. It is also
 121          *       critical that we don't start using the kernel stack
 122          *       until after sr7 has been set to 0.
 123          */
 124
 125         mtsp    %r0,%sr7                        /* get kernel space into sr7 */
 126         STREGM  %r1,FRAME_SIZE(%r30)            /* save r1 (usp) here for now */
 127         mfctl   %cr30,%r1                       /* get task ptr in %r1 */
 128         LDREG   TI_TASK(%r1),%r1
 129
 130         /* Save some registers for sigcontext and potential task
 131            switch (see entry.S for the details of which ones are
 132            saved/restored).  TASK_PT_PSW is zeroed so we can see whether
 133            a process is on a syscall or not.  For an interrupt the real
 134            PSW value is stored.  This is needed for gdb and sys_ptrace. */
 135         STREG   %r0,  TASK_PT_PSW(%r1)
 136         STREG   %r2,  TASK_PT_GR2(%r1)          /* preserve rp */
 137         STREG   %r19, TASK_PT_GR19(%r1)
 138
 139         LDREGM  -FRAME_SIZE(%r30), %r2          /* get users sp back */
 140 #ifdef CONFIG_64BIT
 141         extrd,u %r2,63,1,%r19                   /* W hidden in bottom bit */
 142 #if 0
 143         xor     %r19,%r2,%r2                    /* clear bottom bit */
 144         depd,z  %r19,1,1,%r19
 145         std     %r19,TASK_PT_PSW(%r1)
 146 #endif
 147 #endif
 148         STREG   %r2,  TASK_PT_GR30(%r1)         /* ... and save it */
 149
 150         STREG   %r20, TASK_PT_GR20(%r1)         /* Syscall number */
 151         STREG   %r21, TASK_PT_GR21(%r1)
 152         STREG   %r22, TASK_PT_GR22(%r1)
 153         STREG   %r23, TASK_PT_GR23(%r1)         /* 4th argument */
 154         STREG   %r24, TASK_PT_GR24(%r1)         /* 3rd argument */
 155         STREG   %r25, TASK_PT_GR25(%r1)         /* 2nd argument */
 156         STREG   %r26, TASK_PT_GR26(%r1)         /* 1st argument */
 157         STREG   %r27, TASK_PT_GR27(%r1)         /* user dp */
 158         STREG   %r28, TASK_PT_GR28(%r1)         /* return value 0 */
 159         STREG   %r28, TASK_PT_ORIG_R28(%r1)     /* return value 0 (saved for signals) */
 160         STREG   %r29, TASK_PT_GR29(%r1)         /* return value 1 */
 161         STREG   %r31, TASK_PT_GR31(%r1)         /* preserve syscall return ptr */
 162
 163         ldo     TASK_PT_FR0(%r1), %r27          /* save fpregs from the kernel */
 164         save_fp %r27                            /* or potential task switch  */
 165
 166         mfctl   %cr11, %r27                     /* i.e. SAR */
 167         STREG   %r27, TASK_PT_SAR(%r1)
 168
 169         loadgp
 170
 171 #ifdef CONFIG_64BIT
 172         ldo     -16(%r30),%r29                  /* Reference param save area */
 173         copy    %r19,%r2                        /* W bit back to r2 */
 174 #else
 175         /* no need to save these on stack in wide mode because the first 8
 176          * args are passed in registers */
 177         stw     %r22, -52(%r30)                 /* 5th argument */
 178         stw     %r21, -56(%r30)                 /* 6th argument */
 179 #endif
 180
 181         /* Are we being ptraced? */
 182         mfctl   %cr30, %r1
 183         LDREG   TI_TASK(%r1),%r1
 184         LDREG   TASK_PTRACE(%r1), %r1
 185         bb,<,n  %r1,31,.Ltracesys
 186
 187         /* Note!  We cannot use the syscall table that is mapped
 188         nearby since the gateway page is mapped execute-only. */
 189
 190 #ifdef CONFIG_64BIT
 191         ldil    L%sys_call_table, %r1
 192         or,=    %r2,%r2,%r2
 193         addil   L%(sys_call_table64-sys_call_table), %r1
 194         ldo     R%sys_call_table(%r1), %r19
 195         or,=    %r2,%r2,%r2
 196         ldo     R%sys_call_table64(%r1), %r19
 197 #else
 198         ldil    L%sys_call_table, %r1
 199         ldo     R%sys_call_table(%r1), %r19
 200 #endif
 201         comiclr,>>=     __NR_Linux_syscalls, %r20, %r0
 202         b,n     .Lsyscall_nosys
 203
 204         LDREGX  %r20(%r19), %r19
 205
 206         /* If this is a sys_rt_sigreturn call, and the signal was received
 207          * when not in_syscall, then we want to return via syscall_exit_rfi,
 208          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 209          * trampoline code in signal.c).
 210          */
 211         ldi     __NR_rt_sigreturn,%r2
 212         comb,=  %r2,%r20,.Lrt_sigreturn
 213 .Lin_syscall:
 214         ldil    L%syscall_exit,%r2
 215         be      0(%sr7,%r19)
 216         ldo     R%syscall_exit(%r2),%r2
 217 .Lrt_sigreturn:
 218         comib,<> 0,%r25,.Lin_syscall
 219         ldil    L%syscall_exit_rfi,%r2
 220         be      0(%sr7,%r19)
 221         ldo     R%syscall_exit_rfi(%r2),%r2
 222
 223         /* Note!  Because we are not running where we were linked, any
 224         calls to functions external to this file must be indirect.  To
 225         be safe, we apply the opposite rule to functions within this
 226         file, with local labels given to them to ensure correctness. */
 227
 228 .Lsyscall_nosys:
 229 syscall_nosys:
 230         ldil    L%syscall_exit,%r1
 231         be      R%syscall_exit(%sr7,%r1)
 232         ldo     -ENOSYS(%r0),%r28                  /* set errno */
 233
 234
 235 /* Warning! This trace code is a virtual duplicate of the code above so be
 236  * sure to maintain both! */
 237 .Ltracesys:
 238 tracesys:
 239         /* Need to save more registers so the debugger can see where we
 240          * are.  This saves only the lower 8 bits of PSW, so that the C
 241          * bit is still clear on syscalls, and the D bit is set if this
 242          * full register save path has been executed.  We check the D
 243          * bit on syscall_return_rfi to determine which registers to
 244          * restore.  An interrupt results in a full PSW saved with the
 245          * C bit set, a non-straced syscall entry results in C and D clear
 246          * in the saved PSW.
 247          */
 248         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 249         LDREG   TI_TASK(%r1), %r1
 250         ssm     0,%r2
 251         STREG   %r2,TASK_PT_PSW(%r1)            /* Lower 8 bits only!! */
 252         mfsp    %sr0,%r2
 253         STREG   %r2,TASK_PT_SR0(%r1)
 254         mfsp    %sr1,%r2
 255         STREG   %r2,TASK_PT_SR1(%r1)
 256         mfsp    %sr2,%r2
 257         STREG   %r2,TASK_PT_SR2(%r1)
 258         mfsp    %sr3,%r2
 259         STREG   %r2,TASK_PT_SR3(%r1)
 260         STREG   %r2,TASK_PT_SR4(%r1)
 261         STREG   %r2,TASK_PT_SR5(%r1)
 262         STREG   %r2,TASK_PT_SR6(%r1)
 263         STREG   %r2,TASK_PT_SR7(%r1)
 264         STREG   %r2,TASK_PT_IASQ0(%r1)
 265         STREG   %r2,TASK_PT_IASQ1(%r1)
 266         LDREG   TASK_PT_GR31(%r1),%r2
 267         STREG   %r2,TASK_PT_IAOQ0(%r1)
 268         ldo     4(%r2),%r2
 269         STREG   %r2,TASK_PT_IAOQ1(%r1)
 270         ldo     TASK_REGS(%r1),%r2
 271         /* reg_save %r2 */
 272         STREG   %r3,PT_GR3(%r2)
 273         STREG   %r4,PT_GR4(%r2)
 274         STREG   %r5,PT_GR5(%r2)
 275         STREG   %r6,PT_GR6(%r2)
 276         STREG   %r7,PT_GR7(%r2)
 277         STREG   %r8,PT_GR8(%r2)
 278         STREG   %r9,PT_GR9(%r2)
 279         STREG   %r10,PT_GR10(%r2)
 280         STREG   %r11,PT_GR11(%r2)
 281         STREG   %r12,PT_GR12(%r2)
 282         STREG   %r13,PT_GR13(%r2)
 283         STREG   %r14,PT_GR14(%r2)
 284         STREG   %r15,PT_GR15(%r2)
 285         STREG   %r16,PT_GR16(%r2)
 286         STREG   %r17,PT_GR17(%r2)
 287         STREG   %r18,PT_GR18(%r2)
 288         /* Finished saving things for the debugger */
 289
 290         ldil    L%syscall_trace,%r1
 291         ldil    L%tracesys_next,%r2
 292         be      R%syscall_trace(%sr7,%r1)
 293         ldo     R%tracesys_next(%r2),%r2
 294
 295 tracesys_next:
 296         ldil    L%sys_call_table,%r1
 297         ldo     R%sys_call_table(%r1), %r19
 298
 299         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 300         LDREG   TI_TASK(%r1), %r1
 301         LDREG   TASK_PT_GR20(%r1), %r20
 302         LDREG   TASK_PT_GR26(%r1), %r26         /* Restore the users args */
 303         LDREG   TASK_PT_GR25(%r1), %r25
 304         LDREG   TASK_PT_GR24(%r1), %r24
 305         LDREG   TASK_PT_GR23(%r1), %r23
 306 #ifdef CONFIG_64BIT
 307         LDREG   TASK_PT_GR22(%r1), %r22
 308         LDREG   TASK_PT_GR21(%r1), %r21
 309         ldo     -16(%r30),%r29                  /* Reference param save area */
 310 #endif
 311
 312         comiclr,>>=     __NR_Linux_syscalls, %r20, %r0
 313         b,n     .Lsyscall_nosys
 314
 315         LDREGX  %r20(%r19), %r19
 316
 317         /* If this is a sys_rt_sigreturn call, and the signal was received
 318          * when not in_syscall, then we want to return via syscall_exit_rfi,
 319          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 320          * trampoline code in signal.c).
 321          */
 322         ldi     __NR_rt_sigreturn,%r2
 323         comb,=  %r2,%r20,.Ltrace_rt_sigreturn
 324 .Ltrace_in_syscall:
 325         ldil    L%tracesys_exit,%r2
 326         be      0(%sr7,%r19)
 327         ldo     R%tracesys_exit(%r2),%r2
 328
 329         /* Do *not* call this function on the gateway page, because it
 330         makes a direct call to syscall_trace. */
 331
 332 tracesys_exit:
 333         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 334         LDREG   TI_TASK(%r1), %r1
 335 #ifdef CONFIG_64BIT
 336         ldo     -16(%r30),%r29                  /* Reference param save area */
 337 #endif
 338         bl      syscall_trace, %r2
 339         STREG   %r28,TASK_PT_GR28(%r1)          /* save return value now */
 340         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 341         LDREG   TI_TASK(%r1), %r1
 342         LDREG   TASK_PT_GR28(%r1), %r28         /* Restore return val. */
 343
 344         ldil    L%syscall_exit,%r1
 345         be,n    R%syscall_exit(%sr7,%r1)
 346
 347 .Ltrace_rt_sigreturn:
 348         comib,<> 0,%r25,.Ltrace_in_syscall
 349         ldil    L%tracesys_sigexit,%r2
 350         be      0(%sr7,%r19)
 351         ldo     R%tracesys_sigexit(%r2),%r2
 352
 353 tracesys_sigexit:
 354         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 355         LDREG   0(%r1), %r1
 356 #ifdef CONFIG_64BIT
 357         ldo     -16(%r30),%r29                  /* Reference param save area */
 358 #endif
 359         bl      syscall_trace, %r2
 360         nop
 361
 362         ldil    L%syscall_exit_rfi,%r1
 363         be,n    R%syscall_exit_rfi(%sr7,%r1)
 364
 365
 366         /*********************************************************
 367                 Light-weight-syscall code
 368
 369                 r20 - lws number
 370                 r26,r25,r24,r23,r22 - Input registers
 371                 r28 - Function return register
 372                 r21 - Error code.
 373
 374                 Scracth: Any of the above that aren't being
 375                 currently used, including r1.
 376
 377                 Return pointer: r31 (Not usable)
 378
 379                 Error codes returned by entry path:
 380
 381                 ENOSYS - r20 was an invalid LWS number.
 382
 383         *********************************************************/
 384 lws_start:
 385         /* Gate and ensure we return to userspace */
 386         gate    .+8, %r0
 387         depi    3, 31, 2, %r31  /* Ensure we return to userspace */
 388
 389 #ifdef CONFIG_64BIT
 390         /* FIXME: If we are a 64-bit kernel just
 391          *        turn this on unconditionally.
 392          */
 393         ssm     PSW_SM_W, %r1
 394         extrd,u %r1,PSW_W_BIT,1,%r1
 395         /* sp must be aligned on 4, so deposit the W bit setting into
 396          * the bottom of sp temporarily */
 397         or,ev   %r1,%r30,%r30
 398
 399         /* Clip LWS number to a 32-bit value always */
 400         depdi   0, 31, 32, %r20
 401 #endif
 402
 403         /* Is the lws entry number valid? */
 404         comiclr,>>=     __NR_lws_entries, %r20, %r0
 405         b,n     lws_exit_nosys
 406
 407         /* WARNING: Trashing sr2 and sr3 */
 408         mfsp    %sr7,%r1                        /* get userspace into sr3 */
 409         mtsp    %r1,%sr3
 410         mtsp    %r0,%sr2                        /* get kernel space into sr2 */
 411
 412         /* Load table start */
 413         ldil    L%lws_table, %r1
 414         ldo     R%lws_table(%r1), %r28  /* Scratch use of r28 */
 415         LDREGX  %r20(%sr2,r28), %r21    /* Scratch use of r21 */
 416
 417         /* Jump to lws, lws table pointers already relocated */
 418         be,n    0(%sr2,%r21)
 419
 420 lws_exit_nosys:
 421         ldo     -ENOSYS(%r0),%r21                  /* set errno */
 422         /* Fall through: Return to userspace */
 423
 424 lws_exit:
 425 #ifdef CONFIG_64BIT
 426         /* decide whether to reset the wide mode bit
 427          *
 428          * For a syscall, the W bit is stored in the lowest bit
 429          * of sp.  Extract it and reset W if it is zero */
 430         extrd,u,*<>     %r30,63,1,%r1
 431         rsm     PSW_SM_W, %r0
 432         /* now reset the lowest bit of sp if it was set */
 433         xor     %r30,%r1,%r30
 434 #endif
 435         be,n    0(%sr3, %r31)
 436
 437
 438
 439         /***************************************************
 440                 Implementing CAS as an atomic operation:
 441
 442                 %r26 - Address to examine
 443                 %r25 - Old value to check (old)
 444                 %r24 - New value to set (new)
 445                 %r28 - Return prev through this register.
 446                 %r21 - Kernel error code
 447
 448                 If debugging is DISabled:
 449
 450                 %r21 has the following meanings:
 451
 452                 EAGAIN - CAS is busy, ldcw failed, try again.
 453                 EFAULT - Read or write failed.
 454
 455                 If debugging is enabled:
 456
 457                 EDEADLOCK - CAS called recursively.
 458                 EAGAIN && r28 == 1 - CAS is busy. Lock contended.
 459                 EAGAIN && r28 == 2 - CAS is busy. ldcw failed.
 460                 EFAULT - Read or write failed.
 461
 462                 Scratch: r20, r28, r1
 463
 464         ****************************************************/
 465
 466         /* Do not enable LWS debugging */
 467 #define ENABLE_LWS_DEBUG 0
 468
 469         /* ELF64 Process entry path */
 470 lws_compare_and_swap64:
 471 #ifdef CONFIG_64BIT
 472         b,n     lws_compare_and_swap
 473 #else
 474         /* If we are not a 64-bit kernel, then we don't
 475          * implement having 64-bit input registers
 476          */
 477         b,n     lws_exit_nosys
 478 #endif
 479
 480         /* ELF32 Process entry path */
 481 lws_compare_and_swap32:
 482 #ifdef CONFIG_64BIT
 483         /* Clip all the input registers */
 484         depdi   0, 31, 32, %r26
 485         depdi   0, 31, 32, %r25
 486         depdi   0, 31, 32, %r24
 487 #endif
 488
 489 lws_compare_and_swap:
 490 #ifdef CONFIG_SMP
 491         /* Load start of lock table */
 492         ldil    L%lws_lock_start, %r20
 493         ldo     R%lws_lock_start(%r20), %r28
 494
 495         /* Extract four bits from r26 and hash lock (Bits 4-7) */
 496         extru  %r26, 27, 4, %r20
 497
 498         /* Find lock to use, the hash is either one of 0 to
 499            15, multiplied by 16 (keep it 16-byte aligned)
 500            and add to the lock table offset. */
 501         shlw    %r20, 4, %r20
 502         add     %r20, %r28, %r20
 503
 504 # ifdef ENABLE_LWS_DEBUG
 505         /*
 506                 DEBUG, check for deadlock!
 507                 If the thread register values are the same
 508                 then we were the one that locked it last and
 509                 this is a recurisve call that will deadlock.
 510                 We *must* giveup this call and fail.
 511         */
 512         ldw     4(%sr2,%r20), %r28                      /* Load thread register */
 513         /* WARNING: If cr27 cycles to the same value we have problems */
 514         mfctl   %cr27, %r21                             /* Get current thread register */
 515         cmpb,<>,n       %r21, %r28, cas_lock            /* Called recursive? */
 516         b       lws_exit                                /* Return error! */
 517         ldo     -EDEADLOCK(%r0), %r21
 518 cas_lock:
 519         cmpb,=,n        %r0, %r28, cas_nocontend        /* Is nobody using it? */
 520         ldo     1(%r0), %r28                            /* 1st case */
 521         b       lws_exit                                /* Contended... */
 522         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 523 cas_nocontend:
 524 # endif
 525 /* ENABLE_LWS_DEBUG */
 526
 527         LDCW    0(%sr2,%r20), %r28                      /* Try to acquire the lock */
 528         cmpb,<>,n       %r0, %r28, cas_action           /* Did we get it? */
 529 cas_wouldblock:
 530         ldo     2(%r0), %r28                            /* 2nd case */
 531         b       lws_exit                                /* Contended... */
 532         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 533 #endif
 534 /* CONFIG_SMP */
 535
 536         /*
 537                 prev = *addr;
 538                 if ( prev == old )
 539                   *addr = new;
 540                 return prev;
 541         */
 542
 543         /* NOTES:
 544                 This all works becuse intr_do_signal
 545                 and schedule both check the return iasq
 546                 and see that we are on the kernel page
 547                 so this process is never scheduled off
 548                 or is ever sent any signal of any sort,
 549                 thus it is wholly atomic from usrspaces
 550                 perspective
 551         */
 552 cas_action:
 553 #if defined CONFIG_SMP && defined ENABLE_LWS_DEBUG
 554         /* DEBUG */
 555         mfctl   %cr27, %r1
 556         stw     %r1, 4(%sr2,%r20)
 557 #endif
 558         /* The load and store could fail */
 559 1:      ldw     0(%sr3,%r26), %r28
 560         sub,<>  %r28, %r25, %r0
 561 2:      stw     %r24, 0(%sr3,%r26)
 562 #ifdef CONFIG_SMP
 563         /* Free lock */
 564         stw     %r20, 0(%sr2,%r20)
 565 # ifdef ENABLE_LWS_DEBUG
 566         /* Clear thread register indicator */
 567         stw     %r0, 4(%sr2,%r20)
 568 # endif
 569 #endif
 570         /* Return to userspace, set no error */
 571         b       lws_exit
 572         copy    %r0, %r21
 573
 574 3:
 575         /* Error occured on load or store */
 576 #ifdef CONFIG_SMP
 577         /* Free lock */
 578         stw     %r20, 0(%sr2,%r20)
 579 # ifdef ENABLE_LWS_DEBUG
 580         stw     %r0, 4(%sr2,%r20)
 581 # endif
 582 #endif
 583         b       lws_exit
 584         ldo     -EFAULT(%r0),%r21       /* set errno */
 585         nop
 586         nop
 587         nop
 588         nop
 589
 590         /* Two exception table entries, one for the load,
 591            the other for the store. Either return -EFAULT.
 592            Each of the entries must be relocated. */
 593         .section __ex_table,"aw"
 594         ASM_ULONG_INSN (1b - linux_gateway_page), (3b - linux_gateway_page)
 595         ASM_ULONG_INSN (2b - linux_gateway_page), (3b - linux_gateway_page)
 596         .previous
 597
 598
 599         /* Make sure nothing else is placed on this page */
 600         .align ASM_PAGE_SIZE
 601 END(linux_gateway_page)
 602 ENTRY(end_linux_gateway_page)
 603
 604         /* Relocate symbols assuming linux_gateway_page is mapped
 605            to virtual address 0x0 */
 606
 607 #define LWS_ENTRY(_name_) ASM_ULONG_INSN (lws_##_name_ - linux_gateway_page)
 608
 609         .section .rodata,"a"
 610
 611         .align ASM_PAGE_SIZE
 612         /* Light-weight-syscall table */
 613         /* Start of lws table. */
 614 ENTRY(lws_table)
 615         LWS_ENTRY(compare_and_swap32)   /* 0 - ELF32 Atomic compare and swap */
 616         LWS_ENTRY(compare_and_swap64)   /* 1 - ELF64 Atomic compare and swap */
 617 END(lws_table)
 618         /* End of lws table */
 619
 620         .align ASM_PAGE_SIZE
 621 ENTRY(sys_call_table)
 622 #include "syscall_table.S"
 623 END(sys_call_table)
 624
 625 #ifdef CONFIG_64BIT
 626         .align ASM_PAGE_SIZE
 627 ENTRY(sys_call_table64)
 628 #define SYSCALL_TABLE_64BIT
 629 #include "syscall_table.S"
 630 END(sys_call_table64)
 631 #endif
 632
 633 #ifdef CONFIG_SMP
 634         /*
 635                 All light-weight-syscall atomic operations
 636                 will use this set of locks
 637         */
 638         .section .data
 639         .align 4096
 640 ENTRY(lws_lock_start)
 641         /* lws locks */
 642         .align 16
 643         .rept 16
 644         /* Keep locks aligned at 16-bytes */
 645         .word 1
 646         .word 0
 647         .word 0
 648         .word 0
 649         .endr
 650 END(lws_lock_start)
 651         .previous
 652 #endif
 653 /* CONFIG_SMP for lws_lock_start */
 654
 655 .end
 656
 657