arch/blackfin/mach-common/entry.S

   1 /*
   2  * File:         arch/blackfin/mach-common/entry.S
   3  * Based on:
   4  * Author:       Linus Torvalds
   5  *
   6  * Created:      ?
   7  * Description:  contains the system-call and fault low-level handling routines.
   8  *               This also contains the timer-interrupt handler, as well as all
   9  *               interrupts and faults that can result in a task-switch.
  10  *
  11  * Modified:
  12  *               Copyright 2004-2006 Analog Devices Inc.
  13  *
  14  * Bugs:         Enter bugs at http://blackfin.uclinux.org/
  15  *
  16  * This program is free software; you can redistribute it and/or modify
  17  * it under the terms of the GNU General Public License as published by
  18  * the Free Software Foundation; either version 2 of the License, or
  19  * (at your option) any later version.
  20  *
  21  * This program is distributed in the hope that it will be useful,
  22  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  23  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24  * GNU General Public License for more details.
  25  *
  26  * You should have received a copy of the GNU General Public License
  27  * along with this program; if not, see the file COPYING, or write
  28  * to the Free Software Foundation, Inc.,
  29  * 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
  30  */
  31
  32 /* NOTE: This code handles signal-recognition, which happens every time
  33  * after a timer-interrupt and after each system call.
  34  */
  35
  36
  37 #include <linux/linkage.h>
  38 #include <linux/unistd.h>
  39 #include <asm/blackfin.h>
  40 #include <asm/errno.h>
  41 #include <asm/thread_info.h>  /* TIF_NEED_RESCHED */
  42 #include <asm/asm-offsets.h>
  43 #include <asm/trace.h>
  44
  45 #include <asm/mach-common/context.S>
  46
  47 #if defined(CONFIG_BFIN_SCRATCH_REG_RETN)
  48 # define EX_SCRATCH_REG RETN
  49 #elif defined(CONFIG_BFIN_SCRATCH_REG_RETE)
  50 # define EX_SCRATCH_REG RETE
  51 #else
  52 # define EX_SCRATCH_REG CYCLES
  53 #endif
  54
  55 #if ANOMALY_05000281
  56 ENTRY(_safe_speculative_execution)
  57         NOP;
  58         NOP;
  59         NOP;
  60         jump _safe_speculative_execution;
  61 ENDPROC(_safe_speculative_execution)
  62 #endif
  63
  64 #ifdef CONFIG_EXCPT_IRQ_SYSC_L1
  65 .section .l1.text
  66 #else
  67 .text
  68 #endif
  69
  70 /* Slightly simplified and streamlined entry point for CPLB misses.
  71  * This one does not lower the level to IRQ5, and thus can be used to
  72  * patch up CPLB misses on the kernel stack.
  73  */
  74 ENTRY(_ex_dcplb)
  75 #if ANOMALY_05000261
  76         /*
  77          * Work around an anomaly: if we see a new DCPLB fault, return
  78          * without doing anything.  Then, if we get the same fault again,
  79          * handle it.
  80          */
  81         p5.l = _last_cplb_fault_retx;
  82         p5.h = _last_cplb_fault_retx;
  83         r7 = [p5];
  84         r6 = retx;
  85         [p5] = r6;
  86         cc = r6 == r7;
  87         if !cc jump _return_from_exception;
  88         /* fall through */
  89 #endif
  90 ENDPROC(_ex_dcplb)
  91
  92 ENTRY(_ex_icplb)
  93         (R7:6,P5:4) = [sp++];
  94         ASTAT = [sp++];
  95         SAVE_ALL_SYS
  96         call __cplb_hdr;
  97         DEBUG_START_HWTRACE(p5, r7)
  98         RESTORE_ALL_SYS
  99         SP = EX_SCRATCH_REG;
 100         rtx;
 101 ENDPROC(_ex_icplb)
 102
 103 ENTRY(_ex_syscall)
 104         DEBUG_START_HWTRACE(p5, r7)
 105         (R7:6,P5:4) = [sp++];
 106         ASTAT = [sp++];
 107         raise 15;               /* invoked by TRAP #0, for sys call */
 108         sp = EX_SCRATCH_REG;
 109         rtx
 110 ENDPROC(_ex_syscall)
 111
 112 ENTRY(_ex_soft_bp)
 113         r7 = retx;
 114         r7 += -2;
 115         retx = r7;
 116         jump.s _ex_trap_c;
 117 ENDPROC(_ex_soft_bp)
 118
 119 ENTRY(_ex_single_step)
 120         r7 = retx;
 121         r6 = reti;
 122         cc = r7 == r6;
 123         if cc jump _return_from_exception
 124         r7 = syscfg;
 125         bitclr (r7, 0);
 126         syscfg = R7;
 127
 128         p5.l = lo(IPEND);
 129         p5.h = hi(IPEND);
 130         r6 = [p5];
 131         cc = bittst(r6, 5);
 132         if !cc jump _ex_trap_c;
 133         p4.l = lo(EVT5);
 134         p4.h = hi(EVT5);
 135         r6.h = _exception_to_level5;
 136         r6.l = _exception_to_level5;
 137         r7 = [p4];
 138         cc = r6 == r7;
 139         if !cc jump _ex_trap_c;
 140
 141 ENTRY(_return_from_exception)
 142         DEBUG_START_HWTRACE(p5, r7)
 143 #if ANOMALY_05000257
 144         R7=LC0;
 145         LC0=R7;
 146         R7=LC1;
 147         LC1=R7;
 148 #endif
 149         (R7:6,P5:4) = [sp++];
 150         ASTAT = [sp++];
 151         sp = EX_SCRATCH_REG;
 152         rtx;
 153 ENDPROC(_ex_soft_bp)
 154
 155 ENTRY(_handle_bad_cplb)
 156         /* To get here, we just tried and failed to change a CPLB
 157          * so, handle things in trap_c (C code), by lowering to
 158          * IRQ5, just like we normally do. Since this is not a
 159          * "normal" return path, we have a do alot of stuff to
 160          * the stack to get ready so, we can fall through - we
 161          * need to make a CPLB exception look like a normal exception
 162          */
 163
 164         DEBUG_START_HWTRACE(p5, r7)
 165         RESTORE_ALL_SYS
 166         [--sp] = ASTAT;
 167         [--sp] = (R7:6, P5:4);
 168
 169 ENTRY(_ex_replaceable)
 170         nop;
 171
 172 ENTRY(_ex_trap_c)
 173         /* Make sure we are not in a double fault */
 174         p4.l = lo(IPEND);
 175         p4.h = hi(IPEND);
 176         r7 = [p4];
 177         CC = BITTST (r7, 5);
 178         if CC jump _double_fault;
 179
 180         /* Call C code (trap_c) to handle the exception, which most
 181          * likely involves sending a signal to the current process.
 182          * To avoid double faults, lower our priority to IRQ5 first.
 183          */
 184         P5.h = _exception_to_level5;
 185         P5.l = _exception_to_level5;
 186         p4.l = lo(EVT5);
 187         p4.h = hi(EVT5);
 188         [p4] = p5;
 189         csync;
 190
 191         /* Disable all interrupts, but make sure level 5 is enabled so
 192          * we can switch to that level.  Save the old mask.  */
 193         cli r6;
 194         p4.l = _excpt_saved_imask;
 195         p4.h = _excpt_saved_imask;
 196         [p4] = r6;
 197         r6 = 0x3f;
 198         sti r6;
 199
 200         /* Save the excause into a circular buffer, in case the instruction
 201          * which caused this excecptions causes others.
 202          */
 203         P5.l = _in_ptr_excause;
 204         P5.h = _in_ptr_excause;
 205         R7 = [P5];
 206         R7 += 4;
 207         R6 = 0xF;
 208         R7 = R7 & R6;
 209         [P5] = R7;
 210         R6.l = _excause_circ_buf;
 211         R6.h = _excause_circ_buf;
 212         R7 = R7 + R6;
 213         p5 = R7;
 214         R6 = SEQSTAT;
 215         [P5] = R6;
 216
 217         DEBUG_START_HWTRACE(p5, r7)
 218         (R7:6,P5:4) = [sp++];
 219         ASTAT = [sp++];
 220         SP = EX_SCRATCH_REG;
 221         raise 5;
 222         rtx;
 223 ENDPROC(_ex_trap_c)
 224
 225 /* We just realized we got an exception, while we were processing a different
 226  * exception. This is a unrecoverable event, so crash
 227  */
 228 ENTRY(_double_fault)
 229         /* Turn caches & protection off, to ensure we don't get any more
 230          * double exceptions
 231          */
 232
 233         P4.L = LO(IMEM_CONTROL);
 234         P4.H = HI(IMEM_CONTROL);
 235
 236         R5 = [P4];              /* Control Register*/
 237         BITCLR(R5,ENICPLB_P);
 238         SSYNC;          /* SSYNC required before writing to IMEM_CONTROL. */
 239         .align 8;
 240         [P4] = R5;
 241         SSYNC;
 242
 243         P4.L = LO(DMEM_CONTROL);
 244         P4.H = HI(DMEM_CONTROL);
 245         R5 = [P4];
 246         BITCLR(R5,ENDCPLB_P);
 247         SSYNC;          /* SSYNC required before writing to DMEM_CONTROL. */
 248         .align 8;
 249         [P4] = R5;
 250         SSYNC;
 251
 252         /* Fix up the stack */
 253         (R7:6,P5:4) = [sp++];
 254         ASTAT = [sp++];
 255         SP = EX_SCRATCH_REG;
 256
 257         /* We should be out of the exception stack, and back down into
 258          * kernel or user space stack
 259          */
 260         SAVE_ALL_SYS
 261
 262         r0 = sp;        /* stack frame pt_regs pointer argument ==> r0 */
 263         SP += -12;
 264         call _double_fault_c;
 265         SP += 12;
 266 .L_double_fault_panic:
 267         JUMP .L_double_fault_panic
 268
 269 ENDPROC(_double_fault)
 270
 271 ENTRY(_exception_to_level5)
 272         SAVE_ALL_SYS
 273
 274         /* Restore interrupt mask.  We haven't pushed RETI, so this
 275          * doesn't enable interrupts until we return from this handler.  */
 276         p4.l = _excpt_saved_imask;
 277         p4.h = _excpt_saved_imask;
 278         r6 = [p4];
 279         sti r6;
 280
 281         /* Restore the hardware error vector.  */
 282         P5.h = _evt_ivhw;
 283         P5.l = _evt_ivhw;
 284         p4.l = lo(EVT5);
 285         p4.h = hi(EVT5);
 286         [p4] = p5;
 287         csync;
 288
 289         p2.l = lo(IPEND);
 290         p2.h = hi(IPEND);
 291         csync;
 292         r0 = [p2];              /* Read current IPEND */
 293         [sp + PT_IPEND] = r0;   /* Store IPEND */
 294
 295         /* Pop the excause from the circular buffer and push it on the stack
 296          * (in the right place - if you change the location of SEQSTAT, you
 297          * must change this offset.
 298          */
 299 .L_excep_to_5_again:
 300         P5.l = _out_ptr_excause;
 301         P5.h = _out_ptr_excause;
 302         R7 = [P5];
 303         R7 += 4;
 304         R6 = 0xF;
 305         R7 = R7 & R6;
 306         [P5] = R7;
 307         R6.l = _excause_circ_buf;
 308         R6.h = _excause_circ_buf;
 309         R7 = R7 + R6;
 310         P5 = R7;
 311         R1 = [P5];
 312         [SP + 8] = r1;
 313
 314         r0 = sp;        /* stack frame pt_regs pointer argument ==> r0 */
 315         SP += -12;
 316         call _trap_c;
 317         SP += 12;
 318
 319         /* See if anything else is in the exception buffer
 320          * if there is, process it
 321          */
 322         P5.l = _out_ptr_excause;
 323         P5.h = _out_ptr_excause;
 324         P4.l = _in_ptr_excause;
 325         P4.h = _in_ptr_excause;
 326         R6 = [P5];
 327         R7 = [P4];
 328         CC = R6 == R7;
 329         if ! CC JUMP .L_excep_to_5_again
 330
 331         call _ret_from_exception;
 332         RESTORE_ALL_SYS
 333         rti;
 334 ENDPROC(_exception_to_level5)
 335
 336 ENTRY(_trap) /* Exception: 4th entry into system event table(supervisor mode)*/
 337         /* Since the kernel stack can be anywhere, it's not guaranteed to be
 338          * covered by a CPLB.  Switch to an exception stack; use RETN as a
 339          * scratch register (for want of a better option).
 340          */
 341         EX_SCRATCH_REG = sp;
 342         sp.l = _exception_stack_top;
 343         sp.h = _exception_stack_top;
 344         /* Try to deal with syscalls quickly.  */
 345         [--sp] = ASTAT;
 346         [--sp] = (R7:6, P5:4);
 347         DEBUG_STOP_HWTRACE(p5, r7)
 348         r7 = SEQSTAT;           /* reason code is in bit 5:0 */
 349         r6.l = lo(SEQSTAT_EXCAUSE);
 350         r6.h = hi(SEQSTAT_EXCAUSE);
 351         r7 = r7 & r6;
 352         p5.h = _ex_table;
 353         p5.l = _ex_table;
 354         p4 = r7;
 355         p5 = p5 + (p4 << 2);
 356         p4 = [p5];
 357         jump (p4);
 358
 359 .Lbadsys:
 360         r7 = -ENOSYS;           /* signextending enough */
 361         [sp + PT_R0] = r7;      /* return value from system call */
 362         jump .Lsyscall_really_exit;
 363 ENDPROC(_trap)
 364
 365 ENTRY(_kernel_execve)
 366         link SIZEOF_PTREGS;
 367         p0 = sp;
 368         r3 = SIZEOF_PTREGS / 4;
 369         r4 = 0(x);
 370 0:
 371         [p0++] = r4;
 372         r3 += -1;
 373         cc = r3 == 0;
 374         if !cc jump 0b (bp);
 375
 376         p0 = sp;
 377         sp += -16;
 378         [sp + 12] = p0;
 379         call _do_execve;
 380         SP += 16;
 381         cc = r0 == 0;
 382         if ! cc jump 1f;
 383         /* Success.  Copy our temporary pt_regs to the top of the kernel
 384          * stack and do a normal exception return.
 385          */
 386         r1 = sp;
 387         r0 = (-KERNEL_STACK_SIZE) (x);
 388         r1 = r1 & r0;
 389         p2 = r1;
 390         p3 = [p2];
 391         r0 = KERNEL_STACK_SIZE - 4 (z);
 392         p1 = r0;
 393         p1 = p1 + p2;
 394
 395         p0 = fp;
 396         r4 = [p0--];
 397         r3 = SIZEOF_PTREGS / 4;
 398 0:
 399         r4 = [p0--];
 400         [p1--] = r4;
 401         r3 += -1;
 402         cc = r3 == 0;
 403         if ! cc jump 0b (bp);
 404
 405         r0 = (KERNEL_STACK_SIZE - SIZEOF_PTREGS) (z);
 406         p1 = r0;
 407         p1 = p1 + p2;
 408         sp = p1;
 409         r0 = syscfg;
 410         [SP + PT_SYSCFG] = r0;
 411         [p3 + (TASK_THREAD + THREAD_KSP)] = sp;
 412
 413         RESTORE_CONTEXT;
 414         rti;
 415 1:
 416         unlink;
 417         rts;
 418 ENDPROC(_kernel_execve)
 419
 420 ENTRY(_system_call)
 421         /* Store IPEND */
 422         p2.l = lo(IPEND);
 423         p2.h = hi(IPEND);
 424         csync;
 425         r0 = [p2];
 426         [sp + PT_IPEND] = r0;
 427
 428         /* Store RETS for now */
 429         r0 = rets;
 430         [sp + PT_RESERVED] = r0;
 431         /* Set the stack for the current process */
 432         r7 = sp;
 433         r6.l = lo(ALIGN_PAGE_MASK);
 434         r6.h = hi(ALIGN_PAGE_MASK);
 435         r7 = r7 & r6;           /* thread_info */
 436         p2 = r7;
 437         p2 = [p2];
 438
 439         [p2+(TASK_THREAD+THREAD_KSP)] = sp;
 440
 441         /* Check the System Call */
 442         r7 = __NR_syscall;
 443         /* System call number is passed in P0 */
 444         r6 = p0;
 445         cc = r6 < r7;
 446         if ! cc jump .Lbadsys;
 447
 448         /* are we tracing syscalls?*/
 449         r7 = sp;
 450         r6.l = lo(ALIGN_PAGE_MASK);
 451         r6.h = hi(ALIGN_PAGE_MASK);
 452         r7 = r7 & r6;
 453         p2 = r7;
 454         r7 = [p2+TI_FLAGS];
 455         CC = BITTST(r7,TIF_SYSCALL_TRACE);
 456         if CC JUMP _sys_trace;
 457
 458         /* Execute the appropriate system call */
 459
 460         p4 = p0;
 461         p5.l = _sys_call_table;
 462         p5.h = _sys_call_table;
 463         p5 = p5 + (p4 << 2);
 464         r0 = [sp + PT_R0];
 465         r1 = [sp + PT_R1];
 466         r2 = [sp + PT_R2];
 467         p5 = [p5];
 468
 469         [--sp] = r5;
 470         [--sp] = r4;
 471         [--sp] = r3;
 472         SP += -12;
 473         call (p5);
 474         SP += 24;
 475         [sp + PT_R0] = r0;
 476
 477 .Lresume_userspace:
 478         r7 = sp;
 479         r4.l = lo(ALIGN_PAGE_MASK);
 480         r4.h = hi(ALIGN_PAGE_MASK);
 481         r7 = r7 & r4;           /* thread_info->flags */
 482         p5 = r7;
 483 .Lresume_userspace_1:
 484         /* Disable interrupts.  */
 485         [--sp] = reti;
 486         reti = [sp++];
 487
 488         r7 = [p5 + TI_FLAGS];
 489         r4.l = lo(_TIF_WORK_MASK);
 490         r4.h = hi(_TIF_WORK_MASK);
 491         r7 =  r7 & r4;
 492
 493 .Lsyscall_resched:
 494         cc = BITTST(r7, TIF_NEED_RESCHED);
 495         if !cc jump .Lsyscall_sigpending;
 496
 497         /* Reenable interrupts.  */
 498         [--sp] = reti;
 499         r0 = [sp++];
 500
 501         SP += -12;
 502         call _schedule;
 503         SP += 12;
 504
 505         jump .Lresume_userspace_1;
 506
 507 .Lsyscall_sigpending:
 508         cc = BITTST(r7, TIF_RESTORE_SIGMASK);
 509         if cc jump .Lsyscall_do_signals;
 510         cc = BITTST(r7, TIF_SIGPENDING);
 511         if !cc jump .Lsyscall_really_exit;
 512 .Lsyscall_do_signals:
 513         /* Reenable interrupts.  */
 514         [--sp] = reti;
 515         r0 = [sp++];
 516
 517         r0 = sp;
 518         SP += -12;
 519         call _do_signal;
 520         SP += 12;
 521
 522 .Lsyscall_really_exit:
 523         r5 = [sp + PT_RESERVED];
 524         rets = r5;
 525         rts;
 526 ENDPROC(_system_call)
 527
 528 _sys_trace:
 529         call _syscall_trace;
 530
 531         /* Execute the appropriate system call */
 532
 533         p4 = [SP + PT_P0];
 534         p5.l = _sys_call_table;
 535         p5.h = _sys_call_table;
 536         p5 = p5 + (p4 << 2);
 537         r0 = [sp + PT_R0];
 538         r1 = [sp + PT_R1];
 539         r2 = [sp + PT_R2];
 540         r3 = [sp + PT_R3];
 541         r4 = [sp + PT_R4];
 542         r5 = [sp + PT_R5];
 543         p5 = [p5];
 544
 545         [--sp] = r5;
 546         [--sp] = r4;
 547         [--sp] = r3;
 548         SP += -12;
 549         call (p5);
 550         SP += 24;
 551         [sp + PT_R0] = r0;
 552
 553         call _syscall_trace;
 554         jump .Lresume_userspace;
 555 ENDPROC(_sys_trace)
 556
 557 ENTRY(_resume)
 558         /*
 559          * Beware - when entering resume, prev (the current task) is
 560          * in r0, next (the new task) is in r1.
 561          */
 562         p0 = r0;
 563         p1 = r1;
 564         [--sp] = rets;
 565         [--sp] = fp;
 566         [--sp] = (r7:4, p5:3);
 567
 568         /* save usp */
 569         p2 = usp;
 570         [p0+(TASK_THREAD+THREAD_USP)] = p2;
 571
 572         /* save current kernel stack pointer */
 573         [p0+(TASK_THREAD+THREAD_KSP)] = sp;
 574
 575         /* save program counter */
 576         r1.l = _new_old_task;
 577         r1.h = _new_old_task;
 578         [p0+(TASK_THREAD+THREAD_PC)] = r1;
 579
 580         /* restore the kernel stack pointer */
 581         sp = [p1+(TASK_THREAD+THREAD_KSP)];
 582
 583         /* restore user stack pointer */
 584         p0 = [p1+(TASK_THREAD+THREAD_USP)];
 585         usp = p0;
 586
 587         /* restore pc */
 588         p0 = [p1+(TASK_THREAD+THREAD_PC)];
 589         jump (p0);
 590
 591         /*
 592          * Following code actually lands up in a new (old) task.
 593          */
 594
 595 _new_old_task:
 596         (r7:4, p5:3) = [sp++];
 597         fp = [sp++];
 598         rets = [sp++];
 599
 600         /*
 601          * When we come out of resume, r0 carries "old" task, becuase we are
 602          * in "new" task.
 603          */
 604         rts;
 605 ENDPROC(_resume)
 606
 607 ENTRY(_ret_from_exception)
 608         p2.l = lo(IPEND);
 609         p2.h = hi(IPEND);
 610
 611         csync;
 612         r0 = [p2];
 613         [sp + PT_IPEND] = r0;
 614
 615 1:
 616         r1 = 0x37(Z);
 617         r2 = ~r1;
 618         r2.h = 0;
 619         r0 = r2 & r0;
 620         cc = r0 == 0;
 621         if !cc jump 4f; /* if not return to user mode, get out */
 622
 623         /* Make sure any pending system call or deferred exception
 624          * return in ILAT for this process to get executed, otherwise
 625          * in case context switch happens, system call of
 626          * first process (i.e in ILAT) will be carried
 627          * forward to the switched process
 628          */
 629
 630         p2.l = lo(ILAT);
 631         p2.h = hi(ILAT);
 632         r0 = [p2];
 633         r1 = (EVT_IVG14 | EVT_IVG15) (z);
 634         r0 = r0 & r1;
 635         cc = r0 == 0;
 636         if !cc jump 5f;
 637
 638         /* Set the stack for the current process */
 639         r7 = sp;
 640         r4.l = lo(ALIGN_PAGE_MASK);
 641         r4.h = hi(ALIGN_PAGE_MASK);
 642         r7 = r7 & r4;           /* thread_info->flags */
 643         p5 = r7;
 644         r7 = [p5 + TI_FLAGS];
 645         r4.l = lo(_TIF_WORK_MASK);
 646         r4.h = hi(_TIF_WORK_MASK);
 647         r7 =  r7 & r4;
 648         cc = r7 == 0;
 649         if cc jump 4f;
 650
 651         p0.l = lo(EVT15);
 652         p0.h = hi(EVT15);
 653         p1.l = _schedule_and_signal;
 654         p1.h = _schedule_and_signal;
 655         [p0] = p1;
 656         csync;
 657         raise 15;               /* raise evt14 to do signal or reschedule */
 658 4:
 659         r0 = syscfg;
 660         bitclr(r0, 0);
 661         syscfg = r0;
 662 5:
 663         rts;
 664 ENDPROC(_ret_from_exception)
 665
 666 ENTRY(_return_from_int)
 667         /* If someone else already raised IRQ 15, do nothing.  */
 668         csync;
 669         p2.l = lo(ILAT);
 670         p2.h = hi(ILAT);
 671         r0 = [p2];
 672         cc = bittst (r0, EVT_IVG15_P);
 673         if cc jump 2f;
 674
 675         /* if not return to user mode, get out */
 676         p2.l = lo(IPEND);
 677         p2.h = hi(IPEND);
 678         r0 = [p2];
 679         r1 = 0x17(Z);
 680         r2 = ~r1;
 681         r2.h = 0;
 682         r0 = r2 & r0;
 683         r1 = 1;
 684         r1 = r0 - r1;
 685         r2 = r0 & r1;
 686         cc = r2 == 0;
 687         if !cc jump 2f;
 688
 689         /* Lower the interrupt level to 15.  */
 690         p0.l = lo(EVT15);
 691         p0.h = hi(EVT15);
 692         p1.l = _schedule_and_signal_from_int;
 693         p1.h = _schedule_and_signal_from_int;
 694         [p0] = p1;
 695         csync;
 696 #if ANOMALY_05000281
 697         r0.l = _safe_speculative_execution;
 698         r0.h = _safe_speculative_execution;
 699         reti = r0;
 700 #endif
 701         r0 = 0x801f (z);
 702         STI r0;
 703         raise 15;       /* raise evt15 to do signal or reschedule */
 704         rti;
 705 2:
 706         rts;
 707 ENDPROC(_return_from_int)
 708
 709 ENTRY(_lower_to_irq14)
 710 #if ANOMALY_05000281
 711         r0.l = _safe_speculative_execution;
 712         r0.h = _safe_speculative_execution;
 713         reti = r0;
 714 #endif
 715         r0 = 0x401f;
 716         sti r0;
 717         raise 14;
 718         rti;
 719 ENTRY(_evt14_softirq)
 720 #ifdef CONFIG_DEBUG_HWERR
 721         r0 = 0x3f;
 722         sti r0;
 723 #else
 724         cli r0;
 725 #endif
 726         [--sp] = RETI;
 727         SP += 4;
 728         rts;
 729
 730 _schedule_and_signal_from_int:
 731         /* To end up here, vector 15 was changed - so we have to change it
 732          * back.
 733          */
 734         p0.l = lo(EVT15);
 735         p0.h = hi(EVT15);
 736         p1.l = _evt_system_call;
 737         p1.h = _evt_system_call;
 738         [p0] = p1;
 739         csync;
 740
 741         /* Set orig_p0 to -1 to indicate this isn't the end of a syscall.  */
 742         r0 = -1 (x);
 743         [sp + PT_ORIG_P0] = r0;
 744
 745         p1 = rets;
 746         [sp + PT_RESERVED] = p1;
 747
 748         p0.l = _irq_flags;
 749         p0.h = _irq_flags;
 750         r0 = [p0];
 751         sti r0;
 752
 753         r0 = sp;
 754         sp += -12;
 755         call _finish_atomic_sections;
 756         sp += 12;
 757         jump.s .Lresume_userspace;
 758
 759 _schedule_and_signal:
 760         SAVE_CONTEXT_SYSCALL
 761         /* To end up here, vector 15 was changed - so we have to change it
 762          * back.
 763          */
 764         p0.l = lo(EVT15);
 765         p0.h = hi(EVT15);
 766         p1.l = _evt_system_call;
 767         p1.h = _evt_system_call;
 768         [p0] = p1;
 769         csync;
 770         p0.l = 1f;
 771         p0.h = 1f;
 772         [sp + PT_RESERVED] = P0;
 773         call .Lresume_userspace;
 774 1:
 775         RESTORE_CONTEXT
 776         rti;
 777 ENDPROC(_lower_to_irq14)
 778
 779 /* Make sure when we start, that the circular buffer is initialized properly
 780  * R0 and P0 are call clobbered, so we can use them here.
 781  */
 782 ENTRY(_init_exception_buff)
 783         r0 = 0;
 784         p0.h = _in_ptr_excause;
 785         p0.l = _in_ptr_excause;
 786         [p0] = r0;
 787         p0.h = _out_ptr_excause;
 788         p0.l = _out_ptr_excause;
 789         [p0] = r0;
 790         rts;
 791 ENDPROC(_init_exception_buff)
 792
 793 /* We handle this 100% in exception space - to reduce overhead
 794  * Only potiential problem is if the software buffer gets swapped out of the
 795  * CPLB table - then double fault. - so we don't let this happen in other places
 796  */
 797 #ifdef CONFIG_DEBUG_BFIN_HWTRACE_EXPAND
 798 ENTRY(_ex_trace_buff_full)
 799         [--sp] = P3;
 800         [--sp] = P2;
 801         [--sp] = LC0;
 802         [--sp] = LT0;
 803         [--sp] = LB0;
 804         P5.L = _trace_buff_offset;
 805         P5.H = _trace_buff_offset;
 806         P3 = [P5];              /* trace_buff_offset */
 807         P5.L = lo(TBUFSTAT);
 808         P5.H = hi(TBUFSTAT);
 809         R7 = [P5];
 810         R7 <<= 1;               /* double, since we need to read twice */
 811         LC0 = R7;
 812         R7 <<= 2;               /* need to shift over again,
 813                                  * to get the number of bytes */
 814         P5.L = lo(TBUF);
 815         P5.H = hi(TBUF);
 816         R6 = ((1 << CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN)*1024) - 1;
 817
 818         P2 = R7;
 819         P3 = P3 + P2;
 820         R7 = P3;
 821         R7 = R7 & R6;
 822         P3 = R7;
 823         P2.L = _trace_buff_offset;
 824         P2.H = _trace_buff_offset;
 825         [P2] = P3;
 826
 827         P2.L = _software_trace_buff;
 828         P2.H = _software_trace_buff;
 829
 830         LSETUP (.Lstart, .Lend) LC0;
 831 .Lstart:
 832         R7 = [P5];      /* read TBUF */
 833         P4 = P3 + P2;
 834         [P4] = R7;
 835         P3 += -4;
 836         R7 = P3;
 837         R7 = R7 & R6;
 838 .Lend:
 839         P3 = R7;
 840
 841         LB0 = [sp++];
 842         LT0 = [sp++];
 843         LC0 = [sp++];
 844         P2 = [sp++];
 845         P3 = [sp++];
 846         jump _return_from_exception;
 847 ENDPROC(_ex_trace_buff_full)
 848
 849 #if CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN == 4
 850 .data
 851 #else
 852 .section .l1.data.B
 853 #endif /* CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN */
 854 ENTRY(_trace_buff_offset)
 855         .long 0;
 856 ALIGN
 857 ENTRY(_software_trace_buff)
 858         .rept ((1 << CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN)*256);
 859         .long 0
 860         .endr
 861 #endif /* CONFIG_DEBUG_BFIN_HWTRACE_EXPAND */
 862
 863 #if CONFIG_EARLY_PRINTK
 864 .section .init.text
 865 ENTRY(_early_trap)
 866         SAVE_ALL_SYS
 867         trace_buffer_stop(p0,r0);
 868
 869         /* Turn caches off, to ensure we don't get double exceptions */
 870
 871         P4.L = LO(IMEM_CONTROL);
 872         P4.H = HI(IMEM_CONTROL);
 873
 874         R5 = [P4];              /* Control Register*/
 875         BITCLR(R5,ENICPLB_P);
 876         CLI R1;
 877         SSYNC;          /* SSYNC required before writing to IMEM_CONTROL. */
 878         .align 8;
 879         [P4] = R5;
 880         SSYNC;
 881
 882         P4.L = LO(DMEM_CONTROL);
 883         P4.H = HI(DMEM_CONTROL);
 884         R5 = [P4];
 885         BITCLR(R5,ENDCPLB_P);
 886         SSYNC;          /* SSYNC required before writing to DMEM_CONTROL. */
 887         .align 8;
 888         [P4] = R5;
 889         SSYNC;
 890         STI R1;
 891
 892         r0 = sp;        /* stack frame pt_regs pointer argument ==> r0 */
 893         r1 = RETX;
 894
 895         SP += -12;
 896         call _early_trap_c;
 897         SP += 12;
 898 ENDPROC(_early_trap)
 899 #endif /* CONFIG_EARLY_PRINTK */
 900
 901 /*
 902  * Put these in the kernel data section - that should always be covered by
 903  * a CPLB. This is needed to ensure we don't get double fault conditions
 904  */
 905
 906 #ifdef CONFIG_SYSCALL_TAB_L1
 907 .section .l1.data
 908 #else
 909 .data
 910 #endif
 911 ENTRY(_ex_table)
 912         /* entry for each EXCAUSE[5:0]
 913          * This table must be in sync with the table in ./kernel/traps.c
 914          * EXCPT instruction can provide 4 bits of EXCAUSE, allowing 16 to be user defined
 915          */
 916         .long _ex_syscall       /* 0x00 - User Defined - Linux Syscall */
 917         .long _ex_soft_bp       /* 0x01 - User Defined - Software breakpoint */
 918         .long _ex_replaceable   /* 0x02 - User Defined */
 919         .long _ex_trap_c        /* 0x03 - User Defined - userspace stack overflow */
 920         .long _ex_replaceable   /* 0x04 - User Defined */
 921         .long _ex_replaceable   /* 0x05 - User Defined */
 922         .long _ex_replaceable   /* 0x06 - User Defined */
 923         .long _ex_replaceable   /* 0x07 - User Defined */
 924         .long _ex_replaceable   /* 0x08 - User Defined */
 925         .long _ex_replaceable   /* 0x09 - User Defined */
 926         .long _ex_replaceable   /* 0x0A - User Defined */
 927         .long _ex_replaceable   /* 0x0B - User Defined */
 928         .long _ex_replaceable   /* 0x0C - User Defined */
 929         .long _ex_replaceable   /* 0x0D - User Defined */
 930         .long _ex_replaceable   /* 0x0E - User Defined */
 931         .long _ex_replaceable   /* 0x0F - User Defined */
 932         .long _ex_single_step   /* 0x10 - HW Single step */
 933 #ifdef CONFIG_DEBUG_BFIN_HWTRACE_EXPAND
 934         .long _ex_trace_buff_full /* 0x11 - Trace Buffer Full */
 935 #else
 936         .long _ex_trap_c        /* 0x11 - Trace Buffer Full */
 937 #endif
 938         .long _ex_trap_c        /* 0x12 - Reserved */
 939         .long _ex_trap_c        /* 0x13 - Reserved */
 940         .long _ex_trap_c        /* 0x14 - Reserved */
 941         .long _ex_trap_c        /* 0x15 - Reserved */
 942         .long _ex_trap_c        /* 0x16 - Reserved */
 943         .long _ex_trap_c        /* 0x17 - Reserved */
 944         .long _ex_trap_c        /* 0x18 - Reserved */
 945         .long _ex_trap_c        /* 0x19 - Reserved */
 946         .long _ex_trap_c        /* 0x1A - Reserved */
 947         .long _ex_trap_c        /* 0x1B - Reserved */
 948         .long _ex_trap_c        /* 0x1C - Reserved */
 949         .long _ex_trap_c        /* 0x1D - Reserved */
 950         .long _ex_trap_c        /* 0x1E - Reserved */
 951         .long _ex_trap_c        /* 0x1F - Reserved */
 952         .long _ex_trap_c        /* 0x20 - Reserved */
 953         .long _ex_trap_c        /* 0x21 - Undefined Instruction */
 954         .long _ex_trap_c        /* 0x22 - Illegal Instruction Combination */
 955         .long _ex_dcplb         /* 0x23 - Data CPLB Protection Violation */
 956         .long _ex_trap_c        /* 0x24 - Data access misaligned */
 957         .long _ex_trap_c        /* 0x25 - Unrecoverable Event */
 958         .long _ex_dcplb         /* 0x26 - Data CPLB Miss */
 959         .long _ex_trap_c        /* 0x27 - Data CPLB Multiple Hits - Linux Trap Zero */
 960         .long _ex_trap_c        /* 0x28 - Emulation Watchpoint */
 961         .long _ex_trap_c        /* 0x29 - Instruction fetch access error (535 only) */
 962         .long _ex_trap_c        /* 0x2A - Instruction fetch misaligned */
 963         .long _ex_icplb         /* 0x2B - Instruction CPLB protection Violation */
 964         .long _ex_icplb         /* 0x2C - Instruction CPLB miss */
 965         .long _ex_trap_c        /* 0x2D - Instruction CPLB Multiple Hits */
 966         .long _ex_trap_c        /* 0x2E - Illegal use of Supervisor Resource */
 967         .long _ex_trap_c        /* 0x2E - Illegal use of Supervisor Resource */
 968         .long _ex_trap_c        /* 0x2F - Reserved */
 969         .long _ex_trap_c        /* 0x30 - Reserved */
 970         .long _ex_trap_c        /* 0x31 - Reserved */
 971         .long _ex_trap_c        /* 0x32 - Reserved */
 972         .long _ex_trap_c        /* 0x33 - Reserved */
 973         .long _ex_trap_c        /* 0x34 - Reserved */
 974         .long _ex_trap_c        /* 0x35 - Reserved */
 975         .long _ex_trap_c        /* 0x36 - Reserved */
 976         .long _ex_trap_c        /* 0x37 - Reserved */
 977         .long _ex_trap_c        /* 0x38 - Reserved */
 978         .long _ex_trap_c        /* 0x39 - Reserved */
 979         .long _ex_trap_c        /* 0x3A - Reserved */
 980         .long _ex_trap_c        /* 0x3B - Reserved */
 981         .long _ex_trap_c        /* 0x3C - Reserved */
 982         .long _ex_trap_c        /* 0x3D - Reserved */
 983         .long _ex_trap_c        /* 0x3E - Reserved */
 984         .long _ex_trap_c        /* 0x3F - Reserved */
 985 END(_ex_table)
 986
 987 ENTRY(_sys_call_table)
 988         .long _sys_restart_syscall      /* 0 */
 989         .long _sys_exit
 990         .long _sys_fork
 991         .long _sys_read
 992         .long _sys_write
 993         .long _sys_open         /* 5 */
 994         .long _sys_close
 995         .long _sys_ni_syscall   /* old waitpid */
 996         .long _sys_creat
 997         .long _sys_link
 998         .long _sys_unlink       /* 10 */
 999         .long _sys_execve
