From: Koen Kooi <koen@openembedded.org>
Date: Fri, 5 Jan 2007 18:32:40 +0000 (+0000)
Subject: curl: add 7.16.0, make linking against gnutls work
X-Git-Tag: Release-2010-05/1~9453^2~14^2
X-Git-Url: http://git.openpandora.org/cgi-bin/gitweb.cgi?a=commitdiff_plain;h=a9a883008c7b3a7addef1b51d9c56d8ec520e67c;p=openembedded.git

curl: add 7.16.0, make linking against gnutls work
---

diff --git a/packages/curl/curl_7.16.0.bb b/packages/curl/curl_7.16.0.bb
new file mode 100644
index 0000000000..ae42cb42e3
--- /dev/null
+++ b/packages/curl/curl_7.16.0.bb
@@ -0,0 +1,44 @@
+DESCRIPTION = "Command line tool and library for client-side URL transfers."
+LICENSE = "MIT"
+DEPENDS = "zlib gnutls"
+SECTION = "console/network"
+PR = "r0"
+
+SRC_URI = "http://curl.haxx.se/download/curl-${PV}.tar.bz2"
+S = "${WORKDIR}/curl-${PV}"
+
+inherit autotools pkgconfig binconfig
+
+EXTRA_OECONF = "--with-zlib=${STAGING_LIBDIR}/../ \
+                --with-gnutls=${STAGING_BINDIR_CROSS}/ \
+                --without-ssl \
+		--with-random=/dev/urandom \
+		--without-idn \
+		--enable-crypto-auth \
+		"
+
+do_configure_prepend() {
+	sed -i s:OPT_GNUTLS/bin:OPT_GNUTLS:g configure.ac
+}
+
+do_stage () {
+	install -d ${STAGING_INCDIR}/curl
+	install -m 0644 ${S}/include/curl/*.h ${STAGING_INCDIR}/curl/
+	oe_libinstall -so -a -C lib libcurl ${STAGING_LIBDIR}
+}
+
+PACKAGES += "libcurl libcurl-dev libcurl-doc"
+FILES_${PN} = "${bindir}/curl \
+               ${datadir}/curl/curl-ca-bundle.crt"
+FILES_${PN}-doc = "${mandir}/man1/curl.1"
+FILES_lib${PN} = "${libdir}/lib*.so.*"
+FILES_lib${PN}-dev = "${includedir} \
+                      ${libdir}/lib*.so \
+                      ${libdir}/lib*.a \
+                      ${libdir}/lib*.la \
+                      ${libdir}/pkgconfig \
+                      ${datadir}/aclocal \
+                      ${bindir}/*-config"
+FILES_lib${PN}-doc = "${mandir}/man3 \
+                      ${mandir}/man1/curl-config.1"
+