arch/arm/mm/proc-v7.S

   1 /*
   2  *  linux/arch/arm/mm/proc-v7.S
   3  *
   4  *  Copyright (C) 2001 Deep Blue Solutions Ltd.
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  This is the "shell" of the ARMv7 processor support.
  11  */
  12 #include <linux/init.h>
  13 #include <linux/linkage.h>
  14 #include <asm/assembler.h>
  15 #include <asm/asm-offsets.h>
  16 #include <asm/hwcap.h>
  17 #include <asm/pgtable-hwdef.h>
  18 #include <asm/pgtable.h>
  19
  20 #include "proc-macros.S"
  21
  22 #define TTB_S           (1 << 1)
  23 #define TTB_RGN_NC      (0 << 3)
  24 #define TTB_RGN_OC_WBWA (1 << 3)
  25 #define TTB_RGN_OC_WT   (2 << 3)
  26 #define TTB_RGN_OC_WB   (3 << 3)
  27 #define TTB_NOS         (1 << 5)
  28 #define TTB_IRGN_NC     ((0 << 0) | (0 << 6))
  29 #define TTB_IRGN_WBWA   ((0 << 0) | (1 << 6))
  30 #define TTB_IRGN_WT     ((1 << 0) | (0 << 6))
  31 #define TTB_IRGN_WB     ((1 << 0) | (1 << 6))
  32
  33 /* PTWs cacheable, inner WB not shareable, outer WB not shareable */
  34 #define TTB_FLAGS_UP    TTB_IRGN_WB|TTB_RGN_OC_WB
  35 #define PMD_FLAGS_UP    PMD_SECT_WB
  36
  37 /* PTWs cacheable, inner WBWA shareable, outer WBWA not shareable */
  38 #define TTB_FLAGS_SMP   TTB_IRGN_WBWA|TTB_S|TTB_NOS|TTB_RGN_OC_WBWA
  39 #define PMD_FLAGS_SMP   PMD_SECT_WBWA|PMD_SECT_S
  40
  41 ENTRY(cpu_v7_proc_init)
  42         mov     pc, lr
  43 ENDPROC(cpu_v7_proc_init)
  44
  45 ENTRY(cpu_v7_proc_fin)
  46         mrc     p15, 0, r0, c1, c0, 0           @ ctrl register
  47         bic     r0, r0, #0x1000                 @ ...i............
  48         bic     r0, r0, #0x0006                 @ .............ca.
  49         mcr     p15, 0, r0, c1, c0, 0           @ disable caches
  50         mov     pc, lr
  51 ENDPROC(cpu_v7_proc_fin)
  52
  53 /*
  54  *      cpu_v7_reset(loc)
  55  *
  56  *      Perform a soft reset of the system.  Put the CPU into the
  57  *      same state as it would be if it had been reset, and branch
  58  *      to what would be the reset vector.
  59  *
  60  *      - loc   - location to jump to for soft reset
  61  */
  62         .align  5
  63 ENTRY(cpu_v7_reset)
  64         mov     pc, r0
  65 ENDPROC(cpu_v7_reset)
  66
  67 /*
  68  *      cpu_v7_do_idle()
  69  *
  70  *      Idle the processor (eg, wait for interrupt).
  71  *
  72  *      IRQs are already disabled.
  73  */
  74 ENTRY(cpu_v7_do_idle)
  75         dsb                                     @ WFI may enter a low-power mode
  76         wfi
  77         mov     pc, lr
  78 ENDPROC(cpu_v7_do_idle)
  79
  80 ENTRY(cpu_v7_dcache_clean_area)
  81 #ifndef TLB_CAN_READ_FROM_L1_CACHE
  82         dcache_line_size r2, r3
  83 1:      mcr     p15, 0, r0, c7, c10, 1          @ clean D entry
  84         add     r0, r0, r2
  85         subs    r1, r1, r2
  86         bhi     1b
  87         dsb
  88 #endif
  89         mov     pc, lr
  90 ENDPROC(cpu_v7_dcache_clean_area)
  91
  92 /*
  93  *      cpu_v7_switch_mm(pgd_phys, tsk)
  94  *
  95  *      Set the translation table base pointer to be pgd_phys
  96  *
  97  *      - pgd_phys - physical address of new TTB
  98  *
  99  *      It is assumed that:
 100  *      - we are not using split page tables
 101  */
 102 ENTRY(cpu_v7_switch_mm)
 103 #ifdef CONFIG_MMU
 104         mov     r2, #0
 105         ldr     r1, [r1, #MM_CONTEXT_ID]        @ get mm->context.id
 106         ALT_SMP(orr     r0, r0, #TTB_FLAGS_SMP)
 107         ALT_UP(orr      r0, r0, #TTB_FLAGS_UP)
 108 #ifdef CONFIG_ARM_ERRATA_430973
 109         mcr     p15, 0, r2, c7, c5, 6           @ flush BTAC/BTB
 110 #endif
 111         mcr     p15, 0, r2, c13, c0, 1          @ set reserved context ID
 112         isb
 113 1:      mcr     p15, 0, r0, c2, c0, 0           @ set TTB 0
 114         isb
 115         mcr     p15, 0, r1, c13, c0, 1          @ set context ID
 116         isb
 117 #endif
 118         mov     pc, lr
 119 ENDPROC(cpu_v7_switch_mm)
 120
 121 /*
 122  *      cpu_v7_set_pte_ext(ptep, pte)
 123  *
 124  *      Set a level 2 translation table entry.
 125  *
 126  *      - ptep  - pointer to level 2 translation table entry
 127  *                (hardware version is stored at -1024 bytes)
 128  *      - pte   - PTE value to store
 129  *      - ext   - value for extended PTE bits
 130  */
 131 ENTRY(cpu_v7_set_pte_ext)
 132 #ifdef CONFIG_MMU
 133  ARM(   str     r1, [r0], #-2048        )       @ linux version
 134  THUMB( str     r1, [r0]                )       @ linux version
 135  THUMB( sub     r0, r0, #2048           )
 136
 137         bic     r3, r1, #0x000003f0
 138         bic     r3, r3, #PTE_TYPE_MASK
 139         orr     r3, r3, r2
 140         orr     r3, r3, #PTE_EXT_AP0 | 2
 141
 142         tst     r1, #1 << 4
 143         orrne   r3, r3, #PTE_EXT_TEX(1)
 144
 145         tst     r1, #L_PTE_WRITE
 146         tstne   r1, #L_PTE_DIRTY
 147         orreq   r3, r3, #PTE_EXT_APX
 148
 149         tst     r1, #L_PTE_USER
 150         orrne   r3, r3, #PTE_EXT_AP1
 151         tstne   r3, #PTE_EXT_APX
 152         bicne   r3, r3, #PTE_EXT_APX | PTE_EXT_AP0
 153
 154         tst     r1, #L_PTE_EXEC
 155         orreq   r3, r3, #PTE_EXT_XN
 156
 157         tst     r1, #L_PTE_YOUNG
 158         tstne   r1, #L_PTE_PRESENT
 159         moveq   r3, #0
 160
 161         str     r3, [r0]
 162         mcr     p15, 0, r0, c7, c10, 1          @ flush_pte
 163 #endif
 164         mov     pc, lr
 165 ENDPROC(cpu_v7_set_pte_ext)
 166
 167 cpu_v7_name:
 168         .ascii  "ARMv7 Processor"
 169         .align
 170
 171         __CPUINIT
 172
 173 /*
 174  *      __v7_setup
 175  *
 176  *      Initialise TLB, Caches, and MMU state ready to switch the MMU
 177  *      on.  Return in r0 the new CP15 C1 control register setting.
 178  *
 179  *      We automatically detect if we have a Harvard cache, and use the
 180  *      Harvard cache control instructions insead of the unified cache
 181  *      control instructions.
 182  *
 183  *      This should be able to cover all ARMv7 cores.
 184  *
 185  *      It is assumed that:
 186  *      - cache type register is implemented
 187  */
 188 __v7_ca9mp_setup:
 189 #ifdef CONFIG_SMP
 190         ALT_SMP(mrc     p15, 0, r0, c1, c0, 1)
 191         ALT_UP(mov      r0, #(1 << 6))          @ fake it for UP
 192         tst     r0, #(1 << 6)                   @ SMP/nAMP mode enabled?
 193         orreq   r0, r0, #(1 << 6) | (1 << 0)    @ Enable SMP/nAMP mode and
 194         mcreq   p15, 0, r0, c1, c0, 1           @ TLB ops broadcasting
 195 #endif
 196 __v7_setup:
 197         adr     r12, __v7_setup_stack           @ the local stack
 198         stmia   r12, {r0-r5, r7, r9, r11, lr}
 199         bl      v7_flush_dcache_all
 200         ldmia   r12, {r0-r5, r7, r9, r11, lr}
 201
 202         mrc     p15, 0, r0, c0, c0, 0           @ read main ID register
 203         and     r10, r0, #0xff000000            @ ARM?
 204         teq     r10, #0x41000000
 205         bne     3f
 206         and     r5, r0, #0x00f00000             @ variant
 207         and     r6, r0, #0x0000000f             @ revision
 208         orr     r6, r6, r5, lsr #20-4           @ combine variant and revision
 209         ubfx    r0, r0, #4, #12                 @ primary part number
 210
 211         /* Cortex-A8 Errata */
 212         ldr     r10, =0x00000c08                @ Cortex-A8 primary part number
 213         teq     r0, r10
 214         bne     2f
 215 #ifdef CONFIG_ARM_ERRATA_430973
 216         teq     r5, #0x00100000                 @ only present in r1p*
 217         mrceq   p15, 0, r10, c1, c0, 1          @ read aux control register
 218         orreq   r10, r10, #(1 << 6)             @ set IBE to 1
 219         mcreq   p15, 0, r10, c1, c0, 1          @ write aux control register
 220 #endif
 221 #ifdef CONFIG_ARM_ERRATA_458693
 222         teq     r6, #0x20                       @ only present in r2p0
 223         mrceq   p15, 0, r10, c1, c0, 1          @ read aux control register
 224         orreq   r10, r10, #(1 << 5)             @ set L1NEON to 1
 225         orreq   r10, r10, #(1 << 9)             @ set PLDNOP to 1
 226         mcreq   p15, 0, r10, c1, c0, 1          @ write aux control register
 227 #endif
 228 #ifdef CONFIG_ARM_ERRATA_460075
 229         teq     r6, #0x20                       @ only present in r2p0
 230         mrceq   p15, 1, r10, c9, c0, 2          @ read L2 cache aux ctrl register
 231         tsteq   r10, #1 << 22
 232         orreq   r10, r10, #(1 << 22)            @ set the Write Allocate disable bit
 233         mcreq   p15, 1, r10, c9, c0, 2          @ write the L2 cache aux ctrl register
 234 #endif
 235         b       3f
 236
 237         /* Cortex-A9 Errata */
 238 2:      ldr     r10, =0x00000c09                @ Cortex-A9 primary part number
 239         teq     r0, r10
 240         bne     3f
 241 #ifdef CONFIG_ARM_ERRATA_742230
 242         cmp     r6, #0x22                       @ only present up to r2p2
 243         mrcle   p15, 0, r10, c15, c0, 1         @ read diagnostic register
 244         orrle   r10, r10, #1 << 4               @ set bit #4
 245         mcrle   p15, 0, r10, c15, c0, 1         @ write diagnostic register
 246 #endif
 247 #ifdef CONFIG_ARM_ERRATA_742231
 248         teq     r6, #0x20                       @ present in r2p0
 249         teqne   r6, #0x21                       @ present in r2p1
 250         teqne   r6, #0x22                       @ present in r2p2
 251         mrceq   p15, 0, r10, c15, c0, 1         @ read diagnostic register
 252         orreq   r10, r10, #1 << 12              @ set bit #12
 253         orreq   r10, r10, #1 << 22              @ set bit #22
 254         mcreq   p15, 0, r10, c15, c0, 1         @ write diagnostic register
 255 #endif
 256 #ifdef CONFIG_ARM_ERRATA_743622
 257         teq     r6, #0x20                       @ present in r2p0
 258         teqne   r6, #0x21                       @ present in r2p1
 259         teqne   r6, #0x22                       @ present in r2p2
 260         mrceq   p15, 0, r10, c15, c0, 1         @ read diagnostic register
 261         orreq   r10, r10, #1 << 6               @ set bit #6
 262         mcreq   p15, 0, r10, c15, c0, 1         @ write diagnostic register
 263 #endif
 264
 265 3:      mov     r10, #0
 266 #ifdef HARVARD_CACHE
 267         mcr     p15, 0, r10, c7, c5, 0          @ I+BTB cache invalidate
 268 #endif
 269         dsb
 270 #ifdef CONFIG_MMU
 271         mcr     p15, 0, r10, c8, c7, 0          @ invalidate I + D TLBs
 272         mcr     p15, 0, r10, c2, c0, 2          @ TTB control register
 273         ALT_SMP(orr     r4, r4, #TTB_FLAGS_SMP)
 274         ALT_UP(orr      r4, r4, #TTB_FLAGS_UP)
 275         mcr     p15, 0, r4, c2, c0, 1           @ load TTB1
 276         mov     r10, #0x1f                      @ domains 0, 1 = manager
 277         mcr     p15, 0, r10, c3, c0, 0          @ load domain access register
 278         /*
 279          * Memory region attributes with SCTLR.TRE=1
 280          *
 281          *   n = TEX[0],C,B
 282          *   TR = PRRR[2n+1:2n]         - memory type
 283          *   IR = NMRR[2n+1:2n]         - inner cacheable property
 284          *   OR = NMRR[2n+17:2n+16]     - outer cacheable property
 285          *
 286          *                      n       TR      IR      OR
 287          *   UNCACHED           000     00
 288          *   BUFFERABLE         001     10      00      00
 289          *   WRITETHROUGH       010     10      10      10
 290          *   WRITEBACK          011     10      11      11
 291          *   reserved           110
 292          *   WRITEALLOC         111     10      01      01
 293          *   DEV_SHARED         100     01
 294          *   DEV_NONSHARED      100     01
 295          *   DEV_WC             001     10
 296          *   DEV_CACHED         011     10
 297          *
 298          * Other attributes:
 299          *
 300          *   DS0 = PRRR[16] = 0         - device shareable property
 301          *   DS1 = PRRR[17] = 1         - device shareable property
 302          *   NS0 = PRRR[18] = 0         - normal shareable property
 303          *   NS1 = PRRR[19] = 1         - normal shareable property
 304          *   NOS = PRRR[24+n] = 1       - not outer shareable
 305          */
 306         ldr     r5, =0xff0a81a8                 @ PRRR
 307         ldr     r6, =0x40e040e0                 @ NMRR
 308         mcr     p15, 0, r5, c10, c2, 0          @ write PRRR
 309         mcr     p15, 0, r6, c10, c2, 1          @ write NMRR
 310 #endif
 311         adr     r5, v7_crval
 312         ldmia   r5, {r5, r6}
 313 #ifdef CONFIG_CPU_ENDIAN_BE8
 314         orr     r6, r6, #1 << 25                @ big-endian page tables
 315 #endif
 316         mrc     p15, 0, r0, c1, c0, 0           @ read control register
 317         bic     r0, r0, r5                      @ clear bits them
 318         orr     r0, r0, r6                      @ set them
 319  THUMB( orr     r0, r0, #1 << 30        )       @ Thumb exceptions
 320         mov     pc, lr                          @ return to head.S:__ret
 321 ENDPROC(__v7_setup)
 322
 323         /*   AT
 324          *  TFR   EV X F   I D LR    S
 325          * .EEE ..EE PUI. .T.T 4RVI ZWRS BLDP WCAM
 326          * rxxx rrxx xxx0 0101 xxxx xxxx x111 xxxx < forced
 327          *    1    0 110       0011 1100 .111 1101 < we want
 328          */
 329         .type   v7_crval, #object
 330 v7_crval:
 331         crval   clear=0x0120c302, mmuset=0x10c03c7d, ucset=0x00c01c7c
 332
 333 __v7_setup_stack:
 334         .space  4 * 11                          @ 11 registers
 335
 336         __INITDATA
 337
 338         .type   v7_processor_functions, #object
 339 ENTRY(v7_processor_functions)
 340         .word   v7_early_abort
 341         .word   v7_pabort
 342         .word   cpu_v7_proc_init
 343         .word   cpu_v7_proc_fin
 344         .word   cpu_v7_reset
 345         .word   cpu_v7_do_idle
 346         .word   cpu_v7_dcache_clean_area
 347         .word   cpu_v7_switch_mm
 348         .word   cpu_v7_set_pte_ext
 349         .size   v7_processor_functions, . - v7_processor_functions
 350
 351         .section ".rodata"
 352
 353         .type   cpu_arch_name, #object
 354 cpu_arch_name:
 355         .asciz  "armv7"
 356         .size   cpu_arch_name, . - cpu_arch_name
 357
 358         .type   cpu_elf_name, #object
 359 cpu_elf_name:
 360         .asciz  "v7"
 361         .size   cpu_elf_name, . - cpu_elf_name
 362         .align
 363
 364         .section ".proc.info.init", #alloc, #execinstr
 365
 366         .type   __v7_ca9mp_proc_info, #object
 367 __v7_ca9mp_proc_info:
 368         .long   0x410fc090              @ Required ID value
 369         .long   0xff0ffff0              @ Mask for ID
 370         ALT_SMP(.long \
 371                 PMD_TYPE_SECT | \
 372                 PMD_SECT_AP_WRITE | \
 373                 PMD_SECT_AP_READ | \
 374                 PMD_FLAGS_SMP)
 375         ALT_UP(.long \
 376                 PMD_TYPE_SECT | \
 377                 PMD_SECT_AP_WRITE | \
 378                 PMD_SECT_AP_READ | \
 379                 PMD_FLAGS_UP)
 380         .long   PMD_TYPE_SECT | \
 381                 PMD_SECT_XN | \
 382                 PMD_SECT_AP_WRITE | \
 383                 PMD_SECT_AP_READ
 384         b       __v7_ca9mp_setup
 385         .long   cpu_arch_name
 386         .long   cpu_elf_name
 387         .long   HWCAP_SWP|HWCAP_HALF|HWCAP_THUMB|HWCAP_FAST_MULT|HWCAP_EDSP|HWCAP_TLS
 388         .long   cpu_v7_name
 389         .long   v7_processor_functions
 390         .long   v7wbi_tlb_fns
 391         .long   v6_user_fns
 392         .long   v7_cache_fns
 393         .size   __v7_ca9mp_proc_info, . - __v7_ca9mp_proc_info
 394
 395         /*
 396          * Match any ARMv7 processor core.
 397          */
 398         .type   __v7_proc_info, #object
 399 __v7_proc_info:
 400         .long   0x000f0000              @ Required ID value
 401         .long   0x000f0000              @ Mask for ID
 402         ALT_SMP(.long \
 403                 PMD_TYPE_SECT | \
 404                 PMD_SECT_AP_WRITE | \
 405                 PMD_SECT_AP_READ | \
 406                 PMD_FLAGS_SMP)
 407         ALT_UP(.long \
 408                 PMD_TYPE_SECT | \
 409                 PMD_SECT_AP_WRITE | \
 410                 PMD_SECT_AP_READ | \
 411                 PMD_FLAGS_UP)
 412         .long   PMD_TYPE_SECT | \
 413                 PMD_SECT_XN | \
 414                 PMD_SECT_AP_WRITE | \
 415                 PMD_SECT_AP_READ
 416         b       __v7_setup
 417         .long   cpu_arch_name
 418         .long   cpu_elf_name
 419         .long   HWCAP_SWP|HWCAP_HALF|HWCAP_THUMB|HWCAP_FAST_MULT|HWCAP_EDSP|HWCAP_TLS
 420         .long   cpu_v7_name
 421         .long   v7_processor_functions
 422         .long   v7wbi_tlb_fns
 423         .long   v6_user_fns
 424         .long   v7_cache_fns
 425         .size   __v7_proc_info, . - __v7_proc_info