arch/arm26/kernel/vmlinux-arm26.lds.in

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  * borrowed from Russels ARM port by Ian Molton and subsequently modified.
   5  */
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8
   9 OUTPUT_ARCH(arm)
  10 ENTRY(stext)
  11 jiffies = jiffies_64;
  12 SECTIONS
  13 {
  14         . = TEXTADDR;
  15         .init : {                       /* Init code and data           */
  16                 _stext = .;
  17                 __init_begin = .;
  18                         _sinittext = .;
  19                         *(.init.text)
  20                         _einittext = .;
  21                 __proc_info_begin = .;
  22                         *(.proc.info)
  23                 __proc_info_end = .;
  24                 __arch_info_begin = .;
  25                         *(.arch.info)
  26                 __arch_info_end = .;
  27                 __tagtable_begin = .;
  28                         *(.taglist)
  29                 __tagtable_end = .;
  30                         *(.init.data)
  31                 . = ALIGN(16);
  32                 __setup_start = .;
  33                         *(.init.setup)
  34                 __setup_end = .;
  35                 __early_begin = .;
  36                         *(__early_param)
  37                 __early_end = .;
  38                 __initcall_start = .;
  39                         *(.initcall1.init)
  40                         *(.initcall2.init)
  41                         *(.initcall3.init)
  42                         *(.initcall4.init)
  43                         *(.initcall5.init)
  44                         *(.initcall6.init)
  45                         *(.initcall7.init)
  46                 __initcall_end = .;
  47                 __con_initcall_start = .;
  48                         *(.con_initcall.init)
  49                 __con_initcall_end = .;
  50 #ifdef CONFIG_BLK_DEV_INITRD
  51                 . = ALIGN(32);
  52                 __initramfs_start = .;
  53                         usr/built-in.o(.init.ramfs)
  54                 __initramfs_end = .;
  55 #endif
  56                 . = ALIGN(32768);
  57                 __init_end = .;
  58         }
  59
  60         /DISCARD/ : {                   /* Exit code and data           */
  61                 *(.exit.text)
  62                 *(.exit.data)
  63                 *(.exitcall.exit)
  64         }
  65
  66         .text : {                       /* Real text segment            */
  67                 _text = .;              /* Text and read-only data      */
  68                         *(.text)
  69                         SCHED_TEXT
  70                         LOCK_TEXT
  71                         *(.fixup)
  72                         *(.gnu.warning)
  73                         *(.rodata)
  74                         *(.rodata.*)
  75                         *(.glue_7)
  76                         *(.glue_7t)
  77                 *(.got)                 /* Global offset table          */
  78
  79                 _etext = .;             /* End of text section          */
  80         }
  81
  82         . = ALIGN(16);
  83         __ex_table : {                  /* Exception table              */
  84                 __start___ex_table = .;
  85                         *(__ex_table)
  86                 __stop___ex_table = .;
  87         }
  88
  89         RODATA
  90
  91         . = ALIGN(8192);
  92
  93         .data : {
  94                 /*
  95                  * first, the init task union, aligned
  96                  * to an 8192 byte boundary. (see arm26/kernel/init_task.c)
  97                  */
  98                 *(.init.task)
  99
 100                 /*
 101                  * The cacheline aligned data
 102                  */
 103                 . = ALIGN(32);
 104                 *(.data.cacheline_aligned)
 105
 106                 /*
 107                  * and the usual data section
 108                  */
 109                 *(.data)
 110                 CONSTRUCTORS
 111
 112                 _edata = .;
 113         }
 114
 115         .bss : {
 116                 __bss_start = .;        /* BSS                          */
 117                 *(.bss)
 118                 *(COMMON)
 119                 _end = . ;
 120         }
 121                                         /* Stabs debugging sections.    */
 122         .stab 0 : { *(.stab) }
 123         .stabstr 0 : { *(.stabstr) }
 124         .stab.excl 0 : { *(.stab.excl) }
 125         .stab.exclstr 0 : { *(.stab.exclstr) }
 126         .stab.index 0 : { *(.stab.index) }
 127         .stab.indexstr 0 : { *(.stab.indexstr) }
 128         .comment 0 : { *(.comment) }
 129 }