add bleeding edge git tree for u-boot-openmoko-devel

diff --git a/conf/distro/include/moko-autorev.inc b/conf/distro/include/moko-autorev.inc
index eb0a403..c539081 100644 (file)
--- a/conf/distro/include/moko-autorev.inc
+++ b/conf/distro/include/moko-autorev.inc
@@ -48,6 +48,7 @@ SRCREV_pn-openocd-native ?= "${AUTOREV}"
 SRCREV_pn-python-gsmd ?= "${AUTOREV}"
 
 SRCREV_pn-u-boot-openmoko ?= "${AUTOREV}"
+SRCREV_pn-u-boot-openmoko-devel ?= "${AUTOREV}"
 SRCREV_pn-dfu-util ?= "${AUTOREV}"
 SRCREV_pn-dfu-util-native ?= "${AUTOREV}"
 SRCREV_pn-usbpath ?= "${AUTOREV}"

diff --git a/packages/u-boot/u-boot-openmoko-devel_git.bb b/packages/u-boot/u-boot-openmoko-devel_git.bb
new file mode 100644 (file)
index 0000000..c2e2165
--- /dev/null
+++ b/packages/u-boot/u-boot-openmoko-devel_git.bb
@@ -0,0 +1,70 @@
+DESCRIPTION = "U-boot bootloader w/ Neo1973 (GTA01) and Neo FreeRunner (GTA02) support"
+AUTHOR = "Harald Welte <laforge@openmoko.org>"
+LICENSE = "GPL"
+SECTION = "bootloader"
+PRIORITY = "optional"
+PROVIDES = "virtual/bootloader"
+LOCALVERSION = "+git${SRCREV}"
+PV = "1.3.1${LOCALVERSION}"
+PR = "r0"
+
+UBOOT_MACHINES = "gta01bv2 gta01bv3 gta01bv4 gta02v1 gta02v2 gta02v3 gta02v4"
+
+DEFAULT_PREFERENCE = "-1"
+
+SRCREV_FORMAT = "git.openmoko.org"
+
+SRC_URI = "git://git.openmoko.org/git/u-boot.git;protocol=git;branch=andy \
+  file://uboot-20070311-tools_makefile_ln_sf.patch;patch=1 \
+  file://makefile-no-dirafter.patch;patch=1 \
+"
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = "CROSS_COMPILE=${TARGET_PREFIX}"
+TARGET_LDFLAGS = ""
+
+do_svnrev() {
+       mv -f tools/setlocalversion tools/setlocalversion.old
+       echo "echo ${LOCALVERSION}" >>tools/setlocalversion
+}
+
+do_compile () {
+       chmod +x board/neo1973/gta*/split_by_variant.sh
+       for mach in ${UBOOT_MACHINES}
+       do
+               oe_runmake ${mach}_config
+               oe_runmake clean
+               find board -name lowlevel_foo.bin -exec rm '{}' \;
+               oe_runmake all
+               oe_runmake u-boot.udfu
+               if [ -f u-boot.udfu ]; then
+                       mv u-boot.udfu u-boot_${mach}.bin
+               else
+                       mv u-boot.bin u-boot_${mach}.bin
+               fi
+               if [ -f board/${mach}/lowlevel_foo.bin ]; then
+                       mv board/${mach}/lowlevel_foo.bin lowlevel_foo_${mach}.bin
+               else
+                       find board -name lowlevel_foo.bin -exec mv '{}' lowlevel_foo_${mach}.bin \;
+               fi
+       done
+}
+
+do_deploy () {
+       install -d ${DEPLOY_DIR_IMAGE}
+       for mach in ${UBOOT_MACHINES}
+       do
+               install -m 0644 ${S}/u-boot_${mach}.bin ${DEPLOY_DIR_IMAGE}/u-boot-${mach}-${PV}-${PR}.bin
+               ln -sf ${DEPLOY_DIR_IMAGE}/u-boot-${mach}-${PV}-${PR}.bin ${DEPLOY_DIR_IMAGE}/uboot-${mach}-latest.bin
+               if [ -f ${S}/lowlevel_foo_${mach}.bin ]; then
+                       install -m 0644 ${S}/lowlevel_foo_${mach}.bin ${DEPLOY_DIR_IMAGE}/lowlevel_foo-${mach}-${PV}-${PR}.bin
+                       ln -sf ${DEPLOY_DIR_IMAGE}/lowlevel_foo-${mach}-${PV}-${PR}.bin ${DEPLOY_DIR_IMAGE}/lowlevel-foo-${mach}-latest.bin
+               fi
+       done
+       install -m 0755 tools/mkimage ${STAGING_BINDIR_NATIVE}/uboot-mkimage
+}
+
+do_deploy[dirs] = "${S}"
+addtask deploy before do_package after do_install
+addtask quilt before do_patch after do_unpack
+addtask svnrev before do_patch after do_quilt