From: Graeme Gregory <dp@xora.org.uk>
Date: Mon, 10 Jul 2006 08:26:25 +0000 (+0000)
Subject: fontconfig_2.3.95.bb : new version of fontconfig
X-Git-Tag: Release-2010-05/1~9453^2~1270
X-Git-Url: http://git.openpandora.org/cgi-bin/gitweb.cgi?a=commitdiff_plain;h=581dcc72a26490e33f74ace76d655fe1fe6f3193;p=openembedded.git

fontconfig_2.3.95.bb : new version of fontconfig
autoconf/Makefile magic internall seems to do the right thing in cross
compile situations so this one doesnt need a matching fontconfig-native.
I have left at DEFAULT_PREFERENCE = "-1" to allow for proper evaluation
as this library is fairly core.
This version seems to cure the masses of alignment errors I was getting
using previous versions.
---

diff --git a/packages/fontconfig/fontconfig_2.3.95.bb b/packages/fontconfig/fontconfig_2.3.95.bb
new file mode 100644
index 0000000000..57f8489a6c
--- /dev/null
+++ b/packages/fontconfig/fontconfig_2.3.95.bb
@@ -0,0 +1,51 @@
+SECTION = "libs"
+LICENSE = "BSD"
+DESCRIPTION = "A library for configuring and customizing font access."
+DEPENDS = "expat freetype freetype-native zlib"
+
+SRC_URI = "http://fontconfig.org/release/fontconfig-${PV}.tar.gz"
+
+PR = "r0"
+
+PACKAGES =+ "fontconfig-utils "
+FILES_fontconfig-utils = "${bindir}/*"
+
+DEFAULT_PREFERENCE = "-1"
+
+# Work around past breakage in debian.bbclass
+RPROVIDES_fontconfig-utils = "libfontconfig-utils"
+RREPLACES_fontconfig-utils = "libfontconfig-utils"
+RCONFLICTS_fontconfig-utils = "libfontconfig-utils"
+DEBIAN_NOAUTONAME_fontconfig-utils = "1"
+
+S = "${WORKDIR}/fontconfig-${PV}"
+
+inherit autotools pkgconfig
+
+export HASDOCBOOK="no"
+
+EXTRA_OECONF = " --disable-docs "
+EXTRA_OEMAKE = "FC_LANG=fc-lang FC_GLYPHNAME=fc-glyphname"
+
+# The tarball has some of the patched files as read only, which
+# patch doesn't like at all
+
+fontconfig_do_unpack() {
+       chmod -R u+rw ${S}
+}
+
+python do_unpack () {
+       bb.build.exec_func('base_do_unpack', d)
+       bb.build.exec_func('fontconfig_do_unpack', d)
+}
+
+do_stage () {
+	oe_libinstall -so -a -C src libfontconfig ${STAGING_LIBDIR}
+	install -d ${STAGING_INCDIR}/fontconfig
+	for i in ${S}/fontconfig/*.h; do install -m 0644 $i ${STAGING_INCDIR}/fontconfig/; done
+}
+
+do_install () {
+	autotools_do_install
+}
+