recipes/automake/automake.inc

   1 DESCRIPTION = "A tool for automatically generating Makefiles."
   2 LICENSE = "GPL"
   3 HOMEPAGE = "http://www.gnu.org/software/automake/"
   4 SECTION = "devel"
   5 DEPENDS_virtclass-native = "autoconf-native"
   6 RDEPENDS_automake-native = "autoconf-native perl-native-runtime"
   7 RDEPENDS_automake += "\
   8     autoconf \
   9     perl \
  10     perl-module-bytes \
  11     perl-module-constant \
  12     perl-module-cwd \
  13     perl-module-data-dumper \
  14     perl-module-dynaloader \
  15     perl-module-errno \
  16     perl-module-exporter-heavy \
  17     perl-module-file-basename \
  18     perl-module-file-compare \
  19     perl-module-file-copy \
  20     perl-module-file-glob \
  21     perl-module-file-path \
  22     perl-module-file-spec-unix \
  23     perl-module-file-stat \
  24     perl-module-getopt-long \
  25     perl-module-io \
  26     perl-module-io-file \
  27     perl-module-posix \
  28     perl-module-strict \
  29     perl-module-text-parsewords \
  30     perl-module-vars "
  31 SRC_URI = "${GNU_MIRROR}/automake/automake-${PV}.tar.bz2;name=automake"
  32 INC_PR = "r3"
  33 AUTOMAKE_API = "${@".".join(bb.data.getVar("PV",d,1).split(".")[0:2])}"
  34
  35 inherit autotools
  36
  37 FILES_${PN} += "${datadir}/automake* ${datadir}/aclocal*"
  38
  39 do_configure_prepend () {
  40         if ${@['true', 'false'][bb.data.inherits_class('native', d)]}
  41         then
  42                 export ac_cv_path_PERL="${ac_cv_path_PERL=${bindir}/perl}"
  43         fi
  44 }
  45
  46 do_install_append () {
  47         autotools_do_install
  48         ln -sf aclocal-${AUTOMAKE_API} ${D}${bindir}/aclocal
  49         ln -sf automake-${AUTOMAKE_API} ${D}${bindir}/automake
  50         install -d ${D}${datadir}/aclocal
  51 }
  52
  53 BBCLASSEXTEND = "native"