recipes/tslib/tslib.inc

   1 DESCRIPTION = "tslib is a plugin-based flexible touchscreen access library."
   2 HOMEPAGE = "http://tslib.berlios.de/"
   3 AUTHOR = "Russell King w/ plugins by Chris Larson et. al."
   4 SECTION = "base"
   5 LICENSE = "LGPLv2"
   6 INC_PR = "r23"
   7
   8 SRC_URI += "\
   9   file://ts.conf \
  10   file://ts.conf-collie-2.4 \
  11   file://ts.conf-simpad-2.4 \
  12   file://tslib.sh \
  13 "
  14 SRC_URI_append_mnci += "\
  15   file://devfs.patch;patch=1 \
  16   file://event1.patch;patch=1 \
  17 "
  18
  19 inherit autotools pkgconfig
  20
  21 EXTRA_OECONF        = "--enable-shared"
  22 EXTRA_OECONF_mnci   = "--enable-shared --disable-h3600 --enable-input --disable-corgi --disable-collie --disable-mk712 --disable-arctic2 --disable-ucb1x00 "
  23
  24 do_stage () {
  25         autotools_stage_all
  26 }
  27
  28 do_install () {
  29         autotools_do_install
  30         install -d ${D}${sysconfdir}/profile.d/
  31         install -m 0755 ${WORKDIR}/tslib.sh ${D}${sysconfdir}/profile.d/
  32         install -m 0644 ${WORKDIR}/ts.conf ${D}${sysconfdir}/ts.conf
  33         case ${MACHINE} in
  34         collie)
  35                 install -d ${D}${datadir}/tslib
  36                 install -m 0644 ${WORKDIR}/ts.conf-collie-2.4 ${D}${datadir}/tslib/
  37                 ;;
  38         simpad)
  39                 install -d ${D}${datadir}/tslib
  40                 install -m 0644 ${WORKDIR}/ts.conf-simpad-2.4 ${D}${datadir}/tslib/
  41                 ;;
  42         esac
  43 }
  44
  45 SRC_URI_OVERRIDES_PACKAGE_ARCH = "0"
  46
  47 # People should consider using udev's /dev/input/touchscreen0 symlink
  48 # instead of detect-stylus
  49 #RDEPENDS_tslib-conf_weird-machine = "detect-stylus"
  50 RPROVIDES_tslib-conf = "libts-0.0-conf"
  51
  52 # Machines with machine specific patches
  53 PACKAGE_ARCH_mnci = "${MACHINE_ARCH}"
  54 # Machines with machine specific config files (tslib.sh)
  55 PACKAGE_ARCH_tslib-conf_a780 = "${MACHINE_ARCH}"
  56 PACKAGE_ARCH_tslib-conf_collie = "${MACHINE_ARCH}"
  57 PACKAGE_ARCH_tslib-conf_e680 = "${MACHINE_ARCH}"
  58 PACKAGE_ARCH_tslib-conf_jornada56x = "${MACHINE_ARCH}"
  59 PACKAGE_ARCH_tslib-conf_jornada6xx = "${MACHINE_ARCH}"
  60 PACKAGE_ARCH_tslib-conf_jornada7xx = "${MACHINE_ARCH}"
  61 PACKAGE_ARCH_tslib-conf_netbook-pro = "${MACHINE_ARCH}"
  62 PACKAGE_ARCH_tslib-conf_omap1610h2 = "${MACHINE_ARCH}"
  63 PACKAGE_ARCH_tslib-conf_omap5912osk = "${MACHINE_ARCH}"
  64 PACKAGE_ARCH_tslib-conf_omap3-pandora = "${MACHINE_ARCH}"
  65 PACKAGE_ARCH_tslib-conf_simpad = "${MACHINE_ARCH}"
  66
  67 PACKAGES =+ "tslib-conf libts-dev tslib-tests tslib-calibrate"
  68 DEBIAN_NOAUTONAME_tslib-conf = "1"
  69 DEBIAN_NOAUTONAME_tslib-tests = "1"
  70 DEBIAN_NOAUTONAME_tslib-calibrate = "1"
  71
  72 RDEPENDS_${PN} = "tslib-conf"
  73 # Ship calibration data if it exists
  74 RRECOMMENDS = " pointercal "
  75
  76 FILES_${PN}-dbg += "${libdir}/ts/.debug*"
  77 FILES_tslib-conf = "${sysconfdir}/ts.conf ${sysconfdir}/profile.d/tslib.sh ${datadir}/tslib"
  78 FILES_${PN} = "${libdir}/*.so.* ${libdir}/ts/*.so*"
  79 FILES_libts-dev = "${FILES_tslib-dev} ${libdir}/ts/*.la"
  80 FILES_tslib-calibrate += "${bindir}/ts_calibrate"
  81 FILES_tslib-tests = "${bindir}/ts_harvest ${bindir}/ts_print ${bindir}/ts_print_raw ${bindir}/ts_test"
  82