From: Alex Ferguson <thoughtmonster@gmail.com>
Date: Wed, 19 Jan 2011 16:52:37 +0000 (+0200)
Subject: opentyrian: Add new recipe for opentyrian-hg
X-Git-Url: http://git.openpandora.org/cgi-bin/gitweb.cgi?a=commitdiff_plain;h=23700787c96f84510951c4a284fc892d03abe9ad;p=openembedded.git

opentyrian: Add new recipe for opentyrian-hg

Added a new recipe for opentyrian, a clone of the DOS shoot-em-up
Tyrian. The game depends on SDL and SDL_net.

Signed-off-by: Alex Ferguson <thoughtmonster@gmail.com>
Signed-off-by: Kristoffer Ericson <kristoffer.ericson@gmail.com>
---

diff --git a/recipes/opentyrian/opentyrian_hg.bb b/recipes/opentyrian/opentyrian_hg.bb
new file mode 100644
index 0000000000..5a723cd47b
--- /dev/null
+++ b/recipes/opentyrian/opentyrian_hg.bb
@@ -0,0 +1,39 @@
+DESCRIPTION = "OpenTyrian is a port of the DOS shoot-em-up Tyrian."
+HOMEPAGE = "https://code.google.com/p/opentyrian/"
+SECTION = "games"
+LICENSE = "GPLv2"
+
+DEPENDS = "virtual/libsdl libsdl-net"
+
+REV = "3f3819c0b2"
+PV = "2.1+hg${REV}"
+PR = "r0"
+
+SRC_URI = "hg://opentyrian.googlecode.com/hg;module=opentyrian;rev=${REV} \
+	   http://camanis.net/tyrian/tyrian21.zip;name=data"
+
+S = "${WORKDIR}/opentyrian"
+
+FILES_${PN} += " ${datadir}/applications ${datadir}/pixmaps ${datadir}/opentyrian"
+FILES_${PN}-doc = "${mandir}/man6"
+
+do_compile() {
+	oe_runmake release
+}
+
+do_install() {
+	install -d ${D}${bindir}
+	install -d ${D}${mandir}/man6
+	install -d ${D}${datadir}/pixmaps
+	install -d ${D}${datadir}/applications
+	install -d ${D}${datadir}/opentyrian/data
+
+	install -m 0755 opentyrian ${D}${bindir}
+	install -m 0644 linux/man/opentyrian.6 ${D}${mandir}/man6
+	install -m 0644 -T linux/icons/tyrian-48.png ${D}${datadir}/pixmaps/opentyrian.png
+	install -m 0644 linux/opentyrian.desktop ${D}${datadir}/applications
+	install -m 0644 ${WORKDIR}/tyrian21/* ${D}${datadir}/opentyrian/data
+}
+
+SRC_URI[data.md5sum] = "2a3b206a6de25ed4b771af073f8ca904"
+SRC_URI[data.sha256sum] = "7790d09a2a3addcd33c66ef063d5900eb81cc9c342f4807eb8356364dd1d9277"