Merge oe-devel@oe-devel.bkbits.net:openembedded

into sugarcube.dyndns.org:/home2/oe/bakery/openembedded

2005/04/01 20:50:33+02:00 dyndns.org!reenoo
kaffe: cleanup

BKrev: 424d9815crvtofQNx8gUtZqyJcSbwg

diff --git a/packages/kaffe/kaffe-gtk_cvs.bb b/packages/kaffe/kaffe-gtk_cvs.bb
index e69de29..84d80db 100644 (file)
--- a/packages/kaffe/kaffe-gtk_cvs.bb
+++ b/packages/kaffe/kaffe-gtk_cvs.bb
@@ -0,0 +1,7 @@
+include kaffe.inc
+MAINTAINER = "Rene Wagner <rw@handhelds.org>"
+PV = "1.1.4+cvs${CVSDATE}"
+
+DEPENDS += "glib-2.0 gmp gtk+ libart-lgpl pango zlib kaffeh-native"
+
+EXTRA_OECONF += ""

diff --git a/packages/kaffe/kaffe-qt_cvs.bb b/packages/kaffe/kaffe-qt_cvs.bb
index e69de29..9b7e5b2 100644 (file)
--- a/packages/kaffe/kaffe-qt_cvs.bb
+++ b/packages/kaffe/kaffe-qt_cvs.bb
@@ -0,0 +1,18 @@
+include kaffe.inc
+
+PV = "1.1.4+cvs${CVSDATE}"
+DEPENDS += "libqpe-opie"
+
+CXXFLAGS += " -DQPE "
+EXTRA_OEMAKE += "MOC=${STAGING_BINDIR}/moc"
+EXTRA_OECONF += " --with-qtdir=$QTDIR \
+       --with-awt=qt \
+       --enable-pure-java-math \
+       --without-x \
+       --without-classpath-gtk-awt \
+       --without-kaffe-x-awt \
+       --with-kaffe-qt-awt"
+
+do_configure_prepend() {
+       rm -f m4/libtool.m4
+}

diff --git a/packages/kaffe/kaffe.inc b/packages/kaffe/kaffe.inc
index e69de29..48023d4 100644 (file)
--- a/packages/kaffe/kaffe.inc
+++ b/packages/kaffe/kaffe.inc
@@ -0,0 +1,80 @@
+DESCRIPTION = "Kaffe is a clean room implementation of the Java Virtual Machine"
+HOMEPAGE = "http://www.kaffe.org/"
+LICENSE  = "GPL LGPL W3C Classpath BSD"
+
+DEPENDS = "jikes-native fastjar-native"
+
+SRC_URI = "cvs://readonly:readonly@cvs.kaffe.org/cvs/kaffe;module=kaffe \
+           file://disable-automake-checks.patch;patch=1"
+S = "${WORKDIR}/kaffe"
+
+inherit autotools gettext
+
+EXTRA_OECONF = "--with-engine=jit \
+       --with-threads=unix-pthreads \
+       --disable-alsatest \
+       --disable-esdtest \
+       --disable-sound \
+       --with-jikes"
+
+# kaffe installs to non-standard locations. apply a similar workaround to 
+# the one used in debian. i.e. override prefix
+oe_runconf () {
+       if [ -x ${S}/configure ] ; then
+               cfgcmd="${S}/configure \
+                   --build=${BUILD_SYS} \
+                   --host=${HOST_SYS} \
+                   --target=${TARGET_SYS} \
+                   --prefix=${libdir}/${PN} \
+                   --datadir=${datadir} \
+                   --sysconfdir=${sysconfdir} \
+                   --sharedstatedir=${sharedstatedir}/${PN} \
+                   --includedir=${includedir} \
+                   --oldincludedir=${oldincludedir} \
+                   --infodir=${infodir} \
+                   --mandir=${mandir} \
+                       ${EXTRA_OECONF} \
+                   $@"
+               oenote "Running $cfgcmd..."
+               $cfgcmd || oefatal "oe_runconf failed" 
+       else
+               oefatal "no configure script found"
+       fi
+}
+FILES_${PN} += "${libdir}/${PN}"
+
+do_install () {
+       autotools_do_install
+
+       # move partially duplicate stuff to a single location
+       mv -f ${D}${libdir}/${PN}/bin/* ${D}${libdir}/${PN}/jre/bin
+       rmdir ${D}${libdir}/${PN}/bin
+}
+
+# use update-alternatives for the various wrapper scripts
+alternative_names = "appletviewer \
+install-jar \
+jar \
+java \
+javac \
+javadoc \
+javah \
+javap \
+kaffe \
+kaffeh \
+native2ascii \
+rmic \
+rmiregistry \
+serialver"
+
+pkg_postinst() {
+       for name in ${alternative_names}; do
+               update-alternatives --install ${bindir}/$name $name ${libdir}/${PN}/jre/bin/$name 300
+       done
+}
+
+pkg_postrm() {
+       for name in ${alternative_names}; do
+               update-alternatives --remove $name ${libdir}/${PN}/jre/bin/$name
+       done
+}

diff --git a/packages/kaffe/kaffeh-native_cvs.bb b/packages/kaffe/kaffeh-native_cvs.bb
index e69de29..f5bca08 100644 (file)
--- a/packages/kaffe/kaffeh-native_cvs.bb
+++ b/packages/kaffe/kaffeh-native_cvs.bb
@@ -0,0 +1,17 @@
+include kaffe.inc
+
+PV = "1.1.4+cvs${CVSDATE}"
+
+inherit native
+
+EXTRA_OECONF += " --without-classpath-gtk-awt \
+       --disable-native-awt \
+       --disable-sound \
+       --without-x \
+       --without-kaffe-x-awt \
+       --disable-debug \
+       --disable-gcj"
+
+do_stage() {
+       install -m 0755 kaffe/kaffeh/kaffeh ${STAGING_BINDIR}/
+}