arch/mips/kernel/gdb-low.S

   1 /*
   2  * gdb-low.S contains the low-level trap handler for the GDB stub.
   3  *
   4  * Copyright (C) 1995 Andreas Busse
   5  */
   6 #include <linux/sys.h>
   7
   8 #include <asm/asm.h>
   9 #include <asm/errno.h>
  10 #include <asm/mipsregs.h>
  11 #include <asm/regdef.h>
  12 #include <asm/stackframe.h>
  13 #include <asm/gdb-stub.h>
  14
  15 #ifdef CONFIG_32BIT
  16 #define DMFC0   mfc0
  17 #define DMTC0   mtc0
  18 #define LDC1    lwc1
  19 #define SDC1    lwc1
  20 #endif
  21 #ifdef CONFIG_64BIT
  22 #define DMFC0   dmfc0
  23 #define DMTC0   dmtc0
  24 #define LDC1    ldc1
  25 #define SDC1    ldc1
  26 #endif
  27
  28 /*
  29  * [jsun] We reserves about 2x GDB_FR_SIZE in stack.  The lower (addressed)
  30  * part is used to store registers and passed to exception handler.
  31  * The upper part is reserved for "call func" feature where gdb client
  32  * saves some of the regs, setups call frame and passes args.
  33  *
  34  * A trace shows about 200 bytes are used to store about half of all regs.
  35  * The rest should be big enough for frame setup and passing args.
  36  */
  37
  38 /*
  39  * The low level trap handler
  40  */
  41                 .align  5
  42                 NESTED(trap_low, GDB_FR_SIZE, sp)
  43                 .set    noat
  44                 .set    noreorder
  45
  46                 mfc0    k0, CP0_STATUS
  47                 sll     k0, 3                   /* extract cu0 bit */
  48                 bltz    k0, 1f
  49                 move    k1, sp
  50
  51                 /*
  52                  * Called from user mode, go somewhere else.
  53                  */
  54                 mfc0    k0, CP0_CAUSE
  55                 andi    k0, k0, 0x7c
  56 #ifdef CONFIG_64BIT
  57                 dsll    k0, k0, 1
  58 #endif
  59                 PTR_L   k1, saved_vectors(k0)
  60                 jr      k1
  61                 nop
  62 1:
  63                 move    k0, sp
  64                 PTR_SUBU sp, k1, GDB_FR_SIZE*2  # see comment above
  65                 LONG_S  k0, GDB_FR_REG29(sp)
  66                 LONG_S  $2, GDB_FR_REG2(sp)
  67
  68 /*
  69  * First save the CP0 and special registers
  70  */
  71
  72                 mfc0    v0, CP0_STATUS
  73                 LONG_S  v0, GDB_FR_STATUS(sp)
  74                 mfc0    v0, CP0_CAUSE
  75                 LONG_S  v0, GDB_FR_CAUSE(sp)
  76                 DMFC0   v0, CP0_EPC
  77                 LONG_S  v0, GDB_FR_EPC(sp)
  78                 DMFC0   v0, CP0_BADVADDR
  79                 LONG_S  v0, GDB_FR_BADVADDR(sp)
  80                 mfhi    v0
  81                 LONG_S  v0, GDB_FR_HI(sp)
  82                 mflo    v0
  83                 LONG_S  v0, GDB_FR_LO(sp)
  84
  85 /*
  86  * Now the integer registers
  87  */
  88
  89                 LONG_S  zero, GDB_FR_REG0(sp)           /* I know... */
  90                 LONG_S  $1, GDB_FR_REG1(sp)
  91                 /* v0 already saved */
  92                 LONG_S  $3, GDB_FR_REG3(sp)
  93                 LONG_S  $4, GDB_FR_REG4(sp)
  94                 LONG_S  $5, GDB_FR_REG5(sp)
  95                 LONG_S  $6, GDB_FR_REG6(sp)
  96                 LONG_S  $7, GDB_FR_REG7(sp)
  97                 LONG_S  $8, GDB_FR_REG8(sp)
  98                 LONG_S  $9, GDB_FR_REG9(sp)
  99                 LONG_S  $10, GDB_FR_REG10(sp)
 100                 LONG_S  $11, GDB_FR_REG11(sp)
 101                 LONG_S  $12, GDB_FR_REG12(sp)
 102                 LONG_S  $13, GDB_FR_REG13(sp)
 103                 LONG_S  $14, GDB_FR_REG14(sp)
 104                 LONG_S  $15, GDB_FR_REG15(sp)
 105                 LONG_S  $16, GDB_FR_REG16(sp)
 106                 LONG_S  $17, GDB_FR_REG17(sp)
 107                 LONG_S  $18, GDB_FR_REG18(sp)
 108                 LONG_S  $19, GDB_FR_REG19(sp)
 109                 LONG_S  $20, GDB_FR_REG20(sp)
 110                 LONG_S  $21, GDB_FR_REG21(sp)
 111                 LONG_S  $22, GDB_FR_REG22(sp)
 112                 LONG_S  $23, GDB_FR_REG23(sp)
 113                 LONG_S  $24, GDB_FR_REG24(sp)
 114                 LONG_S  $25, GDB_FR_REG25(sp)
 115                 LONG_S  $26, GDB_FR_REG26(sp)
 116                 LONG_S  $27, GDB_FR_REG27(sp)
 117                 LONG_S  $28, GDB_FR_REG28(sp)
 118                 /* sp already saved */
 119                 LONG_S  $30, GDB_FR_REG30(sp)
 120                 LONG_S  $31, GDB_FR_REG31(sp)
 121
 122                 CLI                             /* disable interrupts */
 123
 124 /*
 125  * Followed by the floating point registers
 126  */
 127                 mfc0    v0, CP0_STATUS          /* FPU enabled? */
 128                 srl     v0, v0, 16
 129                 andi    v0, v0, (ST0_CU1 >> 16)
 130
 131                 beqz    v0,2f                   /* disabled, skip */
 132                  nop
 133
 134                 SDC1    $0, GDB_FR_FPR0(sp)
 135                 SDC1    $1, GDB_FR_FPR1(sp)
 136                 SDC1    $2, GDB_FR_FPR2(sp)
 137                 SDC1    $3, GDB_FR_FPR3(sp)
 138                 SDC1    $4, GDB_FR_FPR4(sp)
 139                 SDC1    $5, GDB_FR_FPR5(sp)
 140                 SDC1    $6, GDB_FR_FPR6(sp)
 141                 SDC1    $7, GDB_FR_FPR7(sp)
 142                 SDC1    $8, GDB_FR_FPR8(sp)
 143                 SDC1    $9, GDB_FR_FPR9(sp)
 144                 SDC1    $10, GDB_FR_FPR10(sp)
 145                 SDC1    $11, GDB_FR_FPR11(sp)
 146                 SDC1    $12, GDB_FR_FPR12(sp)
 147                 SDC1    $13, GDB_FR_FPR13(sp)
 148                 SDC1    $14, GDB_FR_FPR14(sp)
 149                 SDC1    $15, GDB_FR_FPR15(sp)
 150                 SDC1    $16, GDB_FR_FPR16(sp)
 151                 SDC1    $17, GDB_FR_FPR17(sp)
 152                 SDC1    $18, GDB_FR_FPR18(sp)
 153                 SDC1    $19, GDB_FR_FPR19(sp)
 154                 SDC1    $20, GDB_FR_FPR20(sp)
 155                 SDC1    $21, GDB_FR_FPR21(sp)
 156                 SDC1    $22, GDB_FR_FPR22(sp)
 157                 SDC1    $23, GDB_FR_FPR23(sp)
 158                 SDC1    $24, GDB_FR_FPR24(sp)
 159                 SDC1    $25, GDB_FR_FPR25(sp)
 160                 SDC1    $26, GDB_FR_FPR26(sp)
 161                 SDC1    $27, GDB_FR_FPR27(sp)
 162                 SDC1    $28, GDB_FR_FPR28(sp)
 163                 SDC1    $29, GDB_FR_FPR29(sp)
 164                 SDC1    $30, GDB_FR_FPR30(sp)
 165                 SDC1    $31, GDB_FR_FPR31(sp)
 166
 167 /*
 168  * FPU control registers
 169  */
 170
 171                 cfc1    v0, CP1_STATUS
 172                 LONG_S  v0, GDB_FR_FSR(sp)
 173                 cfc1    v0, CP1_REVISION
 174                 LONG_S  v0, GDB_FR_FIR(sp)
 175
 176 /*
 177  * Current stack frame ptr
 178  */
 179
 180 2:
 181                 LONG_S  sp, GDB_FR_FRP(sp)
 182
 183 /*
 184  * CP0 registers (R4000/R4400 unused registers skipped)
 185  */
 186
 187                 mfc0    v0, CP0_INDEX
 188                 LONG_S  v0, GDB_FR_CP0_INDEX(sp)
 189                 mfc0    v0, CP0_RANDOM
 190                 LONG_S  v0, GDB_FR_CP0_RANDOM(sp)
 191                 DMFC0   v0, CP0_ENTRYLO0
 192                 LONG_S  v0, GDB_FR_CP0_ENTRYLO0(sp)
 193                 DMFC0   v0, CP0_ENTRYLO1
 194                 LONG_S  v0, GDB_FR_CP0_ENTRYLO1(sp)
 195                 DMFC0   v0, CP0_CONTEXT
 196                 LONG_S  v0, GDB_FR_CP0_CONTEXT(sp)
 197                 mfc0    v0, CP0_PAGEMASK
 198                 LONG_S  v0, GDB_FR_CP0_PAGEMASK(sp)
 199                 mfc0    v0, CP0_WIRED
 200                 LONG_S  v0, GDB_FR_CP0_WIRED(sp)
 201                 DMFC0   v0, CP0_ENTRYHI
 202                 LONG_S  v0, GDB_FR_CP0_ENTRYHI(sp)
 203                 mfc0    v0, CP0_PRID
 204                 LONG_S  v0, GDB_FR_CP0_PRID(sp)
 205
 206                 .set    at
 207
 208 /*
 209  * Continue with the higher level handler
 210  */
 211
 212                 move    a0,sp
 213
 214                 jal     handle_exception
 215                  nop
 216
 217 /*
 218  * Restore all writable registers, in reverse order
 219  */
 220
 221                 .set    noat
 222
 223                 LONG_L  v0, GDB_FR_CP0_ENTRYHI(sp)
 224                 LONG_L  v1, GDB_FR_CP0_WIRED(sp)
 225                 DMTC0   v0, CP0_ENTRYHI
 226                 mtc0    v1, CP0_WIRED
 227                 LONG_L  v0, GDB_FR_CP0_PAGEMASK(sp)
 228                 LONG_L  v1, GDB_FR_CP0_ENTRYLO1(sp)
 229                 mtc0    v0, CP0_PAGEMASK
 230                 DMTC0   v1, CP0_ENTRYLO1
 231                 LONG_L  v0, GDB_FR_CP0_ENTRYLO0(sp)
 232                 LONG_L  v1, GDB_FR_CP0_INDEX(sp)
 233                 DMTC0   v0, CP0_ENTRYLO0
 234                 LONG_L  v0, GDB_FR_CP0_CONTEXT(sp)
 235                 mtc0    v1, CP0_INDEX
 236                 DMTC0   v0, CP0_CONTEXT
 237
 238
 239 /*
 240  * Next, the floating point registers
 241  */
 242                 mfc0    v0, CP0_STATUS          /* check if the FPU is enabled */
 243                 srl     v0, v0, 16
 244                 andi    v0, v0, (ST0_CU1 >> 16)
 245
 246                 beqz    v0, 3f                  /* disabled, skip */
 247                  nop
 248
 249                 LDC1    $31, GDB_FR_FPR31(sp)
 250                 LDC1    $30, GDB_FR_FPR30(sp)
 251                 LDC1    $29, GDB_FR_FPR29(sp)
 252                 LDC1    $28, GDB_FR_FPR28(sp)
 253                 LDC1    $27, GDB_FR_FPR27(sp)
 254                 LDC1    $26, GDB_FR_FPR26(sp)
 255                 LDC1    $25, GDB_FR_FPR25(sp)
 256                 LDC1    $24, GDB_FR_FPR24(sp)
 257                 LDC1    $23, GDB_FR_FPR23(sp)
 258                 LDC1    $22, GDB_FR_FPR22(sp)
 259                 LDC1    $21, GDB_FR_FPR21(sp)
 260                 LDC1    $20, GDB_FR_FPR20(sp)
 261                 LDC1    $19, GDB_FR_FPR19(sp)
 262                 LDC1    $18, GDB_FR_FPR18(sp)
 263                 LDC1    $17, GDB_FR_FPR17(sp)
 264                 LDC1    $16, GDB_FR_FPR16(sp)
 265                 LDC1    $15, GDB_FR_FPR15(sp)
 266                 LDC1    $14, GDB_FR_FPR14(sp)
 267                 LDC1    $13, GDB_FR_FPR13(sp)
 268                 LDC1    $12, GDB_FR_FPR12(sp)
 269                 LDC1    $11, GDB_FR_FPR11(sp)
 270                 LDC1    $10, GDB_FR_FPR10(sp)
 271                 LDC1    $9, GDB_FR_FPR9(sp)
 272                 LDC1    $8, GDB_FR_FPR8(sp)
 273                 LDC1    $7, GDB_FR_FPR7(sp)
 274                 LDC1    $6, GDB_FR_FPR6(sp)
 275                 LDC1    $5, GDB_FR_FPR5(sp)
 276                 LDC1    $4, GDB_FR_FPR4(sp)
 277                 LDC1    $3, GDB_FR_FPR3(sp)
 278                 LDC1    $2, GDB_FR_FPR2(sp)
 279                 LDC1    $1, GDB_FR_FPR1(sp)
 280                 LDC1    $0, GDB_FR_FPR0(sp)
 281
 282 /*
 283  * Now the CP0 and integer registers
 284  */
 285
 286 3:
 287 #ifdef CONFIG_MIPS_MT_SMTC
 288                 /* Read-modify write of Status must be atomic */
 289                 mfc0    t2, CP0_TCSTATUS
 290                 ori     t1, t2, TCSTATUS_IXMT
 291                 mtc0    t1, CP0_TCSTATUS
 292                 andi    t2, t2, TCSTATUS_IXMT
 293                 _ehb
 294                 DMT     9                               # dmt   t1
 295                 jal     mips_ihb
 296                 nop
 297 #endif /* CONFIG_MIPS_MT_SMTC */
 298                 mfc0    t0, CP0_STATUS
 299                 ori     t0, 0x1f
 300                 xori    t0, 0x1f
 301                 mtc0    t0, CP0_STATUS
 302 #ifdef CONFIG_MIPS_MT_SMTC
 303                 andi    t1, t1, VPECONTROL_TE
 304                 beqz    t1, 9f
 305                 nop
 306                 EMT                                     # emt
 307 9:
 308                 mfc0    t1, CP0_TCSTATUS
 309                 xori    t1, t1, TCSTATUS_IXMT
 310                 or      t1, t1, t2
 311                 mtc0    t1, CP0_TCSTATUS
 312                 _ehb
 313 #endif /* CONFIG_MIPS_MT_SMTC */
 314                 LONG_L  v0, GDB_FR_STATUS(sp)
 315                 LONG_L  v1, GDB_FR_EPC(sp)
 316                 mtc0    v0, CP0_STATUS
 317                 DMTC0   v1, CP0_EPC
 318                 LONG_L  v0, GDB_FR_HI(sp)
 319                 LONG_L  v1, GDB_FR_LO(sp)
 320                 mthi    v0
 321                 mtlo    v1
 322                 LONG_L  $31, GDB_FR_REG31(sp)
 323                 LONG_L  $30, GDB_FR_REG30(sp)
 324                 LONG_L  $28, GDB_FR_REG28(sp)
 325                 LONG_L  $27, GDB_FR_REG27(sp)
 326                 LONG_L  $26, GDB_FR_REG26(sp)
 327                 LONG_L  $25, GDB_FR_REG25(sp)
 328                 LONG_L  $24, GDB_FR_REG24(sp)
 329                 LONG_L  $23, GDB_FR_REG23(sp)
 330                 LONG_L  $22, GDB_FR_REG22(sp)
 331                 LONG_L  $21, GDB_FR_REG21(sp)
 332                 LONG_L  $20, GDB_FR_REG20(sp)
 333                 LONG_L  $19, GDB_FR_REG19(sp)
 334                 LONG_L  $18, GDB_FR_REG18(sp)
 335                 LONG_L  $17, GDB_FR_REG17(sp)
 336                 LONG_L  $16, GDB_FR_REG16(sp)
 337                 LONG_L  $15, GDB_FR_REG15(sp)
 338                 LONG_L  $14, GDB_FR_REG14(sp)
 339                 LONG_L  $13, GDB_FR_REG13(sp)
 340                 LONG_L  $12, GDB_FR_REG12(sp)
 341                 LONG_L  $11, GDB_FR_REG11(sp)
 342                 LONG_L  $10, GDB_FR_REG10(sp)
 343                 LONG_L  $9, GDB_FR_REG9(sp)
 344                 LONG_L  $8, GDB_FR_REG8(sp)
 345                 LONG_L  $7, GDB_FR_REG7(sp)
 346                 LONG_L  $6, GDB_FR_REG6(sp)
 347                 LONG_L  $5, GDB_FR_REG5(sp)
 348                 LONG_L  $4, GDB_FR_REG4(sp)
 349                 LONG_L  $3, GDB_FR_REG3(sp)
 350                 LONG_L  $2, GDB_FR_REG2(sp)
 351                 LONG_L  $1, GDB_FR_REG1(sp)
 352 #if defined(CONFIG_CPU_R3000) || defined(CONFIG_CPU_TX39XX)
 353                 LONG_L  k0, GDB_FR_EPC(sp)
 354                 LONG_L  $29, GDB_FR_REG29(sp)           /* Deallocate stack */
 355                 jr      k0
 356                 rfe
 357 #else
 358                 LONG_L  sp, GDB_FR_REG29(sp)            /* Deallocate stack */
 359
 360                 .set    mips3
 361                 eret
 362                 .set    mips0
 363 #endif
 364                 .set    at
 365                 .set    reorder
 366                 END(trap_low)
 367
 368 LEAF(kgdb_read_byte)
 369 4:              lb      t0, (a0)
 370                 sb      t0, (a1)
 371                 li      v0, 0
 372                 jr      ra
 373                 .section __ex_table,"a"
 374                 PTR     4b, kgdbfault
 375                 .previous
 376                 END(kgdb_read_byte)
 377
 378 LEAF(kgdb_write_byte)
 379 5:              sb      a0, (a1)
 380                 li      v0, 0
 381                 jr      ra
 382                 .section __ex_table,"a"
 383                 PTR     5b, kgdbfault
 384                 .previous
 385                 END(kgdb_write_byte)
 386
 387                 .type   kgdbfault@function
 388                 .ent    kgdbfault
 389
 390 kgdbfault:      li      v0, -EFAULT
 391                 jr      ra
 392                 .end    kgdbfault