add oh-puzzles, the Opened Hand Puzzles Collection (taken from Poky)

diff --git a/packages/puzzles/oh-puzzles_svn.bb b/packages/puzzles/oh-puzzles_svn.bb
new file mode 100644 (file)
index 0000000..85d742c
--- /dev/null
+++ b/packages/puzzles/oh-puzzles_svn.bb
@@ -0,0 +1,43 @@
+DESCRIPTION = "Portable Puzzle Collection"
+LICENSE = "MIT"
+SECTION = "x11"
+DEPENDS = "gtk+ gconf intltool-native librsvg"
+PV = "0.1+svn${SRCDATE}"
+PR = "r4"
+
+inherit autotools pkgconfig
+
+SRC_URI = "svn://svn.o-hand.com/repos/;module=oh-puzzles;proto=http"
+S = "${WORKDIR}/${PN}"
+
+do_install_append () {
+    mv ${D}${bindir} ${D}/usr/games
+
+    install -d ${D}/${datadir}/applications/
+
+    cd ${D}/${prefix}/games
+    for prog in *; do
+        if [ -x $prog ]; then
+            # Convert prog to Title Case
+            title=$(echo $prog | sed 's/\(^\| \)./\U&/g')
+            echo "making ${D}/${datadir}/applications/$prog.desktop"
+            cat <<STOP > ${D}/${datadir}/applications/$prog.desktop
+[Desktop Entry]
+Encoding=UTF-8
+Name=$title
+Exec=${prefix}/games/$prog
+Icon=applications-games
+Terminal=false
+Type=Application
+Categories=Game
+StartupNotify=true
+SingleInstance=true
+Comment=Play $title.
+STOP
+        fi
+    done
+}
+
+FILES_${PN} += "${prefix}/games/*"
+FILES_${PN}-dbg += "${prefix}/games/.debug/*"
+