arch/i386/kernel/entry.S

   1 /*
   2  *  linux/arch/i386/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  */
   6
   7 /*
   8  * entry.S contains the system-call and fault low-level handling routines.
   9  * This also contains the timer-interrupt handler, as well as all interrupts
  10  * and faults that can result in a task-switch.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after a timer-interrupt and after each system call.
  14  *
  15  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  16  * on a 486.
  17  *
  18  * Stack layout in 'ret_from_system_call':
  19  *      ptrace needs to have all regs on the stack.
  20  *      if the order here is changed, it needs to be
  21  *      updated in fork.c:copy_process, signal.c:do_signal,
  22  *      ptrace.c and ptrace.h
  23  *
  24  *       0(%esp) - %ebx
  25  *       4(%esp) - %ecx
  26  *       8(%esp) - %edx
  27  *       C(%esp) - %esi
  28  *      10(%esp) - %edi
  29  *      14(%esp) - %ebp
  30  *      18(%esp) - %eax
  31  *      1C(%esp) - %ds
  32  *      20(%esp) - %es
  33  *      24(%esp) - orig_eax
  34  *      28(%esp) - %eip
  35  *      2C(%esp) - %cs
  36  *      30(%esp) - %eflags
  37  *      34(%esp) - %oldesp
  38  *      38(%esp) - %oldss
  39  *
  40  * "current" is in register %ebx during any slow entries.
  41  */
  42
  43 #include <linux/config.h>
  44 #include <linux/linkage.h>
  45 #include <asm/thread_info.h>
  46 #include <asm/errno.h>
  47 #include <asm/segment.h>
  48 #include <asm/smp.h>
  49 #include <asm/page.h>
  50 #include <asm/desc.h>
  51 #include "irq_vectors.h"
  52
  53 #define nr_syscalls ((syscall_table_size)/4)
  54
  55 EBX             = 0x00
  56 ECX             = 0x04
  57 EDX             = 0x08
  58 ESI             = 0x0C
  59 EDI             = 0x10
  60 EBP             = 0x14
  61 EAX             = 0x18
  62 DS              = 0x1C
  63 ES              = 0x20
  64 ORIG_EAX        = 0x24
  65 EIP             = 0x28
  66 CS              = 0x2C
  67 EFLAGS          = 0x30
  68 OLDESP          = 0x34
  69 OLDSS           = 0x38
  70
  71 CF_MASK         = 0x00000001
  72 TF_MASK         = 0x00000100
  73 IF_MASK         = 0x00000200
  74 DF_MASK         = 0x00000400
  75 NT_MASK         = 0x00004000
  76 VM_MASK         = 0x00020000
  77
  78 #ifdef CONFIG_PREEMPT
  79 #define preempt_stop            cli
  80 #else
  81 #define preempt_stop
  82 #define resume_kernel           restore_nocheck
  83 #endif
  84
  85 #define SAVE_ALL \
  86         cld; \
  87         pushl %es; \
  88         pushl %ds; \
  89         pushl %eax; \
  90         pushl %ebp; \
  91         pushl %edi; \
  92         pushl %esi; \
  93         pushl %edx; \
  94         pushl %ecx; \
  95         pushl %ebx; \
  96         movl $(__USER_DS), %edx; \
  97         movl %edx, %ds; \
  98         movl %edx, %es;
  99
 100 #define RESTORE_INT_REGS \
 101         popl %ebx;      \
 102         popl %ecx;      \
 103         popl %edx;      \
 104         popl %esi;      \
 105         popl %edi;      \
 106         popl %ebp;      \
 107         popl %eax
 108
 109 #define RESTORE_REGS    \
 110         RESTORE_INT_REGS; \
 111 1:      popl %ds;       \
 112 2:      popl %es;       \
 113 .section .fixup,"ax";   \
 114 3:      movl $0,(%esp); \
 115         jmp 1b;         \
 116 4:      movl $0,(%esp); \
 117         jmp 2b;         \
 118 .previous;              \
 119 .section __ex_table,"a";\
 120         .align 4;       \
 121         .long 1b,3b;    \
 122         .long 2b,4b;    \
 123 .previous
 124
 125
 126 ENTRY(ret_from_fork)
 127         pushl %eax
 128         call schedule_tail
 129         GET_THREAD_INFO(%ebp)
 130         popl %eax
 131         jmp syscall_exit
 132
 133 /*
 134  * Return to user mode is not as complex as all this looks,
 135  * but we want the default path for a system call return to
 136  * go as quickly as possible which is why some of this is
 137  * less clear than it otherwise should be.
 138  */
 139
 140         # userspace resumption stub bypassing syscall exit tracing
 141         ALIGN
 142 ret_from_exception:
 143         preempt_stop
 144 ret_from_intr:
 145         GET_THREAD_INFO(%ebp)
 146         movl EFLAGS(%esp), %eax         # mix EFLAGS and CS
 147         movb CS(%esp), %al
 148         testl $(VM_MASK | 3), %eax
 149         jz resume_kernel
 150 ENTRY(resume_userspace)
 151         cli                             # make sure we don't miss an interrupt
 152                                         # setting need_resched or sigpending
 153                                         # between sampling and the iret
 154         movl TI_flags(%ebp), %ecx
 155         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 156                                         # int/exception return?
 157         jne work_pending
 158         jmp restore_all
 159
 160 #ifdef CONFIG_PREEMPT
 161 ENTRY(resume_kernel)
 162         cli
 163         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 164         jnz restore_nocheck
 165 need_resched:
 166         movl TI_flags(%ebp), %ecx       # need_resched set ?
 167         testb $_TIF_NEED_RESCHED, %cl
 168         jz restore_all
 169         testl $IF_MASK,EFLAGS(%esp)     # interrupts off (exception path) ?
 170         jz restore_all
 171         call preempt_schedule_irq
 172         jmp need_resched
 173 #endif
 174
 175 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 176    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 177
 178         # sysenter call handler stub
 179 ENTRY(sysenter_entry)
 180         movl TSS_sysenter_esp0(%esp),%esp
 181 sysenter_past_esp:
 182         sti
 183         pushl $(__USER_DS)
 184         pushl %ebp
 185         pushfl
 186         pushl $(__USER_CS)
 187         pushl $SYSENTER_RETURN
 188
 189 /*
 190  * Load the potential sixth argument from user stack.
 191  * Careful about security.
 192  */
 193         cmpl $__PAGE_OFFSET-3,%ebp
 194         jae syscall_fault
 195 1:      movl (%ebp),%ebp
 196 .section __ex_table,"a"
 197         .align 4
 198         .long 1b,syscall_fault
 199 .previous
 200
 201         pushl %eax
 202         SAVE_ALL
 203         GET_THREAD_INFO(%ebp)
 204
 205         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 206         testw $(_TIF_SYSCALL_EMU|_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 207         jnz syscall_trace_entry
 208         cmpl $(nr_syscalls), %eax
 209         jae syscall_badsys
 210         call *sys_call_table(,%eax,4)
 211         movl %eax,EAX(%esp)
 212         cli
 213         movl TI_flags(%ebp), %ecx
 214         testw $_TIF_ALLWORK_MASK, %cx
 215         jne syscall_exit_work
 216 /* if something modifies registers it must also disable sysexit */
 217         movl EIP(%esp), %edx
 218         movl OLDESP(%esp), %ecx
 219         xorl %ebp,%ebp
 220         sti
 221         sysexit
 222
 223
 224         # system call handler stub
 225 ENTRY(system_call)
 226         pushl %eax                      # save orig_eax
 227         SAVE_ALL
 228         GET_THREAD_INFO(%ebp)
 229                                         # system call tracing in operation / emulation
 230         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 231         testw $(_TIF_SYSCALL_EMU|_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 232         jnz syscall_trace_entry
 233         cmpl $(nr_syscalls), %eax
 234         jae syscall_badsys
 235 syscall_call:
 236         call *sys_call_table(,%eax,4)
 237         movl %eax,EAX(%esp)             # store the return value
 238 syscall_exit:
 239         cli                             # make sure we don't miss an interrupt
 240                                         # setting need_resched or sigpending
 241                                         # between sampling and the iret
 242         movl TI_flags(%ebp), %ecx
 243         testw $_TIF_ALLWORK_MASK, %cx   # current->work
 244         jne syscall_exit_work
 245
 246 restore_all:
 247         movl EFLAGS(%esp), %eax         # mix EFLAGS, SS and CS
 248         # Warning: OLDSS(%esp) contains the wrong/random values if we
 249         # are returning to the kernel.
 250         # See comments in process.c:copy_thread() for details.
 251         movb OLDSS(%esp), %ah
 252         movb CS(%esp), %al
 253         andl $(VM_MASK | (4 << 8) | 3), %eax
 254         cmpl $((4 << 8) | 3), %eax
 255         je ldt_ss                       # returning to user-space with LDT SS
 256 restore_nocheck:
 257         RESTORE_REGS
 258         addl $4, %esp
 259 1:      iret
 260 .section .fixup,"ax"
 261 iret_exc:
 262         sti
 263         pushl $0                        # no error code
 264         pushl $do_iret_error
 265         jmp error_code
 266 .previous
 267 .section __ex_table,"a"
 268         .align 4
 269         .long 1b,iret_exc
 270 .previous
 271
 272 ldt_ss:
 273         larl OLDSS(%esp), %eax
 274         jnz restore_nocheck
 275         testl $0x00400000, %eax         # returning to 32bit stack?
 276         jnz restore_nocheck             # allright, normal return
 277         /* If returning to userspace with 16bit stack,
 278          * try to fix the higher word of ESP, as the CPU
 279          * won't restore it.
 280          * This is an "official" bug of all the x86-compatible
 281          * CPUs, which we can try to work around to make
 282          * dosemu and wine happy. */
 283         subl $8, %esp           # reserve space for switch16 pointer
 284         cli
 285         movl %esp, %eax
 286         /* Set up the 16bit stack frame with switch32 pointer on top,
 287          * and a switch16 pointer on top of the current frame. */
 288         call setup_x86_bogus_stack
 289         RESTORE_REGS
 290         lss 20+4(%esp), %esp    # switch to 16bit stack
 291 1:      iret
 292 .section __ex_table,"a"
 293         .align 4
 294         .long 1b,iret_exc
 295 .previous
 296
 297         # perform work that needs to be done immediately before resumption
 298         ALIGN
 299 work_pending:
 300         testb $_TIF_NEED_RESCHED, %cl
 301         jz work_notifysig
 302 work_resched:
 303         call schedule
 304         cli                             # make sure we don't miss an interrupt
 305                                         # setting need_resched or sigpending
 306                                         # between sampling and the iret
 307         movl TI_flags(%ebp), %ecx
 308         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 309                                         # than syscall tracing?
 310         jz restore_all
 311         testb $_TIF_NEED_RESCHED, %cl
 312         jnz work_resched
 313
 314 work_notifysig:                         # deal with pending signals and
 315                                         # notify-resume requests
 316         testl $VM_MASK, EFLAGS(%esp)
 317         movl %esp, %eax
 318         jne work_notifysig_v86          # returning to kernel-space or
 319                                         # vm86-space
 320         xorl %edx, %edx
 321         call do_notify_resume
 322         jmp resume_userspace
 323
 324         ALIGN
 325 work_notifysig_v86:
 326 #ifdef CONFIG_VM86
 327         pushl %ecx                      # save ti_flags for do_notify_resume
 328         call save_v86_state             # %eax contains pt_regs pointer
 329         popl %ecx
 330         movl %eax, %esp
 331         xorl %edx, %edx
 332         call do_notify_resume
 333         jmp resume_userspace
 334 #endif
 335
 336         # perform syscall exit tracing
 337         ALIGN
 338 syscall_trace_entry:
 339         movl $-ENOSYS,EAX(%esp)
 340         movl %esp, %eax
 341         xorl %edx,%edx
 342         call do_syscall_trace
 343         cmpl $0, %eax
 344         jne resume_userspace            # ret != 0 -> running under PTRACE_SYSEMU,
 345                                         # so must skip actual syscall
 346         movl ORIG_EAX(%esp), %eax
 347         cmpl $(nr_syscalls), %eax
 348         jnae syscall_call
 349         jmp syscall_exit
 350
 351         # perform syscall exit tracing
 352         ALIGN
 353 syscall_exit_work:
 354         testb $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SINGLESTEP), %cl
 355         jz work_pending
 356         sti                             # could let do_syscall_trace() call
 357                                         # schedule() instead
 358         movl %esp, %eax
 359         movl $1, %edx
 360         call do_syscall_trace
 361         jmp resume_userspace
 362
 363         ALIGN
 364 syscall_fault:
 365         pushl %eax                      # save orig_eax
 366         SAVE_ALL
 367         GET_THREAD_INFO(%ebp)
 368         movl $-EFAULT,EAX(%esp)
 369         jmp resume_userspace
 370
 371         ALIGN
 372 syscall_badsys:
 373         movl $-ENOSYS,EAX(%esp)
 374         jmp resume_userspace
 375
 376 #define FIXUP_ESPFIX_STACK \
 377         movl %esp, %eax; \
 378         /* switch to 32bit stack using the pointer on top of 16bit stack */ \
 379         lss %ss:CPU_16BIT_STACK_SIZE-8, %esp; \
 380         /* copy data from 16bit stack to 32bit stack */ \
 381         call fixup_x86_bogus_stack; \
 382         /* put ESP to the proper location */ \
 383         movl %eax, %esp;
 384 #define UNWIND_ESPFIX_STACK \
 385         pushl %eax; \
 386         movl %ss, %eax; \
 387         /* see if on 16bit stack */ \
 388         cmpw $__ESPFIX_SS, %ax; \
 389         jne 28f; \
 390         movl $__KERNEL_DS, %edx; \
 391         movl %edx, %ds; \
 392         movl %edx, %es; \
 393         /* switch to 32bit stack */ \
 394         FIXUP_ESPFIX_STACK \
 395 28:     popl %eax;
 396
 397 /*
 398  * Build the entry stubs and pointer table with
 399  * some assembler magic.
 400  */
 401 .data
 402 ENTRY(interrupt)
 403 .text
 404
 405 vector=0
 406 ENTRY(irq_entries_start)
 407 .rept NR_IRQS
 408         ALIGN
 409 1:      pushl $vector-256
 410         jmp common_interrupt
 411 .data
 412         .long 1b
 413 .text
 414 vector=vector+1
 415 .endr
 416
 417         ALIGN
 418 common_interrupt:
 419         SAVE_ALL
 420         movl %esp,%eax
 421         call do_IRQ
 422         jmp ret_from_intr
 423
 424 #define BUILD_INTERRUPT(name, nr)       \
 425 ENTRY(name)                             \
 426         pushl $nr-256;                  \
 427         SAVE_ALL                        \
 428         movl %esp,%eax;                 \
 429         call smp_/**/name;              \
 430         jmp ret_from_intr;
 431
 432 /* The include is where all of the SMP etc. interrupts come from */
 433 #include "entry_arch.h"
 434
 435 ENTRY(divide_error)
 436         pushl $0                        # no error code
 437         pushl $do_divide_error
 438         ALIGN
 439 error_code:
 440         pushl %ds
 441         pushl %eax
 442         xorl %eax, %eax
 443         pushl %ebp
 444         pushl %edi
 445         pushl %esi
 446         pushl %edx
 447         decl %eax                       # eax = -1
 448         pushl %ecx
 449         pushl %ebx
 450         cld
 451         pushl %es
 452         UNWIND_ESPFIX_STACK
 453         popl %ecx
 454         movl ES(%esp), %edi             # get the function address
 455         movl ORIG_EAX(%esp), %edx       # get the error code
 456         movl %eax, ORIG_EAX(%esp)
 457         movl %ecx, ES(%esp)
 458         movl $(__USER_DS), %ecx
 459         movl %ecx, %ds
 460         movl %ecx, %es
 461         movl %esp,%eax                  # pt_regs pointer
 462         call *%edi
 463         jmp ret_from_exception
 464
 465 ENTRY(coprocessor_error)
 466         pushl $0
 467         pushl $do_coprocessor_error
 468         jmp error_code
 469
 470 ENTRY(simd_coprocessor_error)
 471         pushl $0
 472         pushl $do_simd_coprocessor_error
 473         jmp error_code
 474
 475 ENTRY(device_not_available)
 476         pushl $-1                       # mark this as an int
 477         SAVE_ALL
 478         movl %cr0, %eax
 479         testl $0x4, %eax                # EM (math emulation bit)
 480         jne device_not_available_emulate
 481         preempt_stop
 482         call math_state_restore
 483         jmp ret_from_exception
 484 device_not_available_emulate:
 485         pushl $0                        # temporary storage for ORIG_EIP
 486         call math_emulate
 487         addl $4, %esp
 488         jmp ret_from_exception
 489
 490 /*
 491  * Debug traps and NMI can happen at the one SYSENTER instruction
 492  * that sets up the real kernel stack. Check here, since we can't
 493  * allow the wrong stack to be used.
 494  *
 495  * "TSS_sysenter_esp0+12" is because the NMI/debug handler will have
 496  * already pushed 3 words if it hits on the sysenter instruction:
 497  * eflags, cs and eip.
 498  *
 499  * We just load the right stack, and push the three (known) values
 500  * by hand onto the new stack - while updating the return eip past
 501  * the instruction that would have done it for sysenter.
 502  */
 503 #define FIX_STACK(offset, ok, label)            \
 504         cmpw $__KERNEL_CS,4(%esp);              \
 505         jne ok;                                 \
 506 label:                                          \
 507         movl TSS_sysenter_esp0+offset(%esp),%esp;       \
 508         pushfl;                                 \
 509         pushl $__KERNEL_CS;                     \
 510         pushl $sysenter_past_esp
 511
 512 KPROBE_ENTRY(debug)
 513         cmpl $sysenter_entry,(%esp)
 514         jne debug_stack_correct
 515         FIX_STACK(12, debug_stack_correct, debug_esp_fix_insn)
 516 debug_stack_correct:
 517         pushl $-1                       # mark this as an int
 518         SAVE_ALL
 519         xorl %edx,%edx                  # error code 0
 520         movl %esp,%eax                  # pt_regs pointer
 521         call do_debug
 522         jmp ret_from_exception
 523         .previous .text
 524 /*
 525  * NMI is doubly nasty. It can happen _while_ we're handling
 526  * a debug fault, and the debug fault hasn't yet been able to
 527  * clear up the stack. So we first check whether we got  an
 528  * NMI on the sysenter entry path, but after that we need to
 529  * check whether we got an NMI on the debug path where the debug
 530  * fault happened on the sysenter path.
 531  */
 532 ENTRY(nmi)
 533         pushl %eax
 534         movl %ss, %eax
 535         cmpw $__ESPFIX_SS, %ax
 536         popl %eax
 537         je nmi_16bit_stack
 538         cmpl $sysenter_entry,(%esp)
 539         je nmi_stack_fixup
 540         pushl %eax
 541         movl %esp,%eax
 542         /* Do not access memory above the end of our stack page,
 543          * it might not exist.
 544          */
 545         andl $(THREAD_SIZE-1),%eax
 546         cmpl $(THREAD_SIZE-20),%eax
 547         popl %eax
 548         jae nmi_stack_correct
 549         cmpl $sysenter_entry,12(%esp)
 550         je nmi_debug_stack_check
 551 nmi_stack_correct:
 552         pushl %eax
 553         SAVE_ALL
 554         xorl %edx,%edx          # zero error code
 555         movl %esp,%eax          # pt_regs pointer
 556         call do_nmi
 557         jmp restore_all
 558
 559 nmi_stack_fixup:
 560         FIX_STACK(12,nmi_stack_correct, 1)
 561         jmp nmi_stack_correct
 562 nmi_debug_stack_check:
 563         cmpw $__KERNEL_CS,16(%esp)
 564         jne nmi_stack_correct
 565         cmpl $debug,(%esp)
 566         jb nmi_stack_correct
 567         cmpl $debug_esp_fix_insn,(%esp)
 568         ja nmi_stack_correct
 569         FIX_STACK(24,nmi_stack_correct, 1)
 570         jmp nmi_stack_correct
 571
 572 nmi_16bit_stack:
 573         /* create the pointer to lss back */
 574         pushl %ss
 575         pushl %esp
 576         movzwl %sp, %esp
 577         addw $4, (%esp)
 578         /* copy the iret frame of 12 bytes */
 579         .rept 3
 580         pushl 16(%esp)
 581         .endr
 582         pushl %eax
 583         SAVE_ALL
 584         FIXUP_ESPFIX_STACK              # %eax == %esp
 585         xorl %edx,%edx                  # zero error code
 586         call do_nmi
 587         RESTORE_REGS
 588         lss 12+4(%esp), %esp            # back to 16bit stack
 589 1:      iret
 590 .section __ex_table,"a"
 591         .align 4
 592         .long 1b,iret_exc
 593 .previous
 594
 595 KPROBE_ENTRY(int3)
 596         pushl $-1                       # mark this as an int
 597         SAVE_ALL
 598         xorl %edx,%edx          # zero error code
 599         movl %esp,%eax          # pt_regs pointer
 600         call do_int3
 601         jmp ret_from_exception
 602         .previous .text
 603
 604 ENTRY(overflow)
 605         pushl $0
 606         pushl $do_overflow
 607         jmp error_code
 608
 609 ENTRY(bounds)
 610         pushl $0
 611         pushl $do_bounds
 612         jmp error_code
 613
 614 ENTRY(invalid_op)
 615         pushl $0
 616         pushl $do_invalid_op
 617         jmp error_code
 618
 619 ENTRY(coprocessor_segment_overrun)
 620         pushl $0
 621         pushl $do_coprocessor_segment_overrun
 622         jmp error_code
 623
 624 ENTRY(invalid_TSS)
 625         pushl $do_invalid_TSS
 626         jmp error_code
 627
 628 ENTRY(segment_not_present)
 629         pushl $do_segment_not_present
 630         jmp error_code
 631
 632 ENTRY(stack_segment)
 633         pushl $do_stack_segment
 634         jmp error_code
 635
 636 KPROBE_ENTRY(general_protection)
 637         pushl $do_general_protection
 638         jmp error_code
 639         .previous .text
 640
 641 ENTRY(alignment_check)
 642         pushl $do_alignment_check
 643         jmp error_code
 644
 645 KPROBE_ENTRY(page_fault)
 646         pushl $do_page_fault
 647         jmp error_code
 648         .previous .text
 649
 650 #ifdef CONFIG_X86_MCE
 651 ENTRY(machine_check)
 652         pushl $0
 653         pushl machine_check_vector
 654         jmp error_code
 655 #endif
 656
 657 ENTRY(spurious_interrupt_bug)
 658         pushl $0
 659         pushl $do_spurious_interrupt_bug
 660         jmp error_code
 661
 662 .section .rodata,"a"
 663 #include "syscall_table.S"
 664
 665 syscall_table_size=(.-sys_call_table)