arch/mips/kernel/vmlinux.lds.S

   1 #include <asm/asm-offsets.h>
   2 #include <asm/page.h>
   3 #include <asm-generic/vmlinux.lds.h>
   4
   5 #undef mips
   6 #define mips mips
   7 OUTPUT_ARCH(mips)
   8 ENTRY(kernel_entry)
   9 PHDRS {
  10         text PT_LOAD FLAGS(7);  /* RWX */
  11         note PT_NOTE FLAGS(4);  /* R__ */
  12 }
  13
  14 #ifdef CONFIG_32BIT
  15         #ifdef CONFIG_CPU_LITTLE_ENDIAN
  16                 jiffies  = jiffies_64;
  17         #else
  18                 jiffies  = jiffies_64 + 4;
  19         #endif
  20 #else
  21         jiffies  = jiffies_64;
  22 #endif
  23
  24 SECTIONS
  25 {
  26 #ifdef CONFIG_BOOT_ELF64
  27         /* Read-only sections, merged into text segment: */
  28         /* . = 0xc000000000000000; */
  29
  30         /* This is the value for an Origin kernel, taken from an IRIX kernel.  */
  31         /* . = 0xc00000000001c000; */
  32
  33         /* Set the vaddr for the text segment to a value
  34          *   >= 0xa800 0000 0001 9000 if no symmon is going to configured
  35          *   >= 0xa800 0000 0030 0000 otherwise
  36          */
  37
  38         /* . = 0xa800000000300000; */
  39         . = 0xffffffff80300000;
  40 #endif
  41         . = VMLINUX_LOAD_ADDRESS;
  42         /* read-only */
  43         _text = .;      /* Text and read-only data */
  44         .text : {
  45                 TEXT_TEXT
  46                 SCHED_TEXT
  47                 LOCK_TEXT
  48                 KPROBES_TEXT
  49                 IRQENTRY_TEXT
  50                 *(.text.*)
  51                 *(.fixup)
  52                 *(.gnu.warning)
  53         } :text = 0
  54         _etext = .;     /* End of text section */
  55
  56         EXCEPTION_TABLE(16)
  57
  58         /* Exception table for data bus errors */
  59         __dbe_table : {
  60                 __start___dbe_table = .;
  61                 *(__dbe_table)
  62                 __stop___dbe_table = .;
  63         }
  64
  65         NOTES :text :note
  66         .dummy : { *(.dummy) } :text
  67
  68         RODATA
  69
  70         /* writeable */
  71         .data : {       /* Data */
  72                 . = . + DATAOFFSET;             /* for CONFIG_MAPPED_KERNEL */
  73
  74                 INIT_TASK_DATA(PAGE_SIZE)
  75                 NOSAVE_DATA
  76                 CACHELINE_ALIGNED_DATA(1 << CONFIG_MIPS_L1_CACHE_SHIFT)
  77                 DATA_DATA
  78                 CONSTRUCTORS
  79         }
  80         _gp = . + 0x8000;
  81         .lit8 : {
  82                 *(.lit8)
  83         }
  84         .lit4 : {
  85                 *(.lit4)
  86         }
  87         /* We want the small data sections together, so single-instruction offsets
  88            can access them all, and initialized data all before uninitialized, so
  89            we can shorten the on-disk segment size.  */
  90         .sdata : {
  91                 *(.sdata)
  92         }
  93         _edata =  .;                    /* End of data section */
  94
  95         /* will be freed after init */
  96         . = ALIGN(PAGE_SIZE);           /* Init code and data */
  97         __init_begin = .;
  98         INIT_TEXT_SECTION(PAGE_SIZE)
  99         INIT_DATA_SECTION(16)
 100
 101         . = ALIGN(4);
 102         .mips.machines.init : AT(ADDR(.mips.machines.init) - LOAD_OFFSET) {
 103                 __mips_machines_start = .;
 104                 *(.mips.machines.init)
 105                 __mips_machines_end = .;
 106         }
 107
 108         /* .exit.text is discarded at runtime, not link time, to deal with
 109          * references from .rodata
 110          */
 111         .exit.text : {
 112                 EXIT_TEXT
 113         }
 114         .exit.data : {
 115                 EXIT_DATA
 116         }
 117
 118         PERCPU(PAGE_SIZE)
 119         . = ALIGN(PAGE_SIZE);
 120         __init_end = .;
 121         /* freed after init ends here */
 122
 123         BSS_SECTION(0, 0, 0)
 124
 125         _end = . ;
 126
 127         /* These mark the ABI of the kernel for debuggers.  */
 128         .mdebug.abi32 : {
 129                 KEEP(*(.mdebug.abi32))
 130         }
 131         .mdebug.abi64 : {
 132                 KEEP(*(.mdebug.abi64))
 133         }
 134
 135         /* This is the MIPS specific mdebug section.  */
 136         .mdebug : {
 137                 *(.mdebug)
 138         }
 139
 140         STABS_DEBUG
 141         DWARF_DEBUG
 142
 143         /* These must appear regardless of  .  */
 144         .gptab.sdata : {
 145                 *(.gptab.data)
 146                 *(.gptab.sdata)
 147         }
 148         .gptab.sbss : {
 149                 *(.gptab.bss)
 150                 *(.gptab.sbss)
 151         }
 152
 153         /* Sections to be discarded */
 154         DISCARDS
 155         /DISCARD/ : {
 156                 /* ABI crap starts here */
 157                 *(.MIPS.options)
 158                 *(.options)
 159                 *(.pdr)
 160                 *(.reginfo)
 161         }
 162 }