conf/bitbake.conf

   1 ##################################################################
   2 # Recipe Parsing
   3 ##################################################################
   4 BBMASK = "/(nonworking|obsolete)/"
   5
   6 ##################################################################
   7 # Standard target filesystem layout.
   8 ##################################################################
   9
  10 # Path prefixes
  11 layout_prefix = "${prefix}"
  12 layout_exec_prefix = "${exec_prefix}"
  13 layout_base_prefix = "${base_prefix}"
  14
  15 # Base paths
  16 layout_base_bindir = "${base_bindir}"
  17 layout_base_sbindir = "${base_sbindir}"
  18 layout_base_libdir = "${base_libdir}"
  19
  20 # Architecture independent paths
  21 layout_sysconfdir = "${sysconfdir}"
  22 layout_localstatedir = "${localstatedir}"
  23 layout_servicedir = "${servicedir}"
  24 layout_sharedstatedir = "${sharedstatedir}"
  25 layout_datadir = "${datadir}"
  26 layout_infodir = "${infodir}"
  27 layout_mandir = "${mandir}"
  28 layout_docdir = "${docdir}"
  29
  30 # Architecture dependent paths
  31 layout_bindir = "${bindir}"
  32 layout_sbindir = "${sbindir}"
  33 layout_libdir = "${libdir}"
  34 layout_includedir = "${includedir}"
  35 layout_libexecdir = "${libexecdir}"
  36
  37 ##################################################################
  38 # Standard target filesystem paths.
  39 ##################################################################
  40
  41 # Path prefixes
  42 export base_prefix = ""
  43 export prefix = "/usr"
  44 export exec_prefix = "/usr"
  45
  46 # Base paths
  47 export base_bindir = "${base_prefix}/bin"
  48 export base_sbindir = "${base_prefix}/sbin"
  49 export base_libdir = "${base_prefix}/lib"
  50
  51 # Architecture independent paths
  52 export datadir = "${prefix}/share"
  53 export sysconfdir = "${base_prefix}/etc"
  54 export servicedir = "${base_prefix}/srv"
  55 export sharedstatedir = "${base_prefix}/com"
  56 export localstatedir = "${base_prefix}/var"
  57 export infodir = "${datadir}/info"
  58 export mandir = "${datadir}/man"
  59 export docdir = "${datadir}/doc"
  60
  61 # Architecture dependent paths
  62 export bindir = "${exec_prefix}/bin"
  63 export sbindir = "${exec_prefix}/sbin"
  64 export libexecdir = "${exec_prefix}/libexec"
  65 export libdir = "${exec_prefix}/lib"
  66 export includedir = "${exec_prefix}/include"
  67 export oldincludedir = "${exec_prefix}/include"
  68
  69 #
  70 # These must match the various bbclass layout definitions
  71 #
  72 base_bindir_native = "/bin"
  73 base_sbindir_native = "/sbin"
  74 sysconfdir_native = "/etc"
  75 prefix_native = "/usr"
  76 bindir_native = "${prefix_native}/bin"
  77 sbindir_native = "${prefix_native}/sbin"
  78 includedir_native = "${prefix_native}/include"
  79 libdir_native = "${prefix_native}/lib"
  80 datadir_native = "${prefix_native}/share"
  81 bindir_cross = "/bin"
  82
  83 #
  84 # Cross recipes need to know about the target layout
  85 # := is used carefully here
  86 #
  87 target_datadir := "${datadir}"
  88 # Used to find env/perl/python
  89 USRBINPATH = "${bindir}"
  90 USRBINPATH_class-native = "/usr/bin"
  91 USRBINPATH_class-nativesdk = "/usr/bin"
  92
  93 ##################################################################
  94 # Architecture-dependent build variables.
  95 ##################################################################
  96
  97 BUILD_ARCH = "${@os.uname()[4]}"
  98 BUILD_OS = "${@os.uname()[0].lower()}"
  99 BUILD_VENDOR = ""
 100 BUILD_SYS = "${BUILD_ARCH}${BUILD_VENDOR}-${BUILD_OS}"
 101 BUILD_PREFIX = ""
 102 BUILD_CC_ARCH = ""
 103 BUILD_EXEEXT = ""
 104
 105 HOST_ARCH = "${TARGET_ARCH}"
 106 HOST_OS = "${TARGET_OS}"
 107 HOST_VENDOR = "${TARGET_VENDOR}"
 108 HOST_SYS = "${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
 109 HOST_PREFIX = "${TARGET_PREFIX}"
 110 HOST_CC_ARCH = "${TARGET_CC_ARCH}"
 111 HOST_EXEEXT = ""
 112
 113 TARGET_ARCH ?= "INVALID"
 114 TARGET_OS = "INVALID"
 115 TARGET_VENDOR = "${BUILD_VENDOR}"
 116 TARGET_SYS = "${TARGET_ARCH}${TARGET_VENDOR}${@['-' + bb.data.getVar('TARGET_OS', d, 1), ''][bb.data.getVar('TARGET_OS', d, 1) == ('' or 'custom')]}"
 117 TARGET_PREFIX = "${TARGET_SYS}-"
 118 TARGET_CC_ARCH = ""
 119 TARGET_EXEEXT = ""
 120
 121 SDK_ARCH ?= "${BUILD_ARCH}"
 122 SDK_OS ?= "${BUILD_OS}"
 123 SDK_VENDOR ?= "${BUILD_VENDOR}"
 124 SDK_SYS = "${SDK_ARCH}${SDK_VENDOR}${@['-' + bb.data.getVar('SDK_OS', d, 1), ''][bb.data.getVar('SDK_OS', d, 1) == ('' or 'custom')]}"
 125 SDK_PREFIX = "${SDK_SYS}-"
 126 SDK_CC_ARCH ?= "${BUILD_CC_ARCH}"
 127 SDK_EXEEXT = ""
 128
 129 # A shortcut for the commonly used value
 130 EXEEXT = "${HOST_EXEEXT}"
 131
 132 BASE_PACKAGE_ARCH = "${HOST_ARCH}"
 133 PACKAGE_ARCH = "${BASE_PACKAGE_ARCH}"
 134 PACKAGE_EXTRA_ARCHS ?= ""
 135 MACHINE_ARCH = "${@[bb.data.getVar('BASE_PACKAGE_ARCH', d, 1), bb.data.getVar('MACHINE', d, 1)][bool(bb.data.getVar('MACHINE', d, 1))]}"
 136 PACKAGE_ARCHS = "all any noarch ${TARGET_ARCH} ${PACKAGE_EXTRA_ARCHS} ${MACHINE}"
 137
 138 MULTIMACH_ARCH = "${PACKAGE_ARCH}"
 139 MULTIMACH_TARGET_SYS = "${MULTIMACH_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 140 MULTIMACH_HOST_SYS = "${MULTIMACH_ARCH}${HOST_VENDOR}-${HOST_OS}"
 141 BASEPKG_HOST_SYS = "${BASE_PACKAGE_ARCH}${HOST_VENDOR}-${HOST_OS}"
 142 BASEPKG_TARGET_SYS = "${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 143
 144 # select proper CPU to get binary locales generated
 145 QEMU_OPTIONS = ""
 146 QEMU_OPTIONS_iwmmxt  = "-cpu pxa270-c5"
 147 QEMU_OPTIONS_armv6   = "-cpu arm1136"
 148 QEMU_OPTIONS_armv6-novfp = "-cpu arm1136"
 149 QEMU_OPTIONS_armv7a   = "-cpu cortex-a8"
 150
 151 ##################################################################
 152 # Date/time variables.
 153 ##################################################################
 154
 155 DATE := "${@time.strftime('%Y%m%d',time.gmtime())}"
 156 TIME := "${@time.strftime('%H%M%S',time.gmtime())}"
 157 DATETIME = "${DATE}${TIME}"
 158
 159 ##################################################################
 160 # Openembedded Software Prerequisites.
 161 ##################################################################
 162
 163 # python-native should be here but python relies on building
 164 # its own in staging
 165 ASSUME_PROVIDED = "\
 166     bc-native \
 167     bzip2-native \
 168     cvs-native \
 169     diffstat-native \
 170     patch-native \
 171     perl-native-runtime \
 172     python-native-runtime \
 173     svn-native \
 174     texinfo-native \
 175     util-linux-native \
 176     "
 177
 178 ##################################################################
 179 # Package default variables.
 180 ##################################################################
 181 PN = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[0] or 'defaultpkgname'}"
 182 PV = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[1] or '1.0'}"
 183 PR = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[2] or 'r0'}"
 184 PF = "${PN}-${EXTENDPE}${PV}-${PR}"
 185 EXTENDPE = "${@['','${PE\x7d_'][bb.data.getVar('PE',d,1) > 0]}"
 186 EXTENDPEVER = "${@['','${PE\x7d:'][bb.data.getVar('PE',d,1) > 0]}"
 187 EXTENDPV = "${EXTENDPEVER}${PV}-${PR}${DISTRO_PR}"
 188 P = "${PN}-${PV}"
 189
 190 # Define a PR for kernels that machines can override so things like
 191 # modules get rebuilt
 192 MACHINE_KERNEL_PR = ""
 193
 194 # Base package name
 195 # Automatically derives "foo" from "foo-native", "foo-cross" or "foo-initial"
 196 # otherwise it is the same as PN and P
 197 SPECIAL_PKGSUFFIX = "-native -cross -initial -intermediate -nativesdk -crosssdk -cross-canadian -sdk"
 198 BPN = "${@base_prune_suffix(bb.data.getVar('PN', d, True), bb.data.getVar('SPECIAL_PKGSUFFIX', d, True).split(), d)}"
 199 BP = "${BPN}-${PV}"
 200
 201 # Package info.
 202
 203 SECTION = "base"
 204 PRIORITY = "optional"
 205 DESCRIPTION = "Version ${PV}-${PR} of package ${PN}"
 206 LICENSE = "unknown"
 207 MAINTAINER = "OpenEmbedded Team <openembedded-devel@lists.openembedded.org>"
 208 HOMEPAGE = "unknown"
 209
 210 # Package dependencies and provides.
 211
 212 # Ensure that -dev packages recommend the corresponding -dev packages of their
 213 # deps, and the same for -dbg.
 214 DEPCHAIN_PRE  = ""
 215 DEPCHAIN_POST = "-dev -dbg"
 216
 217 DEPENDS = ""
 218 RDEPENDS = ""
 219 PROVIDES = ""
 220 PROVIDES_prepend = "${P} ${PF} ${PN} "
 221 RPROVIDES = ""
 222
 223 MULTI_PROVIDER_WHITELIST = "virtual/libintl"
 224
 225 SOLIBS = ".so.*"
 226 SOLIBS_darwin = ".*.dylib"
 227 SOLIBS_darwin8 = ".*.dylib"
 228 SOLIBS_darwin9 = ".*.dylib"
 229
 230 SOLIBSDEV = ".so"
 231 SOLIBSDEV_darwin = ".dylib"
 232 SOLIBSDEV_darwin8 = ".dylib"
 233 SOLIBSDEV_darwin9 = ".dylib"
 234
 235 PACKAGES = "${PN}-dbg ${PN} ${PN}-doc ${PN}-dev ${PN}-static ${PN}-locale"
 236 #enable this when bitbake is upgraded to cope with ++ values in the field
 237 PACKAGES_DYNAMIC = "${PN}-locale-*"
 238 FILES = ""
 239
 240 FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} \
 241             ${sysconfdir} ${sharedstatedir} ${localstatedir} \
 242             ${base_bindir}/* ${base_sbindir}/* \
 243             ${base_libdir}/*${SOLIBS} \
 244             ${datadir}/${PN} ${libdir}/${PN}/* \
 245             ${datadir}/pixmaps ${datadir}/applications \
 246             ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
 247             ${libdir}/bonobo/servers"
 248
 249 FILES_${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
 250             ${datadir}/gnome/help"
 251 SECTION_${PN}-doc = "doc"
 252
 253 FILES_${PN}-static = "${libdir}/*.a ${base_libdir}/*.a"
 254
 255 FILES_${PN}-dev = "${includedir} ${libdir}/lib*${SOLIBSDEV} ${libdir}/*.la \
 256                 ${libdir}/*.o ${libdir}/pkgconfig \
 257                 ${base_libdir}/*.o ${datadir}/aclocal ${datadir}/pkgconfig"
 258 SECTION_${PN}-dev = "devel"
 259 ALLOW_EMPTY_${PN}-dev = "1"
 260 RDEPENDS_${PN}-dev = "${PN} (= ${EXTENDPV})"
 261
 262 FILES_${PN}-dbg = "${bindir}/.debug ${sbindir}/.debug ${libexecdir}/.debug ${libdir}/.debug \
 263             ${base_bindir}/.debug ${base_sbindir}/.debug ${base_libdir}/.debug ${libdir}/${PN}/.debug \
 264             ${libdir}/matchbox-panel/.debug"
 265 SECTION_${PN}-dbg = "devel"
 266 ALLOW_EMPTY_${PN}-dbg = "1"
 267 RRECOMMENDS_${PN}-dbg = "${PN} (= ${EXTENDPV})"
 268
 269 FILES_${PN}-locale = "${datadir}/locale"
 270
 271 # File manifest
 272
 273 export MANIFEST = "${FILESDIR}/manifest"
 274
 275 # file:// search paths
 276 FILE_DIRNAME = "${@os.path.dirname(bb.data.getVar('FILE', d))}"
 277 FILESPATHBASE = "${FILE_DIRNAME}"
 278 FILESPATHPKG = "${PF}:${P}:${PN}:${BP}:${BPN}:files:."
 279 FILESPATH = "${@':'.join([os.path.normpath(os.path.join(fp, p, o)) for fp in d.getVar('FILESPATHBASE', 1).split(':') for p in d.getVar('FILESPATHPKG', 1).split(':') for o in (d.getVar('OVERRIDES', 1) + ':').split(':') if os.path.exists(os.path.join(fp, p, o))])}"
 280 FILESDIR = "${@bb.which(d.getVar('FILESPATH', 1), '.')}"
 281
 282 ##################################################################
 283 # General work and output directories for the build system.
 284 ##################################################################
 285
 286 TMPDIR = "${TOPDIR}/tmp"
 287 CACHE = "${TMPDIR}/cache${@['', '/' + str(bb.data.getVar('MACHINE', d, 1))][bool(bb.data.getVar('MACHINE', d, 1))]}"
 288 CO_DIR = "${DL_DIR}"
 289 CVSDIR = "${CO_DIR}/cvs"
 290 SVNDIR = "${CO_DIR}/svn"
 291 GITDIR = "${CO_DIR}/git"
 292 BZRDIR = "${CO_DIR}/bzr"
 293 HGDIR = "${CO_DIR}/hg"
 294
 295 STAMP = "${TMPDIR}/stamps/${MULTIMACH_TARGET_SYS}/${PF}"
 296 WORKDIR = "${TMPDIR}/work/${MULTIMACH_TARGET_SYS}/${PF}"
 297 T = "${WORKDIR}/temp"
 298 D = "${WORKDIR}/image"
 299 S = "${WORKDIR}/${BP}"
 300 B = "${S}"
 301
 302 STAGING_DIR = "${TMPDIR}/staging"
 303
 304 STAGING_DIR_JAVA = "${STAGING_DIR}/java"
 305 STAGING_DIR_NATIVE = "${STAGING_DIR}/${BUILD_SYS}"
 306 STAGING_BINDIR_NATIVE = "${STAGING_DIR_NATIVE}${bindir_native}"
 307 STAGING_SBINDIR_NATIVE = "${STAGING_DIR_NATIVE}${sbindir_native}"
 308 STAGING_BINDIR_CROSS  = "${STAGING_DIR_NATIVE}${bindir_native}/${MULTIMACH_HOST_SYS}"
 309 STAGING_BINDIR_CROSS_BASEPKG = "${STAGING_DIR_NATIVE}${bindir_native}/${BASEPKG_TARGET_SYS}"
 310 STAGING_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${libdir_native}"
 311 STAGING_INCDIR_NATIVE = "${STAGING_DIR_NATIVE}${includedir_native}"
 312 STAGING_ETCDIR_NATIVE = "${STAGING_DIR_NATIVE}${sysconfdir_native}"
 313 STAGING_DATADIR_NATIVE = "${STAGING_DIR_NATIVE}${datadir_native}"
 314
 315 # This should really be MULTIMACH_HOST_SYS but that breaks "all" and machine
 316 # specific packages - hack around it for now.
 317 STAGING_DIR_HOST = "${STAGING_DIR}/${BASEPKG_HOST_SYS}"
 318 STAGING_BINDIR = "${STAGING_DIR_HOST}${bindir}"
 319 STAGING_LIBDIR = "${STAGING_DIR_HOST}${libdir}"
 320 STAGING_INCDIR = "${STAGING_DIR_HOST}${includedir}"
 321 STAGING_ETCDIR = "${STAGING_DIR_HOST}${sysconfdir}"
 322 STAGING_DATADIR = "${STAGING_DIR_HOST}${datadir}"
 323 STAGING_EXECPREFIXDIR = "${STAGING_DIR_HOST}${exec_prefix}"
 324 STAGING_LOADER_DIR = "${STAGING_DIR_HOST}/loader"
 325 STAGING_FIRMWARE_DIR = "${STAGING_DIR_HOST}/firmware"
 326 STAGING_PYDIR = "${STAGING_DIR}/lib/python2.4"
 327
 328 # This should really be MULTIMACH_TARGET_SYS but that breaks "all" and machine
 329 # specific packages - hack around it for now.
 330 STAGING_DIR_TARGET = "${STAGING_DIR}/${BASEPKG_TARGET_SYS}"
 331
 332 STAGING_DIR_SDK = "${STAGING_DIR}/${SDK_SYS}"
 333
 334 # Setting DEPLOY_DIR outside of TMPDIR is helpful, when you are using
 335 # packaged staging and/or multimachine.
 336 DEPLOY_DIR ?= "${TMPDIR}/deploy"
 337 DEPLOY_DIR_TAR = "${DEPLOY_DIR}/tar"
 338 DEPLOY_DIR_IPK = "${DEPLOY_DIR}/ipk"
 339 DEPLOY_DIR_RPM = "${DEPLOY_DIR}/rpm"
 340 DEPLOY_DIR_DEB = "${DEPLOY_DIR}/deb"
 341 DEPLOY_DIR_IMAGE = "${DEPLOY_DIR}/images"
 342 DEPLOY_DIR_TOOLS = "${DEPLOY_DIR}/tools"
 343
 344 PKGDATA_DIR = "${TMPDIR}/pkgdata/${MULTIMACH_TARGET_SYS}"
 345
 346 SDK_NAME = "${DISTRO}/${TARGET_ARCH}"
 347 SDK_PATH = "/usr/local/${SDK_NAME}"
 348 SDKPATH = "${SDK_PATH}"
 349
 350 ##################################################################
 351 # Kernel info.
 352 ##################################################################
 353
 354 STAGING_KERNEL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/kernel"
 355
 356 ##################################################################
 357 # Specific image creation and rootfs population info.
 358 ##################################################################
 359
 360 IMAGE_ROOTFS = "${TMPDIR}/rootfs/${PN}"
 361 IMAGE_BASENAME = "${PN}"
 362 IMAGE_NAME = "${IMAGE_BASENAME}-${MACHINE}-${DATETIME}"
 363 IMAGE_LINK_NAME = "${IMAGE_BASENAME}-${MACHINE}"
 364 IMAGE_EXTRA_SPACE = 10240
 365
 366 UBI_VOLNAME ?= "${MACHINE}-rootfs"
 367
 368 IMAGE_CMD = ""
 369 IMAGE_CMD_jffs2 = "mkfs.jffs2 -x lzo --root=${IMAGE_ROOTFS} --faketime --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
 370 IMAGE_CMD_yaffs2 = "mkyaffs2image ${EXTRA_IMAGECMD} ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.yaffs2"
 371 IMAGE_CMD_cramfs = "mkcramfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cramfs ${EXTRA_IMAGECMD}"
 372 IMAGE_CMD_ext2 = "genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}"
 373 IMAGE_CMD_ext2.gz = "install -d ${DEPLOY_DIR_IMAGE}/tmp.gz ; genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.gz"
 374 IMAGE_CMD_ext3 = "genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
 375 IMAGE_CMD_ext3.gz = "install -d ${DEPLOY_DIR_IMAGE}/tmp.gz ; genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.gz"
 376 IMAGE_CMD_squashfs = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs ${EXTRA_IMAGECMD} -noappend"
 377 IMAGE_CMD_squashfs-lzma = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs-lzma ${EXTRA_IMAGECMD} -noappend -comp lzma"
 378 IMAGE_CMD_tar = "cd ${IMAGE_ROOTFS} && tar -cvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar ."
 379 IMAGE_CMD_tar.gz = "cd ${IMAGE_ROOTFS} && tar -zcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.gz ."
 380 IMAGE_CMD_tar.bz2 = "cd ${IMAGE_ROOTFS} && tar -jcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.bz2 ."
 381 IMAGE_CMD_cpio = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio) ${EXTRA_IMAGECMD}"
 382 IMAGE_CMD_cpio.gz = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz) ${EXTRA_IMAGECMD}"
 383 IMAGE_CMD_cpio.gz.u-boot = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz) ${EXTRA_IMAGECMD}; mkimage -A ${UBOOT_ARCH} -O linux -T ramdisk -C gzip -n ${IMAGE_NAME} -d ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz.u-boot"
 384 IMAGE_CMD_cpio.lzma = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | lzma -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.lzma) ${EXTRA_IMAGECMD}"
 385 IMAGE_CMD_ubi = "echo \[ubifs\] > ubinize.cfg ; echo mode=ubi >> ubinize.cfg ; echo image=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs >> ubinize.cfg ; echo vol_id=0 >> ubinize.cfg ; echo vol_type=dynamic >> ubinize.cfg ; echo vol_name=${UBI_VOLNAME} >> ubinize.cfg ; echo vol_flags=autoresize >> ubinize.cfg;mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs ${MKUBIFS_ARGS} && ubinize -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubi ${UBINIZE_ARGS} ubinize.cfg"
 386 IMAGE_CMD_ubifs = "mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.ubifs.img ${MKUBIFS_ARGS}"
 387
 388 EXTRA_IMAGECMD = ""
 389 EXTRA_IMAGECMD_jffs2 = ""
 390 EXTRA_IMAGECMD_yaffs2 = "1"
 391 EXTRA_IMAGECMD_squashfs = ""
 392 EXTRA_IMAGECMD_squashfs-lzma = ""
 393 EXTRA_IMAGECMD_cpio = ""
 394 EXTRA_IMAGECMD_cpio.gz = ""
 395 EXTRA_IMAGECMD_cpio.lzma = ""
 396 EXTRA_IMAGECMD_ubi = ""
 397 EXTRA_IMAGECMD_ubifs = ""
 398
 399 IMAGE_DEPENDS = ""
 400 IMAGE_DEPENDS_jffs2 = "mtd-utils-native"
 401 IMAGE_DEPENDS_yaffs2 = "yaffs2-utils-native"
 402 IMAGE_DEPENDS_cramfs = "cramfs-native"
 403 IMAGE_DEPENDS_ext2 = "genext2fs-native"
 404 IMAGE_DEPENDS_ext2.gz = "genext2fs-native"
 405 IMAGE_DEPENDS_ext3 = "genext2fs-native e2fsprogs-native"
 406 IMAGE_DEPENDS_ext3.gz = "genext2fs-native e2fsprogs-native"
 407 IMAGE_DEPENDS_cpio.gz.u-boot = "u-boot-mkimage-native"
 408 IMAGE_DEPENDS_cpio.lzma = "lzma-native"
 409 IMAGE_DEPENDS_squashfs = "squashfs-tools-native"
 410 IMAGE_DEPENDS_squashfs-lzma = "squashfs-tools-native"
 411 IMAGE_DEPENDS_ubi = "mtd-utils-native"
 412 IMAGE_DEPENDS_ubifs = "mtd-utils-native"
 413
 414 EXTRA_IMAGEDEPENDS = ""
 415
 416 ##################################################################
 417 # Toolchain info.
 418 ##################################################################
 419
 420 CROSS_DIR = "${TMPDIR}/cross/${BASE_PACKAGE_ARCH}"
 421 CROSS_DATADIR = "${CROSS_DIR}/share"
 422 PATH_prepend = "${STAGING_BINDIR_CROSS}:${STAGING_BINDIR_CROSS_BASEPKG}:${STAGING_SBINDIR_NATIVE}:${STAGING_BINDIR_NATIVE}:${CROSS_DIR}/${bindir_cross}:${STAGING_DIR_NATIVE}${base_sbindir_native}:${STAGING_DIR_NATIVE}${base_bindir_native}:"
 423 export PATH
 424
 425 ##################################################################
 426 # Build utility info.
 427 ##################################################################
 428
 429 CCACHE = "${@bb.which(bb.data.getVar('PATH', d, 1), 'ccache') and 'ccache '}"
 430 TOOLCHAIN_OPTIONS = ""
 431 TOOLCHAIN_PATH ?= "${CROSS_DIR}"
 432 TOOLCHAIN_SYSPATH ?= "${TOOLCHAIN_PATH}/${TARGET_SYS}"
 433
 434 export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 435 export CXX = "${CCACHE}${HOST_PREFIX}g++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 436 export F77 = "${CCACHE}${HOST_PREFIX}g77 ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 437 export CPP = "${HOST_PREFIX}gcc -E${TOOLCHAIN_OPTIONS}"
 438 export LD = "${HOST_PREFIX}ld${TOOLCHAIN_OPTIONS}"
 439 export CCLD = "${CC}"
 440 export AR = "${HOST_PREFIX}ar"
 441 export AS = "${HOST_PREFIX}as"
 442 export RANLIB = "${HOST_PREFIX}ranlib"
 443 export STRIP = "${HOST_PREFIX}strip"
 444 export OBJCOPY = "${HOST_PREFIX}objcopy"
 445 export OBJDUMP = "${HOST_PREFIX}objdump"
 446 export NM = "${HOST_PREFIX}nm"
 447 PYTHON = "${@sys.executable}"
 448
 449 export BUILD_CC = "${CCACHE}${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
 450 export BUILD_CXX = "${CCACHE}${BUILD_PREFIX}g++ ${BUILD_CC_ARCH}"
 451 export BUILD_F77 = "${CCACHE}${BUILD_PREFIX}g77 ${BUILD_CC_ARCH}"
 452 export BUILD_CPP = "${BUILD_PREFIX}cpp"
 453 export BUILD_LD = "${BUILD_PREFIX}ld"
 454 export BUILD_CCLD = "${BUILD_PREFIX}gcc"
 455 export BUILD_AR = "${BUILD_PREFIX}ar"
 456 export BUILD_RANLIB = "${BUILD_PREFIX}ranlib"
 457 export BUILD_STRIP = "${BUILD_PREFIX}strip"
 458
 459 export MAKE = "make"
 460 EXTRA_OEMAKE = "-e MAKEFLAGS="
 461
 462 ##################################################################
 463 # Patch handling.
 464 ##################################################################
 465 PATCHTOOL = 'quilt'
 466 PATCHRESOLVE = 'noop'
 467
 468 ##################################################################
 469 # Build flags and options.
 470 ##################################################################
 471
 472 export BUILD_CPPFLAGS = "-isystem${STAGING_INCDIR_NATIVE}"
 473 export CPPFLAGS = "${TARGET_CPPFLAGS}"
 474 export TARGET_CPPFLAGS = "-isystem${STAGING_DIR_TARGET}${includedir}"
 475 export SDK_CPPFLAGS = "-isystem${STAGING_DIR_SDK}${includedir} -isystem${STAGING_DIR_HOST}${includedir}"
 476
 477 export BUILD_CFLAGS = "${BUILD_CPPFLAGS} ${BUILD_OPTIMIZATION}"
 478 export CFLAGS = "${TARGET_CFLAGS}"
 479 export TARGET_CFLAGS = "${TARGET_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 480 export SDK_CFLAGS = "${SDK_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 481
 482 export BUILD_CXXFLAGS = "${BUILD_CFLAGS} -fpermissive"
 483 export CXXFLAGS = "${TARGET_CXXFLAGS}"
 484 export TARGET_CXXFLAGS = "${TARGET_CFLAGS} -fpermissive"
 485 export SDK_CXXFLAGS = "${SDK_CFLAGS} -fpermissive"
 486
 487 export BUILD_LDFLAGS = "-L${STAGING_LIBDIR_NATIVE} \
 488                         -Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} \
 489                         -Wl,-rpath,${STAGING_LIBDIR_NATIVE} -Wl,-O1"
 490
 491 export LDFLAGS = "${TARGET_LDFLAGS}"
 492 export TARGET_LDFLAGS = "-L${STAGING_DIR_TARGET}${libdir} \
 493                          -Wl,-rpath-link,${STAGING_DIR_TARGET}${libdir} \
 494                          -Wl,-O1 \
 495                          ${TARGET_LINK_HASH_STYLE}"
 496 export SDK_LDFLAGS = "-L${STAGING_DIR_SDK}${libdir} \
 497                          -Wl,-rpath-link,${STAGING_DIR_SDK}${libdir} \
 498                          -Wl,-O1"
 499
 500 # Which flags to leave by strip-flags() in bin/build/oebuild.sh ?
 501 ALLOWED_FLAGS = "-O -mcpu -march -pipe"
 502
 503 # Pass parallel make options to the compile task only
 504 EXTRA_OEMAKE_prepend_task_do_compile = "${PARALLEL_MAKE} "
 505 EXTRA_OEMAKE_prepend_task-compile = "${PARALLEL_MAKE} "
 506
 507 ##################################################################
 508 # Optimization flags.
 509 ##################################################################
 510
 511 FULL_OPTIMIZATION = "-fexpensive-optimizations -fomit-frame-pointer -frename-registers -O2"
 512 DEBUG_OPTIMIZATION = "-O -fno-omit-frame-pointer -g"
 513 SELECTED_OPTIMIZATION = "${@bb.data.getVar(['FULL_OPTIMIZATION', 'DEBUG_OPTIMIZATION'][bb.data.getVar('DEBUG_BUILD', d, 1) == '1'], d, 1)}"
 514 BUILD_OPTIMIZATION = "-O2 -g"
 515
 516 ##################################################################
 517 # Bootstrap stuff.
 518 ##################################################################
 519
 520 BOOTSTRAP_EXTRA_RDEPENDS = ""
 521 BOOTSTRAP_EXTRA_RRECOMMENDS = ""
 522
 523 ##################################################################
 524 # Palmtop stuff.
 525 ##################################################################
 526
 527 export QTDIR = "${STAGING_DIR_HOST}/qt2"
 528 export QPEDIR = "${STAGING_DIR_HOST}"
 529 export OPIEDIR = "${STAGING_DIR_HOST}"
 530 export palmtopdir = "${libdir}/opie"
 531 export palmqtdir = "${palmtopdir}"
 532
 533 ##################################################################
 534 # Download locations and utilities.
 535 ##################################################################
 536
 537 OE_STRICT_CHECKSUMS ?= "1"
 538
 539 ADOBE_MIRROR = "http://fpdownload.macromedia.com/get/flashplayer/current/"
 540 APACHE_MIRROR = "http://www.apache.org/dist"
 541 DEBIAN_MIRROR = "ftp://ftp.debian.org/debian/pool"
 542 E_CVS = "cvs://anonymous@anoncvs.enlightenment.org/var/cvs/e"
 543 E_URI = "http://enlightenment.freedesktop.org/files"
 544 FREEBSD_MIRROR = "ftp://ftp.freebsd.org/pub/FreeBSD/"
 545 FREEDESKTOP_CVS = "cvs://anoncvs:anoncvs@anoncvs.freedesktop.org/cvs"
 546 FREESMARTPHONE_GIT = "git://git.freesmartphone.org"
 547 GENTOO_MIRROR = "http://distfiles.gentoo.org/distfiles"
 548 GNOME_GIT = "git://git.gnome.org"
 549 GNOME_MIRROR = "http://ftp.gnome.org/pub/GNOME/sources"
 550 GNU_MIRROR = "ftp://ftp.gnu.org/gnu"
 551 GPE_MIRROR = "http://gpe.linuxtogo.org/download/source"
 552 GPE_EXTRA_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/extra;module=${PN}"
 553 GPE_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/base;module=${PN}"
 554 GPEPHONE_MIRROR = "http://gpephone.linuxtogo.org/download/gpephone"
 555 GPEPHONE_SVN = "svn://projects.linuxtogo.org/svn/gpephone/trunk/source;module=${PN}"
 556 HANDHELDS_CVS = "cvs://anoncvs:anoncvs@anoncvs.handhelds.org/cvs"
 557 KERNELORG_MIRROR = "http://www.kernel.org/pub"
 558 SOURCEFORGE_MIRROR = "http://downloads.sourceforge.net"
 559 XLIBS_MIRROR = "http://xlibs.freedesktop.org/release"
 560 XORG_MIRROR = "http://xorg.freedesktop.org/releases"
 561
 562 # You can use the mirror of your country to get faster downloads by putting
 563 #  export DEBIAN_MIRROR = "ftp://ftp.de.debian.org/debian/pool"
 564 #     into your local.conf
 565
 566 FETCHCMD_svn = "/usr/bin/env svn"
 567 FETCHCMD_cvs = "/usr/bin/env cvs"
 568 FETCHCMD_wget = "/usr/bin/env wget -t 5 --no-check-certificate"
 569 FETCHCMD_bzr = "/usr/bin/env bzr"
 570 FETCHCMD_hg = "/usr/bin/env hg"
 571
 572 FETCHCOMMAND = "ERROR, this must be a BitBake bug"
 573 FETCHCOMMAND_wget = "/usr/bin/env 'PATH=${PATH}' wget -t 5 --passive-ftp --no-check-certificate -P ${DL_DIR} '${URI}'"
 574 FETCHCOMMAND_cvs = "/usr/bin/env 'PATH=${PATH}' cvs '-d${CVSROOT}' co ${CVSCOOPTS} ${CVSMODULE}"
 575 FETCHCOMMAND_svn = "/usr/bin/env svn co ${SVNCOOPTS} ${SVNROOT} ${SVNMODULE}"
 576 RESUMECOMMAND = "ERROR, this must be a BitBake bug"
 577 RESUMECOMMAND_wget = "/usr/bin/env 'PATH=${PATH}' wget -c -t 5 --passive-ftp --no-check-certificate -P ${DL_DIR} '${URI}'"
 578 UPDATECOMMAND = "ERROR, this must be a BitBake bug"
 579 UPDATECOMMAND_cvs = "/usr/bin/env 'PATH=${PATH}' cvs -d${CVSROOT} update -d -P ${CVSCOOPTS}"
 580 UPDATECOMMAND_svn = "/usr/bin/env svn update ${SVNCOOPTS}"
 581 SRCDATE = "${DATE}"
 582 SRCREV = "1"
 583 SRCPV = "${@bb.fetch.get_srcrev(d)}"
 584 AUTOREV = "${SRCPV}"
 585
 586 SRC_URI = "file://${FILE}"
 587
 588 ##################################################################
 589 # UI/Interaction Configuration
 590 ##################################################################
 591
 592 SHELLRCCMD = "bash --rcfile $TERMRCFILE"
 593 export SHELLCMDS = "${SHELLRCCMD}"
 594 # Some common terminal programs to choose from
 595 GNOME_TERMCMD = 'gnome-terminal --disable-factory -t "$TERMWINDOWTITLE"'
 596 GNOME_TERMCMDRUN = '${GNOME_TERMCMD} -x $SHELLCMDS'
 597 SCREEN_TERMCMD = 'screen -D -m -t "$TERMWINDOWTITLE"'
 598 SCREEN_TERMCMDRUN = '${SCREEN_TERMCMD} $SHELLCMDS'
 599 XTERM_TERMCMD = 'xterm -T "$TERMWINDOWTITLE"'
 600 XTERM_TERMCMDRUN = '${XTERM_TERMCMD} -e $SHELLCMDS'
 601 KONSOLE_TERMCMD = 'konsole -T "$TERMWINDOWTITLE"'
 602 KONSOLE_TERMCMDRUN = '${KONSOLE_TERMCMD} -e $SHELLCMDS'
 603
 604 # Set a default
 605 TERMCMD ?= "${GNOME_TERMCMD}"
 606 TERMCMDRUN ?= "${GNOME_TERMCMDRUN}"
 607
 608 ##################################################################
 609 # Miscellaneous utilities.
 610 ##################################################################
 611
 612 MKTEMPDIRCMD = "mktemp -d -q ${TMPBASE}"
 613 MKTEMPCMD = "mktemp -q ${TMPBASE}"
 614
 615 # GNU patch tries to be intellgent about checking out read-only files from
 616 # a RCS, which freaks out those special folks with active Perforce clients
 617 # the following makes patch ignore RCS:
 618
 619 export PATCH_GET="0"
 620
 621 # Program to be used to build ipkg packages
 622
 623 IPKGBUILDCMD = "ipkg-build -o 0 -g 0"
 624
 625 ##################################################################
 626 # Not sure about the rest of this yet.
 627 ##################################################################
 628
 629 # slot - currently unused by OE. portage remnants
 630 SLOT = "0"
 631
 632 # Other
 633
 634 export PKG_CONFIG_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}${libdir}/pkgconfig"
 635 export PKG_CONFIG_PATH = "${PKG_CONFIG_DIR}:${STAGING_DATADIR}/pkgconfig"
 636 export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 637 export PKG_CONFIG_DISABLE_UNINSTALLED = "yes"
 638
 639 export XDG_DATA_DIRS = "${STAGING_DATADIR}"
 640
 641 export QMAKE_MKSPEC_PATH = "${STAGING_DATADIR_NATIVE}/qmake"
 642 export STAGING_SIPDIR = "${STAGING_DATADIR_NATIVE}/sip"
 643 export STAGING_IDLDIR = "${STAGING_DATADIR}/idl"
 644
 645 # library package naming
 646 AUTO_LIBNAME_PKGS = "${PACKAGES}"
 647
 648 # Globally toggle certain dependencies
 649 ENTERPRISE_DISTRO ?= "0"
 650
 651 # Pre-build configuration output
 652
 653 BUILDCFG_HEADER = "Build Configuration:"
 654 BUILDCFG_VARS ?= "BB_VERSION METADATA_BRANCH METADATA_REVISION TARGET_ARCH TARGET_OS MACHINE DISTRO DISTRO_VERSION"
 655 BUILDCFG_VARS_append_arm = " TARGET_FPU"
 656 BUILDCFG_VARS_append_armeb = " TARGET_FPU"
 657 BUILDCFG_NEEDEDVARS ?= "TARGET_ARCH TARGET_OS"
 658
 659 ###
 660 ### Config file processing
 661 ###
 662
 663 # Overrides are processed left to right, so the ones that are named later take precedence.
 664 # You generally want them to go from least to most specific.
 665 #
 666 # This means that an envionment variable named '<foo>_arm' overrides an
 667 # environment variable '<foo>' (when ${TARGET_ARCH} is arm).
 668 # an environment variable '<foo>_ramses' overrides '<foo>' but doesn't override
 669 # '<foo>_arm' when ${MACHINE} is 'ramses'.
 670 # If you use combination ie '<foo>_arm_ramses', then '<foo>_arm_ramses' will override
 671 # '<foo>_arm' and then '<foo>' will be overriden with that value from '<foo>_arm'.
 672 # And finally '<foo>_local' overrides anything, but with lowest priority.
 673 #
 674 # This works for  functions as well, they are really just environment variables.
 675 # Default OVERRIDES to make compilation fail fast in case of build system misconfiguration.
 676 OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:fail-fast:pn-${PN}"
 677 # Alternative OVERRIDES definition without "fail fast", usually only for native building and Scratchbox toolchains.
 678 #OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:pn-${PN}"
 679
 680 ##################################################################
 681 # Include the rest of the config files.
 682 ##################################################################
 683
 684 require conf/collections.inc
 685 include conf/site.conf
 686 include conf/auto.conf
 687 include conf/local.conf
 688 # USERDISTRO should always contain original DISTRO value as set by user
 689 # If a distro config overrides DISTRO for whatever reason (e.g. to get
 690 # overrides like it wants), USERDISTRO must be reassigned with := first
 691 USERDISTRO = "${DISTRO}"
 692 include conf/build/${BUILD_SYS}.conf
 693 include conf/target/${TARGET_SYS}.conf
 694 include conf/machine/${MACHINE}.conf
 695 include conf/distro/${DISTRO}.conf
 696 include conf/documentation.conf
 697 require conf/sanity.conf
 698 require conf/abi_version.conf
 699 require conf/enterprise.conf
 700 require conf/compatibility-providers.conf
 701
 702 ##################################################################
 703 # Weak variables (usually to retain backwards compatibility)
 704 ##################################################################
 705
 706 DL_DIR ?= "${TMPDIR}/downloads"
 707 IMAGE_FSTYPES ?= "tar.gz"
 708 PCMCIA_MANAGER ?= "pcmcia-cs"
 709 DEFAULT_TASK_PROVIDER ?= "task-base"
 710 MACHINE_TASK_PROVIDER ?= "${DEFAULT_TASK_PROVIDER}"
 711 IMAGE_ROOTFS_SIZE ?= "65536"
 712 IMAGE_ROOTFS_SIZE_ext2 ?= "65536"
 713 IMAGE_ROOTFS_SIZE_ext2.gz ?= "65536"
 714 IMAGE_ROOTFS_SIZE_ext3 ?= "65536"
 715 IMAGE_ROOTFS_SIZE_ext3.gz ?= "65536"
 716 DISTRO_PR ?= ""
 717
 718 # Forcefully set CACHE now so future changes to things like
 719 # MACHINE don't change the path to the cache
 720 CACHE := "${CACHE}"
 721
 722 # Default to disabling packaged staging code
 723 export PSTAGING_ACTIVE = "0"
 724
 725 ##################################################################
 726 # Magic Cookie for SANITY CHECK
 727 ##################################################################
 728 OES_BITBAKE_CONF = "1"
 729
 730 ##################################################################
 731 # Machine properties and task-base stuff
 732 ##################################################################
 733
 734 MACHINE_FEATURES ?= "kernel26"
 735 DISTRO_FEATURES ?= ""
 736
 737 # This is used to limit what packages goes into images built, so set big by default
 738 ROOT_FLASH_SIZE ?= "256"
 739
 740 MACHINE_GUI_CLASS ?= "smallscreen"
 741 # GUI_MACHINE_CLASS is deprecated, please use MACHINE_GUI_CLASS instead
 742 GUI_MACHINE_CLASS ?= "${MACHINE_GUI_CLASS}"
 743 MACHINE_DISPLAY_WIDTH_PIXELS ?= "240"
 744 MACHINE_DISPLAY_HEIGHT_PIXELS ?= "320"
 745 MACHINE_DISPLAY_ORIENTATION ?= "0"
 746 MACHINE_DISPLAY_BPP ?= "16"
 747
 748 DISTRO_EXTRA_RDEPENDS ?= ""
 749 DISTRO_EXTRA_RRECOMMENDS ?= ""
 750 MACHINE_EXTRA_RDEPENDS ?= ""
 751 MACHINE_EXTRA_RRECOMMENDS ?= ""
 752 MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
 753 MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
 754
 755 COMBINED_FEATURES = "\
 756     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "alsa", d)} \
 757     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "bluetooth", d)} \
 758     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "ext2", d)} \
 759     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "vfat", d)} \
 760     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "irda", d)} \
 761     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pcmcia", d)} \
 762     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pci", d)} \
 763     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbgadget", d)} \
 764     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbhost", d)} \
 765     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "wifi", d)}"
 766
 767 # We want madwifi if all of the following are true:
 768 # - distro has pci, wifi, and madwifi in its features
 769 # - machine has pci in its features
 770 COMBINED_FEATURES += "${@base_ifelse( \
 771     base_contains('DISTRO_FEATURES', ('pci', 'wifi', 'madwifi'), True, False, d) and \
 772     base_contains('MACHINE_FEATURES', 'pci', True, False, d), \
 773     'madwifi', '')}"
 774
 775 # We want hostap if all of the following are true:
 776 # - 'wifi' and 'hostap' are in distro features
 777 # - either 'pci' or 'pcmcia' are in both distro and machine features
 778 COMBINED_FEATURES += "${@base_ifelse( \
 779     base_contains('DISTRO_FEATURES', ('wifi', 'hostap'), True, False, d) and \
 780     ((base_contains('MACHINE_FEATURES', 'pci', True, False, d) and \
 781       base_contains('DISTRO_FEATURES', 'pci', True, False, d)) or \
 782      (base_contains('MACHINE_FEATURES', 'pcmcia', True, False, d) and \
 783       base_contains('DISTRO_FEATURES', 'pcmcia', True, False, d))), \
 784     'hostap', '')}"
 785
 786 # Make sure MACHINE isn't exported
 787 # (breaks binutils at least)
 788 MACHINE[unexport] = "1"
 789
 790 # Make sure TARGET_ARCH isn't exported
 791 # (breaks Makefiles using implicit rules, e.g. quilt, as GNU make has this
 792 # in them, undocumented)
 793 TARGET_ARCH[unexport] = "1"
 794
 795 # Make sure DISTRO isn't exported
 796 # (breaks sysvinit at least)
 797 DISTRO[unexport] = "1"
 798