e2fsprogs(-native): update to 1.41.5

* add staging tweak from poky to get stuff into /bin instead of /sbin

diff --git a/conf/checksums.ini b/conf/checksums.ini
index b7acaba..0c44a72 100644 (file)
--- a/conf/checksums.ini
+++ b/conf/checksums.ini
@@ -5078,6 +5078,10 @@ sha256=2cc10fee2b29add737e454eb634513135b34a638f7ca2b18364864fe089020dc
 md5=59033388df36987d2b9c9bbf7e19bd57
 sha256=2cc10fee2b29add737e454eb634513135b34a638f7ca2b18364864fe089020dc
 
+[http://downloads.sourceforge.net/e2fsprogs/e2fsprogs-1.41.5.tar.gz]
+md5=e218df6c84fc17c1126d31de9472a76c
+sha256=b3d7d0e1058a3740ddae83d47285bd9dce161eec9e299dde7996ed721da32198
+
 [http://downloads.sourceforge.net/e2fsprogs/e2fsprogs-libs-1.33.tar.gz]
 md5=c7545bb05e0c2fc59174f0dc455c6519
 sha256=a65d064bee3e97c164d07a490692db0e73da8da10019ad9a89866706c93ae703

diff --git a/recipes/e2fsprogs/e2fsprogs-native_1.41.2.bb b/recipes/e2fsprogs/e2fsprogs-native_1.41.2.bb
index f2c3898..e79958c 100644 (file)
--- a/recipes/e2fsprogs/e2fsprogs-native_1.41.2.bb
+++ b/recipes/e2fsprogs/e2fsprogs-native_1.41.2.bb
@@ -2,7 +2,7 @@ SECTION = "base"
 require e2fsprogs.inc
 inherit native
 
-PR = "r1"
+PR = "r2"
 DEFAULT_PREFERENCE = "-1"
 
 EXTRA_OECONF = ""
@@ -12,5 +12,9 @@ PACKAGES = ""
 DEPENDS = ""
 
 do_stage () {
-        oe_runmake install
+       oe_runmake install
+       install -d ${STAGING_BINDIR_NATIVE}/
+       for b in ${e2miscbins}; do
+       install -m 0755 misc/$b ${STAGING_BINDIR_NATIVE}/ || die "failed to install $b"
+       done
 }

diff --git a/recipes/e2fsprogs/e2fsprogs-native_1.41.5.bb b/recipes/e2fsprogs/e2fsprogs-native_1.41.5.bb
new file mode 100644 (file)
index 0000000..b29064f
--- /dev/null
+++ b/recipes/e2fsprogs/e2fsprogs-native_1.41.5.bb
@@ -0,0 +1,19 @@
+SECTION = "base"
+require e2fsprogs.inc
+inherit native
+
+SRC_URI += "file://mkinstalldirs.patch;patch=1"
+
+EXTRA_OECONF = ""
+
+FILESPATH = "${@base_set_filespath([ '${FILE_DIRNAME}/e2fsprogs-${PV}', '${FILE_DIRNAME}/e2fsprogs', '${FILE_DIRNAME}/files', '${FILE_DIRNAME}' ], d)}"
+PACKAGES = ""
+DEPENDS = ""
+
+do_stage () {
+       autotools_stage_all
+       install -d ${STAGING_BINDIR_NATIVE}/
+       for b in ${e2miscbins}; do
+               install -m 0755 misc/$b ${STAGING_BINDIR_NATIVE}/ || die "failed to install $b"
+       done
+}

diff --git a/recipes/e2fsprogs/e2fsprogs.inc b/recipes/e2fsprogs/e2fsprogs.inc
index b7a1223..6821d71 100644 (file)
--- a/recipes/e2fsprogs/e2fsprogs.inc
+++ b/recipes/e2fsprogs/e2fsprogs.inc
@@ -15,3 +15,8 @@ EXTRA_OECONF = "${@['','--disable-tls'][bb.data.getVar('ARM_ABI', d, 1) == 'oabi
                --enable-dynamic-e2fsck --disable-nls --sbindir=${base_sbindir}"
 
 PARALLEL_MAKE = ""
+
+e2miscbins = "mke2fs badblocks tune2fs dumpe2fs blkid logsave e2image fsck \
+              e2undo chattr lsattr uuidgen mklost+found filefrag uuidd e2initrd_helper"
+
+

diff --git a/recipes/e2fsprogs/e2fsprogs-1.41.4/mkinstalldirs.patch b/recipes/e2fsprogs/e2fsprogs/mkinstalldirs.patch
similarity index 100%
rename from recipes/e2fsprogs/e2fsprogs-1.41.4/mkinstalldirs.patch
rename to recipes/e2fsprogs/e2fsprogs/mkinstalldirs.patch

diff --git a/recipes/e2fsprogs/e2fsprogs_1.41.5.bb b/recipes/e2fsprogs/e2fsprogs_1.41.5.bb
new file mode 100644 (file)
index 0000000..4fc357f
--- /dev/null
+++ b/recipes/e2fsprogs/e2fsprogs_1.41.5.bb
@@ -0,0 +1,96 @@
+require e2fsprogs.inc
+
+SRC_URI += "file://mkinstalldirs.patch;patch=1"
+
+DEPENDS += "gettext-native"
+
+do_compile_prepend () {
+       find ./ -print|xargs chmod u=rwX
+       ( cd util; ${BUILD_CC} subst.c -o subst )
+}
+
+ext2fsheaders = "ext2_ext_attr.h bitops.h ext2_err.h \
+                ext2_types.h ext2_fs.h ext2_io.h \
+                ext2fs.h"
+e2pheaders = "e2p.h"
+
+do_stage () {
+       oe_libinstall -a -C lib libe2p ${STAGING_LIBDIR}/
+       oe_libinstall -a -C lib libext2fs ${STAGING_LIBDIR}/
+       install -d ${STAGING_INCDIR}/e2p
+       for h in ${e2pheaders}; do
+               install -m 0644 lib/e2p/$h ${STAGING_INCDIR}/e2p/ || die "failed to install $h"
+       done
+       install -d ${STAGING_INCDIR}/ext2fs
+       for h in ${ext2fsheaders}; do
+               install -m 0644 lib/ext2fs/$h ${STAGING_INCDIR}/ext2fs/ || die "failed to install $h"
+       done
+       autotools_stage_all
+}
+
+# blkid used to be part of e2fsprogs but is useful outside, add it
+# as an RDEPENDS so that anything relying on it being in e2fsprogs
+# still works
+RDEPENDS_e2fsprogs = "e2fsprogs-blkid e2fsprogs-uuidgen e2fsprogs-badblocks"
+
+FILES_${PN} += "${libdir}/e2initrd_helper"
+
+PACKAGES =+ "e2fsprogs-blkid e2fsprogs-uuidgen e2fsprogs-e2fsck e2fsprogs-mke2fs e2fsprogs-fsck e2fsprogs-tune2fs e2fsprogs-badblocks"
+FILES_e2fsprogs-blkid = "${base_sbindir}/blkid.${PN}"
+FILES_e2fsprogs-uuidgen = "${bindir}/uuidgen"
+FILES_e2fsprogs-fsck = "${base_sbindir}/fsck.${PN}"
+FILES_e2fsprogs-e2fsck = "${base_sbindir}/e2fsck.${PN} ${base_sbindir}/fsck.ext*.${PN}"
+FILES_e2fsprogs-mke2fs = "${base_sbindir}/mke2fs.${PN} ${base_sbindir}/mkfs.ext*.${PN}"
+FILES_e2fsprogs-tune2fs = "${base_sbindir}/tune2fs ${base_sbindir}/e2label ${base_sbindir}/findfs"
+FILES_e2fsprogs-badblocks = "${base_sbindir}/badblocks"
+
+do_install_append () {
+       mv ${D}${base_sbindir}/fsck ${D}${base_sbindir}/fsck.${PN}
+       mv ${D}${base_sbindir}/blkid ${D}${base_sbindir}/blkid.${PN}
+       mv ${D}${base_sbindir}/e2fsck ${D}${base_sbindir}/e2fsck.${PN}
+       mv ${D}${base_sbindir}/fsck.ext2 ${D}${base_sbindir}/fsck.ext2.${PN}
+       mv ${D}${base_sbindir}/fsck.ext3 ${D}${base_sbindir}/fsck.ext3.${PN}
+       mv ${D}${base_sbindir}/mke2fs ${D}${base_sbindir}/mke2fs.${PN}
+       mv ${D}${base_sbindir}/mkfs.ext2 ${D}${base_sbindir}/mkfs.ext2.${PN}
+       mv ${D}${base_sbindir}/mkfs.ext3 ${D}${base_sbindir}/mkfs.ext3.${PN}
+}
+
+pkg_postinst_e2fsprogs-fsck () {
+       update-alternatives --install ${base_sbindir}/fsck fsck fsck.${PN} 100
+}
+
+pkg_prerm_e2fsprogs-fsck () {
+       update-alternatives --remove fsck fsck.${PN}
+}
+
+pkg_postinst_e2fsprogs-blkid () {
+    update-alternatives --install ${base_sbindir}/blkid blkid blkid.${PN} 100
+}
+
+pkg_prerm_e2fsprogs-blkid () {
+    update-alternatives --remove blkid blkid.${PN}
+}
+
+pkg_postinst_e2fsprogs-e2fsck () {
+       update-alternatives --install ${base_sbindir}/e2fsck e2fsck e2fsck.${PN} 100
+       update-alternatives --install ${base_sbindir}/fsck.ext2 fsck.ext2 fsck.ext2.${PN} 100
+       update-alternatives --install ${base_sbindir}/fsck.ext3 fsck.ext3 fsck.ext3.${PN} 100
+}
+
+pkg_prerm_e2fsprogs-e2fsck () {
+       update-alternatives --remove e2fsck e2fsck.${PN}
+       update-alternatives --remove fsck.ext2 fsck.ext2.${PN}
+       update-alternatives --remove fsck.ext3 fsck.ext3.${PN}
+}
+
+pkg_postinst_e2fsprogs-mke2fs () {
+       update-alternatives --install ${base_sbindir}/mke2fs mke2fs mke2fs.${PN} 100
+       update-alternatives --install ${base_sbindir}/mkfs.ext2 mkfs.ext2 mkfs.ext2.${PN} 100
+       update-alternatives --install ${base_sbindir}/mkfs.ext3 mkfs.ext3 mkfs.ext3.${PN} 100
+}
+
+pkg_prerm_e2fsprogs-mke2fs () {
+       update-alternatives --remove mke2fs mke2fs.${PN}
+       update-alternatives --remove mkfs.ext2 mkfs.ext2.${PN}
+       update-alternatives --remove mkfs.ext3 mkfs.ext3.${PN}
+}