arch/m32r/kernel/vmlinux.lds.S

   1 /* ld script to make M32R Linux kernel
   2  */
   3
   4 #include <asm-generic/vmlinux.lds.h>
   5 #include <asm/addrspace.h>
   6 #include <asm/page.h>
   7
   8 OUTPUT_ARCH(m32r)
   9 ENTRY(startup_32)
  10 #if defined(__LITTLE_ENDIAN__)
  11        jiffies = jiffies_64;
  12 #else
  13        jiffies = jiffies_64 + 4;
  14 #endif
  15 SECTIONS
  16 {
  17   . = CONFIG_MEMORY_START + __PAGE_OFFSET;
  18   eit_vector = .;
  19
  20   . = . + 0x1000;
  21   .empty_zero_page : { *(.empty_zero_page) } = 0
  22
  23   /* read-only */
  24   _text = .;                    /* Text and read-only data */
  25   .boot : { *(.boot) } = 0
  26   .text : {
  27         *(.text)
  28         SCHED_TEXT
  29         LOCK_TEXT
  30         *(.fixup)
  31         *(.gnu.warning)
  32         } = 0x9090
  33 #ifdef CONFIG_SMP
  34   . = ALIGN(65536);
  35   .eit_vector4 : { *(.eit_vector4) }
  36 #endif
  37   _etext = .;                   /* End of text section */
  38
  39   . = ALIGN(16);                /* Exception table */
  40   __start___ex_table = .;
  41   __ex_table : { *(__ex_table) }
  42   __stop___ex_table = .;
  43
  44   RODATA
  45
  46   /* writeable */
  47   .data : {                     /* Data */
  48         *(.spu)
  49         *(.spi)
  50         *(.data)
  51         CONSTRUCTORS
  52         }
  53
  54   . = ALIGN(4096);
  55   __nosave_begin = .;
  56   .data_nosave : { *(.data.nosave) }
  57   . = ALIGN(4096);
  58   __nosave_end = .;
  59
  60   . = ALIGN(4096);
  61   .data.page_aligned : { *(.data.idt) }
  62
  63   . = ALIGN(32);
  64   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  65
  66   _edata = .;                   /* End of data section */
  67
  68   . = ALIGN(8192);              /* init_task */
  69   .data.init_task : { *(.data.init_task) }
  70
  71   /* will be freed after init */
  72   . = ALIGN(4096);              /* Init code and data */
  73   __init_begin = .;
  74   .init.text : {
  75         _sinittext = .;
  76         *(.init.text)
  77         _einittext = .;
  78   }
  79   .init.data : { *(.init.data) }
  80   . = ALIGN(16);
  81   __setup_start = .;
  82   .init.setup : { *(.init.setup) }
  83   __setup_end = .;
  84   __initcall_start = .;
  85   .initcall.init : {
  86         *(.initcall1.init)
  87         *(.initcall2.init)
  88         *(.initcall3.init)
  89         *(.initcall4.init)
  90         *(.initcall5.init)
  91         *(.initcall6.init)
  92         *(.initcall7.init)
  93   }
  94   __initcall_end = .;
  95   __con_initcall_start = .;
  96   .con_initcall.init : { *(.con_initcall.init) }
  97   __con_initcall_end = .;
  98   SECURITY_INIT
  99   . = ALIGN(4);
 100   __alt_instructions = .;
 101   .altinstructions : { *(.altinstructions) }
 102   __alt_instructions_end = .;
 103   .altinstr_replacement : { *(.altinstr_replacement) }
 104   /* .exit.text is discard at runtime, not link time, to deal with references
 105      from .altinstructions and .eh_frame */
 106   .exit.text : { *(.exit.text) }
 107   .exit.data : { *(.exit.data) }
 108   . = ALIGN(4096);
 109   __initramfs_start = .;
 110   .init.ramfs : { *(.init.ramfs) }
 111   __initramfs_end = .;
 112   . = ALIGN(32);
 113   __per_cpu_start = .;
 114   .data.percpu  : { *(.data.percpu) }
 115   __per_cpu_end = .;
 116   . = ALIGN(4096);
 117   __init_end = .;
 118   /* freed after init ends here */
 119
 120   __bss_start = .;              /* BSS */
 121   .bss : { *(.bss) }
 122   . = ALIGN(4);
 123   __bss_stop = .;
 124
 125   _end = . ;
 126
 127   /* Sections to be discarded */
 128   /DISCARD/ : {
 129         *(.exit.text)
 130         *(.exit.data)
 131         *(.exitcall.exit)
 132         }
 133
 134   /* Stabs debugging sections.  */
 135   .stab 0 : { *(.stab) }
 136   .stabstr 0 : { *(.stabstr) }
 137   .stab.excl 0 : { *(.stab.excl) }
 138   .stab.exclstr 0 : { *(.stab.exclstr) }
 139   .stab.index 0 : { *(.stab.index) }
 140   .stab.indexstr 0 : { *(.stab.indexstr) }
 141   .comment 0 : { *(.comment) }
 142 }