1000         .long _sys_chdir
1001         .long _sys_time
1002         .long _sys_mknod
1003         .long _sys_chmod                /* 15 */
1004         .long _sys_chown        /* chown16 */
1005         .long _sys_ni_syscall   /* old break syscall holder */
1006         .long _sys_ni_syscall   /* old stat */
1007         .long _sys_lseek
1008         .long _sys_getpid       /* 20 */
1009         .long _sys_mount
1010         .long _sys_ni_syscall   /* old umount */
1011         .long _sys_setuid
1012         .long _sys_getuid
1013         .long _sys_stime                /* 25 */
1014         .long _sys_ptrace
1015         .long _sys_alarm
1016         .long _sys_ni_syscall   /* old fstat */
1017         .long _sys_pause
1018         .long _sys_ni_syscall   /* old utime */ /* 30 */
1019         .long _sys_ni_syscall   /* old stty syscall holder */
1020         .long _sys_ni_syscall   /* old gtty syscall holder */
1021         .long _sys_access
1022         .long _sys_nice
1023         .long _sys_ni_syscall   /* 35 */ /* old ftime syscall holder */
1024         .long _sys_sync
1025         .long _sys_kill
1026         .long _sys_rename
1027         .long _sys_mkdir
1028         .long _sys_rmdir                /* 40 */
1029         .long _sys_dup
1030         .long _sys_pipe
1031         .long _sys_times
1032         .long _sys_ni_syscall   /* old prof syscall holder */
1033         .long _sys_brk          /* 45 */
1034         .long _sys_setgid
1035         .long _sys_getgid
1036         .long _sys_ni_syscall   /* old sys_signal */
1037         .long _sys_geteuid      /* geteuid16 */
1038         .long _sys_getegid      /* getegid16 */ /* 50 */
1039         .long _sys_acct
1040         .long _sys_umount       /* recycled never used phys() */
1041         .long _sys_ni_syscall   /* old lock syscall holder */
1042         .long _sys_ioctl
1043         .long _sys_fcntl                /* 55 */
1044         .long _sys_ni_syscall   /* old mpx syscall holder */
1045         .long _sys_setpgid
1046         .long _sys_ni_syscall   /* old ulimit syscall holder */
1047         .long _sys_ni_syscall   /* old old uname */
1048         .long _sys_umask                /* 60 */
1049         .long _sys_chroot
1050         .long _sys_ustat
1051         .long _sys_dup2
1052         .long _sys_getppid
1053         .long _sys_getpgrp      /* 65 */
1054         .long _sys_setsid
1055         .long _sys_ni_syscall   /* old sys_sigaction */
1056         .long _sys_sgetmask
1057         .long _sys_ssetmask
1058         .long _sys_setreuid     /* setreuid16 */        /* 70 */
1059         .long _sys_setregid     /* setregid16 */
1060         .long _sys_ni_syscall   /* old sys_sigsuspend */
1061         .long _sys_ni_syscall   /* old sys_sigpending */
1062         .long _sys_sethostname
1063         .long _sys_setrlimit    /* 75 */
1064         .long _sys_ni_syscall   /* old getrlimit */
1065         .long _sys_getrusage
1066         .long _sys_gettimeofday
1067         .long _sys_settimeofday
1068         .long _sys_getgroups    /* getgroups16 */       /* 80 */
1069         .long _sys_setgroups    /* setgroups16 */
1070         .long _sys_ni_syscall   /* old_select */
1071         .long _sys_symlink
1072         .long _sys_ni_syscall   /* old lstat */
1073         .long _sys_readlink     /* 85 */
1074         .long _sys_uselib
1075         .long _sys_ni_syscall   /* sys_swapon */
1076         .long _sys_reboot
1077         .long _sys_ni_syscall   /* old_readdir */
1078         .long _sys_ni_syscall   /* sys_mmap */  /* 90 */
1079         .long _sys_munmap
1080         .long _sys_truncate
1081         .long _sys_ftruncate
1082         .long _sys_fchmod
1083         .long _sys_fchown       /* fchown16 */  /* 95 */
1084         .long _sys_getpriority
1085         .long _sys_setpriority
1086         .long _sys_ni_syscall   /* old profil syscall holder */
1087         .long _sys_statfs
1088         .long _sys_fstatfs      /* 100 */
1089         .long _sys_ni_syscall
1090         .long _sys_ni_syscall   /* old sys_socketcall */
1091         .long _sys_syslog
1092         .long _sys_setitimer
1093         .long _sys_getitimer    /* 105 */
1094         .long _sys_newstat
1095         .long _sys_newlstat
1096         .long _sys_newfstat
1097         .long _sys_ni_syscall   /* old uname */
1098         .long _sys_ni_syscall   /* iopl for i386 */ /* 110 */
1099         .long _sys_vhangup
1100         .long _sys_ni_syscall   /* obsolete idle() syscall */
1101         .long _sys_ni_syscall   /* vm86old for i386 */
1102         .long _sys_wait4
1103         .long _sys_ni_syscall   /* 115 */ /* sys_swapoff */
1104         .long _sys_sysinfo
1105         .long _sys_ni_syscall   /* old sys_ipc */
1106         .long _sys_fsync
1107         .long _sys_ni_syscall   /* old sys_sigreturn */
1108         .long _sys_clone                /* 120 */
1109         .long _sys_setdomainname
1110         .long _sys_newuname
1111         .long _sys_ni_syscall   /* old sys_modify_ldt */
1112         .long _sys_adjtimex
1113         .long _sys_ni_syscall   /* 125 */ /* sys_mprotect */
1114         .long _sys_ni_syscall   /* old sys_sigprocmask */
1115         .long _sys_ni_syscall   /* old "creat_module" */
1116         .long _sys_init_module
1117         .long _sys_delete_module
1118         .long _sys_ni_syscall   /* 130: old "get_kernel_syms" */
1119         .long _sys_quotactl
1120         .long _sys_getpgid
1121         .long _sys_fchdir
1122         .long _sys_bdflush
1123         .long _sys_ni_syscall   /* 135 */ /* sys_sysfs */
1124         .long _sys_personality
1125         .long _sys_ni_syscall   /* for afs_syscall */
1126         .long _sys_setfsuid     /* setfsuid16 */
1127         .long _sys_setfsgid     /* setfsgid16 */
1128         .long _sys_llseek       /* 140 */
1129         .long _sys_getdents
1130         .long _sys_ni_syscall   /* sys_select */
1131         .long _sys_flock
1132         .long _sys_ni_syscall   /* sys_msync */
1133         .long _sys_readv                /* 145 */
1134         .long _sys_writev
1135         .long _sys_getsid
1136         .long _sys_fdatasync
1137         .long _sys_sysctl
1138         .long _sys_ni_syscall   /* 150 */ /* sys_mlock */
1139         .long _sys_ni_syscall   /* sys_munlock */
1140         .long _sys_ni_syscall   /* sys_mlockall */
1141         .long _sys_ni_syscall   /* sys_munlockall */
1142         .long _sys_sched_setparam
1143         .long _sys_sched_getparam /* 155 */
1144         .long _sys_sched_setscheduler
1145         .long _sys_sched_getscheduler
1146         .long _sys_sched_yield
1147         .long _sys_sched_get_priority_max
1148         .long _sys_sched_get_priority_min  /* 160 */
1149         .long _sys_sched_rr_get_interval
1150         .long _sys_nanosleep
1151         .long _sys_mremap
1152         .long _sys_setresuid    /* setresuid16 */
1153         .long _sys_getresuid    /* getresuid16 */       /* 165 */
1154         .long _sys_ni_syscall   /* for vm86 */
1155         .long _sys_ni_syscall   /* old "query_module" */
1156         .long _sys_ni_syscall   /* sys_poll */
1157         .long _sys_nfsservctl
1158         .long _sys_setresgid    /* setresgid16 */       /* 170 */
1159         .long _sys_getresgid    /* getresgid16 */
1160         .long _sys_prctl
1161         .long _sys_rt_sigreturn
1162         .long _sys_rt_sigaction
1163         .long _sys_rt_sigprocmask /* 175 */
1164         .long _sys_rt_sigpending
1165         .long _sys_rt_sigtimedwait
1166         .long _sys_rt_sigqueueinfo
1167         .long _sys_rt_sigsuspend
1168         .long _sys_pread64      /* 180 */
1169         .long _sys_pwrite64
1170         .long _sys_lchown       /* lchown16 */
1171         .long _sys_getcwd
1172         .long _sys_capget
1173         .long _sys_capset       /* 185 */
1174         .long _sys_sigaltstack
1175         .long _sys_sendfile
1176         .long _sys_ni_syscall   /* streams1 */
1177         .long _sys_ni_syscall   /* streams2 */
1178         .long _sys_vfork                /* 190 */
1179         .long _sys_getrlimit
1180         .long _sys_mmap2
1181         .long _sys_truncate64
1182         .long _sys_ftruncate64
1183         .long _sys_stat64       /* 195 */
1184         .long _sys_lstat64
1185         .long _sys_fstat64
1186         .long _sys_chown
1187         .long _sys_getuid
1188         .long _sys_getgid       /* 200 */
1189         .long _sys_geteuid
1190         .long _sys_getegid
1191         .long _sys_setreuid
1192         .long _sys_setregid
1193         .long _sys_getgroups    /* 205 */
1194         .long _sys_setgroups
1195         .long _sys_fchown
1196         .long _sys_setresuid
1197         .long _sys_getresuid
1198         .long _sys_setresgid    /* 210 */
1199         .long _sys_getresgid
1200         .long _sys_lchown
1201         .long _sys_setuid
1202         .long _sys_setgid
1203         .long _sys_setfsuid     /* 215 */
1204         .long _sys_setfsgid
1205         .long _sys_pivot_root
1206         .long _sys_ni_syscall   /* sys_mincore */
1207         .long _sys_ni_syscall   /* sys_madvise */
1208         .long _sys_getdents64   /* 220 */
1209         .long _sys_fcntl64
1210         .long _sys_ni_syscall   /* reserved for TUX */
1211         .long _sys_ni_syscall
1212         .long _sys_gettid
1213         .long _sys_readahead    /* 225 */
1214         .long _sys_setxattr
1215         .long _sys_lsetxattr
1216         .long _sys_fsetxattr
1217         .long _sys_getxattr
1218         .long _sys_lgetxattr    /* 230 */
1219         .long _sys_fgetxattr
1220         .long _sys_listxattr
1221         .long _sys_llistxattr
1222         .long _sys_flistxattr
1223         .long _sys_removexattr  /* 235 */
1224         .long _sys_lremovexattr
1225         .long _sys_fremovexattr
1226         .long _sys_tkill
1227         .long _sys_sendfile64
1228         .long _sys_futex                /* 240 */
1229         .long _sys_sched_setaffinity
1230         .long _sys_sched_getaffinity
1231         .long _sys_ni_syscall   /* sys_set_thread_area */
1232         .long _sys_ni_syscall   /* sys_get_thread_area */
1233         .long _sys_io_setup     /* 245 */
1234         .long _sys_io_destroy
1235         .long _sys_io_getevents
1236         .long _sys_io_submit
1237         .long _sys_io_cancel
1238         .long _sys_ni_syscall   /* 250 */ /* sys_alloc_hugepages */
1239         .long _sys_ni_syscall   /* sys_freec_hugepages */
1240         .long _sys_exit_group
1241         .long _sys_lookup_dcookie
1242         .long _sys_bfin_spinlock
1243         .long _sys_epoll_create /* 255 */
1244         .long _sys_epoll_ctl
1245         .long _sys_epoll_wait
1246         .long _sys_ni_syscall /* remap_file_pages */
1247         .long _sys_set_tid_address
1248         .long _sys_timer_create /* 260 */
1249         .long _sys_timer_settime
1250         .long _sys_timer_gettime
1251         .long _sys_timer_getoverrun
1252         .long _sys_timer_delete
1253         .long _sys_clock_settime /* 265 */
1254         .long _sys_clock_gettime
1255         .long _sys_clock_getres
1256         .long _sys_clock_nanosleep
1257         .long _sys_statfs64
1258         .long _sys_fstatfs64    /* 270 */
1259         .long _sys_tgkill
1260         .long _sys_utimes
1261         .long _sys_fadvise64_64
1262         .long _sys_ni_syscall /* vserver */
1263         .long _sys_ni_syscall /* 275, mbind */
1264         .long _sys_ni_syscall /* get_mempolicy */
1265         .long _sys_ni_syscall /* set_mempolicy */
1266         .long _sys_mq_open
1267         .long _sys_mq_unlink
1268         .long _sys_mq_timedsend /* 280 */
1269         .long _sys_mq_timedreceive
1270         .long _sys_mq_notify
1271         .long _sys_mq_getsetattr
1272         .long _sys_ni_syscall /* kexec_load */
1273         .long _sys_waitid       /* 285 */
1274         .long _sys_add_key
1275         .long _sys_request_key
1276         .long _sys_keyctl
1277         .long _sys_ioprio_set
1278         .long _sys_ioprio_get   /* 290 */
1279         .long _sys_inotify_init
1280         .long _sys_inotify_add_watch
1281         .long _sys_inotify_rm_watch
1282         .long _sys_ni_syscall /* migrate_pages */
1283         .long _sys_openat       /* 295 */
1284         .long _sys_mkdirat
1285         .long _sys_mknodat
1286         .long _sys_fchownat
1287         .long _sys_futimesat
1288         .long _sys_fstatat64    /* 300 */
1289         .long _sys_unlinkat
1290         .long _sys_renameat
1291         .long _sys_linkat
1292         .long _sys_symlinkat
1293         .long _sys_readlinkat   /* 305 */
1294         .long _sys_fchmodat
1295         .long _sys_faccessat
1296         .long _sys_pselect6
1297         .long _sys_ppoll
1298         .long _sys_unshare      /* 310 */
1299         .long _sys_sram_alloc
1300         .long _sys_sram_free
1301         .long _sys_dma_memcpy
1302         .long _sys_accept
1303         .long _sys_bind         /* 315 */
1304         .long _sys_connect
1305         .long _sys_getpeername
1306         .long _sys_getsockname
1307         .long _sys_getsockopt
1308         .long _sys_listen       /* 320 */
1309         .long _sys_recv
1310         .long _sys_recvfrom
1311         .long _sys_recvmsg
1312         .long _sys_send
1313         .long _sys_sendmsg      /* 325 */
1314         .long _sys_sendto
1315         .long _sys_setsockopt
1316         .long _sys_shutdown
1317         .long _sys_socket
1318         .long _sys_socketpair   /* 330 */
1319         .long _sys_semctl
1320         .long _sys_semget
1321         .long _sys_semop
1322         .long _sys_msgctl
1323         .long _sys_msgget       /* 335 */
1324         .long _sys_msgrcv
1325         .long _sys_msgsnd
1326         .long _sys_shmat
1327         .long _sys_shmctl
1328         .long _sys_shmdt        /* 340 */
1329         .long _sys_shmget
1330         .long _sys_splice
1331         .long _sys_sync_file_range
1332         .long _sys_tee
1333         .long _sys_vmsplice     /* 345 */
1334         .long _sys_epoll_pwait
1335         .long _sys_utimensat
1336         .long _sys_signalfd
1337         .long _sys_timerfd
1338         .long _sys_eventfd      /* 350 */
1339         .long _sys_pread64
1340         .long _sys_pwrite64
1341         .long _sys_fadvise64
1342         .long _sys_set_robust_list
1343         .long _sys_get_robust_list      /* 355 */
1344         .long _sys_fallocate
1345         .rept NR_syscalls-(.-_sys_call_table)/4
1346         .long _sys_ni_syscall
1347         .endr
1348 _excpt_saved_imask:
1349         .long 0;
1350
1351 _exception_stack:
1352         .rept 1024
1353         .long 0;
1354         .endr
1355 _exception_stack_top:
1356
1357 #if ANOMALY_05000261
1358 /* Used by the assembly entry point to work around an anomaly.  */
1359 _last_cplb_fault_retx:
1360         .long 0;
1361 #endif
1362 /*
1363  * Single instructions can have multiple faults, which need to be
1364  * handled by traps.c, in irq5. We store the exception cause to ensure
1365  * we don't miss a double fault condition
1366  */
1367 ENTRY(_in_ptr_excause)
1368         .long 0;
1369 ENTRY(_out_ptr_excause)
1370         .long 0;
1371 ALIGN
1372 ENTRY(_excause_circ_buf)
1373         .rept 4
1374         .long 0
1375         .endr