recipes/db/db3_3.2.9.bb

   1 SECTION = "libs"
   2 DESCRIPTION = "Berkeley DB v3."
   3 HOMEPAGE = "http://www.oracle.com/technology/products/berkeley-db/db/index.html"
   4 LICENSE = "BSD"
   5 PR = "r3"
   6 VIRTUAL_NAME ?= "virtual/db"
   7 CONFLICTS = "db"
   8
   9 # it doesn't make any sense to have multiple relational
  10 # databases on an embedded machine, virtual/db allows
  11 # a build to select the desired one.
  12 PROVIDES += "${VIRTUAL_NAME}"
  13
  14 SRC_URI = "http://download.oracle.com/berkeley-db/db-${PV}.tar.gz \
  15            file://autofoo.patch;patch=1"
  16 S = "${WORKDIR}/db-${PV}/dist"
  17 B = "${WORKDIR}/db-${PV}/build_unix"
  18
  19 inherit autotools
  20
  21 EXTRA_OECONF = "--enable-shared --enable-compat185 --enable-static"
  22 EXTRA_OEMAKE = "'SHELL=/bin/sh' 'ar=`which ${AR}` cr' 'chmod=`which chmod`' \
  23                 'cp=`which cp`' 'ln=`which ln`' 'mkdir=`which mkdir`' 'ranlib=`which ${RANLIB}`' \
  24                 'rm=`which rm`' 'strip=`which ${STRIP}`'"
  25
  26 PACKAGES = "${PN}-dbg ${PN} ${PN}-bin ${PN}-dev ${PN}-doc ${PN}-locale"
  27
  28 FILES_${PN} = "${libdir}/libdb-3.2*so*"
  29 FILES_${PN}-bin = "${bindir}"
  30 FILES_${PN}-dev = "${includedir} ${libdir}/libdb.so ${libdir}/libdb.a \
  31                    ${libdir}/libdb-3.so ${libdir}/libdb.la ${libdir}/libdb-3.2.a \
  32                    ${libdir}/libdb-3.2.la"
  33
  34 do_configure_prepend () {
  35         set -e
  36         (
  37                 cd ${S}
  38                 . ./RELEASE
  39                 (echo "AC_DEFUN(AM_VERSION_SET, [" &&
  40                 echo "AC_SUBST(DB_VERSION_MAJOR)" &&
  41                 echo "AC_DEFINE(DB_VERSION_MAJOR, [$DB_VERSION_MAJOR])" &&
  42                 echo "DB_VERSION_MAJOR=$DB_VERSION_MAJOR" &&
  43                 echo "AC_SUBST(DB_VERSION_MINOR)" &&
  44                 echo "AC_DEFINE(DB_VERSION_MINOR, [$DB_VERSION_MINOR])" &&
  45                 echo "DB_VERSION_MINOR=$DB_VERSION_MINOR" &&
  46                 echo "AC_SUBST(DB_VERSION_PATCH)" &&
  47                 echo "AC_DEFINE(DB_VERSION_PATCH, [$DB_VERSION_PATCH])" &&
  48                 echo "DB_VERSION_PATCH=$DB_VERSION_PATCH" &&
  49                 echo "AC_SUBST(DB_VERSION_STRING)" &&
  50                 echo "AC_DEFINE(DB_VERSION_STRING, [$DB_VERSION_STRING])" &&
  51                 echo "DB_VERSION_STRING=\"\\\"\$DB_VERSION_STRING\\\"\"" &&
  52                 echo "])dnl") > acinclude.m4
  53         )
  54 }
  55
  56 do_configure () {
  57         rm -f ${S}/configure
  58         autotools_do_configure
  59 }
  60
  61 do_compile () {
  62         oe_runmake
  63 }
  64
  65 do_stage () {
  66         install -m 0644 db_185.h ../include/db_cxx.h db.h ${STAGING_INCDIR}/
  67         oe_libinstall -so -a libdb-3.2 ${STAGING_LIBDIR}
  68         ln -sf libdb-3.2.so ${STAGING_LIBDIR}/libdb.so
  69         ln -sf libdb-3.2.a ${STAGING_LIBDIR}/libdb.a
  70 }
  71
  72 do_install () {
  73         oe_runmake \
  74                 prefix=${D}${prefix} \
  75                 exec_prefix=${D}${exec_prefix} \
  76                 bindir=${D}${bindir} \
  77                 includedir=${D}${includedir} \
  78                 libdir=${D}${libdir} \
  79                 docdir=${D}${docdir} \
  80                 install
  81 }
  82
  83 python do_package() {
  84         if bb.data.getVar('DEBIAN_NAMES', d, 1):
  85                 bb.data.setVar('PKG_${PN}', 'libdb3', d)
  86         bb.build.exec_func('package_do_package', d)
  87 }