DESCRIPTION = "Tools and libraries to support the C64+ DSP found in TI's OMAP3 hardware."
HOMEPAGE="http://tkscript.de/c64_tools/"
LICENSE = "MIT LGPL GPL"

PV = "20150208"
PR = "r0"

SRCREV = "679b53e220e61d6faa91d921b3f8c85209a3cd1b"

SRC_URI = " \
  git://github.com/bsp2/c64_tools.git;protocol=git;branch=master \
  file://c64_tools.rules \
  file://op_dsp_c64.sh \
  file://99_c64_tools \
"

S = "${WORKDIR}/git"

TARGET_CFLAGS += "-Wall -I../include "
PARALLEL_MAKE = ""


do_compile() {
  cd ${S}/libc64/
  # TARGET_SHARED=libc64.so.1
  oe_runmake -f makefile.linux clean bin
  ln -fs libc64.so.1 libc64.so
  cd ${S}/c64_load/
  touch libc64 # :(
  oe_runmake -f makefile.linux clean bin
}

do_install() {
  install -d ${D}${libdir}/
  install -m 0755 ${S}/libc64/libc64.so.1 ${D}${libdir}/
  install -d ${D}${sbindir}
  install -m 0755 ${S}/c64_load/c64_load ${D}${sbindir}/

  # dsp images
  install -d ${D}${base_libdir}/dsp
  install -m 0644 ${S}/dsp/core/core.out ${D}${base_libdir}/dsp/

  # script, udev rule, sudoers
  install -d ${D}${prefix}/pandora/scripts/
  #install -m 0755 ${S}/scripts/go64.sh ${D}${prefix}/pandora/scripts/op_dsp_c64.sh
  install -m 0755 ${WORKDIR}/op_dsp_c64.sh ${D}${prefix}/pandora/scripts/
  install -d ${D}${base_libdir}/udev/rules.d/
  install -m 0644 ${WORKDIR}/c64_tools.rules ${D}${base_libdir}/udev/rules.d/
  install -d ${D}${sysconfdir}/sudoers.d/
  install -m 440 ${WORKDIR}/99_c64_tools ${D}${sysconfdir}/sudoers.d/

  # -dev stuff
  install -d ${D}${includedir}/c64_tools/include
  install -d ${D}${includedir}/c64_tools/dsp/libc64_dsp/include
  install -m 0644 ${S}/include/*.h ${D}${includedir}/c64_tools/include
  install -m 0644 dsp/libc64_dsp/include/com.h ${D}${includedir}/c64_tools/dsp/libc64_dsp/include/com.h
  install -m 0644 ${S}/libc64/libc64.a ${D}${libdir}/
  cp -a ${S}/libc64/libc64.so ${D}${libdir}/
}

FILES_${PN} += " \
  ${base_libdir}/dsp ${prefix}/pandora/scripts \
  ${base_libdir}/udev/rules.d ${sysconfdir}/sudoers.d/ \
"

PACKAGE_ARCH = "${MACHINE_ARCH}"
COMPATIBLE_MACHINE = "omap3-pandora"