recipes/ezx/ezx-gen-blob_svn.bb

   1 DESCRIPTION = "Generic Blob [Bootloader] for the Motorola EZX platform"
   2 SECTION = "bootloaders"
   3 AUTHOR = "OpenEZX Team"
   4 HOMEPAGE = "http://people.openezx.org/wyrm/gen-blob"
   5 LICENSE = "GPL"
   6 PROVIDES = "virtual/bootloader"
   7 DEPENDS = "virtual/kernel"
   8 SRCREV = "2517"
   9 PV = "1.0.0+svnr${SRCPV}"
  10 PE = "1"
  11 PR = "r1"
  12
  13 SRC_URI = "\
  14   svn://svn.openezx.org/trunk/src/blob/;module=gen-blob;proto=http \
  15   file://remove-bogus-sed.patch;patch=1 \
  16 "
  17 S = "${WORKDIR}/gen-blob"
  18
  19 inherit autotools
  20
  21 EXTRA_OECONF = "\
  22   --with-board=lubbock \
  23   --with-cpu=pxa262 \
  24   --with-linux-prefix=${STAGING_KERNEL_DIR} \
  25   --enable-usb \
  26 "
  27
  28 do_configure() {
  29         gnu-configize
  30         oe_runconf
  31 }
  32
  33 do_deploy() {
  34         install -d ${DEPLOY_DIR_IMAGE}
  35         install -m 0644 src/blob/blob-a780  ${DEPLOY_DIR_IMAGE}/gen-blob-for-1stgen.${SRCDATE}
  36         install -m 0644 src/blob/blob-a1200 ${DEPLOY_DIR_IMAGE}/gen-blob-for-2ndgen.${SRCDATE}
  37 }
  38
  39 addtask deploy before do_build after do_compile
  40
  41 PACKAGE_ARCH = "${MACHINE_ARCH}"