2 * linux/arch/arm/boot/compressed/head.S
4 * Copyright (C) 1996-2002 Russell King
5 * Copyright (C) 2004 Hyok S. Choi (MPU support)
7 * This program is free software; you can redistribute it and/or modify
8 * it under the terms of the GNU General Public License version 2 as
9 * published by the Free Software Foundation.
11 #include <linux/linkage.h>
17 * Note that these macros must not contain any code which is not
18 * 100% relocatable. Any attempt to do so will result in a crash.
19 * Please select one of the following when turning on debugging.
23 #if defined(CONFIG_DEBUG_ICEDCC)
25 #if defined(CONFIG_CPU_V6) || defined(CONFIG_CPU_V6K) || defined(CONFIG_CPU_V7)
26 .macro loadsp, rb, tmp
29 mcr p14, 0, \ch, c0, c5, 0
31 #elif defined(CONFIG_CPU_XSCALE)
32 .macro loadsp, rb, tmp
35 mcr p14, 0, \ch, c8, c0, 0
38 .macro loadsp, rb, tmp
41 mcr p14, 0, \ch, c1, c0, 0
47 #include <mach/debug-macro.S>
53 #if defined(CONFIG_ARCH_SA1100)
54 .macro loadsp, rb, tmp
55 mov \rb, #0x80000000 @ physical base address
56 #ifdef CONFIG_DEBUG_LL_SER3
57 add \rb, \rb, #0x00050000 @ Ser3
59 add \rb, \rb, #0x00010000 @ Ser1
62 #elif defined(CONFIG_ARCH_S3C2410)
63 .macro loadsp, rb, tmp
65 add \rb, \rb, #0x4000 * CONFIG_S3C_LOWLEVEL_UART_PORT
68 .macro loadsp, rb, tmp
86 .macro debug_reloc_start
89 kphex r6, 8 /* processor id */
91 kphex r7, 8 /* architecture id */
92 #ifdef CONFIG_CPU_CP15
94 mrc p15, 0, r0, c1, c0
95 kphex r0, 8 /* control reg */
98 kphex r5, 8 /* decompressed kernel start */
100 kphex r9, 8 /* decompressed kernel end */
102 kphex r4, 8 /* kernel execution address */
107 .macro debug_reloc_end
109 kphex r5, 8 /* end of kernel */
112 bl memdump /* dump 256 bytes at start of kernel */
116 .section ".start", #alloc, #execinstr
118 * sort out different calling conventions
121 .arm @ Always enter in ARM state
123 .type start,#function
129 THUMB( adr r12, BSYM(1f) )
132 .word 0x016f2818 @ Magic numbers to help the loader
133 .word start @ absolute load/run zImage address
134 .word _edata @ zImage end address
136 1: mov r7, r1 @ save architecture ID
137 mov r8, r2 @ save atags pointer
139 #ifndef __ARM_ARCH_2__
141 * Booting from Angel - need to enter SVC mode and disable
142 * FIQs/IRQs (numeric definitions from angel arm.h source).
143 * We only do this if we were in user mode on entry.
145 mrs r2, cpsr @ get current mode
146 tst r2, #3 @ not user?
148 mov r0, #0x17 @ angel_SWIreason_EnterSVC
149 ARM( swi 0x123456 ) @ angel_SWI_ARM
150 THUMB( svc 0xab ) @ angel_SWI_THUMB
152 mrs r2, cpsr @ turn off interrupts to
153 orr r2, r2, #0xc0 @ prevent angel from running
156 teqp pc, #0x0c000003 @ turn off interrupts
160 * Note that some cache flushing and other stuff may
161 * be needed here - is there an Angel SWI call for this?
165 * some architecture specific code can be inserted
166 * by the linker here, but it should preserve r7, r8, and r9.
171 #ifdef CONFIG_AUTO_ZRELADDR
172 @ determine final kernel image address
174 and r4, r4, #0xf8000000
175 add r4, r4, #TEXT_OFFSET
183 ldmia r0, {r1, r2, r3, r6, r10, r11, r12}
187 * We might be running at a different address. We need
188 * to fix up various pointers.
190 sub r0, r0, r1 @ calculate the delta offset
191 add r6, r6, r0 @ _edata
192 add r10, r10, r0 @ inflated kernel size location
195 * The kernel build system appends the size of the
196 * decompressed kernel at the end of the compressed data
197 * in little-endian form.
201 orr r9, r9, lr, lsl #8
204 orr r9, r9, lr, lsl #16
205 orr r9, r9, r10, lsl #24
207 #ifndef CONFIG_ZBOOT_ROM
208 /* malloc space is above the relocated stack (64k max) */
210 add r10, sp, #0x10000
213 * With ZBOOT_ROM the bss/stack is non relocatable,
214 * but someone could still run this code from RAM,
215 * in which case our reference is _edata.
220 mov r5, #0 @ init dtb size to 0
221 #ifdef CONFIG_ARM_APPENDED_DTB
226 * r4 = final kernel address
227 * r5 = appended dtb size (still unknown)
229 * r7 = architecture ID
230 * r8 = atags/device tree pointer
231 * r9 = size of decompressed image
232 * r10 = end of this image, including bss/stack/malloc space if non XIP
237 * if there are device trees (dtb) appended to zImage, advance r10 so that the
238 * dtb data will get relocated along with the kernel if necessary.
243 ldr r1, =0xedfe0dd0 @ sig is 0xd00dfeed big endian
248 bne dtb_check_done @ not found
250 #ifdef CONFIG_ARM_ATAG_DTB_COMPAT
252 * OK... Let's do some funky business here.
253 * If we do have a DTB appended to zImage, and we do have
254 * an ATAG list around, we want the later to be translated
255 * and folded into the former here. To be on the safe side,
256 * let's temporarily move the stack away into the malloc
257 * area. No GOT fixup has occurred yet, but none of the
258 * code we're about to call uses any global variable.
261 stmfd sp!, {r0-r3, ip, lr}
268 * If returned value is 1, there is no ATAG at the location
269 * pointed by r8. Try the typical 0x100 offset from start
270 * of RAM and hope for the best.
273 sub r0, r4, #TEXT_OFFSET
279 ldmfd sp!, {r0-r3, ip, lr}
283 mov r8, r6 @ use the appended device tree
286 * Make sure that the DTB doesn't end up in the final
287 * kernel's .bss area. To do so, we adjust the decompressed
288 * kernel size to compensate if that .bss size is larger
289 * than the relocated code.
291 ldr r5, =_kernel_bss_size
292 adr r1, wont_overwrite
297 /* Get the dtb's size */
300 /* convert r5 (dtb size) to little endian */
301 eor r1, r5, r5, ror #16
302 bic r1, r1, #0x00ff0000
304 eor r5, r5, r1, lsr #8
307 /* preserve 64-bit alignment */
311 /* relocate some pointers past the appended dtb */
319 * Check to see if we will overwrite ourselves.
320 * r4 = final kernel address
321 * r9 = size of decompressed image
322 * r10 = end of this image, including bss/stack/malloc space if non XIP
324 * r4 - 16k page directory >= r10 -> OK
325 * r4 + image length <= address of wont_overwrite -> OK
331 adr r9, wont_overwrite
336 * Relocate ourselves past the end of the decompressed kernel.
338 * r10 = end of the decompressed kernel
339 * Because we always copy ahead, we need to do it from the end and go
340 * backward in case the source and destination overlap.
343 * Bump to the next 256-byte boundary with the size of
344 * the relocation code added. This avoids overwriting
345 * ourself when the offset is small.
347 add r10, r10, #((reloc_code_end - restart + 256) & ~255)
350 /* Get start of code we want to copy and align it down. */
354 sub r9, r6, r5 @ size to copy
355 add r9, r9, #31 @ rounded up to a multiple
356 bic r9, r9, #31 @ ... of 32 bytes
360 1: ldmdb r6!, {r0 - r3, r10 - r12, lr}
362 stmdb r9!, {r0 - r3, r10 - r12, lr}
365 /* Preserve offset to relocated code. */
368 #ifndef CONFIG_ZBOOT_ROM
369 /* cache_clean_flush may use the stack, so relocate it */
375 adr r0, BSYM(restart)
381 * If delta is zero, we are running at the address we were linked at.
385 * r4 = kernel execution address
386 * r5 = appended dtb size (0 if not present)
387 * r7 = architecture ID
399 #ifndef CONFIG_ZBOOT_ROM
401 * If we're running fully PIC === CONFIG_ZBOOT_ROM = n,
402 * we need to fix up pointers into the BSS region.
403 * Note that the stack pointer has already been fixed up.
409 * Relocate all entries in the GOT table.
410 * Bump bss entries to _edata + dtb size
412 1: ldr r1, [r11, #0] @ relocate entries in the GOT
413 add r1, r1, r0 @ This fixes up C references
414 cmp r1, r2 @ if entry >= bss_start &&
415 cmphs r3, r1 @ bss_end > entry
416 addhi r1, r1, r5 @ entry += dtb size
417 str r1, [r11], #4 @ next entry
421 /* bump our bss pointers too */
428 * Relocate entries in the GOT table. We only relocate
429 * the entries that are outside the (relocated) BSS region.
431 1: ldr r1, [r11, #0] @ relocate entries in the GOT
432 cmp r1, r2 @ entry < bss_start ||
433 cmphs r3, r1 @ _end < entry
434 addlo r1, r1, r0 @ table. This fixes up the
435 str r1, [r11], #4 @ C references.
440 not_relocated: mov r0, #0
441 1: str r0, [r2], #4 @ clear bss
449 * The C runtime environment should now be setup sufficiently.
450 * Set up some pointers, and start decompressing.
451 * r4 = kernel execution address
452 * r7 = architecture ID
456 mov r1, sp @ malloc space above stack
457 add r2, sp, #0x10000 @ 64k max
462 mov r0, #0 @ must be zero
463 mov r1, r7 @ restore architecture number
464 mov r2, r8 @ restore atags pointer
465 ARM( mov pc, r4 ) @ call kernel
466 THUMB( bx r4 ) @ entry point is always ARM
471 .word __bss_start @ r2
474 .word input_data_end - 4 @ r10 (inflated size location)
475 .word _got_start @ r11
477 .word .L_user_stack_end @ sp
480 #ifdef CONFIG_ARCH_RPC
482 params: ldr r0, =0x10000100 @ params_phys for RPC
489 * Turn on the cache. We need to setup some page tables so that we
490 * can have both the I and D caches on.
492 * We place the page tables 16k down from the kernel execution address,
493 * and we hope that nothing else is using it. If we're using it, we
497 * r4 = kernel execution address
498 * r7 = architecture number
501 * r0, r1, r2, r3, r9, r10, r12 corrupted
502 * This routine must preserve:
506 cache_on: mov r3, #8 @ cache_on function
510 * Initialize the highest priority protection region, PR7
511 * to cover all 32bit address and cacheable and bufferable.
513 __armv4_mpu_cache_on:
514 mov r0, #0x3f @ 4G, the whole
515 mcr p15, 0, r0, c6, c7, 0 @ PR7 Area Setting
516 mcr p15, 0, r0, c6, c7, 1
519 mcr p15, 0, r0, c2, c0, 0 @ D-cache on
520 mcr p15, 0, r0, c2, c0, 1 @ I-cache on
521 mcr p15, 0, r0, c3, c0, 0 @ write-buffer on
524 mcr p15, 0, r0, c5, c0, 1 @ I-access permission
525 mcr p15, 0, r0, c5, c0, 0 @ D-access permission
528 mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
529 mcr p15, 0, r0, c7, c5, 0 @ flush(inval) I-Cache
530 mcr p15, 0, r0, c7, c6, 0 @ flush(inval) D-Cache
531 mrc p15, 0, r0, c1, c0, 0 @ read control reg
532 @ ...I .... ..D. WC.M
533 orr r0, r0, #0x002d @ .... .... ..1. 11.1
534 orr r0, r0, #0x1000 @ ...1 .... .... ....
536 mcr p15, 0, r0, c1, c0, 0 @ write control reg
539 mcr p15, 0, r0, c7, c5, 0 @ flush(inval) I-Cache
540 mcr p15, 0, r0, c7, c6, 0 @ flush(inval) D-Cache
543 __armv3_mpu_cache_on:
544 mov r0, #0x3f @ 4G, the whole
545 mcr p15, 0, r0, c6, c7, 0 @ PR7 Area Setting
548 mcr p15, 0, r0, c2, c0, 0 @ cache on
549 mcr p15, 0, r0, c3, c0, 0 @ write-buffer on
552 mcr p15, 0, r0, c5, c0, 0 @ access permission
555 mcr p15, 0, r0, c7, c0, 0 @ invalidate whole cache v3
557 * ?? ARMv3 MMU does not allow reading the control register,
558 * does this really work on ARMv3 MPU?
560 mrc p15, 0, r0, c1, c0, 0 @ read control reg
561 @ .... .... .... WC.M
562 orr r0, r0, #0x000d @ .... .... .... 11.1
563 /* ?? this overwrites the value constructed above? */
565 mcr p15, 0, r0, c1, c0, 0 @ write control reg
567 /* ?? invalidate for the second time? */
568 mcr p15, 0, r0, c7, c0, 0 @ invalidate whole cache v3
571 __setup_mmu: sub r3, r4, #16384 @ Page directory size
572 bic r3, r3, #0xff @ Align the pointer
575 * Initialise the page tables, turning on the cacheable and bufferable
576 * bits for the RAM area only.
580 mov r9, r9, lsl #18 @ start of RAM
581 add r10, r9, #0x10000000 @ a reasonable RAM size
585 1: cmp r1, r9 @ if virt > start of RAM
586 #ifdef CONFIG_CPU_DCACHE_WRITETHROUGH
587 orrhs r1, r1, #0x08 @ set cacheable
589 orrhs r1, r1, #0x0c @ set cacheable, bufferable
591 cmp r1, r10 @ if virt > end of RAM
592 bichs r1, r1, #0x0c @ clear cacheable, bufferable
593 str r1, [r0], #4 @ 1:1 mapping
598 * If ever we are running from Flash, then we surely want the cache
599 * to be enabled also for our execution instance... We map 2MB of it
600 * so there is no map overlap problem for up to 1 MB compressed kernel.
601 * If the execution is in RAM then we would only be duplicating the above.
607 orr r1, r1, r2, lsl #20
608 add r0, r3, r2, lsl #2
615 __arm926ejs_mmu_cache_on:
616 #ifdef CONFIG_CPU_DCACHE_WRITETHROUGH
617 mov r0, #4 @ put dcache in WT mode
618 mcr p15, 7, r0, c15, c0, 0
621 __armv4_mmu_cache_on:
626 mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
627 mcr p15, 0, r0, c8, c7, 0 @ flush I,D TLBs
628 mrc p15, 0, r0, c1, c0, 0 @ read control reg
629 orr r0, r0, #0x5000 @ I-cache enable, RR cache replacement
631 #ifdef CONFIG_CPU_ENDIAN_BE8
632 orr r0, r0, #1 << 25 @ big-endian page tables
634 bl __common_mmu_cache_on
636 mcr p15, 0, r0, c8, c7, 0 @ flush I,D TLBs
640 __armv7_mmu_cache_on:
643 mrc p15, 0, r11, c0, c1, 4 @ read ID_MMFR0
647 mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
649 mcrne p15, 0, r0, c8, c7, 0 @ flush I,D TLBs
651 mrc p15, 0, r0, c1, c0, 0 @ read control reg
652 bic r0, r0, #1 << 28 @ clear SCTLR.TRE
653 orr r0, r0, #0x5000 @ I-cache enable, RR cache replacement
654 orr r0, r0, #0x003c @ write buffer
656 #ifdef CONFIG_CPU_ENDIAN_BE8
657 orr r0, r0, #1 << 25 @ big-endian page tables
659 orrne r0, r0, #1 @ MMU enabled
661 mcrne p15, 0, r3, c2, c0, 0 @ load page table pointer
662 mcrne p15, 0, r1, c3, c0, 0 @ load domain access control
664 mcr p15, 0, r0, c1, c0, 0 @ load control register
665 mrc p15, 0, r0, c1, c0, 0 @ and read it back
667 mcr p15, 0, r0, c7, c5, 4 @ ISB
674 mcr p15, 0, r0, c7, c7, 0 @ Invalidate whole cache
675 mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
676 mcr p15, 0, r0, c8, c7, 0 @ flush UTLB
677 mrc p15, 0, r0, c1, c0, 0 @ read control reg
678 orr r0, r0, #0x1000 @ I-cache enable
679 bl __common_mmu_cache_on
681 mcr p15, 0, r0, c8, c7, 0 @ flush UTLB
688 mcr p15, 0, r0, c7, c0, 0 @ invalidate whole cache v3
689 mcr p15, 0, r0, c5, c0, 0 @ invalidate whole TLB v3
691 bl __common_mmu_cache_on
693 mcr p15, 0, r0, c5, c0, 0 @ invalidate whole TLB v3
696 __common_mmu_cache_on:
697 #ifndef CONFIG_THUMB2_KERNEL
699 orr r0, r0, #0x000d @ Write buffer, mmu
702 mcr p15, 0, r3, c2, c0, 0 @ load page table pointer
703 mcr p15, 0, r1, c3, c0, 0 @ load domain access control
705 .align 5 @ cache line aligned
706 1: mcr p15, 0, r0, c1, c0, 0 @ load control register
707 mrc p15, 0, r0, c1, c0, 0 @ and read it back to
708 sub pc, lr, r0, lsr #32 @ properly flush pipeline
711 #define PROC_ENTRY_SIZE (4*5)
714 * Here follow the relocatable cache support functions for the
715 * various processors. This is a generic hook for locating an
716 * entry and jumping to an instruction at the specified offset
717 * from the start of the block. Please note this is all position
727 call_cache_fn: adr r12, proc_types
728 #ifdef CONFIG_CPU_CP15
729 mrc p15, 0, r9, c0, c0 @ get processor ID
731 ldr r9, =CONFIG_PROCESSOR_ID
733 1: ldr r1, [r12, #0] @ get value
734 ldr r2, [r12, #4] @ get mask
735 eor r1, r1, r9 @ (real ^ match)
737 ARM( addeq pc, r12, r3 ) @ call cache function
738 THUMB( addeq r12, r3 )
739 THUMB( moveq pc, r12 ) @ call cache function
740 add r12, r12, #PROC_ENTRY_SIZE
744 * Table for cache operations. This is basically:
747 * - 'cache on' method instruction
748 * - 'cache off' method instruction
749 * - 'cache flush' method instruction
751 * We match an entry using: ((real_id ^ match) & mask) == 0
753 * Writethrough caches generally only need 'on' and 'off'
754 * methods. Writeback caches _must_ have the flush method
758 .type proc_types,#object
760 .word 0x41560600 @ ARM6/610
762 W(b) __arm6_mmu_cache_off @ works, but slow
763 W(b) __arm6_mmu_cache_off
766 @ b __arm6_mmu_cache_on @ untested
767 @ b __arm6_mmu_cache_off
768 @ b __armv3_mmu_cache_flush
770 .word 0x00000000 @ old ARM ID
779 .word 0x41007000 @ ARM7/710
781 W(b) __arm7_mmu_cache_off
782 W(b) __arm7_mmu_cache_off
786 .word 0x41807200 @ ARM720T (writethrough)
788 W(b) __armv4_mmu_cache_on
789 W(b) __armv4_mmu_cache_off
793 .word 0x41007400 @ ARM74x
795 W(b) __armv3_mpu_cache_on
796 W(b) __armv3_mpu_cache_off
797 W(b) __armv3_mpu_cache_flush
799 .word 0x41009400 @ ARM94x
801 W(b) __armv4_mpu_cache_on
802 W(b) __armv4_mpu_cache_off
803 W(b) __armv4_mpu_cache_flush
805 .word 0x41069260 @ ARM926EJ-S (v5TEJ)
807 W(b) __arm926ejs_mmu_cache_on
808 W(b) __armv4_mmu_cache_off
809 W(b) __armv5tej_mmu_cache_flush
811 .word 0x00007000 @ ARM7 IDs
820 @ Everything from here on will be the new ID system.
822 .word 0x4401a100 @ sa110 / sa1100
824 W(b) __armv4_mmu_cache_on
825 W(b) __armv4_mmu_cache_off
826 W(b) __armv4_mmu_cache_flush
828 .word 0x6901b110 @ sa1110
830 W(b) __armv4_mmu_cache_on
831 W(b) __armv4_mmu_cache_off
832 W(b) __armv4_mmu_cache_flush
835 .word 0xffffff00 @ PXA9xx
836 W(b) __armv4_mmu_cache_on
837 W(b) __armv4_mmu_cache_off
838 W(b) __armv4_mmu_cache_flush
840 .word 0x56158000 @ PXA168
842 W(b) __armv4_mmu_cache_on
843 W(b) __armv4_mmu_cache_off
844 W(b) __armv5tej_mmu_cache_flush
846 .word 0x56050000 @ Feroceon
848 W(b) __armv4_mmu_cache_on
849 W(b) __armv4_mmu_cache_off
850 W(b) __armv5tej_mmu_cache_flush
852 #ifdef CONFIG_CPU_FEROCEON_OLD_ID
853 /* this conflicts with the standard ARMv5TE entry */
854 .long 0x41009260 @ Old Feroceon
856 b __armv4_mmu_cache_on
857 b __armv4_mmu_cache_off
858 b __armv5tej_mmu_cache_flush
861 .word 0x66015261 @ FA526
863 W(b) __fa526_cache_on
864 W(b) __armv4_mmu_cache_off
865 W(b) __fa526_cache_flush
867 @ These match on the architecture ID
869 .word 0x00020000 @ ARMv4T
871 W(b) __armv4_mmu_cache_on
872 W(b) __armv4_mmu_cache_off
873 W(b) __armv4_mmu_cache_flush
875 .word 0x00050000 @ ARMv5TE
877 W(b) __armv4_mmu_cache_on
878 W(b) __armv4_mmu_cache_off
879 W(b) __armv4_mmu_cache_flush
881 .word 0x00060000 @ ARMv5TEJ
883 W(b) __armv4_mmu_cache_on
884 W(b) __armv4_mmu_cache_off
885 W(b) __armv5tej_mmu_cache_flush
887 .word 0x0007b000 @ ARMv6
889 W(b) __armv4_mmu_cache_on
890 W(b) __armv4_mmu_cache_off
891 W(b) __armv6_mmu_cache_flush
893 .word 0x000f0000 @ new CPU Id
895 W(b) __armv7_mmu_cache_on
896 W(b) __armv7_mmu_cache_off
897 W(b) __armv7_mmu_cache_flush
899 .word 0 @ unrecognised type
908 .size proc_types, . - proc_types
911 * If you get a "non-constant expression in ".if" statement"
912 * error from the assembler on this line, check that you have
913 * not accidentally written a "b" instruction where you should
916 .if (. - proc_types) % PROC_ENTRY_SIZE != 0
917 .error "The size of one or more proc_types entries is wrong."
921 * Turn off the Cache and MMU. ARMv3 does not support
922 * reading the control register, but ARMv4 does.
925 * r0, r1, r2, r3, r9, r12 corrupted
926 * This routine must preserve:
930 cache_off: mov r3, #12 @ cache_off function
933 __armv4_mpu_cache_off:
934 mrc p15, 0, r0, c1, c0
936 mcr p15, 0, r0, c1, c0 @ turn MPU and cache off
938 mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
939 mcr p15, 0, r0, c7, c6, 0 @ flush D-Cache
940 mcr p15, 0, r0, c7, c5, 0 @ flush I-Cache
943 __armv3_mpu_cache_off:
944 mrc p15, 0, r0, c1, c0
946 mcr p15, 0, r0, c1, c0, 0 @ turn MPU and cache off
948 mcr p15, 0, r0, c7, c0, 0 @ invalidate whole cache v3
951 __armv4_mmu_cache_off:
953 mrc p15, 0, r0, c1, c0
955 mcr p15, 0, r0, c1, c0 @ turn MMU and cache off
957 mcr p15, 0, r0, c7, c7 @ invalidate whole cache v4
958 mcr p15, 0, r0, c8, c7 @ invalidate whole TLB v4
962 __armv7_mmu_cache_off:
963 mrc p15, 0, r0, c1, c0
969 mcr p15, 0, r0, c1, c0 @ turn MMU and cache off
971 bl __armv7_mmu_cache_flush
974 mcr p15, 0, r0, c8, c7, 0 @ invalidate whole TLB
976 mcr p15, 0, r0, c7, c5, 6 @ invalidate BTC
977 mcr p15, 0, r0, c7, c10, 4 @ DSB
978 mcr p15, 0, r0, c7, c5, 4 @ ISB
981 __arm6_mmu_cache_off:
982 mov r0, #0x00000030 @ ARM6 control reg.
983 b __armv3_mmu_cache_off
985 __arm7_mmu_cache_off:
986 mov r0, #0x00000070 @ ARM7 control reg.
987 b __armv3_mmu_cache_off
989 __armv3_mmu_cache_off:
990 mcr p15, 0, r0, c1, c0, 0 @ turn MMU and cache off
992 mcr p15, 0, r0, c7, c0, 0 @ invalidate whole cache v3
993 mcr p15, 0, r0, c5, c0, 0 @ invalidate whole TLB v3
997 * Clean and flush the cache to maintain consistency.
1000 * r1, r2, r3, r9, r10, r11, r12 corrupted
1001 * This routine must preserve:
1009 __armv4_mpu_cache_flush:
1012 mcr p15, 0, ip, c7, c6, 0 @ invalidate D cache
1013 mov r1, #7 << 5 @ 8 segments
1014 1: orr r3, r1, #63 << 26 @ 64 entries
1015 2: mcr p15, 0, r3, c7, c14, 2 @ clean & invalidate D index
1016 subs r3, r3, #1 << 26
1017 bcs 2b @ entries 63 to 0
1018 subs r1, r1, #1 << 5
1019 bcs 1b @ segments 7 to 0
1022 mcrne p15, 0, ip, c7, c5, 0 @ invalidate I cache
1023 mcr p15, 0, ip, c7, c10, 4 @ drain WB
1026 __fa526_cache_flush:
1028 mcr p15, 0, r1, c7, c14, 0 @ clean and invalidate D cache
1029 mcr p15, 0, r1, c7, c5, 0 @ flush I cache
1030 mcr p15, 0, r1, c7, c10, 4 @ drain WB
1033 __armv6_mmu_cache_flush:
1035 mcr p15, 0, r1, c7, c14, 0 @ clean+invalidate D
1036 mcr p15, 0, r1, c7, c5, 0 @ invalidate I+BTB
1037 mcr p15, 0, r1, c7, c15, 0 @ clean+invalidate unified
1038 mcr p15, 0, r1, c7, c10, 4 @ drain WB
1041 __armv7_mmu_cache_flush:
1042 mrc p15, 0, r10, c0, c1, 5 @ read ID_MMFR1
1043 tst r10, #0xf << 16 @ hierarchical cache (ARMv7)
1046 mcr p15, 0, r10, c7, c14, 0 @ clean+invalidate D
1049 mcr p15, 0, r10, c7, c10, 5 @ DMB
1050 stmfd sp!, {r0-r7, r9-r11}
1051 mrc p15, 1, r0, c0, c0, 1 @ read clidr
1052 ands r3, r0, #0x7000000 @ extract loc from clidr
1053 mov r3, r3, lsr #23 @ left align loc bit field
1054 beq finished @ if loc is 0, then no need to clean
1055 mov r10, #0 @ start clean at cache level 0
1057 add r2, r10, r10, lsr #1 @ work out 3x current cache level
1058 mov r1, r0, lsr r2 @ extract cache type bits from clidr
1059 and r1, r1, #7 @ mask of the bits for current cache only
1060 cmp r1, #2 @ see what cache we have at this level
1061 blt skip @ skip if no cache, or just i-cache
1062 mcr p15, 2, r10, c0, c0, 0 @ select current cache level in cssr
1063 mcr p15, 0, r10, c7, c5, 4 @ isb to sych the new cssr&csidr
1064 mrc p15, 1, r1, c0, c0, 0 @ read the new csidr
1065 and r2, r1, #7 @ extract the length of the cache lines
1066 add r2, r2, #4 @ add 4 (line length offset)
1068 ands r4, r4, r1, lsr #3 @ find maximum number on the way size
1069 clz r5, r4 @ find bit position of way size increment
1071 ands r7, r7, r1, lsr #13 @ extract max number of the index size
1073 mov r9, r4 @ create working copy of max way size
1075 ARM( orr r11, r10, r9, lsl r5 ) @ factor way and cache number into r11
1076 ARM( orr r11, r11, r7, lsl r2 ) @ factor index number into r11
1077 THUMB( lsl r6, r9, r5 )
1078 THUMB( orr r11, r10, r6 ) @ factor way and cache number into r11
1079 THUMB( lsl r6, r7, r2 )
1080 THUMB( orr r11, r11, r6 ) @ factor index number into r11
1081 mcr p15, 0, r11, c7, c14, 2 @ clean & invalidate by set/way
1082 subs r9, r9, #1 @ decrement the way
1084 subs r7, r7, #1 @ decrement the index
1087 add r10, r10, #2 @ increment cache number
1091 ldmfd sp!, {r0-r7, r9-r11}
1092 mov r10, #0 @ swith back to cache level 0
1093 mcr p15, 2, r10, c0, c0, 0 @ select current cache level in cssr
1095 mcr p15, 0, r10, c7, c10, 4 @ DSB
1096 mcr p15, 0, r10, c7, c5, 0 @ invalidate I+BTB
1097 mcr p15, 0, r10, c7, c10, 4 @ DSB
1098 mcr p15, 0, r10, c7, c5, 4 @ ISB
1101 __armv5tej_mmu_cache_flush:
1102 1: mrc p15, 0, r15, c7, c14, 3 @ test,clean,invalidate D cache
1104 mcr p15, 0, r0, c7, c5, 0 @ flush I cache
1105 mcr p15, 0, r0, c7, c10, 4 @ drain WB
1108 __armv4_mmu_cache_flush:
1109 mov r2, #64*1024 @ default: 32K dcache size (*2)
1110 mov r11, #32 @ default: 32 byte line size
1111 mrc p15, 0, r3, c0, c0, 1 @ read cache type
1112 teq r3, r9 @ cache ID register present?
1117 mov r2, r2, lsl r1 @ base dcache size *2
1118 tst r3, #1 << 14 @ test M bit
1119 addne r2, r2, r2, lsr #1 @ +1/2 size if M == 1
1123 mov r11, r11, lsl r3 @ cache line size in bytes
1126 bic r1, r1, #63 @ align to longest cache line
1129 ARM( ldr r3, [r1], r11 ) @ s/w flush D cache
1130 THUMB( ldr r3, [r1] ) @ s/w flush D cache
1131 THUMB( add r1, r1, r11 )
1135 mcr p15, 0, r1, c7, c5, 0 @ flush I cache
1136 mcr p15, 0, r1, c7, c6, 0 @ flush D cache
1137 mcr p15, 0, r1, c7, c10, 4 @ drain WB
1140 __armv3_mmu_cache_flush:
1141 __armv3_mpu_cache_flush:
1143 mcr p15, 0, r1, c7, c0, 0 @ invalidate whole cache v3
1147 * Various debugging routines for printing hex characters and
1148 * memory, which again must be relocatable.
1152 .type phexbuf,#object
1154 .size phexbuf, . - phexbuf
1156 @ phex corrupts {r0, r1, r2, r3}
1157 phex: adr r3, phexbuf
1171 @ puts corrupts {r0, r1, r2, r3}
1173 1: ldrb r2, [r0], #1
1186 @ putc corrupts {r0, r1, r2, r3}
1193 @ memdump corrupts {r0, r1, r2, r3, r10, r11, r12, lr}
1194 memdump: mov r12, r0
1197 2: mov r0, r11, lsl #2
1205 ldr r0, [r12, r11, lsl #2]
1227 .section ".stack", "aw", %nobits
1228 .L_user_stack: .space 4096