recipes/gtk+/gtk+.inc

   1 DESCRIPTION = "GTK+ is a multi-platform toolkit for creating graphical user interfaces. Offering a complete \
   2 set of widgets, GTK+ is suitable for projects ranging from small one-off projects to complete application suites."
   3 HOMEPAGE = "http://www.gtk.org"
   4 SECTION = "libs"
   5 LICENSE = "LGPL"
   6 PRIORITY = "optional"
   7 DEPENDS = "glib-2.0 tiff pango atk jpeg libpng libxext libxcursor gtk-doc libgcrypt cups \
   8            libxrandr libxdamage libxrender libxcomposite"
   9 PROVIDES = "gdk-pixbuf"
  10
  11 INC_PR = "r6"
  12
  13 inherit autotools pkgconfig
  14
  15 LEAD_SONAME = "libgtk-x11-2.0.so"
  16
  17 FILES_${PN} = "${bindir}/gdk-pixbuf-query-loaders \
  18         ${bindir}/gtk-update-icon-cache \
  19         ${bindir}/gtk-query-immodules-2.0 \
  20         ${libdir}/lib*.so.* \
  21         ${datadir}/themes ${sysconfdir} \
  22         ${libdir}/gtk-2.0/${LIBV}/engines/libpixmap.so"
  23 RDEPENDS_${PN} = "hicolor-icon-theme"
  24
  25 FILES_${PN}-dev += " \
  26         ${datadir}/gtk-2.0/include \
  27         ${libdir}/gtk-2.0/include \
  28         ${bindir}/gdk-pixbuf-csource \
  29         ${bindir}/gtk-builder-convert"
  30
  31 FILES_${PN}-dbg += " \
  32         ${libdir}/gtk-2.0/modules/.debug/* \
  33         ${libdir}/gtk-2.0/${LIBV}/loaders/.debug/* \
  34         ${libdir}/gtk-2.0/${LIBV}/immodules/.debug/* \
  35         ${libdir}/gtk-2.0/${LIBV}/engines/.debug/* \
  36         ${libdir}/gtk-2.0/${LIBV}/printbackends/.debug/*"
  37
  38 NEATSTUFF = " ttf-dejavu-sans gdk-pixbuf-loader-png gdk-pixbuf-loader-jpeg gdk-pixbuf-loader-gif gdk-pixbuf-loader-xpm "
  39
  40 RRECOMMENDS_${PN} = " ${NEATSTUFF} "
  41 RRECOMMENDS_${PN}_linux = " ${NEATSTUFF} glibc-gconv-iso8859-1 "
  42 RRECOMMENDS_${PN}_linux-gnueabi = " ${NEATSTUFF} glibc-gconv-iso8859-1"
  43
  44
  45
  46 do_stage () {
  47         oe_libinstall -so -C gtk libgtk-x11-2.0 ${STAGING_LIBDIR}
  48         oe_libinstall -so -C gdk libgdk-x11-2.0 ${STAGING_LIBDIR}
  49         oe_libinstall -so -C contrib/gdk-pixbuf-xlib libgdk_pixbuf_xlib-2.0 ${STAGING_LIBDIR}
  50         oe_libinstall -so -C gdk-pixbuf libgdk_pixbuf-2.0 ${STAGING_LIBDIR}
  51         if test -d modules/other/gail/libgail-util ; then
  52                 oe_libinstall -so -C modules/other/gail/libgail-util libgailutil ${STAGING_LIBDIR}
  53         fi
  54
  55         autotools_stage_includes
  56
  57         mkdir -p ${STAGING_LIBDIR}/gtk-2.0/include
  58         install -m 0644 gdk/gdkconfig.h ${STAGING_LIBDIR}/gtk-2.0/include/gdkconfig.h
  59         # Copy over all headers, since the maemo stuff needs access to the private api. *sigh*
  60         cp gtk/*.h ${STAGING_INCDIR}/gtk-2.0/gtk/
  61
  62         install -m 0644 m4macros/gtk-2.0.m4 ${STAGING_DATADIR}/aclocal/
  63 }
  64
  65 do_install_append () {
  66         install -d ${D}${sysconfdir}/gtk-2.0
  67         rm -f ${D}${libdir}/gtk-2.0/*/*.la ${D}${libdir}/gtk-2.0/${LIBV}/*/*.la
  68 }
  69
  70 postinst_prologue() {
  71 if [ "x$D" != "x" ]; then
  72   exit 1
  73 fi
  74
  75 }