arch/ia64/kernel/vmlinux.lds.S

   1
   2 #include <asm/cache.h>
   3 #include <asm/ptrace.h>
   4 #include <asm/system.h>
   5 #include <asm/pgtable.h>
   6
   7 #define LOAD_OFFSET     (KERNEL_START - KERNEL_TR_PAGE_SIZE)
   8 #include <asm-generic/vmlinux.lds.h>
   9
  10 #define IVT_TEXT                                                        \
  11                 VMLINUX_SYMBOL(__start_ivt_text) = .;                   \
  12                 *(.text.ivt)                                            \
  13                 VMLINUX_SYMBOL(__end_ivt_text) = .;
  14
  15 OUTPUT_FORMAT("elf64-ia64-little")
  16 OUTPUT_ARCH(ia64)
  17 ENTRY(phys_start)
  18 jiffies = jiffies_64;
  19 PHDRS {
  20   code   PT_LOAD;
  21   percpu PT_LOAD;
  22   data   PT_LOAD;
  23 }
  24 SECTIONS
  25 {
  26   /* Sections to be discarded */
  27   /DISCARD/ : {
  28         *(.exit.text)
  29         *(.exit.data)
  30         *(.exitcall.exit)
  31         *(.IA_64.unwind.exit.text)
  32         *(.IA_64.unwind_info.exit.text)
  33         }
  34
  35   v = PAGE_OFFSET;      /* this symbol is here to make debugging easier... */
  36   phys_start = _start - LOAD_OFFSET;
  37
  38   code : { } :code
  39   . = KERNEL_START;
  40
  41   _text = .;
  42   _stext = .;
  43
  44   .text : AT(ADDR(.text) - LOAD_OFFSET)
  45     {
  46         IVT_TEXT
  47         *(.text)
  48         SCHED_TEXT
  49         LOCK_TEXT
  50         KPROBES_TEXT
  51         *(.gnu.linkonce.t*)
  52     }
  53   .text2 : AT(ADDR(.text2) - LOAD_OFFSET)
  54         { *(.text2) }
  55 #ifdef CONFIG_SMP
  56   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET)
  57         { *(.text.lock) }
  58 #endif
  59   _etext = .;
  60
  61   /* Read-only data */
  62
  63   /* Exception table */
  64   . = ALIGN(16);
  65   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET)
  66         {
  67           __start___ex_table = .;
  68           *(__ex_table)
  69           __stop___ex_table = .;
  70         }
  71
  72   /* MCA table */
  73   . = ALIGN(16);
  74   __mca_table : AT(ADDR(__mca_table) - LOAD_OFFSET)
  75         {
  76           __start___mca_table = .;
  77           *(__mca_table)
  78           __stop___mca_table = .;
  79         }
  80
  81   .data.patch.phys_stack_reg : AT(ADDR(.data.patch.phys_stack_reg) - LOAD_OFFSET)
  82         {
  83           __start___phys_stack_reg_patchlist = .;
  84           *(.data.patch.phys_stack_reg)
  85           __end___phys_stack_reg_patchlist = .;
  86         }
  87
  88   /* Global data */
  89   _data = .;
  90
  91   /* Unwind info & table: */
  92   . = ALIGN(8);
  93   .IA_64.unwind_info : AT(ADDR(.IA_64.unwind_info) - LOAD_OFFSET)
  94         { *(.IA_64.unwind_info*) }
  95   .IA_64.unwind : AT(ADDR(.IA_64.unwind) - LOAD_OFFSET)
  96         {
  97           __start_unwind = .;
  98           *(.IA_64.unwind*)
  99           __end_unwind = .;
 100         }
 101
 102   RODATA
 103
 104   .opd : AT(ADDR(.opd) - LOAD_OFFSET)
 105         { *(.opd) }
 106
 107   /* Initialization code and data: */
 108
 109   . = ALIGN(PAGE_SIZE);
 110   __init_begin = .;
 111   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET)
 112         {
 113           _sinittext = .;
 114           *(.init.text)
 115           _einittext = .;
 116         }
 117
 118   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET)
 119         { *(.init.data) }
 120
 121   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET)
 122         {
 123           __initramfs_start = .;
 124           *(.init.ramfs)
 125           __initramfs_end = .;
 126         }
 127
 128    . = ALIGN(16);
 129   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET)
 130         {
 131           __setup_start = .;
 132           *(.init.setup)
 133           __setup_end = .;
 134         }
 135   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET)
 136         {
 137           __initcall_start = .;
 138         INITCALLS
 139           __initcall_end = .;
 140         }
 141
 142   .data.patch.vtop : AT(ADDR(.data.patch.vtop) - LOAD_OFFSET)
 143         {
 144           __start___vtop_patchlist = .;
 145           *(.data.patch.vtop)
 146           __end___vtop_patchlist = .;
 147         }
 148
 149   .data.patch.mckinley_e9 : AT(ADDR(.data.patch.mckinley_e9) - LOAD_OFFSET)
 150         {
 151           __start___mckinley_e9_bundles = .;
 152           *(.data.patch.mckinley_e9)
 153           __end___mckinley_e9_bundles = .;
 154         }
 155
 156 #if defined(CONFIG_IA64_GENERIC)
 157   /* Machine Vector */
 158   . = ALIGN(16);
 159   .machvec : AT(ADDR(.machvec) - LOAD_OFFSET)
 160         {
 161           machvec_start = .;
 162           *(.machvec)
 163           machvec_end = .;
 164         }
 165 #endif
 166
 167    __con_initcall_start = .;
 168   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET)
 169         { *(.con_initcall.init) }
 170   __con_initcall_end = .;
 171   __security_initcall_start = .;
 172   .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET)
 173         { *(.security_initcall.init) }
 174   __security_initcall_end = .;
 175   . = ALIGN(PAGE_SIZE);
 176   __init_end = .;
 177
 178   /* The initial task and kernel stack */
 179   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET)
 180         { *(.data.init_task) }
 181
 182   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET)
 183         { *(__special_page_section)
 184           __start_gate_section = .;
 185           *(.data.gate)
 186           __stop_gate_section = .;
 187         }
 188   . = ALIGN(PAGE_SIZE);         /* make sure the gate page doesn't expose
 189                                  * kernel data
 190                                  */
 191
 192   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET)
 193         { *(.data.read_mostly) }
 194
 195   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET)
 196         { *(.data.cacheline_aligned) }
 197
 198   /* Per-cpu data: */
 199   percpu : { } :percpu
 200   . = ALIGN(PERCPU_PAGE_SIZE);
 201   __phys_per_cpu_start = .;
 202   .data.percpu PERCPU_ADDR : AT(__phys_per_cpu_start - LOAD_OFFSET)
 203         {
 204                 __per_cpu_start = .;
 205                 *(.data.percpu)
 206                 __per_cpu_end = .;
 207         }
 208   . = __phys_per_cpu_start + PERCPU_PAGE_SIZE;  /* ensure percpu data fits
 209                                                  * into percpu page size
 210                                                  */
 211
 212   data : { } :data
 213   .data : AT(ADDR(.data) - LOAD_OFFSET)
 214         { *(.data) *(.data1) *(.gnu.linkonce.d*) CONSTRUCTORS }
 215
 216   . = ALIGN(16);        /* gp must be 16-byte aligned for exc. table */
 217   .got : AT(ADDR(.got) - LOAD_OFFSET)
 218         { *(.got.plt) *(.got) }
 219   __gp = ADDR(.got) + 0x200000;
 220   /* We want the small data sections together, so single-instruction offsets
 221      can access them all, and initialized data all before uninitialized, so
 222      we can shorten the on-disk segment size.  */
 223   .sdata : AT(ADDR(.sdata) - LOAD_OFFSET)
 224         { *(.sdata) *(.sdata1) *(.srdata) }
 225   _edata  =  .;
 226   _bss = .;
 227   .sbss : AT(ADDR(.sbss) - LOAD_OFFSET)
 228         { *(.sbss) *(.scommon) }
 229   .bss : AT(ADDR(.bss) - LOAD_OFFSET)
 230         { *(.bss) *(COMMON) }
 231
 232   _end = .;
 233
 234   code : { } :code
 235   /* Stabs debugging sections.  */
 236   .stab 0 : { *(.stab) }
 237   .stabstr 0 : { *(.stabstr) }
 238   .stab.excl 0 : { *(.stab.excl) }
 239   .stab.exclstr 0 : { *(.stab.exclstr) }
 240   .stab.index 0 : { *(.stab.index) }
 241   .stab.indexstr 0 : { *(.stab.indexstr) }
 242   /* DWARF debug sections.
 243      Symbols in the DWARF debugging sections are relative to the beginning
 244      of the section so we begin them at 0.  */
 245   /* DWARF 1 */
 246   .debug          0 : { *(.debug) }
 247   .line           0 : { *(.line) }
 248   /* GNU DWARF 1 extensions */
 249   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 250   .debug_sfnames  0 : { *(.debug_sfnames) }
 251   /* DWARF 1.1 and DWARF 2 */
 252   .debug_aranges  0 : { *(.debug_aranges) }
 253   .debug_pubnames 0 : { *(.debug_pubnames) }
 254   /* DWARF 2 */
 255   .debug_info     0 : { *(.debug_info) }
 256   .debug_abbrev   0 : { *(.debug_abbrev) }
 257   .debug_line     0 : { *(.debug_line) }
 258   .debug_frame    0 : { *(.debug_frame) }
 259   .debug_str      0 : { *(.debug_str) }
 260   .debug_loc      0 : { *(.debug_loc) }
 261   .debug_macinfo  0 : { *(.debug_macinfo) }
 262   /* SGI/MIPS DWARF 2 extensions */
 263   .debug_weaknames 0 : { *(.debug_weaknames) }
 264   .debug_funcnames 0 : { *(.debug_funcnames) }
 265   .debug_typenames 0 : { *(.debug_typenames) }
 266   .debug_varnames  0 : { *(.debug_varnames) }
 267   /* These must appear regardless of  .  */
 268   /* Discard them for now since Intel SoftSDV cannot handle them.
 269   .comment 0 : { *(.comment) }
 270   .note 0 : { *(.note) }
 271   */
 272   /DISCARD/ : { *(.comment) }
 273   /DISCARD/ : { *(.note) }
 274 }