DESCRIPTION = "3.2 Linux kernel for the Pandora handheld console"
SECTION = "kernel"
LICENSE = "GPLv2"
COMPATIBLE_MACHINE = "omap3-pandora"
PACKAGE_ARCH = "${MACHINE_ARCH}"

PR = "r9"

# we already build 2.6 kernel using OE infrastructure, and
# as we don't know how to build another one into the same image
# (especially out-of-tree modules), we just package manually prebuilt one
# git://git.openpandora.org/pandora-kernel.git , branch pandora-3.2
# commit: 36620cbb21b150a6417ba42e8244f80bf9094660
SRC_URI = "http://notaz.gp2x.de/misc/pnd/oe_rootfs_extra_r9.tar.bz2"

S = "${WORKDIR}"

do_install() {
  cp -a ${S}/boot ${D}/
  cp -a ${S}/lib ${D}/
}

FILES_${PN} = "boot lib"

pkg_postinst_${PN} () {
  # this will cause depmod to be run on next boot
  rm -f /lib/modules/`uname -r`/modules.dep
  sync

  if ! grep -q '[[:blank:]]/[[:blank:]]*ubifs' /proc/mounts; then
    test -e /media/PANDORABOOT/uImage && oldkernel=/media/PANDORABOOT/uImage
    test -e /media/PANDORABOOT/uImage-3 && oldkernel=/media/PANDORABOOT/uImage-3
    test -e /media/BOOT/uImage && oldkernel=/media/BOOT/uImage
    test -e /media/BOOT/uImage-3 && oldkernel=/media/BOOT/uImage-3

    if test -n "$oldkernel"; then
      cp /boot/uImage-3 $oldkernel
      msg="Updated kernel has beed copied to ${oldkernel}. \
If this location is wrong, copy /boot/uImage-3 to the location \
where your kernel is booted from (usually set in boot.txt / autoboot.txt)."
    else
      msg="The kernel in /boot/uImage-3 has been updated. You need to \
copy it to the location where kernel is booted from (usually set in \
boot.txt / autoboot.txt) or the system might not start after reboot."
    fi
    sync
    if test -n "$DISPLAY"; then
      zenity --info --text "$msg"
    else
      echo "=================================="
      echo "$msg"
      sleep 5
    fi
  fi
}

PACKAGE_STRIP = "no"
SRC_URI[md5sum] = "81570f375aba85409d6e68619df93aa7"
SRC_URI[sha256sum] = "2b9fe4a2d585916fedf082c8e0a5c4ee1f89b0a2176976c2c0627dc7e3fee3bd"