classes/rootfs_ipk.bbclass

   1 #
   2 # Creates a root filesystem out of IPKs
   3 #
   4 # This rootfs can be mounted via root-nfs or it can be put into an cramfs/jffs etc.
   5 # See image.bbclass for a usage of this.
   6 #
   7
   8 do_rootfs[depends] += "opkg-native:do_populate_sysroot"
   9 do_rootfs[lockfiles] = "${DEPLOY_DIR_IPK}.lock"
  10
  11 IPKG_TMP_DIR = "${IMAGE_ROOTFS}-tmp"
  12 IPKG_ARGS = "-f ${IPKGCONF_TARGET} -o ${IMAGE_ROOTFS} -t ${IPKG_TMP_DIR} ${@base_conditional("PACKAGE_INSTALL_NO_DEPS", "1", "-nodeps", "", d)}"
  13
  14 PACKAGE_INSTALL_NO_DEPS ?= "0"
  15
  16 # What support to provide for online management of packages at run time?
  17 #  full -> traditional system, opkg is installed with all metadata
  18 #  add -> opkg is installed with basic conf files but no status database; can add new packages at runtime but not modify existing ones
  19 #  none -> opkg not installed at all, no metadata or config files provided
  20 ONLINE_PACKAGE_MANAGEMENT ?= "full"
  21
  22 # Which packages to not install on the basis of a recommendation
  23 BAD_RECOMMENDATIONS ?= ""
  24
  25 IPKG_VARIANT ?= "opkg"
  26
  27 RDEPENDS_append = " ${@base_conditional("ONLINE_PACKAGE_MANAGEMENT", "none", "", "${IPKG_VARIANT} opkg-collateral", d)}"
  28 PACKAGE_INSTALL_append = " ${@base_conditional("ONLINE_PACKAGE_MANAGEMENT", "none", "", "${IPKG_VARIANT} opkg-collateral", d)}"
  29
  30 fakeroot rootfs_ipk_do_rootfs () {
  31         set -x
  32
  33         package_generate_ipkg_conf
  34
  35         mkdir -p ${T}
  36         mkdir -p ${IPKG_TMP_DIR}
  37         mkdir -p ${IMAGE_ROOTFS}${libdir}/opkg/
  38
  39         STATUS=${IMAGE_ROOTFS}${libdir}/opkg/status
  40         # prime the status file with bits that we don't want
  41         for i in ${BAD_RECOMMENDATIONS}; do
  42                 echo "Package: $i" >> $STATUS
  43                 echo "Architecture: ${TARGET_ARCH}" >> $STATUS
  44                 echo "Status: deinstall hold not-installed" >> $STATUS
  45                 echo >> $STATUS
  46         done
  47
  48         opkg-cl ${IPKG_ARGS} update
  49
  50         if [ ! -z "${PACKAGE_INSTALL}" ]; then
  51                 opkg-cl ${IPKG_ARGS} install ${PACKAGE_INSTALL}
  52         fi
  53         if [ ! -z "${PACKAGE_INSTALL_ATTEMPTONLY}" ]; then
  54                 for i in ${PACKAGE_INSTALL_ATTEMPTONLY}; do
  55                         opkg-cl ${IPKG_ARGS} install $i 2>&1 || true
  56                 done > ${T}/log.do_rootfs-attemptonly.${PID}
  57         fi
  58
  59         export D=${IMAGE_ROOTFS}
  60         export OFFLINE_ROOT=${IMAGE_ROOTFS}
  61         export IPKG_OFFLINE_ROOT=${IMAGE_ROOTFS}
  62         export OPKG_OFFLINE_ROOT=${IPKG_OFFLINE_ROOT}
  63
  64         if [ "${ONLINE_PACKAGE_MANAGEMENT}" != "none" ]; then
  65                 mkdir -p ${IMAGE_ROOTFS}${sysconfdir}/opkg/
  66                 grep "^arch" ${IPKGCONF_TARGET} >${IMAGE_ROOTFS}${sysconfdir}/opkg/arch.conf
  67         fi
  68
  69         for i in ${IMAGE_ROOTFS}${libdir}/opkg/info/*.preinst; do
  70                 if [ -f $i ] && ! sh -e $i; then
  71                         opkg-cl ${IPKG_ARGS} flag unpacked `basename $i .preinst`
  72                 fi
  73         done
  74         for i in ${IMAGE_ROOTFS}${libdir}/opkg/info/*.postinst; do
  75                 if [ -f $i ] && ! sh -e $i configure; then
  76                         opkg-cl ${IPKG_ARGS} flag unpacked `basename $i .postinst`
  77                 fi
  78         done
  79
  80         install -d ${IMAGE_ROOTFS}/${sysconfdir}
  81         echo ${BUILDNAME} > ${IMAGE_ROOTFS}/${sysconfdir}/version
  82
  83         ${ROOTFS_POSTPROCESS_COMMAND}
  84
  85         if [ "${ONLINE_PACKAGE_MANAGEMENT}" != "none" ]; then
  86                 if [ "${ONLINE_PACKAGE_MANAGEMENT}" = "add" ]; then
  87                         rm -f ${IMAGE_ROOTFS}${libdir}/opkg/status
  88                         rm -f ${IMAGE_ROOTFS}${libdir}/opkg/*/*
  89                 else
  90                         rm -f ${IMAGE_ROOTFS}${libdir}/opkg/lists/*
  91                 fi
  92
  93                 # Remove lists, but leave SHR's tmp dir if it exists.
  94                 rm -f ${IMAGE_ROOTFS}/var/lib/opkg/* || true
  95
  96                 # Keep these lines until package manager selection is implemented
  97                 ln -s opkg ${IMAGE_ROOTFS}${sysconfdir}/ipkg
  98                 ln -s opkg ${IMAGE_ROOTFS}${libdir}/ipkg
  99         else
 100                 rm -rf ${IMAGE_ROOTFS}${libdir}/opkg
 101                 rm -rf ${IMAGE_ROOTFS}/usr/lib/opkg
 102                 rm -rf ${IMAGE_ROOTFS}/var/lib/opkg
 103         fi
 104
 105         log_check rootfs
 106         rm -rf ${IPKG_TMP_DIR}
 107
 108         if [ "${ONLINE_PACKAGE_MANAGEMENT}" != "none" ]; then
 109                 rootfs_ipk_insert_feed_uris
 110         fi
 111 }
 112
 113 rootfs_ipk_insert_feed_uris () {
 114
 115         echo "Building feeds for [${DISTRO}].."
 116
 117         for line in ${FEED_URIS}
 118         do
 119                 # strip leading and trailing spaces/tabs, then split into name and uri
 120                 line_clean="`echo "$line"|sed 's/^[ \t]*//;s/[ \t]*$//'`"
 121                 feed_name="`echo "$line_clean" | sed -n 's/\(.*\)##\(.*\)/\1/p'`"
 122                 feed_uri="`echo "$line_clean" | sed -n 's/\(.*\)##\(.*\)/\2/p'`"
 123
 124                 echo "Added $feed_name feed with URL $feed_uri"
 125
 126                 # insert new feed-sources
 127                 echo "src/gz $feed_name $feed_uri" >> ${IMAGE_ROOTFS}/etc/opkg/${feed_name}-feed.conf
 128         done
 129
 130         # Allow to use package deploy directory contents as quick devel-testing
 131         # feed. This creates individual feed configs for each arch subdir of those
 132         # specified as compatible for the current machine.
 133         # NOTE: Development-helper feature, NOT a full-fledged feed.
 134         if [ -n "${FEED_DEPLOYDIR_BASE_URI}" ]; then
 135             for arch in ${PACKAGE_ARCHS}
 136             do
 137                 echo "src/gz local-$arch ${FEED_DEPLOYDIR_BASE_URI}/$arch" >> ${IMAGE_ROOTFS}/etc/opkg/local-$arch-feed.conf
 138             done
 139         fi
 140 }
 141
 142
 143 rootfs_ipk_log_check() {
 144         target="$1"
 145         lf_path="$2"
 146
 147         lf_txt="`cat $lf_path`"
 148         for keyword_die in "Cannot find package" "Cannot satisfy the following dependencies" \
 149             "exit 1" ERR Fail
 150         do
 151                 if (echo "$lf_txt" | grep -v log_check | grep -w "$keyword_die") >/dev/null 2>&1
 152                 then
 153                         echo "log_check: There were error messages in the logfile"
 154                         printf "log_check: Matched keyword: [$keyword_die]\n"
 155                         echo "$lf_txt" | grep -v log_check | grep -i "$keyword_die" -C1
 156                         echo ""
 157                         do_exit=1
 158                 fi
 159         done
 160         test "$do_exit" = 1 && exit 1
 161         true
 162 }
 163
 164 remove_packaging_data_files() {
 165         rm -rf ${IMAGE_ROOTFS}${libdir}/opkg/
 166 }