DESCRIPTION = "3.2 Linux kernel for the Pandora handheld console"
SECTION = "kernel"
LICENSE = "GPLv2"
COMPATIBLE_MACHINE = "omap3-pandora"
PACKAGE_ARCH = "${MACHINE_ARCH}"

PR = "r25"

# we already build 2.6 kernel using OE infrastructure, and
# as we don't know how to build another one into the same image
# (especially out-of-tree modules), we just package manually prebuilt one
# git://git.openpandora.org/pandora-kernel.git , branch pandora-3.2
# commit: 52ea40e670c7ec5b6a523ed9dab180df3801f757
# out-of-tree modules are built from:
# http://git.openpandora.org/cgi-bin/gitweb.cgi?p=sgx.git
# http://notaz.gp2x.de/misc/pnd/oe_rootfs_extra_modules.tar.bz2
SRC_URI = "http://notaz.gp2x.de/misc/pnd/oe_rootfs_extra_${PR}.tar.bz2"

S = "${WORKDIR}"

do_install() {
  cp -a ${S}/boot ${D}/
  cp -a ${S}/lib ${D}/
  rm -f ${D}/lib/modules/*/modules.dep*

  # dupes from other OE packages..
  rm -rf ${D}/lib/firmware/vicam
  rm -rf ${D}/lib/firmware/ttusb-budget
}

PACKAGES =+ "linux-firmware-media"

FILES_${PN} = "boot lib"
FILES_linux-firmware-media = "lib/firmware"

pkg_postinst_${PN} () {
  # this will cause depmod to be run on next boot
  rm -f /lib/modules/`uname -r`/modules.dep
  sync

  if ! grep -q '[[:blank:]]/[[:blank:]]*ubifs' /proc/mounts; then
    for dir in `ls -d /media/*boot* 2> /dev/null` `ls -d /media/*BOOT* 2> /dev/null`; do
      test -e $dir/uImage && oldkernel=$dir/uImage
      test -e $dir/uImage-3 && oldkernel=$dir/uImage-3
    done

    if test -n "$oldkernel"; then
      cp /boot/uImage-3 $oldkernel
      msg="Updated kernel has beed copied to ${oldkernel}. \
If this location is wrong, copy /boot/uImage-3 to the location \
where your kernel is booted from (usually set in boot.txt / autoboot.txt)."
    else
      msg="The kernel in /boot/uImage-3 has been updated. You need to \
copy it to the location where kernel is booted from (usually set in \
boot.txt / autoboot.txt) or the system might not start after reboot."
    fi
    sync
    if test -n "$DISPLAY"; then
      zenity --info --text "$msg"
    else
      echo "=================================="
      echo "$msg"
      sleep 5
    fi
  fi
}

PACKAGE_STRIP = "no"
SRC_URI[md5sum] = "08f425f1f031272e3f12029abbe9468f"
SRC_URI[sha256sum] = "5747b357651c7fe3ccb2410217f12a653f223ce011f51908e31a862979443554"