arch/m68k/kernel/entry_mm.S

   1 /* -*- mode: asm -*-
   2  *
   3  *  linux/arch/m68k/kernel/entry.S
   4  *
   5  *  Copyright (C) 1991, 1992  Linus Torvalds
   6  *
   7  * This file is subject to the terms and conditions of the GNU General Public
   8  * License.  See the file README.legal in the main directory of this archive
   9  * for more details.
  10  *
  11  * Linux/m68k support by Hamish Macdonald
  12  *
  13  * 68060 fixes by Jesper Skov
  14  *
  15  */
  16
  17 /*
  18  * entry.S  contains the system-call and fault low-level handling routines.
  19  * This also contains the timer-interrupt handler, as well as all interrupts
  20  * and faults that can result in a task-switch.
  21  *
  22  * NOTE: This code handles signal-recognition, which happens every time
  23  * after a timer-interrupt and after each system call.
  24  *
  25  */
  26
  27 /*
  28  * 12/03/96 Jes: Currently we only support m68k single-cpu systems, so
  29  *               all pointers that used to be 'current' are now entry
  30  *               number 0 in the 'current_set' list.
  31  *
  32  *  6/05/00 RZ:  addedd writeback completion after return from sighandler
  33  *               for 68040
  34  */
  35
  36 #include <linux/linkage.h>
  37 #include <asm/entry.h>
  38 #include <asm/errno.h>
  39 #include <asm/setup.h>
  40 #include <asm/segment.h>
  41 #include <asm/traps.h>
  42 #include <asm/unistd.h>
  43
  44 #include <asm/asm-offsets.h>
  45
  46 .globl system_call, buserr, trap, resume
  47 .globl sys_call_table
  48 .globl sys_fork, sys_clone, sys_vfork
  49 .globl ret_from_interrupt, bad_interrupt
  50 .globl auto_irqhandler_fixup
  51 .globl user_irqvec_fixup
  52
  53 .text
  54 ENTRY(buserr)
  55         SAVE_ALL_INT
  56         GET_CURRENT(%d0)
  57         movel   %sp,%sp@-               | stack frame pointer argument
  58         bsrl    buserr_c
  59         addql   #4,%sp
  60         jra     .Lret_from_exception
  61
  62 ENTRY(trap)
  63         SAVE_ALL_INT
  64         GET_CURRENT(%d0)
  65         movel   %sp,%sp@-               | stack frame pointer argument
  66         bsrl    trap_c
  67         addql   #4,%sp
  68         jra     .Lret_from_exception
  69
  70         | After a fork we jump here directly from resume,
  71         | so that %d1 contains the previous task
  72         | schedule_tail now used regardless of CONFIG_SMP
  73 ENTRY(ret_from_fork)
  74         movel   %d1,%sp@-
  75         jsr     schedule_tail
  76         addql   #4,%sp
  77         jra     .Lret_from_exception
  78
  79 do_trace_entry:
  80         movel   #-ENOSYS,%sp@(PT_OFF_D0)| needed for strace
  81         subql   #4,%sp
  82         SAVE_SWITCH_STACK
  83         jbsr    syscall_trace
  84         RESTORE_SWITCH_STACK
  85         addql   #4,%sp
  86         movel   %sp@(PT_OFF_ORIG_D0),%d0
  87         cmpl    #NR_syscalls,%d0
  88         jcs     syscall
  89 badsys:
  90         movel   #-ENOSYS,%sp@(PT_OFF_D0)
  91         jra     ret_from_syscall
  92
  93 do_trace_exit:
  94         subql   #4,%sp
  95         SAVE_SWITCH_STACK
  96         jbsr    syscall_trace
  97         RESTORE_SWITCH_STACK
  98         addql   #4,%sp
  99         jra     .Lret_from_exception
 100
 101 ENTRY(ret_from_signal)
 102         tstb    %curptr@(TASK_INFO+TINFO_FLAGS+2)
 103         jge     1f
 104         jbsr    syscall_trace
 105 1:      RESTORE_SWITCH_STACK
 106         addql   #4,%sp
 107 /* on 68040 complete pending writebacks if any */
 108 #ifdef CONFIG_M68040
 109         bfextu  %sp@(PT_OFF_FORMATVEC){#0,#4},%d0
 110         subql   #7,%d0                          | bus error frame ?
 111         jbne    1f
 112         movel   %sp,%sp@-
 113         jbsr    berr_040cleanup
 114         addql   #4,%sp
 115 1:
 116 #endif
 117         jra     .Lret_from_exception
 118
 119 ENTRY(system_call)
 120         SAVE_ALL_SYS
 121
 122         GET_CURRENT(%d1)
 123         | save top of frame
 124         movel   %sp,%curptr@(TASK_THREAD+THREAD_ESP0)
 125
 126         | syscall trace?
 127         tstb    %curptr@(TASK_INFO+TINFO_FLAGS+2)
 128         jmi     do_trace_entry
 129         cmpl    #NR_syscalls,%d0
 130         jcc     badsys
 131 syscall:
 132         jbsr    @(sys_call_table,%d0:l:4)@(0)
 133         movel   %d0,%sp@(PT_OFF_D0)     | save the return value
 134 ret_from_syscall:
 135         |oriw   #0x0700,%sr
 136         movew   %curptr@(TASK_INFO+TINFO_FLAGS+2),%d0
 137         jne     syscall_exit_work
 138 1:      RESTORE_ALL
 139
 140 syscall_exit_work:
 141         btst    #5,%sp@(PT_OFF_SR)      | check if returning to kernel
 142         bnes    1b                      | if so, skip resched, signals
 143         lslw    #1,%d0
 144         jcs     do_trace_exit
 145         jmi     do_delayed_trace
 146         lslw    #8,%d0
 147         jmi     do_signal_return
 148         pea     resume_userspace
 149         jra     schedule
 150
 151
 152 ENTRY(ret_from_exception)
 153 .Lret_from_exception:
 154         btst    #5,%sp@(PT_OFF_SR)      | check if returning to kernel
 155         bnes    1f                      | if so, skip resched, signals
 156         | only allow interrupts when we are really the last one on the
 157         | kernel stack, otherwise stack overflow can occur during
 158         | heavy interrupt load
 159         andw    #ALLOWINT,%sr
 160
 161 resume_userspace:
 162         moveb   %curptr@(TASK_INFO+TINFO_FLAGS+3),%d0
 163         jne     exit_work
 164 1:      RESTORE_ALL
 165
 166 exit_work:
 167         | save top of frame
 168         movel   %sp,%curptr@(TASK_THREAD+THREAD_ESP0)
 169         lslb    #1,%d0
 170         jmi     do_signal_return
 171         pea     resume_userspace
 172         jra     schedule
 173
 174
 175 do_signal_return:
 176         |andw   #ALLOWINT,%sr
 177         subql   #4,%sp                  | dummy return address
 178         SAVE_SWITCH_STACK
 179         pea     %sp@(SWITCH_STACK_SIZE)
 180         bsrl    do_signal
 181         addql   #4,%sp
 182         RESTORE_SWITCH_STACK
 183         addql   #4,%sp
 184         jbra    resume_userspace
 185
 186 do_delayed_trace:
 187         bclr    #7,%sp@(PT_OFF_SR)      | clear trace bit in SR
 188         pea     1                       | send SIGTRAP
 189         movel   %curptr,%sp@-
 190         pea     LSIGTRAP
 191         jbsr    send_sig
 192         addql   #8,%sp
 193         addql   #4,%sp
 194         jbra    resume_userspace
 195
 196
 197 /* This is the main interrupt handler for autovector interrupts */
 198
 199 ENTRY(auto_inthandler)
 200         SAVE_ALL_INT
 201         GET_CURRENT(%d0)
 202         addqb   #1,%curptr@(TASK_INFO+TINFO_PREEMPT+1)
 203                                         |  put exception # in d0
 204         bfextu  %sp@(PT_OFF_FORMATVEC){#4,#10},%d0
 205         subw    #VEC_SPUR,%d0
 206
 207         movel   %sp,%sp@-
 208         movel   %d0,%sp@-               |  put vector # on stack
 209 auto_irqhandler_fixup = . + 2
 210         jsr     do_IRQ                  |  process the IRQ
 211         addql   #8,%sp                  |  pop parameters off stack
 212
 213 ret_from_interrupt:
 214         subqb   #1,%curptr@(TASK_INFO+TINFO_PREEMPT+1)
 215         jeq     ret_from_last_interrupt
 216 2:      RESTORE_ALL
 217
 218         ALIGN
 219 ret_from_last_interrupt:
 220         moveq   #(~ALLOWINT>>8)&0xff,%d0
 221         andb    %sp@(PT_OFF_SR),%d0
 222         jne     2b
 223
 224         /* check if we need to do software interrupts */
 225         tstl    irq_stat+CPUSTAT_SOFTIRQ_PENDING
 226         jeq     .Lret_from_exception
 227         pea     ret_from_exception
 228         jra     do_softirq
 229
 230 /* Handler for user defined interrupt vectors */
 231
 232 ENTRY(user_inthandler)
 233         SAVE_ALL_INT
 234         GET_CURRENT(%d0)
 235         addqb   #1,%curptr@(TASK_INFO+TINFO_PREEMPT+1)
 236                                         |  put exception # in d0
 237         bfextu  %sp@(PT_OFF_FORMATVEC){#4,#10},%d0
 238 user_irqvec_fixup = . + 2
 239         subw    #VEC_USER,%d0
 240
 241         movel   %sp,%sp@-
 242         movel   %d0,%sp@-               |  put vector # on stack
 243         jsr     do_IRQ                  |  process the IRQ
 244         addql   #8,%sp                  |  pop parameters off stack
 245
 246         subqb   #1,%curptr@(TASK_INFO+TINFO_PREEMPT+1)
 247         jeq     ret_from_last_interrupt
 248         RESTORE_ALL
 249
 250 /* Handler for uninitialized and spurious interrupts */
 251
 252 ENTRY(bad_inthandler)
 253         SAVE_ALL_INT
 254         GET_CURRENT(%d0)
 255         addqb   #1,%curptr@(TASK_INFO+TINFO_PREEMPT+1)
 256
 257         movel   %sp,%sp@-
 258         jsr     handle_badint
 259         addql   #4,%sp
 260
 261         subqb   #1,%curptr@(TASK_INFO+TINFO_PREEMPT+1)
 262         jeq     ret_from_last_interrupt
 263         RESTORE_ALL
 264
 265
 266 ENTRY(sys_fork)
 267         SAVE_SWITCH_STACK
 268         pea     %sp@(SWITCH_STACK_SIZE)
 269         jbsr    m68k_fork
 270         addql   #4,%sp
 271         RESTORE_SWITCH_STACK
 272         rts
 273
 274 ENTRY(sys_clone)
 275         SAVE_SWITCH_STACK
 276         pea     %sp@(SWITCH_STACK_SIZE)
 277         jbsr    m68k_clone
 278         addql   #4,%sp
 279         RESTORE_SWITCH_STACK
 280         rts
 281
 282 ENTRY(sys_vfork)
 283         SAVE_SWITCH_STACK
 284         pea     %sp@(SWITCH_STACK_SIZE)
 285         jbsr    m68k_vfork
 286         addql   #4,%sp
 287         RESTORE_SWITCH_STACK
 288         rts
 289
 290 ENTRY(sys_sigreturn)
 291         SAVE_SWITCH_STACK
 292         jbsr    do_sigreturn
 293         RESTORE_SWITCH_STACK
 294         rts
 295
 296 ENTRY(sys_rt_sigreturn)
 297         SAVE_SWITCH_STACK
 298         jbsr    do_rt_sigreturn
 299         RESTORE_SWITCH_STACK
 300         rts
 301
 302 resume:
 303         /*
 304          * Beware - when entering resume, prev (the current task) is
 305          * in a0, next (the new task) is in a1,so don't change these
 306          * registers until their contents are no longer needed.
 307          */
 308
 309         /* save sr */
 310         movew   %sr,%a0@(TASK_THREAD+THREAD_SR)
 311
 312         /* save fs (sfc,%dfc) (may be pointing to kernel memory) */
 313         movec   %sfc,%d0
 314         movew   %d0,%a0@(TASK_THREAD+THREAD_FS)
 315
 316         /* save usp */
 317         /* it is better to use a movel here instead of a movew 8*) */
 318         movec   %usp,%d0
 319         movel   %d0,%a0@(TASK_THREAD+THREAD_USP)
 320
 321         /* save non-scratch registers on stack */
 322         SAVE_SWITCH_STACK
 323
 324         /* save current kernel stack pointer */
 325         movel   %sp,%a0@(TASK_THREAD+THREAD_KSP)
 326
 327         /* save floating point context */
 328 #ifndef CONFIG_M68KFPU_EMU_ONLY
 329 #ifdef CONFIG_M68KFPU_EMU
 330         tstl    m68k_fputype
 331         jeq     3f
 332 #endif
 333         fsave   %a0@(TASK_THREAD+THREAD_FPSTATE)
 334
 335 #if defined(CONFIG_M68060)
 336 #if !defined(CPU_M68060_ONLY)
 337         btst    #3,m68k_cputype+3
 338         beqs    1f
 339 #endif
 340         /* The 060 FPU keeps status in bits 15-8 of the first longword */
 341         tstb    %a0@(TASK_THREAD+THREAD_FPSTATE+2)
 342         jeq     3f
 343 #if !defined(CPU_M68060_ONLY)
 344         jra     2f
 345 #endif
 346 #endif /* CONFIG_M68060 */
 347 #if !defined(CPU_M68060_ONLY)
 348 1:      tstb    %a0@(TASK_THREAD+THREAD_FPSTATE)
 349         jeq     3f
 350 #endif
 351 2:      fmovemx %fp0-%fp7,%a0@(TASK_THREAD+THREAD_FPREG)
 352         fmoveml %fpcr/%fpsr/%fpiar,%a0@(TASK_THREAD+THREAD_FPCNTL)
 353 3:
 354 #endif  /* CONFIG_M68KFPU_EMU_ONLY */
 355         /* Return previous task in %d1 */
 356         movel   %curptr,%d1
 357
 358         /* switch to new task (a1 contains new task) */
 359         movel   %a1,%curptr
 360
 361         /* restore floating point context */
 362 #ifndef CONFIG_M68KFPU_EMU_ONLY
 363 #ifdef CONFIG_M68KFPU_EMU
 364         tstl    m68k_fputype
 365         jeq     4f
 366 #endif
 367 #if defined(CONFIG_M68060)
 368 #if !defined(CPU_M68060_ONLY)
 369         btst    #3,m68k_cputype+3
 370         beqs    1f
 371 #endif
 372         /* The 060 FPU keeps status in bits 15-8 of the first longword */
 373         tstb    %a1@(TASK_THREAD+THREAD_FPSTATE+2)
 374         jeq     3f
 375 #if !defined(CPU_M68060_ONLY)
 376         jra     2f
 377 #endif
 378 #endif /* CONFIG_M68060 */
 379 #if !defined(CPU_M68060_ONLY)
 380 1:      tstb    %a1@(TASK_THREAD+THREAD_FPSTATE)
 381         jeq     3f
 382 #endif
 383 2:      fmovemx %a1@(TASK_THREAD+THREAD_FPREG),%fp0-%fp7
 384         fmoveml %a1@(TASK_THREAD+THREAD_FPCNTL),%fpcr/%fpsr/%fpiar
 385 3:      frestore %a1@(TASK_THREAD+THREAD_FPSTATE)
 386 4:
 387 #endif  /* CONFIG_M68KFPU_EMU_ONLY */
 388
 389         /* restore the kernel stack pointer */
 390         movel   %a1@(TASK_THREAD+THREAD_KSP),%sp
 391
 392         /* restore non-scratch registers */
 393         RESTORE_SWITCH_STACK
 394
 395         /* restore user stack pointer */
 396         movel   %a1@(TASK_THREAD+THREAD_USP),%a0
 397         movel   %a0,%usp
 398
 399         /* restore fs (sfc,%dfc) */
 400         movew   %a1@(TASK_THREAD+THREAD_FS),%a0
 401         movec   %a0,%sfc
 402         movec   %a0,%dfc
 403
 404         /* restore status register */
 405         movew   %a1@(TASK_THREAD+THREAD_SR),%sr
 406
 407         rts
 408