DESCRIPTION = "SGX driver binary blobs, armhf version"
LICENSE = "TSPA"
RDEPENDS = "armhflibc6 armhflibgcc1 libgles-omap3-es23"

PR = "r0"

SGXPV = "4_10_00_01"
IMGPV = "1.10.2359475"

BINFILE = "Graphics_SDK_setuplinux_4_10_00_01_hardfp_minimal_demos.bin"
SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/sdo_sb/targetcontent/gfxsdk/${SGXPV}/exports/${BINFILE} \
"

# Logic to unpack installjammer file
TI_BIN_UNPK_CMDS="Y: qY:workdir:Y"
require ti-eula-unpack.inc

S = "${WORKDIR}/Graphics_SDK_${SGXPV}"

export ES3LOCATION ?= "${S}/gfx_rel_es3.x"
export ES5LOCATION ?= "${S}/gfx_rel_es5.x"

DL = ${D}/usr/lib/arm-linux-gnueabihf

do_configure() {
	# clear out old stuff
	find Binaries/ | xargs rm -f || true
}

do_compile() {
	find ${S} -name "*_org" -delete
}

do_install () {
	install -d ${DL}
	install -d ${DL}/.debug

	# these don't differ between ES3 and ES5
	for f in libEGL libpvrPVR2D_BLITWSEGL libpvrPVR2D_DRIWSEGL libpvrPVR2D_FLIPWSEGL libpvrPVR2D_FRONTWSEGL libpvrPVR2D_LINUXFBWSEGL libusc; do
		cp -a ${ES3LOCATION}/${f}.so ${DL}/
		cp -a ${ES3LOCATION}/${f}.dbg ${DL}/.debug/
	done

	# unused: libGLES_CM_eglimage libGLESv2_eglimage libglslcompiler_eglimage libIMGegl_eglimage libsrv_um_dri

	# separate for ES3 and ES5
	for esrev in 3 5; do
		install -d ${DL}/ES${esrev}.0/.debug

		ESLOCATION=$(eval echo $(echo \$\{ES${esrev}LOCATION\}))
		for f in libews libGLES_CM libGLESv2 libglslcompiler libIMGegl libpvr2d libpvrEWS_REMWSEGL libpvrEWS_WSEGL libPVRScopeServices libsrv_init libsrv_um pvr_drv; do
			cp -a ${ESLOCATION}/${f}.so ${DL}/ES${esrev}.0/
			cp -a ${ESLOCATION}/${f}.dbg ${DL}/ES${esrev}.0/.debug/
		done
	done

	# for compatibility with other systems
	cd ${DL}/
	ln -s libEGL.so libEGL.so.1
	ln -s libGLES_CM.so libGLESv1_CM.so
	ln -s libGLES_CM.so libGLESv1_CM.so.1
	ln -s libGLESv2.so libGLESv2.so.2
	cd -
}

FILES_${PN} = "usr/lib/arm-linux-gnueabihf"

FILES_${PN}-dbg = "usr/lib/arm-linux-gnueabihf/.debug \
                   usr/lib/arm-linux-gnueabihf/ES*/.debug \
"

#HACK! These are binaries, so we can't guarantee that LDFLAGS match :(
INSANE_SKIP_${PN} = True

# Append to update-rc.d postinst
pkg_postinst_${PN}_append() {
rm -f $D${sysconfdir}/powervr-esrev-armhf
/etc/init.d/pvr-init restart || true
}

SRC_URI[md5sum] = "15a3ccb66e98580e474fc112565f66b6"