recipes/pandora-system/pandora-libpnd.bb

   1 DESCRIPTION = "Support for the PND format in Pandora images (lib, daemon, init script etc.)"
   2 LICENSE = "lGPL"
   3
   4 PR = "r1"
   5
   6 PARALLEL_MAKE = ""
   7
   8 SRC_URI = " \
   9           git://openpandora.org/pandora-libraries.git;protocol=git;branch=master \
  10           file://rc.pndnotifyd \
  11           file://rc.pndevmapperd \
  12           file://op_pnd_run.desktop \
  13 "
  14
  15 SRCREV = "f03bf767b821f2f8e0a22e5d3422f4e5dfae8a2d"
  16
  17 S = "${WORKDIR}/git"
  18
  19 inherit update-rc.d
  20
  21 TARGET_CC_ARCH += "${LDFLAGS}"
  22 TARGET_CFLAGS += "-Wall -I./include"
  23
  24 PACKAGES =+ "${PN}-pndnotifyd ${PN}-pndevmapperd"
  25
  26 RDEPENDS_${PN} += "${PN}-pndnotifyd ${PN}-pndevmapperd"
  27
  28 INITSCRIPT_PACKAGES = "${PN}-pndnotifyd ${PN}-pndevmapperd"
  29
  30 INITSCRIPT_NAME_${PN}-pndnotifyd = "pndnotifyd-init"
  31 INITSCRIPT_PARAMS_${PN}-pndnotifyd = "start 30 5 3 . stop 40 0 1 6 ."
  32
  33 INITSCRIPT_NAME_${PN}-pndevmapperd = "pndevmapperd-init"
  34 INITSCRIPT_PARAMS_${PN}-pndevmapperd = "start 30 5 3 . stop 40 0 1 6 ."
  35
  36 RDEPENDS_${PN}-pndnotifyd += "${PN}"
  37 RDEPENDS_${PN}-pndevmapperd += "${PN}"
  38
  39 do_compile_prepend() {
  40           cd ${S}/
  41 }
  42
  43 do_compile() {
  44           oe_runmake
  45           oe_runmake deploy
  46 }
  47
  48 do_install() {
  49           install -d ${D}${sysconfdir}/pandora/conf/
  50           install -m 0644 ${S}/deployment/etc/pandora/conf/apps ${D}${sysconfdir}/pandora/conf/apps
  51           install -m 0644 ${S}/deployment/etc/pandora/conf/desktop ${D}${sysconfdir}/pandora/conf/desktop
  52           install -m 0644 ${S}/deployment/etc/pandora/conf/categories ${D}${sysconfdir}/pandora/conf/categories
  53           install -m 0644 ${S}/deployment/etc/pandora/conf/eventmap ${D}${sysconfdir}/pandora/conf/eventmap
  54           install -d ${D}${libdir}/
  55           install -m 0644 ${S}/deployment/usr/lib/libpnd* ${D}${libdir}/
  56           install -m 0644 ${S}/deployment/usr/lib/libpnd.so.1.0.1 ${D}${libdir}/libpnd.so.1
  57
  58           install -d ${D}${bindir}/
  59           install -m 0755 ${S}/deployment/usr/bin/pndnotifyd ${D}${bindir}/pndnotifyd
  60           install -m 0755 ${S}/deployment/usr/bin/pndevmapperd ${D}${bindir}/pndevmapperd
  61           install -m 0755 ${S}/deployment/usr/bin/pnd_run ${D}${bindir}/pnd_run
  62           install -m 0755 ${S}/deployment/usr/bin/pnd_info ${D}${bindir}/pnd_info
  63
  64           install -d ${D}${prefix}/pandora/
  65           install -d ${D}${prefix}/pandora/apps/
  66           install -d ${D}${prefix}/pandora/scripts/
  67           install -m 0755 ${S}/deployment/usr/pandora/scripts/* ${D}${prefix}/pandora/scripts
  68           install -m 0755 ${S}/testdata/scripts/* ${D}${prefix}/pandora/scripts
  69
  70           install -d ${D}${sysconfdir}/init.d/
  71           install -m 0755 ${WORKDIR}/rc.pndnotifyd ${D}${sysconfdir}/init.d/pndnotifyd-init
  72           install -m 0755 ${WORKDIR}/rc.pndevmapperd ${D}${sysconfdir}/init.d/pndevmapperd-init
  73
  74           install -d ${D}${prefix}/local/share/applications/
  75
  76           install -d ${D}${includedir}/
  77           install -m 0644 ${S}/include/pnd* ${D}${includedir}/
  78
  79           install -d ${D}${sysconfdir}/sudoers.d/
  80           install -m 440 ${S}/testdata/sh/sudoers ${D}${sysconfdir}/sudoers.d/99_libpnd
  81
  82           install -d ${D}${datadir}/applications/
  83           install -m 0644 ${WORKDIR}/op_pnd_run.desktop ${D}${datadir}/applications/
  84 }
  85
  86 FILES_${PN} += "${bindir} ${sbindir} ${prefix}/pandora/*"
  87 FILES_${PN}-pndnotifyd = "${sysconfdir}/init.d/pndnotifyd-init ${bindir}/pndnotifyd"
  88 FILES_${PN}-pndevmapperd = "${sysconfdir}/init.d/pndevmapperd-init ${bindir}/pndevmapperd "
  89 FILES_${PN}-dev += "${libdir}/libpnd.a ${includedir}/pnd*"