arch/alpha/kernel/vmlinux.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2
   3 OUTPUT_FORMAT("elf64-alpha")
   4 OUTPUT_ARCH(alpha)
   5 ENTRY(__start)
   6 PHDRS { kernel PT_LOAD ; }
   7 jiffies = jiffies_64;
   8 SECTIONS
   9 {
  10 #ifdef CONFIG_ALPHA_LEGACY_START_ADDRESS
  11   . = 0xfffffc0000310000;
  12 #else
  13   . = 0xfffffc0001010000;
  14 #endif
  15
  16   _text = .;                                    /* Text and read-only data */
  17   .text : {
  18         *(.text)
  19         SCHED_TEXT
  20         LOCK_TEXT
  21         *(.fixup)
  22         *(.gnu.warning)
  23   } :kernel
  24   _etext = .;                                   /* End of text section */
  25
  26   . = ALIGN(16);
  27   __start___ex_table = .;                       /* Exception table */
  28   __ex_table : { *(__ex_table) }
  29   __stop___ex_table = .;
  30
  31   RODATA
  32
  33   /* Will be freed after init */
  34   . = ALIGN(8192);                              /* Init code and data */
  35   __init_begin = .;
  36   .init.text : {
  37         _sinittext = .;
  38         *(.init.text)
  39         _einittext = .;
  40   }
  41   .init.data : { *(.init.data) }
  42
  43   . = ALIGN(16);
  44   __setup_start = .;
  45   .init.setup : { *(.init.setup) }
  46   __setup_end = .;
  47
  48   . = ALIGN(8);
  49   __initcall_start = .;
  50   .initcall.init : {
  51         *(.initcall1.init)
  52         *(.initcall2.init)
  53         *(.initcall3.init)
  54         *(.initcall4.init)
  55         *(.initcall5.init)
  56         *(.initcall6.init)
  57         *(.initcall7.init)
  58   }
  59   __initcall_end = .;
  60
  61   . = ALIGN(8192);
  62   __initramfs_start = .;
  63   .init.ramfs : { *(.init.ramfs) }
  64   __initramfs_end = .;
  65
  66   . = ALIGN(8);
  67   .con_initcall.init : {
  68         __con_initcall_start = .;
  69         *(.con_initcall.init)
  70         __con_initcall_end = .;
  71   }
  72
  73   . = ALIGN(8);
  74   SECURITY_INIT
  75
  76   . = ALIGN(64);
  77   __per_cpu_start = .;
  78   .data.percpu : { *(.data.percpu) }
  79   __per_cpu_end = .;
  80
  81   . = ALIGN(2*8192);
  82   __init_end = .;
  83   /* Freed after init ends here */
  84
  85   /* Note 2 page alignment above.  */
  86   .data.init_thread : { *(.data.init_thread) }
  87
  88   . = ALIGN(8192);
  89   .data.page_aligned : { *(.data.page_aligned) }
  90
  91   . = ALIGN(64);
  92   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  93
  94   _data = .;
  95   .data : {                                     /* Data */
  96         *(.data)
  97         CONSTRUCTORS
  98   }
  99
 100   .got : { *(.got) }
 101   .sdata : { *(.sdata) }
 102
 103   _edata = .;                                   /* End of data section */
 104
 105   __bss_start = .;
 106   .sbss : { *(.sbss) *(.scommon) }
 107   .bss : { *(.bss) *(COMMON) }
 108   __bss_stop = .;
 109
 110   _end = .;
 111
 112   /* Sections to be discarded */
 113   /DISCARD/ : { *(.exit.text) *(.exit.data) *(.exitcall.exit) }
 114
 115   .mdebug 0 : { *(.mdebug) }
 116   .note 0 : { *(.note) }
 117   .comment 0 : { *(.comment) }
 118
 119   /* Stabs debugging sections */
 120   .stab 0 : { *(.stab) }
 121   .stabstr 0 : { *(.stabstr) }
 122   .stab.excl 0 : { *(.stab.excl) }
 123   .stab.exclstr 0 : { *(.stab.exclstr) }
 124   .stab.index 0 : { *(.stab.index) }
 125   .stab.indexstr 0 : { *(.stab.indexstr) }
 126   /* DWARF 1 */
 127   .debug          0 : { *(.debug) }
 128   .line           0 : { *(.line) }
 129   /* GNU DWARF 1 extensions */
 130   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 131   .debug_sfnames  0 : { *(.debug_sfnames) }
 132   /* DWARF 1.1 and DWARF 2 */
 133   .debug_aranges  0 : { *(.debug_aranges) }
 134   .debug_pubnames 0 : { *(.debug_pubnames) }
 135   /* DWARF 2 */
 136   .debug_info     0 : { *(.debug_info) }
 137   .debug_abbrev   0 : { *(.debug_abbrev) }
 138   .debug_line     0 : { *(.debug_line) }
 139   .debug_frame    0 : { *(.debug_frame) }
 140   .debug_str      0 : { *(.debug_str) }
 141   .debug_loc      0 : { *(.debug_loc) }
 142   .debug_macinfo  0 : { *(.debug_macinfo) }
 143   /* SGI/MIPS DWARF 2 extensions */
 144   .debug_weaknames 0 : { *(.debug_weaknames) }
 145   .debug_funcnames 0 : { *(.debug_funcnames) }
 146   .debug_typenames 0 : { *(.debug_typenames) }
 147   .debug_varnames  0 : { *(.debug_varnames) }
 148 }